// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Arrays.sol)

pragma solidity 0.8.7;

import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";

/**
 * @dev Collection of functions related to array types.
 */
library Arrays {
    /**
     * @dev Access an array in an "unsafe" way. Skips solidity "index-out-of-range" check.
     *
     * WARNING: Only use if you are certain `pos` is lower than the array length.
     */
    function unsafeMemoryAccess(
        uint256[] memory arr,
        uint256 pos
    ) internal pure returns (uint256 res) {
        assembly {
            res := mload(add(add(arr, 0x20), mul(pos, 0x20)))
        }
    }

    /**
     * @dev Access an array in an "unsafe" way. Skips solidity "index-out-of-range" check.
     *
     * WARNING: Only use if you are certain `pos` is lower than the array length.
     */
    function unsafeMemoryAccess(
        address[] memory arr,
        uint256 pos
    ) internal pure returns (address res) {
        assembly {
            res := mload(add(add(arr, 0x20), mul(pos, 0x20)))
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC1155/utils/ERC1155Holder.sol)

pragma solidity ^0.8.0;

import "./ERC1155Receiver.sol";

/**
 * Simple implementation of `ERC1155Receiver` that will allow a contract to hold ERC1155 tokens.
 *
 * IMPORTANT: When inheriting this contract, you must include a way to use the received tokens, otherwise they will be
 * stuck.
 *
 * @dev _Available since v3.1._
 */
contract ERC1155Holder is ERC1155Receiver {
    function onERC1155Received(
        address,
        address,
        uint256,
        uint256,
        bytes memory
    ) public virtual override returns (bytes4) {
        return this.onERC1155Received.selector;
    }

    function onERC1155BatchReceived(
        address,
        address,
        uint256[] memory,
        uint256[] memory,
        bytes memory
    ) public virtual override returns (bytes4) {
        return this.onERC1155BatchReceived.selector;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC1155/utils/ERC1155Receiver.sol)

pragma solidity ^0.8.0;

import "../IERC1155Receiver.sol";
import "../../../utils/introspection/ERC165.sol";

/**
 * @dev _Available since v3.1._
 */
abstract contract ERC1155Receiver is ERC165, IERC1155Receiver {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return interfaceId == type(IERC1155Receiver).interfaceId || super.supportsInterface(interfaceId);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

pragma solidity 0.8.7;
import "@openzeppelin/contracts/access/Ownable.sol";

abstract contract ForeverOwnable is Ownable {
    error CannotRenounceOwnership();

    /// @notice Blocks renouncing ownership.
    /// @dev Prevents orphaned contract.
    function renounceOwnership() public virtual override onlyOwner {
        revert CannotRenounceOwnership();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] calldata accounts,
        uint256[] calldata ids
    ) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 amount, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC1155/IERC1155Receiver.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev _Available since v3.1._
 */
interface IERC1155Receiver is IERC165 {
    /**
     * @dev Handles the receipt of a single ERC1155 token type. This function is
     * called at the end of a `safeTransferFrom` after the balance has been updated.
     *
     * NOTE: To accept the transfer, this must return
     * `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
     * (i.e. 0xf23a6e61, or its own function selector).
     *
     * @param operator The address which initiated the transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param id The ID of the token being transferred
     * @param value The amount of tokens being transferred
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
     */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    ) external returns (bytes4);

    /**
     * @dev Handles the receipt of a multiple ERC1155 token types. This function
     * is called at the end of a `safeBatchTransferFrom` after the balances have
     * been updated.
     *
     * NOTE: To accept the transfer(s), this must return
     * `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
     * (i.e. 0xbc197c81, or its own function selector).
     *
     * @param operator The address which initiated the batch transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param ids An array containing ids of each token being transferred (order and length must match values array)
     * @param values An array containing amounts of each token being transferred (order and length must match ids array)
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
     */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.7;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IPrimeRewards {
    struct CacheInfo {
        uint256 amount;
        int256 rewardDebt;
    }

    struct PoolInfo {
        uint256 accPrimePerShare; // The amount of accumulated PRIME per share
        uint256 allocPoint; // share of the contract's per second rewards to that pool
        uint256 lastRewardTimestamp; // last time stamp at which rewards were assigned
        uint256[] tokenIds; // ParallelAlpha tokenIds required to cache in the pool
        uint256 totalSupply; // Total number of cached sets in pool
    }

    event Cache(address indexed user, uint256 indexed pid, uint256 amount);
    event Withdraw(address indexed user, uint256 indexed pid, uint256 amount);
    event EmergencyWithdraw(
        address indexed user,
        uint256 indexed pid,
        uint256 amount
    );
    event Claim(
        address indexed user,
        uint256 indexed pid,
        uint256 amount,
        uint256 indexed currencyId
    );
    event LogPoolAddition(uint256 indexed pid, uint256[] tokenIds);
    event EndTimestampUpdated(uint256 endTimestamp, uint256 indexed currencyID);
    event RewardIncrease(uint256 amount, uint256 indexed currencyID);
    event RewardDecrease(uint256 amount, uint256 indexed currencyID);
    event CachingPaused(bool cachingPaused);
    event LogPoolSetAllocPoint(
        uint256 indexed pid,
        uint256 allocPoint,
        uint256 totalAllocPoint,
        uint256 indexed currencyId
    );
    event LogUpdatePool(
        uint256 indexed pid,
        uint256 lastRewardTimestamp,
        uint256 supply,
        uint256 accPerShare,
        uint256 indexed currencyId
    );
    event LogSetPerSecond(
        uint256 amount,
        uint256 startTimestamp,
        uint256 endTimestamp,
        uint256 indexed currencyId
    );

    // Public variables

    function PRIME() external view returns (IERC20);

    function parallelAlpha() external view returns (IERC1155);

    function poolInfo(uint256 _pid) external view returns (PoolInfo memory);

    function cacheInfo(
        uint256 _pid,
        address _user
    ) external view returns (CacheInfo memory);

    function startTimestamp() external view returns (uint256);

    function endTimestamp() external view returns (uint256);

    function primeAmount() external view returns (uint256);

    function primeAmountPerSecond() external view returns (uint256);

    function primeAmountPerSecondPrecision() external view returns (uint256);

    function totalAllocPoint() external view returns (uint256);

    function cachingPaused() external view returns (bool);

    // Functions
    function poolLength() external view returns (uint256 pools);

    function getPoolTokenIds(
        uint256 _pid
    ) external view returns (uint256[] memory);

    function updateAllPools() external;

    function getPoolCacheAmounts(
        uint256[] calldata _pids,
        address[] calldata _addresses
    ) external view returns (uint256[] memory);

    function pendingPrime(
        uint256 _pid,
        address _user
    ) external view returns (uint256 pending);

    function massUpdatePools(uint256[] calldata _pids) external;

    function updatePool(uint256 _pid) external;

    function cache(uint256 _pid, uint256 _amount) external;

    function withdraw(uint256 _pid, uint256 _amount) external;

    function emergencyWithdraw(uint256 _pid) external;

    function claimPrime(uint256 _pid) external;

    function claimPrimePools(uint256[] calldata _pids) external;

    function withdrawAndClaimPrime(uint256 _pid, uint256 _amount) external;
}

pragma solidity 0.8.7;

interface IRewarder {
    function setMerkleRoot(bytes32 _newMerkleRoot) external;

    function claim(bytes calldata claimData) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.7;

// Interfaces
import {IRewarder} from "./interfaces/IRewarder.sol";
import {IPrimeRewards} from "./interfaces/IPrimeRewards.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {IERC1155} from "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
// Inheritance
import {ForeverOwnable} from "./util/ForeverOwnable.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {ERC1155Holder} from "@openzeppelin/contracts/token/ERC1155/utils/ERC1155Holder.sol";
// Util
import {Arrays} from "./util/Arrays.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

/// @title   ParagonsDAO Sleeves
/// @notice  This contract allows users to sleeve and unsleeve their Parallel Alpha cards. Co-operative caching of parasets is required when possible. Caching rewards are used to incentivize both sleeving and caching behaviour.
/// @author  Felix & RarityCapital
contract Sleeves is ForeverOwnable, ReentrancyGuard, ERC1155Holder {
    using SafeERC20 for IERC20;
    using Arrays for uint256[];
    /// EVENTS ///
    /// @notice Emitted whenever a batch of cards is sleeved
    /// @param user The user that sleeved a batch, they own these cards in this contract's data structures
    /// @param tokenIds The tokenIds of cards in batch
    /// @param amounts The amounts of cards in batch, in order of tokenIds
    event SleeveBatch(
        address indexed user,
        uint256[] tokenIds,
        uint256[] amounts
    );
    /// @notice Emitted whenever a batch of cards is unsleeved
    /// @param user The user that unsleeved a batch, this contract's data structures reflect the decrease in balance
    /// @param tokenIds The tokenIds of cards in batch
    /// @param amounts The amounts of cards in batch, in order of tokenIds
    /// @param fee The fee paid to unsleeve, in PDT, weighted by rarityScore
    event UnsleeveBatch(
        address indexed user,
        uint256[] tokenIds,
        uint256[] amounts,
        uint256 fee
    );
    /// @notice Emitted whenever a batch of parasets are cached
    /// @param poolIds The poolIds cached
    /// @param amounts The amounts of parasets, in order of poolIds
    event CacheBatch(uint256[] poolIds, uint256[] amounts);
    /// @notice Emitted whenever a batch of parasets are withdrawn
    /// @dev Note the proof component is a user pointing to a tokenId it is owed, but the contract has less than that amount, therefore it must be cached.
    /// @param user The user that withdrew a batch
    /// @param poolIds The poolIds withdrawn
    /// @param tokenIds The tokenIds proof used to withdraw, in order of poolIds
    /// @param amounts The amounts of tokenIds withdrawn, in order of poolIds
    event WithdrawWithProofBatch(
        address indexed user,
        uint256[] poolIds,
        uint256[] tokenIds,
        uint256[] amounts
    );
    /// @notice Emitted when adminSyncPools is called
    /// @param start The first poolId synced
    /// @param end The last poolId synced
    event SyncPools(uint256 start, uint256 end);
    /// @notice Emitted when adminSetMaxDepositsPerCard is called
    /// @param nextUnsleeveBaseFee The next unsleeveBaseFee
    event SetUnsleeveBaseFee(uint256 nextUnsleeveBaseFee);
    /// @notice Emitted when adminSetMaxDepositsPerCard is called
    /// @param nextRewarder The next Rewarder
    event SetRewarder(address nextRewarder);

    /// ERRORS ///
    /// @notice Error when a Zero Address is used
    error ZeroAddress();
    /// @notice Error when an argument length is invalid, typically on different sized arrays.
    error ArgumentLengthMismatch();
    /// @notice Error when Sleeves.sol doesn't want to accept any more of a tokenId
    error NotAcceptingAnyMore(uint256 tokenId);
    /// @notice Error when Sleeves.sol doesn't owe the user any more of this tokenId
    error InsufficientBalance(address user, uint256 tokenId);
    /// @notice Error when Sleeves.sol can't verify that two tokenIds share the same pool
    error DifferentPoolId(uint256 tokenId0, uint256 tokenId1);
    /// @notice Error when Sleeves.sol
    error InvalidCannotCacheProof(uint256 poolId, uint256 tokenId);
    /// @notice Error when Sleeves.sol can't verify that a tokenId is in a poolId
    error InvalidPoolMembership(uint256 poolId, uint256 tokenId);
    /// @notice Error when Sleeves.sol doesn't believe it should perform a withdraw operation
    error NoNeedToWithdraw(uint256 poolId);
    /// @notice Invalid Max Deposits Per Card
    error MaxDepositPerCardBelowBalance(
        uint256 tokenId,
        uint256 currentBalance,
        uint256 nextMaxDepositsPerCard
    );
    /// @notice a pool sync fails when a duplicate tokenId to poolId is found
    error DuplicateTokenId(uint256 tokenId, uint256 poolId);
    /// @notice When a lookup on tokenIdToPooliIds is unset
    error UnsetTokenId(uint256 tokenId);
    /// @notice cannot set unsleeveBaseFee unreasonably high
    error UnsleeveBaseFeeTooHigh(uint256 nextUnsleeveBaseFee);

    /// CONSTANTS ///
    /// @notice The precision used for all calculations
    uint256 public constant PRECISION = 1e18;
    /// @notice The maximum unsleeve base fee at 100 PDT
    uint256 public constant maxUnsleeveBaseFee = 100 * 1e18;
    /* solhint-disable var-name-mixedcase */
    IERC20 public Prime;
    IERC20 public Pdt;
    IERC1155 public ParallelAlpha;
    IPrimeRewards public PrimeRewards;
    IRewarder public Rewarder;
    /* solhint-enable var-name-mixedcase */

    /// STATE VARIABLES ///
    /// @notice First pool ID
    uint256 public firstPoolId;
    /// @notice Last pool ID
    uint256 public lastPoolId;
    /// @notice This is the base fee to unsleeve an entire paraset.
    uint256 public unsleeveBaseFee;
    /// @notice Data structure that tracks user sleeves and unsleeves.
    /// @dev address => tokenId => balance.
    mapping(address => mapping(uint256 => uint256)) public userBalances;
    /// @notice Data structure that tracks if Sleeves.sol is willing to accept more of tokenIds.
    /// @dev For each paraset, MIN_[i=parasetTokenIds](supply_i).
    mapping(uint256 => uint256) public maxDepositsPerCard;
    /// @notice Data structure that tracks each card's rarity score.
    /// @dev Offchain, this is = 1/supply_i / SUM_[j=parasetTokenIds](1/supply_j).
    mapping(uint256 => uint256) public rarityScores;
    /// @notice Mapping from tokenIds to their poolIds
    /// @dev This is used for lookups, trading gas on admin commands for later simple lookups. NOTE: This is poolID + 1.
    mapping(uint256 => uint256) public tokenIdsToPoolNumbers;

    /// GUARDS ///
    modifier sameLength(uint256 a, uint256 b) {
        if (a != b) revert ArgumentLengthMismatch();
        _;
    }

    /// @notice Setups up the contract with all the necessary dependencies.
    /// @dev Notice we approveAll on PrimeRewards for ParallelAlpha.
    constructor(
        uint256 nextFirstPoolId,
        IERC20 nextPrime,
        IERC20 nextPdt,
        IERC1155 nextParallelAlpha,
        IPrimeRewards nextPrimeRewards,
        IRewarder nextRewarder
    ) {
        if (address(nextPrime) == address(0)) revert ZeroAddress();
        if (address(nextPdt) == address(0)) revert ZeroAddress();
        if (address(nextParallelAlpha) == address(0)) revert ZeroAddress();
        if (address(nextPrimeRewards) == address(0)) revert ZeroAddress();
        if (address(nextRewarder) == address(0)) revert ZeroAddress();

        firstPoolId = nextFirstPoolId;
        lastPoolId = nextFirstPoolId;
        Prime = nextPrime;
        Pdt = nextPdt;
        ParallelAlpha = nextParallelAlpha;
        PrimeRewards = nextPrimeRewards;
        Rewarder = nextRewarder;
        ParallelAlpha.setApprovalForAll(address(nextPrimeRewards), true);
    }

    /// PRIVATE FUNCTIONS ///
    /// @notice Sleeves cards. Contract now owes user these cards.
    /// @dev NOTE: THIS FUNCTION ASSUMES SOME BATCH TRANSFER IS ALREADY DONE. Notice the maxDepositsPerCard constraint is checked.
    /// @param user The address to credit this sleeve.
    /// @param tokenIds The tokenIds involved in this sleeve.
    /// @param amounts The amounts of each tokenId involved in this sleeve.
    function _sleeveBatch(
        address user,
        uint256[] memory tokenIds,
        uint256[] memory amounts
    ) private {
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 amount = amounts.unsafeMemoryAccess(i);

            // Check cards in Sleeve do not exceed maxDepositsPerCard
            uint256 nextBalance = amount +
                ParallelAlpha.balanceOf(address(this), tokenId) +
                PrimeRewards
                    .cacheInfo(_getPoolId(tokenId), address(this))
                    .amount;
            if (nextBalance > maxDepositsPerCard[tokenId])
                revert NotAcceptingAnyMore(tokenId);

            unchecked {
                // Overflow not possible - amount is bounded by ERC1155 max supply, which fits in uint256. https://etherscan.io/address/0x76be3b62873462d2142405439777e971754e8e77#code.
                userBalances[user][tokenId] += amount;
                ++i;
            }
        }
        emit SleeveBatch(user, tokenIds, amounts);
    }

    /// @notice Unsleeves cards and take a PDT fee. PDT fee is weighted by rarity score, less rare cards are cheaper to unsleeve.
    /// @dev NOTE: Assumes rarityScores are uploaded WITH PRECISION.
    /// @param user The address to debt this unsleeve.
    /// @param tokenIds The tokenIds involved in this unsleeve.
    /// @param amounts The amounts of each tokenId involved in this unsleeve.
    function _unsleeveBatch(
        address user,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    ) private sameLength(tokenIds.length, amounts.length) nonReentrant {
        uint256 totalRarityScore = 0;
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 amount = amounts.unsafeMemoryAccess(i);

            if (userBalances[user][tokenId] < amount)
                revert InsufficientBalance(user, tokenId);
            totalRarityScore += rarityScores[tokenId] * amount;

            unchecked {
                // Underflow not possible -  userBalances[user][tokenId] >= amount LEQV userBalances[user][tokenId] - amount >= 0
                userBalances[user][tokenId] -= amount;
                ++i;
            }
        }

        // Fee: user => Sleeves.sol
        // Cards: Sleeves.sol => user
        uint256 fee = (totalRarityScore * unsleeveBaseFee) / PRECISION;
        if (fee > 0) Pdt.safeTransferFrom(user, address(this), fee);

        ParallelAlpha.safeBatchTransferFrom(
            address(this),
            user,
            tokenIds,
            amounts,
            ""
        );
        emit UnsleeveBatch(user, tokenIds, amounts, fee);
    }

    /// @notice Caches paraset x amount in PrimeRewards.
    /// @dev Note this is a private function and should not be called externally.
    function _cacheBatch(
        uint256[] memory poolIds,
        uint256[] memory amounts
    ) private sameLength(poolIds.length, amounts.length) {
        for (uint256 i = 0; i < poolIds.length; ) {
            uint256 poolId = poolIds.unsafeMemoryAccess(i);
            uint256 amount = amounts.unsafeMemoryAccess(i);
            PrimeRewards.cache(poolId, amount);
            unchecked {
                ++i;
            }
        }
        emit CacheBatch(poolIds, amounts);
    }

    /// @notice Withdraws from PrimeRewards only if necessary for an unsleeve.
    /// @dev User needs to prove that they (A) are owed some amount of tokenId and in poolId (B) that this contract is holding less than that amount. NOTE: This function should only withdraw exactly what is needed to pay back user.
    /// @param user The user initiating a withdraw.
    /// @param poolIds The poolId to withdraw.
    /// @param tokenIds The tokenId Sleeves.sol owes user.
    /// @param amounts The amount of tokenId Sleeves owes user.
    function _withdrawWithProofBatch(
        address user,
        uint256[] calldata poolIds,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    )
        private
        sameLength(poolIds.length, tokenIds.length)
        sameLength(tokenIds.length, amounts.length)
    {
        // (+) ASSUME user is owed tokenIds x amounts.
        for (uint256 i = 0; i < poolIds.length; ) {
            uint256 poolId = poolIds.unsafeMemoryAccess(i);
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 amount = amounts.unsafeMemoryAccess(i);
            // (A): Paraset contains this tokenId
            if (poolId != _getPoolId(tokenId))
                revert InvalidPoolMembership(poolId, tokenId);
            // (B): User is owed more than this contract is holding
            if (amount <= ParallelAlpha.balanceOf(address(this), tokenId))
                revert NoNeedToWithdraw(poolId);
            // (A) & (B) For this poolId, we must withdraw some amount of tokenId from PrimeRewards
            uint256 withdrawAmount = amount -
                ParallelAlpha.balanceOf(address(this), tokenId);
            PrimeRewards.withdraw(poolId, withdrawAmount);
            unchecked {
                ++i;
            }
        }
        emit WithdrawWithProofBatch(user, poolIds, tokenIds, amounts);

        // THIS makes the assumption hold. User is owed tokenIds x amounts, else whole transaction reverts. (+)
        _unsleeveBatch(user, tokenIds, amounts);
    }

    /// @notice Some actions need to prove that there are no parasets left to be cached.
    /// @dev The proof is a pointer to an empty tokenId in the paraset. If the paraset can be cached, then there are no empty tokenIds. If the paraset cannot be cached, then there must exist some empty tokenId.
    /// @param tokenIds The tokenIds to check.
    /// @param cannotCacheProofs empty Proofs.
    function _noUncachedGuard(
        uint256[] memory tokenIds,
        uint256[] memory cannotCacheProofs
    ) private view sameLength(tokenIds.length, cannotCacheProofs.length) {
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 cannotCacheProof = cannotCacheProofs.unsafeMemoryAccess(i);

            uint256 poolId = _getPoolId(tokenId);
            if (poolId != _getPoolId(cannotCacheProof))
                revert DifferentPoolId(tokenId, cannotCacheProof);
            // There must be a zero amount of proof in this paraset so that this contract cannot cache
            if (ParallelAlpha.balanceOf(address(this), cannotCacheProof) != 0)
                revert InvalidCannotCacheProof(poolId, cannotCacheProof);

            unchecked {
                ++i;
            }
        }
    }

    /// @notice Set a batch of tokenIds to a poolId
    /// @dev NOTE: If the poolNumber is already set, we revert, enforcing a 1:1 mapping. We also set to a nonzero value, so we can tell that it is set.
    /// @param tokenIds The tokenIds to set.
    /// @param poolId To this poolId.
    function _setTokenIdsToPoolId(
        uint256[] memory tokenIds,
        uint256 poolId
    ) private {
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            // If its already set, revert.
            if (tokenIdsToPoolNumbers[tokenId] != 0)
                revert DuplicateTokenId(tokenId, poolId);
            tokenIdsToPoolNumbers[tokenId] = poolId + 1;
            unchecked {
                ++i;
            }
        }
    }

    /// @notice Get the poolId of a tokenId
    /// @dev NOTE: If the poolID is 0, we know this value was never set.
    /// @param tokenId The tokenId to get.
    function _getPoolId(uint256 tokenId) private view returns (uint256) {
        uint256 poolNumber = tokenIdsToPoolNumbers[tokenId];
        // If unset, revert.
        if (poolNumber == 0) revert UnsetTokenId(tokenId);
        return poolNumber - 1;
    }

    /// PUBLIC FUNCTIONS ///
    /// @notice Performs a mass sleeve and cache operation using ERC1155 batch transfer hook.
    /// @dev Why hook? Because no approvals needed. Why no custom errors ? Because they don't play nice in OZ/ERC1155 hooks. Notice there are a few edge cases in interactions that we must not consider a user sleeving and must return the selector right away.
    /// @dev https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC1155/ERC1155.sol#L381
    /// @param operator The operator of the batch transfer
    /// @param from The source of the batch transfer
    /// @param sleeveTokenIds The tokenIds of cards in batch trabsfer
    /// @param sleeveAmounts The amounts of cards in batch transfer, in order of tokenIds
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] memory sleeveTokenIds,
        uint256[] memory sleeveAmounts,
        bytes memory data
    ) public virtual override returns (bytes4) {
        /* solhint-disable custom-errors */
        require(msg.sender == address(ParallelAlpha), "NotParallelAlpha");

        // PrimeRewards uncaches do not count as sleeveThenCaches
        if (from == address(PrimeRewards))
            return this.onERC1155BatchReceived.selector;
        // adminSleeve() do not count as sleeveThenCaches
        if (operator == address(this))
            return this.onERC1155BatchReceived.selector;

        (
            uint256[] memory cachePoolIds,
            uint256[] memory cacheAmounts,
            uint256[] memory cannotCacheProofs
        ) = abi.decode(data, (uint256[], uint256[], uint256[]));

        // Sleeve
        _sleeveBatch(from, sleeveTokenIds, sleeveAmounts);
        // Then cache
        if (cachePoolIds.length != 0) _cacheBatch(cachePoolIds, cacheAmounts);

        // No set may be left uncached if possible to be cached.  "For all parasets touched, there must exist some tokenId in the paraset with empty balance in this contract"
        _noUncachedGuard(sleeveTokenIds, cannotCacheProofs);

        return this.onERC1155BatchReceived.selector;
        /* solhint-disable custom-errors */
    }

    /// @notice Withdraw parasets if necessary from PrimeRewards.sol then perform a mass unsleeve.
    /// @dev _withdrawWithProofBatch should be called with the most withdraws first, to avoid redundant withdraws.
    function withdrawThenUnsleeve(
        uint256[] calldata withdrawPoolIds,
        uint256[] calldata withdrawTokenIds,
        uint256[] calldata withdrawAmounts,
        uint256[] calldata unsleeveTokenIds,
        uint256[] calldata unsleeveAmounts
    ) external {
        // Withdraw
        if (withdrawPoolIds.length != 0)
            _withdrawWithProofBatch(
                msg.sender,
                withdrawPoolIds,
                withdrawTokenIds,
                withdrawAmounts
            );
        // Then unsleeve
        _unsleeveBatch(msg.sender, unsleeveTokenIds, unsleeveAmounts);
    }

    // @notice Proxy out to Rewarder implementation.
    function claim(bytes calldata claimData) external nonReentrant {
        Rewarder.claim(claimData);
    }

    /// ADMIN FUNCTIONS ///
    /// @notice Admin can initiate a sleeve action.
    /// @dev NOTE: This must do the batch transfer, since on the public hooks, we assume it is already done.
    function adminSleeveBatch(
        address user,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    ) external onlyOwner {
        // Usually this is assumed on the public hooks. Here, we explicitly transfer.
        ParallelAlpha.safeBatchTransferFrom(
            user,
            address(this),
            tokenIds,
            amounts,
            ""
        );
        _sleeveBatch(user, tokenIds, amounts);
    }

    /// @notice Admin can initiate an unsleeve action.
    function adminUnsleeveBatch(
        address user,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    ) external onlyOwner {
        _unsleeveBatch(user, tokenIds, amounts);
    }

    /// @notice Admin can initiate a cache action.
    /// @dev This is more so an unexpected behaviour operation.
    function adminCacheBatch(
        uint256[] memory poolIds,
        uint256[] memory amounts
    ) external onlyOwner {
        _cacheBatch(poolIds, amounts);
    }

    /// @notice Admin can initiate a _withdrawWithProof action.
    function adminWithdrawWithProofBatch(
        address user,
        uint256[] calldata poolIds,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    ) external onlyOwner {
        _withdrawWithProofBatch(user, poolIds, tokenIds, amounts);
    }

    /// @notice Admin can initiate an emergency withdraw action.
    /// @dev This is more so an EMERGENCY operation.
    function adminEmergencyWithdraw(uint256 poolId) external onlyOwner {
        PrimeRewards.emergencyWithdraw(poolId);
    }

    /// @notice Admin can harvest rewards from PrimeRewards, sending all to a destination.
    function adminClaimPrime(
        uint256[] calldata pids,
        address destination
    ) external onlyOwner {
        for (uint256 i = 0; i < pids.length; ) {
            uint256 pid = pids.unsafeMemoryAccess(i);
            PrimeRewards.claimPrime(pid);
            unchecked {
                ++i;
            }
        }
        uint256 balance = Prime.balanceOf(address(this));
        Prime.safeTransfer(destination, balance);
    }

    /// @notice Admin can move arbitrary ERC20 from this contract, sending all to a destination. This is mostly for PDT fees.
    function adminTransferERC20(
        IERC20 token,
        address destination
    ) external onlyOwner {
        uint256 balance = token.balanceOf(address(this));
        token.safeTransfer(destination, balance);
    }

    /// @notice Sets poolLength state variable. Also sets tokenIdsToPoolNumbers mapping.
    function adminSyncPools() external onlyOwner {
        uint256 nextPoolLength = PrimeRewards.poolLength();
        uint256 startSyncFromId = lastPoolId == firstPoolId
            ? firstPoolId
            : lastPoolId + 1;
        // Map tokenIds => poolIds, pay now for later lookups
        for (uint256 i = startSyncFromId; i < nextPoolLength; ) {
            uint256[] memory tokenIds = PrimeRewards.getPoolTokenIds(i);
            _setTokenIdsToPoolId(tokenIds, i);
            unchecked {
                ++i;
            }
        }
        lastPoolId = nextPoolLength - 1;
        emit SyncPools(startSyncFromId, nextPoolLength - 1);
    }

    function adminSetMaxDepositsPerCard(
        uint256[] calldata tokenIds,
        uint256[] calldata nextMaxDepositsPerCards
    )
        external
        sameLength(tokenIds.length, nextMaxDepositsPerCards.length)
        onlyOwner
    {
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 nextMaxDepositsPerCard = nextMaxDepositsPerCards
                .unsafeMemoryAccess(i);

            uint256 currentBalance = ParallelAlpha.balanceOf(
                address(this),
                tokenId
            ) +
                PrimeRewards
                    .cacheInfo(_getPoolId(tokenId), address(this))
                    .amount;

            if (nextMaxDepositsPerCard < currentBalance)
                revert MaxDepositPerCardBelowBalance(
                    tokenId,
                    currentBalance,
                    nextMaxDepositsPerCard
                );

            maxDepositsPerCard[tokenId] = nextMaxDepositsPerCard;
            unchecked {
                ++i;
            }
        }
    }

    function adminSetRarityScores(
        uint256[] calldata tokenIds,
        uint256[] calldata nextRarityScores
    ) external sameLength(tokenIds.length, nextRarityScores.length) onlyOwner {
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds.unsafeMemoryAccess(i);
            uint256 nextRarityScore = nextRarityScores.unsafeMemoryAccess(i);
            rarityScores[tokenId] = nextRarityScore;
            unchecked {
                ++i;
            }
        }
    }

    function adminSetUnsleeveBaseFee(
        uint256 nextUnsleeveBaseFee
    ) external onlyOwner {
        if (nextUnsleeveBaseFee > maxUnsleeveBaseFee)
            revert UnsleeveBaseFeeTooHigh(nextUnsleeveBaseFee);
        unsleeveBaseFee = nextUnsleeveBaseFee;
        emit SetUnsleeveBaseFee(nextUnsleeveBaseFee);
    }

    function adminSetRewarder(IRewarder nextRewarder) external onlyOwner {
        if (address(nextRewarder) == address(0)) revert ZeroAddress();
        Rewarder = nextRewarder;
        emit SetRewarder(address(nextRewarder));
    }

    /// VIEW FUNCTIONS ///
    function getUserBalances(
        address user,
        uint256[] calldata tokenIds
    ) external view returns (uint256[] memory) {
        uint256[] memory balances = new uint256[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ) {
            balances[i] = userBalances[user][tokenIds[i]];
            unchecked {
                ++i;
            }
        }
        return balances;
    }

    function getRemainingDepositsPerCards(
        uint256[] calldata tokenIds
    ) external view returns (uint256[] memory) {
        uint256[] memory _remainingDepositsPerCards = new uint256[](
            tokenIds.length
        );
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds[i];
            uint256 balance = ParallelAlpha.balanceOf(address(this), tokenId) +
                PrimeRewards
                    .cacheInfo(_getPoolId(tokenId), address(this))
                    .amount;

            _remainingDepositsPerCards[i] =
                maxDepositsPerCard[tokenIds[i]] -
                balance;

            unchecked {
                ++i;
            }
        }
        return _remainingDepositsPerCards;
    }

    function getRarityScores(
        uint256[] calldata tokenIds
    ) external view returns (uint256[] memory) {
        uint256[] memory _rarityScores = new uint256[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds[i];
            _rarityScores[i] = rarityScores[tokenId];
            unchecked {
                ++i;
            }
        }
        return _rarityScores;
    }

    function getTokensIdToPoolIds(
        uint256[] calldata tokenIds
    ) external view returns (uint256[] memory) {
        uint256[] memory _tokenIdsToPoolIds = new uint256[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ) {
            uint256 tokenId = tokenIds[i];
            _tokenIdsToPoolIds[i] = _getPoolId(tokenId);
            unchecked {
                ++i;
            }
        }
        return _tokenIdsToPoolIds;
    }

    // PURE FUNCTIONS //
    /// @notice Calculate safeBatchTransferFrom hook data
    /// @dev Luxury on Etherscan UI
    function getSleeveThenCacheData(
        uint256[] calldata cachePoolId,
        uint256[] calldata cacheAmounts,
        uint256[] calldata cannotCacheBecauseOfTokenIds
    ) external pure returns (bytes memory) {
        return
            abi.encode(cachePoolId, cacheAmounts, cannotCacheBecauseOfTokenIds);
    }

    // DISABLED FUNCTIONS //
    /// @notice Disable transfers that are not batches to Sleeves.sol.
    /// @dev Mainly to reduce complexity.
    function onERC1155Received(
        address,
        address,
        uint256,
        uint256,
        bytes memory
    ) public virtual override returns (bytes4) {
        // No custom error, this bubbles up better into ERC1155 errors.
        require(false, "NO SINGLE TRANSFER");
    }
}

{
  "compilationTarget": {
    "contracts/Sleeves.sol": "Sleeves"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 10000
  },
  "remappings": []
}