// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
interface Aggregator {
    function latestRoundData()
        external
        view
        returns (
            uint80 roundId,
            int256 answer,
            uint256 startedAt,
            uint256 updatedAt,
            uint80 answeredInRound
        );
}

interface ITaskChainPresale {
    function getAvailableTokensInStage() external view returns(uint256);
    function tokensBought(address _user) external view returns(uint256);
    function tokensSoldPerStage(uint256 _stage) external view returns(uint256);

}

contract TaskChainPresaleV2 is Ownable, ReentrancyGuard, Pausable {
    using SafeERC20 for IERC20;
    // Addresses for the various roles in the contract
    address private fundsAddress;
    address private tokenHolderAddress;
    address public saleTokenAddress =
        0x4C2e29dbc437C4b781963E5B2B393b1D4ea64b19;

    // Tokens and prices per stage
    uint256[11] public tokensInStages;
    uint256[11] public pricePerStage;

    // The token balance for each buyer
    mapping(address => uint256) public tokensBought;

    // Track which buyers have claimed their tokens
    mapping(address => bool) public tokensClaimed;
    mapping(uint256 => uint256) public tokensSoldPerStage;

    // Interfaces for the USDT token and the oracle price feed
    IERC20 public usdt;
    Aggregator public priceFeed;

    // Track whether claims are active and the current sale stage
    bool public claimActive;
    Stages public stage;

    ITaskChainPresale public taskChainPresaleV1 = ITaskChainPresale(0x49afa06E429f3Fd5B28Dd2980D673B72eD5dbf28);

    bool public isDataTransfferedFromV1;

    mapping(address => bool) public isUserDataTransfferedFromV1;

    // Stages of the sale
    enum Stages {
        BETA_STAGE,
        STAGE_1,
        STAGE_2,
        STAGE_3,
        STAGE_4,
        STAGE_5,
        STAGE_6,
        STAGE_7,
        STAGE_8,
        STAGE_9,
        STAGE_10
    }

    // Events to be emitted by the contract
    event claimStart(bool claimActive);
    event TokenBought(address indexed buyer, uint256 amount, uint256 timestamp);
    event TokensClaimed(
        address indexed claimer,
        uint256 amount,
        uint256 timestamp
    );

    /**
     * @dev Constructor for the presale contract
     * @param _usdt address to send USDT token
     * @param _oracle Oracle contract to fetch ETH/USDT price
     */

    constructor(
        address _usdt,
        address _oracle
    ) ReentrancyGuard() nonZeroAddress(_usdt) nonZeroAddress(_oracle) {
        usdt = IERC20(_usdt);
        priceFeed = Aggregator(_oracle);

        tokenHolderAddress = 0xc493fD92b08579682935520e9779Ee71CbD29A09;
        fundsAddress = 0xC35A5df1Bc74C7e96AfA6e047890f46459369743; 
        claimActive = false;
        stage = Stages.BETA_STAGE;
        tokensInStages = [
            280_000_000,
            300_000_000,
            300_000_000,
            200_000_000,
            200_000_000,
            200_000_000,
            200_000_000,
            200_000_000,
            200_000_000,
            360_000_000,
            360_000_000
        ];
        pricePerStage = [
            4000_000_000_000_000,
            5000_000_000_000_000,
            5200_000_000_000_000,
            5500_000_000_000_000,
            5700_000_000_000_000,
            6000_000_000_000_000,
            6500_000_000_000_000,
            8000_000_000_000_000,
            8500_000_000_000_000,
            9000_000_000_000_000,
            9500_000_000_000_000
        ];
    }

    modifier claimable() {
        require(claimActive == true, "Claiming is not active yet.");
        _;
    }

    modifier nonZeroAddress(address _addr) {
        require(_addr != address(0), "Address can't be zero");
        _;
    }

    /**
     * @dev buyTokenWithETH allows users to buy tokens with ETH
     * @param _tokenAmount total number of tokens user wants to buy
     */

    function buyTokenWithETH(
        uint256 _tokenAmount
    ) external payable nonReentrant whenNotPaused {
        require(_tokenAmount > 0, "Cannot buy zero tokens.");
        require(
            _tokenAmount <= getAvailableTokensInStage(),
            "Insufficient tokens available."
        );

        uint256 ethCost = calculateEthCost(_tokenAmount);
        require(msg.value >= ethCost, "Not enough ETH sent.");
        // Calculate excess ETH by user
        uint256 excessAmount = msg.value - ethCost;

        // Refund the excess ETH to the buyer
        if (excessAmount > 0) {
            (bool successTransferExcess, ) = payable(msg.sender).call{
                value: excessAmount
            }("");
            require(
                successTransferExcess,
                "Failed to send ETH to funds address."
            );
        }
        saveData(_tokenAmount);

        (bool success, ) = payable(fundsAddress).call{value: ethCost}("");
        require(success, "Failed to send ETH to funds address.");

        emit TokenBought(msg.sender, _tokenAmount, block.timestamp);
    }

    /**
     * @dev buyTokenWithUSDT allows users to buy tokens with USDT
     * @param _tokenAmount total number of tokens user wants to buy
     */

    function buyTokenWithUSDT(
        uint256 _tokenAmount
    ) public nonReentrant whenNotPaused {
        require(_tokenAmount > 0, "Cannot buy zero tokens.");
        require(
            _tokenAmount <= getAvailableTokensInStage(),
            "Insufficient tokens available."
        );
        uint256 usdtCost = calculateUsdtCost(_tokenAmount);
          
        saveData(_tokenAmount);

        usdt.safeTransferFrom(msg.sender, fundsAddress, usdtCost);

        emit TokenBought(msg.sender, _tokenAmount, block.timestamp);
    }

    /**
     * @dev claimTokens allows users to claim tokens after the sale is over
     */
     
    function claimTokens() external claimable nonReentrant {

        uint256 _tokensBought = getBoughtTokensAmount(msg.sender);

        require(
            _tokensBought > 0,
            "You have not bought any tokens."
        );
        require(
            !tokensClaimed[msg.sender],
            "You have already claimed your tokens."
        );
        tokensClaimed[msg.sender] = true;
        IERC20(saleTokenAddress).transferFrom(
            tokenHolderAddress,
            msg.sender,
            _tokensBought * 10 ** 18
        );
        emit TokensClaimed(msg.sender, _tokensBought, block.timestamp);
    }

    /**
     * @dev calculateEthCost helper function to calculate ETH cost for a given token amount
     */

    function calculateEthCost(
        uint256 _tokenAmount
    ) public view returns (uint256) {
        uint256 price = pricePerStage[uint256(stage)];
        (, int256 priceETH, , , ) = priceFeed.latestRoundData();
        uint256 ethCost = (_tokenAmount * price * 10 ** 18) /
            (uint256(priceETH) * 10 ** 10);
        return ethCost;
    }

    /**
     * @dev EthToTokenHelper function to calculate ETH cost for a given token amount
     */
    function EthToTokenHelper(uint _ethAmount) public view returns (uint256) {
        uint256 price = pricePerStage[uint256(stage)];
        (, int256 priceETH, , , ) = priceFeed.latestRoundData();
        uint256 tokenAmount = (_ethAmount * uint256(priceETH) * 10 ** 10) /
            (price * 10 ** 18);
        return tokenAmount;
    }

    /**
     * @dev USDTToTokenHelper function to calculate ETH cost for a given token amount
     */
    function USDTToTokenHelper(uint _usdtAmount) public view returns (uint256) {
        uint256 price = pricePerStage[uint256(stage)];
        uint256 tokenAmount = (_usdtAmount * 10 ** 12) / price;
        return tokenAmount;
    }

    /**
     * @dev calculateUsdtCost helper function to calculate UST cost for a given token amount
     */

    function calculateUsdtCost(
        uint256 _tokenAmount
    ) public view returns (uint256) {
        uint256 price = pricePerStage[uint256(stage)];
        uint256 usdtCost = (_tokenAmount * price) / (10 ** 12);
        return usdtCost;
    }
    
    function getAvailableTokensInStage() public view returns (uint256) {
        if(!isDataTransfferedFromV1){
            return taskChainPresaleV1.getAvailableTokensInStage();
        }else{
            return tokensInStages[uint256(stage)] - tokensSoldPerStage[uint256(stage)];
        }
    }
    
    function getBoughtTokensAmount(address _user) public view returns(uint256){
        if(!isUserDataTransfferedFromV1[_user]){
            return taskChainPresaleV1.tokensBought(_user);
        }else{
            return tokensBought[_user];
        }
    }

    function getSoldTokensInCurrentStage() public view returns(uint256){
        if(!isDataTransfferedFromV1){
            return taskChainPresaleV1.tokensSoldPerStage(uint256(stage));
        }else{
            return tokensSoldPerStage[uint256(stage)];
        }
    }

     /**
     * @dev checks data from V1 and rewrites it on V2 if necessary 
     */
     function saveData(uint256 _tokenAmount) internal {
        if(!isDataTransfferedFromV1){
            // Only first transaction should pass through this scope
            uint256 soldOnV1 = taskChainPresaleV1.tokensSoldPerStage(uint256(stage));
            tokensSoldPerStage[uint256(stage)] = soldOnV1 + _tokenAmount;
            isDataTransfferedFromV1 = true;
        }else{
            tokensSoldPerStage[uint256(stage)] += _tokenAmount;
        }

        if(!isUserDataTransfferedFromV1[msg.sender]){
            // Only first transaction of user should pass through this scope
            uint256 tokensBoughtOnV1 = taskChainPresaleV1.tokensBought(msg.sender);
            tokensBought[msg.sender] = tokensBoughtOnV1 + _tokenAmount;

            isUserDataTransfferedFromV1[msg.sender] = true;
        }else{
            tokensBought[msg.sender] += _tokenAmount;
        }
     }

    /**
     * @dev setFundsAddress allows owner to set the funds address
     * @param _fundsAddress address of the funds address
     */
    function setFundsAddress(
        address _fundsAddress
    ) external onlyOwner nonZeroAddress(fundsAddress) {
        fundsAddress = _fundsAddress;
    }

    /**
     * @dev setTokenHolder allows owner to set the token holder address
     * @param _tokenHolder address of the token holder
     */

    function setTokenHolder(
        address _tokenHolder
    ) external onlyOwner nonZeroAddress(_tokenHolder) {
        tokenHolderAddress = _tokenHolder;
    }


    /**
     * @dev switchStage allows owner to switch to the next stage
     */

    function switchStage() external onlyOwner {
        require(
            uint256(stage) >= 0 && uint256(stage) <= 10,
            "Invalid stage transition."
        );

        require(isDataTransfferedFromV1, "Transfer data from V1");

        // If it's not the first stage, move the remaining tokens to the next stage
        if (uint256(stage) >= 0 && uint256(stage) <= 9) {
            uint256 remainingTokens = tokensInStages[uint256(stage)] -
                tokensSoldPerStage[uint256(stage)];

            tokensInStages[uint256(stage) + 1] += remainingTokens;
        }

        // Move to the next stage
        stage = Stages(uint256(stage) + 1);
    }

    /**
     * @dev startClaim allows owner to start the claiming process
     */

    function startClaim() external onlyOwner {
        claimActive = true;
        emit claimStart(claimActive);
    }

    /**
     * @dev pauseContract allows owner to pause the contract
     */

    function pauseContract() external onlyOwner {
        _pause();
    }

    /**
     * @dev unpauseContract allows owner to unpause the contract
     */

    function unpauseContract() external onlyOwner {
        _unpause();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "compilationTarget": {
    "contracts/TaskChainPresaleV2.sol": "TaskChainPresaleV2"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}