Multi Stable DZAR MultiToken V1

/*
                                             ,╓╦╦#▒▒▒▒ÅÅ▀╝╝╝╝Φê#╦╗╓
                                        ,╦▒▒▀╙`                       `
                                      ╔╣╜                  `"─q╖
                                    ╔╝     ,╔∩                    "%╗,
                                   ╬     ╔╣╬                          "Φ╦
                                 ,╩    ,▒╬╬                              ╙╦
                                 ╩     ╬╬╬▌                                ╙⌐
                                ║     ▐╬╬╬Γ                                 ╙
                           ┌    ╬     ║╬╬╬Γ                                          ⌐
                           Γ    ╬     ▐╬╬╬▌                                          ▐
                           ⌐    ╚▒     ╬╬╬╬                                          ]
                           ⌐     ╣▒    `▒╬╬▒                                         ]
                           ╕      ▒╬╦    "▀╬╬▒,                                      ║
                           ╬       ╟╬╬▒╖      `╙╚▒╦╗,                                ╬
                           ╫        `╫╬╬╬╬▒▒#╦╖    `╙▀▒▒╗,            ,╔#▒▒╩         ╬
                           ▐           "╙▀╣╬╬╬╬╬╬▒╗,              ╓@▒╬▒▀╜^           Γ
                                             `╙▒╬╬╬╬╬▒,        ╦╣▒╜
                               ,╖╦»-.            ╙╣╬╬╬╬▒╗, ,╓╣▒"            .-«╗╖
                              ▒╬  ╓╗╗╦╓             ╚╬╬╬╬╬╬╬╩            .╓╗╦╗,  ╬▒
                              ╬╬ ╣╬╬╬╬╬╬▒╩            ╙╬╬╬╜            ║╣╬╬╬╬╬╬▌ ╬╬
                              ╟╬▒ ╬╬╬╬╬╬Γ ║▒╬▒╦,                 ╓#▒╬▒╦ ]╬╬╬╬╬▒ ▒╬▌
                               ╬╬╕ ╬╬╬╬╬ ]╬╬╬╬╬╬╬▒╗,   ╓▒╖  ,╓╦╣╬╬╬╬╬╬╬  ╬╬╬╬╬ ╣╬╬
                               ╬╬Σ ╬╬╬╬╬⌐║╬╬╬╬╬╬╬╬╬╬╬╬╬▌"╣╬╬╬╬╬╬╬╬╬╬╬╬╬▒]╬╬╬╬╬ ╬╬╬
                               ╬╬∩]╬╬╬╬╬b╬╬╬╬╬╬╬╬╬╬▀╬╬▒   ▒▀╬▀╬╬╬╬╬╬╬╬╬╬║╬╬╬╬╬ ║╬╬
                               ╬╬╦ ╚╬╬╬╬╬╬╬╬╬╬╬▀╙╓@╬ `     `└▒╗⌠╙▀╬╬╬╬╬╬╬╬╬╬╬╩ ╣╬╬
                               ╬╬╬╦  `"""`` ,╓╦▒▀╠▀           ╚╬╢▒╦,  `""""   ╣╬╬╬
                                ╣╬╬╬▒###▒▒▒╬▀╙ ',╓ê▒╣▀╜╙"``""ⁿ─ `¬ ╙▀╬▒▒▒##▒╣╬╬╬▀
                                  `"╙╙╙"`     ╔╣▀",╦≈┘""""╙≈╗,          `"╙╙╙"
                                        ,╓╗⌐╔▒╩╓∩`  ,╓╦  ╗╖,  `%╖ ╬╦.╗╖,
                                    ,╦╣╬╬╬ #╬,╩  ╔╣╬╬╬╬  ╬╬╬╬▒╗  ╚⌐╣▒ ╣╬╬▒╦,
                           ╓╦⌐╣╦ ╓@▒╬╬╬╬▀ ╔╬]╩ é╬╬╬╬╬╬╬  ╬╬╬╬╬╬╬╗ ╙∩╬╦ ╚╬╬╬╬╬▒╦ ╔╬ ╦╓
                      ,╓ê▒╬╬▒╩⌐  ╙╬╬╬╬╩   ╬▌╬ ╣╬╬╠╬╬╬╫╬  ╬╬╬╠╬╬╬╬▒ ╟║╬   ╙╬╬╬╬╩  ,╜╣╬╬▒▒╦
                  ,╦▒▒╬▒▀"              ╬ ╬╬Σ╒╬╬╬╬╬╬╬Ö#▒▒╦╙╬╬╬╬╬╬╬b╞╬╬ ╠              "╚▒╬╬▒╗,
                @╦ ▀╙                 ╔▒╬ ╟╬▌▐╬╬╬╬╬╬╩▐╬╬╬╬▌╙▒╬╬╬╬╬▌║╬╬ ╣╬╦                 ╙▀ ╔▒
                                    ╙╬╬╬╬╦ ╬╬∩╬╬▀"  ,╔╬╬╬╬╦,  `╚╬╬½╬╬ ╔╬╬╬╬╩
                                    ╔╙╬╬╬╬╗ ╣╬▄ ,╔@▒╬╬╬╬╬╬╠╬╬▒╦  ╓▒╬ é╬╬╬╬Γ╦
                              ,╓╦▒╬▒╙▒└╬╬▀`  ╙▒╬╬╬╬╬╬╬╬╬╬╬╬╬╬╠╬╬╬╬╜  `▀╬╬Γ╣╩#╬▒╦╦        ,
                       .  ╓╦▒╬╬╬╬╬╬╬▒╙▒        `╚╬╬╬╬╬╬╬╬╬╬╬╬╬╬▀`       `╣Γ╣╬╬╬╬╬╬╬▒╦╖  /
                      ╫ ╚╬╬╬╬╬╬╬╬╬╬╬╬▒└▒            "╙╨╨╨╨╙"            ╣Γ╣╬╬╬╬╬╬╬╬╬╬╬╬▀ ▒
                    `╦ ╬⌐╙╬╬╬╬╬╬╬╬╬╬╬╬▒⌐▒                              ╣Γ╣╬╬╬╬╬╬╬╬╬╬╬╬▀,▒ ╓`
                      % ╣╕╙╬╬╬╬╬╬╬╬╬╬╬╬▒∩▒                            ▒\╣╬╬╬╬╬╬╬╬╬╬╬╬╩,▒ #
                       ╙⌐╫╦└╬╬╬╬╬╬╬╬╬╬╬╬╬µ╣⌐                         ▒,▒╬╬╬╬╬╬╬╬╬╬╬╬Γ╓▒ ╩
                          ╟╦ ╬╬╬╬╬╬╬╬╬╬╬╬╬⌐                           ▒╬╬╬╬╬╬╬╬╬╬╬╬Γ╔▌
                           ╚╦ ▒╬╬╬╬╬╬▒╜`                                `╙╣╬╬╬╬╬╬╬ ╔▀
                            ╙▒ ╣╬▀╙                                          ╙▀╬╬ á▀


                    ███╗   ███╗██╗   ██╗██╗  ████████╗██╗███████╗██╗    ██╗ █████╗ ██████╗
                    ████╗ ████║██║   ██║██║  ╚══██╔══╝██║██╔════╝██║    ██║██╔══██╗██╔══██╗
                    ██╔████╔██║██║   ██║██║     ██║   ██║███████╗██║ █╗ ██║███████║██████╔╝
                    ██║╚██╔╝██║██║   ██║██║     ██║   ██║╚════██║██║███╗██║██╔══██║██╔═══╝
                    ██║ ╚═╝ ██║╚██████╔╝███████╗██║   ██║███████║╚███╔███╔╝██║  ██║██║
                    ╚═╝     ╚═╝ ╚═════╝ ╚══════╝╚═╝   ╚═╝╚══════╝ ╚══╝╚══╝ ╚═╝  ╚═╝╚═╝

         ██████╗ ██████╗ ██████╗ ██╗   ██╗██████╗ ██╗ ██████╗ ██╗  ██╗████████╗    ██████╗ ██╗   ██╗
        ██╔════╝██╔═══██╗██╔══██╗╚██╗ ██╔╝██╔══██╗██║██╔════╝ ██║  ██║╚══██╔══╝    ██╔══██╗╚██╗ ██╔╝
        ██║     ██║   ██║██████╔╝ ╚████╔╝ ██████╔╝██║██║  ███╗███████║   ██║       ██████╔╝ ╚████╔╝
        ██║     ██║   ██║██╔═══╝   ╚██╔╝  ██╔══██╗██║██║   ██║██╔══██║   ██║       ██╔══██╗  ╚██╔╝
        ╚██████╗╚██████╔╝██║        ██║   ██║  ██║██║╚██████╔╝██║  ██║   ██║       ██████╔╝   ██║
         ╚═════╝ ╚═════╝ ╚═╝        ╚═╝   ╚═╝  ╚═╝╚═╝ ╚═════╝ ╚═╝  ╚═╝   ╚═╝       ╚═════╝    ╚═╝

 ██████╗██████╗ ██╗   ██╗██████╗ ████████╗ ██████╗     ███╗   ███╗ █████╗ ███╗   ██╗██╗ █████╗  ██████╗███████╗
██╔════╝██╔══██╗╚██╗ ██╔╝██╔══██╗╚══██╔══╝██╔═══██╗    ████╗ ████║██╔══██╗████╗  ██║██║██╔══██╗██╔════╝██╔════╝
██║     ██████╔╝ ╚████╔╝ ██████╔╝   ██║   ██║   ██║    ██╔████╔██║███████║██╔██╗ ██║██║███████║██║     ███████╗
██║     ██╔══██╗  ╚██╔╝  ██╔═══╝    ██║   ██║   ██║    ██║╚██╔╝██║██╔══██║██║╚██╗██║██║██╔══██║██║     ╚════██║
╚██████╗██║  ██║   ██║   ██║        ██║   ╚██████╔╝    ██║ ╚═╝ ██║██║  ██║██║ ╚████║██║██║  ██║╚██████╗███████║
 ╚═════╝╚═╝  ╚═╝   ╚═╝   ╚═╝        ╚═╝    ╚═════╝     ╚═╝     ╚═╝╚═╝  ╚═╝╚═╝  ╚═══╝╚═╝╚═╝  ╚═╝ ╚═════╝╚══════╝
*/

// File: @openzeppelin/contracts/GSN/Context.sol

pragma solidity ^0.5.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
contract Context {
    // Empty internal constructor, to prevent people from mistakenly deploying
    // an instance of this contract, which should be used via inheritance.
    constructor () internal { }
    // solhint-disable-previous-line no-empty-blocks

    function _msgSender() internal view returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol

pragma solidity ^0.5.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP. Does not include
 * the optional functions; to access them see {ERC20Detailed}.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: @openzeppelin/contracts/math/SafeMath.sol

pragma solidity ^0.5.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     *
     * _Available since v2.4.0._
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol

pragma solidity ^0.5.0;




/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20Mintable}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for `sender`'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: mint to the zero address");

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

     /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: burn from the zero address");

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`.`amount` is then deducted
     * from the caller's allowance.
     *
     * See {_burn} and {_approve}.
     */
    function _burnFrom(address account, uint256 amount) internal {
        _burn(account, amount);
        _approve(account, _msgSender(), _allowances[account][_msgSender()].sub(amount, "ERC20: burn amount exceeds allowance"));
    }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20Detailed.sol

pragma solidity ^0.5.0;


/**
 * @dev Optional functions from the ERC20 standard.
 */
contract ERC20Detailed is IERC20 {
    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for `name`, `symbol`, and `decimals`. All three of
     * these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol, uint8 decimals) public {
        _name = name;
        _symbol = symbol;
        _decimals = decimals;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }
}

// File: @openzeppelin/contracts/utils/Address.sol

pragma solidity ^0.5.5;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * This test is non-exhaustive, and there may be false-negatives: during the
     * execution of a contract's constructor, its address will be reported as
     * not containing a contract.
     *
     * IMPORTANT: It is unsafe to assume that an address for which this
     * function returns false is an externally-owned account (EOA) and not a
     * contract.
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies in extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        // According to EIP-1052, 0x0 is the value returned for not-yet created accounts
        // and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned
        // for accounts without code, i.e. `keccak256('')`
        bytes32 codehash;
        bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470;
        // solhint-disable-next-line no-inline-assembly
        assembly { codehash := extcodehash(account) }
        return (codehash != 0x0 && codehash != accountHash);
    }

    /**
     * @dev Converts an `address` into `address payable`. Note that this is
     * simply a type cast: the actual underlying value is not changed.
     *
     * _Available since v2.4.0._
     */
    function toPayable(address account) internal pure returns (address payable) {
        return address(uint160(account));
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     *
     * _Available since v2.4.0._
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-call-value
        (bool success, ) = recipient.call.value(amount)("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
}

// File: @openzeppelin/contracts/token/ERC20/SafeERC20.sol

pragma solidity ^0.5.0;




/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves.

        // A Solidity high level call has three parts:
        //  1. The target address is checked to verify it contains contract code
        //  2. The call itself is made, and success asserted
        //  3. The return value is decoded, which in turn checks the size of the returned data.
        // solhint-disable-next-line max-line-length
        require(address(token).isContract(), "SafeERC20: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = address(token).call(data);
        require(success, "SafeERC20: low-level call failed");

        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// File: contracts/helpers/UniversalERC20.sol

pragma solidity ^0.5.0;




library UniversalERC20 {

    using SafeMath for uint256;
    using SafeERC20 for IERC20;

    IERC20 private constant ZERO_ADDRESS = IERC20(0x0000000000000000000000000000000000000000);
    IERC20 private constant ETH_ADDRESS = IERC20(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE);

    function universalTransfer(IERC20 token, address to, uint256 amount) internal {
        universalTransfer(token, to, amount, false);
    }

    function universalTransfer(IERC20 token, address to, uint256 amount, bool mayFail) internal returns(bool) {
        if (amount == 0) {
            return true;
        }

        if (token == ZERO_ADDRESS || token == ETH_ADDRESS) {
            if (mayFail) {
                return address(uint160(to)).send(amount);
            } else {
                address(uint160(to)).transfer(amount);
                return true;
            }
        } else {
            token.safeTransfer(to, amount);
            return true;
        }
    }

    function universalApprove(IERC20 token, address to, uint256 amount) internal {

        if (token != ZERO_ADDRESS && token != ETH_ADDRESS) {

            token.safeApprove(to, amount);
        }
    }

    function universalTransferFrom(IERC20 token, address from, address to, uint256 amount) internal {
        if (amount == 0) {
            return;
        }

        if (token == ZERO_ADDRESS || token == ETH_ADDRESS) {

            require(from == msg.sender && msg.value >= amount, "msg.value is less then expected");

            if (to != address(this)) {

                address(uint160(to)).transfer(amount);
            }

            if (msg.value > amount) {

                msg.sender.transfer(msg.value.sub(amount));
            }
        } else {

            token.safeTransferFrom(from, to, amount);
        }
    }

    function universalBalanceOf(IERC20 token, address who) internal view returns (uint256) {
        if (token == ZERO_ADDRESS || token == ETH_ADDRESS) {
            return who.balance;
        } else {
            return token.balanceOf(who);
        }
    }
}

// File: contracts/IMultiTokenArbitraryCallReceiver.sol

pragma solidity ^0.5.0;


interface IMultiTokenArbitraryCallReceiver {

    function handleFlashLoan(
        IERC20[] calldata tokens,
        uint256[] calldata amounts,
        uint256[] calldata fees,
        bytes calldata data
    ) external payable;
}

// File: contracts/MultiToken.sol

pragma solidity ^0.5.0;






contract MultiToken is ERC20, ERC20Detailed {

    using SafeMath for uint256;
    using UniversalERC20 for IERC20;

    IERC20[] public tokens;
    mapping(address => bool) public isSubToken;

    uint256 flashLoanIndex;

    bool public isShutdown = false;
    address public feeReceiver;
    address public owner;

    event Initialized(
        uint256 indexed mintAmount,
        uint256[] tokenAmounts
    );

    event Swapped(
        address indexed fromToken,
        address indexed toToken,
        address indexed who,
        uint256 amount,
        uint256 returnAmount
    );

    event FlashLoaned(
        uint256 indexed index,
        address indexed to,
        address indexed target
    );

    constructor(
        string memory name,
        string memory symbol,
        uint8 decimals,
        IERC20[] memory _tokens,
        address _owner,
        address _feeReceiver
    )
    public ERC20Detailed(name, symbol, decimals)
    {

        require(bytes(name).length > 0, "constructor: name should not be empty");
        require(bytes(symbol).length > 0, "constructor: symbol should not be empty");
        require(_tokens.length >= 2, "Contract does not support less than 2 inner tokens");

        tokens = _tokens;
        owner = _owner;
        feeReceiver = _feeReceiver;

        for (uint i = 0; i < tokens.length; i++) {

            isSubToken[address(tokens[i])] = true;

            for (uint j = 0; j < i; j++) {

                require(tokens[i] != tokens[j], "Only unique tokens are allowed");
            }
        }
    }

    function setFeeReceiver(address _feeReceiver) public {

        require(msg.sender == owner, "Only owner is allowed");
        feeReceiver = _feeReceiver;
    }

    function setOwner(address _owner) public {

        require(msg.sender == owner, "Only owner is allowed");
        owner = _owner;
    }

    function shutdown() public {

        require(msg.sender == owner, "Only owner is allowed");
        isShutdown = true;
    }

    function init(
        uint256 mintAmount,
        uint256[] memory tokenAmounts
    ) public payable {

        require(isShutdown == false, "Contract is shutdown");
        require(totalSupply() == 0, "Total supply should be zero");

        for (uint256 i = 0; i < tokens.length; i++) {

            require(tokenAmounts[i] != 0, "Token amount should be non-zero");

            tokens[i].universalTransferFrom(
                msg.sender,
                address(this),
                tokenAmounts[i]
            );
        }

        _mint(msg.sender, mintAmount);

        emit Initialized(
            mintAmount,
            tokenAmounts
        );
    }

    function tokensLength() public view returns (uint256) {

        return tokens.length;
    }

    function getSubTokens() public view returns (IERC20[] memory) {

        return tokens;
    }

    function mint(uint256 amount) public payable returns (bool) {

        require(amount < 1e27, "Max mint amount is 1e27");
        require(totalSupply() > 0, "Total supply should be bigger then zero");

        for (uint256 i = 0; i < tokens.length; i++) {

            uint256 tokenAmount;

            if (tokens[i] == IERC20(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)) {

                tokenAmount = tokens[i].universalBalanceOf(address(this)).sub(msg.value).mul(amount).div(totalSupply());
            } else {

                tokenAmount = tokens[i].universalBalanceOf(address(this)).mul(amount).div(totalSupply());
            }

            require(tokenAmount != 0, "Token amount should be non-zero");

            tokens[i].universalTransferFrom(
                msg.sender,
                address(this),
                tokenAmount
            );
        }

        _mint(msg.sender, amount);

        return true;
    }

    function getTokenValues(uint256 amount) view public returns (uint256[] memory values) {

        values = new uint[](tokens.length);

        for (uint i = 0; i < tokens.length; i++) {

            values[i] = tokens[i].universalBalanceOf(address(this)).mul(amount).div(totalSupply());
        }
    }

    function burn(uint256 amount) public {

        burn(amount, tokens);
    }

    function burn(uint256 amount, IERC20[] memory _tokens) public {

        for (uint i = 0; i < _tokens.length; i++) {

            _tokens[i].universalTransfer(
                msg.sender,
                tokens[i].universalBalanceOf(address(this)).mul(amount).div(totalSupply())
            );
        }

        _burn(msg.sender, amount);
    }

    function _getReturn(
        IERC20 fromToken,
        IERC20 toToken,
        uint256 amount
    ) internal view returns (uint256 returnAmount) {

        require(isSubToken[address(fromToken)], "From token is not a sub token");
        require(isSubToken[address(toToken)], "To token is not a sub token");

        uint256 inputAmountWithFee = amount.mul(990);
        // 0.1% fee
        uint256 numerator = inputAmountWithFee.mul(toToken.universalBalanceOf(address(this)));
        uint256 denominator = fromToken.universalBalanceOf(address(this)).sub(msg.value).mul(1000).add(inputAmountWithFee);

        return numerator.div(denominator);
    }

    function getReturn(
        IERC20 fromToken,
        IERC20 toToken,
        uint256 amount
    ) public view returns (uint256 returnAmount) {

        return _getReturn(
            fromToken,
            toToken,
            amount
        );
    }

    function swap(
        IERC20 fromToken,
        IERC20 toToken,
        uint256 amount,
        uint256 minReturn
    ) public payable returns (uint256 returnAmount) {

        return swap(
            fromToken,
            toToken,
            amount,
            minReturn,
            address(0x0)
        );
    }

    function swap(
        IERC20 fromToken,
        IERC20 toToken,
        uint256 amount,
        uint256 minReturn,
        address referrer
    ) public payable returns (uint256 returnAmount) {

        returnAmount = getReturn(fromToken, toToken, amount);
        require(isShutdown == false, "Contract is shutdown");
        require(returnAmount > 0, "The return amount is zero");
        require(returnAmount >= minReturn, "The return amount is less than minReturn value");

        fromToken.universalTransferFrom(msg.sender, address(this), amount);
        toToken.universalTransfer(msg.sender, returnAmount);

        uint256 fee;

        if (referrer != address(0x0)) {

            fee = amount.mul(5).div(1000).div(2);
            fromToken.universalTransfer(referrer, fee, true);
        } else {

            fee = amount.mul(5).div(1000);
        }

        if (feeReceiver != address(this)) {

            fromToken.universalTransfer(feeReceiver, fee, true);
        }

        emit Swapped(
            address(fromToken),
            address(toToken),
            msg.sender,
            amount,
            returnAmount
        );
    }

    function flashLoan(
        IERC20[] memory loanTokens,
        uint256[] memory amounts,
        address target,
        bytes memory data
    ) public {

        require(isShutdown == false, "Contract is shutdown");

        flashLoanIndex++;

        uint256 lastFlashLoanIndex = flashLoanIndex;

        // Backup original balances and lend tokens
        uint256[] memory prevAmounts = new uint[](loanTokens.length);
        uint256[] memory fees = new uint[](loanTokens.length);

        for (uint i = 0; i < loanTokens.length; i++) {

            prevAmounts[i] = loanTokens[i].universalBalanceOf(address(this));
            fees[i] = amounts[i].mul(1).div(100000);

            require(loanTokens[i].universalTransfer(target, amounts[i], true));
        }

        // Perform arbitrary call
        IMultiTokenArbitraryCallReceiver(target).handleFlashLoan(
            loanTokens,
            amounts,
            fees,
            data
        );

        // Ensure original balances were restored
        for (uint i = 0; i < loanTokens.length; i++) {

            require(loanTokens[i].universalBalanceOf(address(this)) >= prevAmounts[i].add(fees[i]));

            if (feeReceiver != address(this)) {

                require(loanTokens[i].universalTransfer(feeReceiver, fees[i].div(2), true));
                // send half of the tokens to the fee receiver
            }
        }

        require(lastFlashLoanIndex == flashLoanIndex, "Reentrancy is not allowed");

        emit FlashLoaned(
            flashLoanIndex,
            msg.sender,
            target
        );
    }

    function() external payable {

        require(msg.sender != tx.origin);
    }
}

// File: contracts/MultiSwap.sol

pragma solidity ^0.5.0;


contract MultiSwap {

    event MultiTokenCreated(
        address indexed creator,
        uint256 indexed id,
        address indexed multiTokenAddress
    );

    address public owner;
    address public feeReceiver;
    MultiToken[] public multiTokens;

    constructor(
        address _owner,
        address _feeReceiver
    ) public {

        owner = _owner;
        feeReceiver = _feeReceiver;
    }

    function setFeeReceiver(address _feeReceiver) public {

        require(msg.sender == owner, "Only owner is allowed");
        feeReceiver = _feeReceiver;
    }

    function setOwner(address _owner) public {

        require(msg.sender == owner, "Only owner is allowed");
        owner = _owner;
    }

    function multiTokensLength() public view returns (uint256) {

        return multiTokens.length;
    }

    function deployMultiToken(
        string memory name,
        string memory symbol,
        uint8 decimals,
        IERC20[] memory tokens
    ) public {

        multiTokens.push(
            new MultiToken(
                name,
                symbol,
                decimals,
                tokens,
                owner,
                feeReceiver
            )
        );

        emit MultiTokenCreated(
            msg.sender,
            multiTokens.length - 1,
            address(multiTokens[multiTokens.length - 1])
        );
    }

    function findByToken(IERC20 token) public view returns (address[] memory result) {

        uint256 counter = 0;
        address[] memory tempResult = new address[](multiTokens.length);

        for (uint256 i = 0; i < multiTokens.length; i++) {

            if (multiTokens[i].isSubToken(address(token))) {

                counter++;
                tempResult[i] = address(multiTokens[i]);
            }
        }

        result = new address[](counter);

        for (uint256 i = 0; i < tempResult.length; i++) {

            if (tempResult[i] != address(0)) {

                result[--counter] = address(tempResult[i]);
            }
        }
    }

    function findByTokenPair(
        IERC20 fromToken,
        IERC20 toToken
    ) public view returns (address[] memory result) {

        uint256 counter = 0;
        address[] memory tempResult = new address[](multiTokens.length);

        for (uint256 i = 0; i < multiTokens.length; i++) {

            if (
                multiTokens[i].isSubToken(address(fromToken)) &&
                multiTokens[i].isSubToken(address(toToken))
            ) {

                counter++;
                tempResult[i] = address(multiTokens[i]);
            }
        }

        result = new address[](counter);

        for (uint256 i = 0; i < tempResult.length; i++) {

            if (tempResult[i] != address(0)) {

                result[--counter] = address(tempResult[i]);
            }
        }
    }
}

{
  "compilationTarget": {
    "MultiToken.sol": "MultiToken"
  },
  "evmVersion": "petersburg",
  "libraries": {},
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}