// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @dev StakingPool interface
 */
interface IStakePool {
    event Staked(
        address indexed token,
        address indexed staker_,
        uint256 requestedAmount_,
        uint256 stakedAmount_
    );
    event PaidOut(
        address indexed token,
        address indexed rewardToken,
        address indexed staker_,
        uint256 amount_,
        uint256 reward_
    );

    function stake(uint256 amount) external returns (bool);

    function stakeFor(address staker, uint256 amount) external returns (bool);

    function stakeOf(address account) external view returns (uint256);

    function tokenAddress() external view returns (address);

    function stakedTotal() external view returns (uint256);

    function stakedBalance() external view returns (uint256);

    function stakingStarts() external view returns (uint256);

    function stakingEnds() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IStakePoolFactory {
    function owner() external view returns (address);

    function addTokensTo(address to, uint256 amount) external returns (uint256);

    function removeTokensFrom(
        address from,
        uint256 amount
    ) external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

library SafeAmount {
    using SafeERC20 for IERC20;

    function safeTransferFrom(
        address token,
        address from,
        address to,
        uint256 amount
    ) internal returns (uint256) {
        uint256 preBalance = IERC20(token).balanceOf(to);
        IERC20(token).transferFrom(from, to, amount);
        uint256 postBalance = IERC20(token).balanceOf(to);
        return postBalance - preBalance;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "../common/SafeAmount.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

library StakeLibrary {
    using SafeERC20 for IERC20;
    event Staked(
        address indexed token,
        address indexed staker_,
        uint256 requestedAmount_,
        uint256 stakedAmount_
    );
    event PaidOut(
        address indexed token,
        address indexed rewardToken,
        address indexed staker_,
        uint256 amount_,
        uint256 reward_
    );

    struct StakeState {
        uint256 stakedTotal;
        uint256 stakedBalance;
        uint256 withdrawnEarly;
        mapping(address => uint256) _stakes;
    }

    struct StakeRewardState {
        uint256 rewardBalance;
        uint256 rewardsTotal;
        uint256 earlyWithdrawReward;
        mapping(address => uint256) _claimed;
    }

    function VERSION() external pure returns (uint) {
        return 2001;
    }

    function tryStake(
        address payer,
        address staker,
        uint256 amount,
        uint256 stakingStarts,
        uint256 stakingEnds,
        uint256 stakingCap,
        address tokenAddress,
        StakeState storage state
    )
        public
        _after(stakingStarts)
        _before(stakingEnds)
        _positive(amount)
        returns (uint256)
    {
        // check the remaining amount to be staked
        // For pay per transfer tokens we limit the cap on incoming tokens for simplicity. This might
        // mean that cap may not necessary fill completely which is ok.
        uint256 remaining = amount;
        // uint256 stakedTotal = state.stakedTotal;
        {
            uint256 stakedBalance = state.stakedBalance;
            if (stakingCap > 0 && remaining > (stakingCap - stakedBalance)) {
                remaining = stakingCap - stakedBalance;
            }
        }
        // These requires are not necessary, because it will never happen, but won't hurt to double check
        // this is because stakedTotal and stakedBalance are only modified in this method during the staking period
        require(remaining > 0, "StakeLibrary: Staking cap is filled");
        // require((remaining + stakedTotal) <= stakingCap, "StakeLibrary: this will increase staking amount pass the cap");
        // Update remaining in case actual amount paid was different.
        remaining = _payMe(payer, remaining, tokenAddress);
        emit Staked(tokenAddress, staker, amount, remaining);

        // Transfer is completed
        return remaining;
    }

    function stake(
        address payer,
        address staker,
        uint256 amount,
        uint256 stakingStarts,
        uint256 stakingEnds,
        uint256 stakingCap,
        address tokenAddress,
        StakeState storage state
    ) external returns (uint256) {
        uint256 remaining = tryStake(
            payer,
            staker,
            amount,
            stakingStarts,
            stakingEnds,
            stakingCap,
            tokenAddress,
            state
        );

        // Transfer is completed
        state.stakedBalance = state.stakedBalance + remaining;
        state.stakedTotal = state.stakedTotal + remaining;
        state._stakes[staker] = state._stakes[staker] + remaining;

        // return the amount staked
        return remaining;
    }

    function addReward(
        uint256 rewardAmount,
        uint256 withdrawableAmount,
        address rewardTokenAddress,
        StakeRewardState storage state
    ) external returns (bool) {
        require(rewardAmount > 0, "StakeLibrary: reward must be positive");
        require(
            withdrawableAmount >= 0,
            "StakeLibrary: withdrawable amount cannot be negative"
        );
        require(
            withdrawableAmount <= rewardAmount,
            "StakeLibrary: withdrawable amount must be less than or equal to the reward amount"
        );
        address from = msg.sender;
        rewardAmount = _payMe(from, rewardAmount, rewardTokenAddress);

        state.rewardsTotal += rewardAmount;
        state.rewardBalance += rewardAmount;
        state.earlyWithdrawReward += withdrawableAmount;

        return true;
    }

    function addMarginalReward(
        address rewardTokenAddress,
        address tokenAddress,
        address me,
        uint256 stakedBalance,
        uint256 earlyWithdrawReward,
        StakeRewardState storage state
    ) external returns (bool) {
        uint256 amount = IERC20(rewardTokenAddress).balanceOf(me) -
            state.rewardsTotal;

        // if the reward token is the same as the staking token, then we need to subtract the staked balance
        if (rewardTokenAddress == tokenAddress) {
            amount = amount - stakedBalance;
        }

        // just in case but should never happen
        require(amount >= 0, "StakeLibrary: negative reward");
        if (amount == 0) {
            return true; // No reward to add. Its ok. No need to fail callers.
        }

        // if the early reward is bigger then revert
        require(
            amount >= earlyWithdrawReward,
            "StakeLibrary: reward must be greater than or equal to the early withdraw reward"
        );

        state.rewardsTotal += amount;
        state.rewardBalance += amount;
        state.earlyWithdrawReward += earlyWithdrawReward;

        return true;
    }

    function tryClaimReward(
        address from,
        address rewardTokenAddress,
        uint256 withdrawStarts,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) public _after(withdrawStarts) _realAddress(msg.sender) returns (uint256) {
        uint256 staked = state._stakes[from];
        require(staked > 0, "StakeLibrary: no staked balance");
        return
            _claimReward(
                rewardTokenAddress,
                from,
                withdrawEnds,
                stakingEnds,
                state,
                rewardState
            );
    }

    function claimReward(
        address from,
        address rewardTokenAddress,
        uint256 withdrawStarts,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) public returns (bool) {
        tryClaimReward(
            from,
            rewardTokenAddress,
            withdrawStarts,
            withdrawEnds,
            stakingEnds,
            state,
            rewardState
        );
        return true;
    }

    function tryWithdraw(
        address from,
        address tokenAddress,
        address rewardTokenAddress,
        uint256 amount,
        uint256 withdrawStarts,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    )
        public
        _after(withdrawStarts)
        _positive(amount)
        _realAddress(msg.sender)
        returns (uint256)
    {
        require(
            amount <= state._stakes[from],
            "StakeLibrary: not enough balance"
        );

        return
            _withdraw(
                tokenAddress,
                rewardTokenAddress,
                from,
                amount,
                withdrawEnds,
                stakingEnds,
                state,
                rewardState
            );
    }

    function withdraw(
        address from,
        address tokenAddress,
        address rewardTokenAddress,
        uint256 amount,
        uint256 withdrawStarts,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) public returns (bool) {
        uint256 wdAmount = tryWithdraw(
            from,
            tokenAddress,
            rewardTokenAddress,
            amount,
            withdrawStarts,
            withdrawEnds,
            stakingEnds,
            state,
            rewardState
        );
        state.stakedBalance = state.stakedBalance - wdAmount;
        state._stakes[from] = state._stakes[from] - wdAmount;
        return true;
    }

    function calculateReward(
        address from,
        uint256 amount,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) public view returns (uint256) {
        if (amount == 0) {
            return 0;
        }

        uint256 claimed = rewardState._claimed[from];
        uint256 reward = 0;

        if (block.timestamp < withdrawEnds) {
            reward = _calculateRewardEarly(
                amount,
                withdrawEnds,
                stakingEnds,
                state,
                rewardState
            );
        } else {
            reward = _calculateRewardAfterClose(amount, state, rewardState);
        }

        return reward - claimed;
    }

    function _calculateRewardEarly(
        uint256 amount,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) private view returns (uint256) {
        // if the pool is not over, then no reward yet
        if (stakingEnds >= block.timestamp) {
            return 0;
        }

        uint256 denom = (withdrawEnds - stakingEnds) * state.stakedTotal;
        uint256 reward = ((block.timestamp - stakingEnds) *
            rewardState.earlyWithdrawReward *
            amount) / denom;
        return reward;
    }

    function _calculateRewardAfterClose(
        uint256 amount,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) private view returns (uint256) {
        uint256 rewBal = rewardState.rewardBalance;
        uint256 reward = (rewBal * amount) / state.stakedBalance;
        return reward;
    }

    function _claimReward(
        address rewardTokenAddress,
        address from,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) private _realAddress(from) returns (uint256) {
        uint256 amount = state._stakes[from];
        uint256 reward = calculateReward(
            from,
            amount,
            withdrawEnds,
            stakingEnds,
            state,
            rewardState
        );
        rewardState.rewardBalance -= reward;
        rewardState._claimed[from] += reward;
        bool paid = _payDirect(from, reward, rewardTokenAddress);
        require(paid, "StakeLibrary: error paying");
        emit PaidOut(
            rewardTokenAddress,
            rewardTokenAddress,
            from,
            amount,
            reward
        );
        return reward;
    }

    function _withdraw(
        address tokenAddress,
        address rewardTokenAddress,
        address from,
        uint256 amount,
        uint256 withdrawEnds,
        uint256 stakingEnds,
        StakeState storage state,
        StakeRewardState storage rewardState
    ) private _realAddress(from) returns (uint256) {
        uint256 reward = calculateReward(
            from,
            amount,
            withdrawEnds,
            stakingEnds,
            state,
            rewardState
        );
        rewardState.rewardBalance -= reward;
        rewardState._claimed[from] += reward;
        bool principalPaid = _payDirect(from, amount, tokenAddress);
        bool rewardPaid = _payDirect(from, reward, rewardTokenAddress);
        require(principalPaid && rewardPaid, "StakeLibrary: error paying");
        emit PaidOut(tokenAddress, rewardTokenAddress, from, amount, reward);
        return amount;
    }

    function _payMe(
        address payer,
        uint256 amount,
        address token
    ) internal returns (uint256) {
        return _payTo(payer, address(this), amount, token);
    }

    function _payTo(
        address allower,
        address receiver,
        uint256 amount,
        address token
    ) internal returns (uint256) {
        // Request to transfer amount from the contract to receiver.
        // contract does not own the funds, so the allower must have added allowance to the contract
        // Allower is the original owner.
        return SafeAmount.safeTransferFrom(token, allower, receiver, amount);
    }

    function _payDirect(
        address to,
        uint256 amount,
        address token
    ) internal returns (bool) {
        if (amount == 0) {
            return true;
        }
        IERC20(token).safeTransfer(to, amount);
        return true;
    }

    modifier _realAddress(address addr) {
        require(addr != address(0), "StakeLibrary: zero address");
        _;
    }

    modifier _positive(uint256 amount) {
        require(amount != 0, "StakeLibrary: negative amount");
        _;
    }

    modifier _after(uint eventTime) {
        require(
            block.timestamp >= eventTime,
            "StakeLibrary: bad after timing for the request"
        );
        _;
    }

    modifier _before(uint eventTime) {
        require(
            block.timestamp < eventTime,
            "StakeLibrary: bad before timing for the request"
        );
        _;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./StakePoolRewardable.sol";
import "./StakePoolOptimized.sol";

import "@openzeppelin/contracts/interfaces/IERC20.sol";
import "./interfaces/IStakePoolFactory.sol";

contract StakePool is StakePoolOptimized, StakePoolRewardable {
    address public factory;

    constructor(
        string memory name_,
        address tokenAddress_,
        address rewardTokenAddress_,
        uint stakingStarts_,
        uint stakingEnds_,
        uint withdrawStarts_,
        uint withdrawEnds_,
        uint256 stakingCap_
    )
        StakePoolOptimized(
            name_,
            tokenAddress_,
            stakingStarts_,
            stakingEnds_,
            withdrawStarts_,
            withdrawEnds_,
            stakingCap_
        )
    {
        require(
            rewardTokenAddress_ != address(0),
            "StakingPool: 0 reward address"
        );
        rewardTokenAddress = rewardTokenAddress_;
        factory = msg.sender;
    }

    modifier onlyOwner() {
        require(
            msg.sender == IStakePoolFactory(factory).owner(),
            "StakePool: caller is not the owner"
        );
        _;
    }

    function rewardOf(address account) external view returns (uint256) {
        return
            StakeLibrary.calculateReward(
                account,
                stakeState._stakes[account],
                withdrawEnds,
                stakingEnds,
                stakeState,
                rewardState
            );
    }

    function _annualize(
        uint256 reward,
        uint256 year,
        uint256 dt
    ) internal pure returns (uint256) {
        return (reward * year) / dt;
    }

    function minimumRewardMaturity() external view returns (uint256) {
        uint256 dt = withdrawEnds - stakingEnds;
        uint256 amount = 1e18;
        if (stakingCap > 0) {
            amount = stakingCap;
        } else {
            amount = stakeState.stakedTotal;
        }

        if (amount == 0) {
            return 0;
        }

        uint256 reward = StakeLibrary.calculateReward(
            address(0),
            amount,
            withdrawEnds,
            stakingEnds,
            stakeState,
            rewardState
        );

        return _annualize(reward, 365 days, dt);
    }

    function calculatedReward() external view returns (uint256) {
        if (rewardState.rewardsTotal == 0) {
            return 0;
        }
        if (stakingCap > 0) {
            return
                StakeLibrary.calculateReward(
                    address(0),
                    stakingCap,
                    withdrawEnds,
                    stakingEnds,
                    stakeState,
                    rewardState
                );
        } else {
            return
                StakeLibrary.calculateReward(
                    address(0),
                    stakeState.stakedTotal,
                    withdrawEnds,
                    stakingEnds,
                    stakeState,
                    rewardState
                );
        }
    }

    function addReward(
        uint256 rewardAmount,
        uint256 withdrawableAmount
    ) external onlyOwner returns (bool) {
        return
            StakeLibrary.addReward(
                rewardAmount,
                withdrawableAmount,
                rewardTokenAddress,
                rewardState
            );
    }

    function addMarginalReward(
        uint256 withdrawableAmount
    ) external onlyOwner returns (bool) {
        return
            StakeLibrary.addMarginalReward(
                rewardTokenAddress,
                tokenAddress,
                address(this),
                stakedBalance(),
                withdrawableAmount,
                rewardState
            );
    }

    function stakeFor(
        address staker,
        uint256 amount
    ) external override returns (bool) {
        uint256 amountStaked = _stake(msg.sender, staker, amount);
        IStakePoolFactory(factory).addTokensTo(staker, amountStaked);
        return amountStaked > 0;
    }

    function stake(uint256 amount) external override returns (bool) {
        uint256 amountStaked = _stake(msg.sender, msg.sender, amount);
        IStakePoolFactory(factory).addTokensTo(msg.sender, amountStaked);
        return amountStaked > 0;
    }

    function exitPool() external returns (bool) {
        IStakePoolFactory(factory).removeTokensFrom(
            msg.sender,
            stakeState._stakes[msg.sender]
        );
        return
            StakeLibrary.withdraw(
                msg.sender,
                tokenAddress,
                rewardTokenAddress,
                stakeState._stakes[msg.sender],
                withdrawStarts,
                withdrawEnds,
                stakingEnds,
                stakeState,
                rewardState
            );
    }

    function claimReward() public returns (bool) {
        return
            StakeLibrary.claimReward(
                msg.sender,
                rewardTokenAddress,
                withdrawStarts,
                withdrawEnds,
                stakingEnds,
                stakeState,
                rewardState
            );
    }

    function emergencyWithdraw(address _token) public onlyOwner {
        if (_token == address(0)) {
            payable(msg.sender).transfer(address(this).balance);
        } else {
            uint256 balance = IERC20(_token).balanceOf(address(this));
            IERC20(_token).transfer(msg.sender, balance);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/interfaces/IERC20.sol";
import "./StakePool.sol";

contract StakePoolFactory {
    uint256 constant BP_DIVISOR = 10000;

    event StakePoolCreated(address indexed stakePool, address indexed owner);
    event Transfer(address indexed from, address indexed to, uint256 amount);

    address[] public allPools;
    mapping(address => bool) public isPool;
    address public owner;

    string public name = "DuckDAO Farm";
    string public symbol = "DDF";
    uint8 public decimals = 18;
    uint256 public totalSupply;
    mapping(address => uint256) public balanceOf;
    mapping(address => uint256) public ratios;

    constructor(address owner_) {
        owner = owner_;
    }

    modifier onlyOwner() {
        require(
            msg.sender == owner,
            "StakePoolFactory: caller is not the owner"
        );
        _;
    }

    modifier onlyPool() {
        require(isPool[msg.sender], "StakePoolFactory: caller is not a pool");
        _;
    }

    function allowance(address, address) external pure returns (uint256) {
        return 0;
    }

    function approve(address, uint256) external pure returns (bool) {
        return false;
    }

    function allPoolsLength() external view returns (uint256) {
        return allPools.length;
    }

    function getPool(uint256 index) external view returns (address) {
        return allPools[index];
    }

    function getPools(
        uint256 index,
        uint256 pageSize
    ) external view returns (address[] memory) {
        address[] memory pools = new address[](pageSize);
        for (uint256 i = 0; i < pageSize; i++) {
            if (index + i < allPools.length) {
                pools[i] = allPools[index + i];
            } else {
                break;
            }
        }
        return pools;
    }

    function createStakePool(
        string memory name_,
        address tokenAddress,
        address rewardTokenAddress,
        uint256 stakingStarts,
        uint256 stakingEnds,
        uint256 withdrawStarts,
        uint256 withdrawEnds,
        uint256 stakingCap,
        uint256 ratio
    ) external onlyOwner returns (address) {
        StakePool stakePool = new StakePool{
            salt: keccak256(abi.encode(name, tokenAddress, rewardTokenAddress))
        }(
            name_,
            tokenAddress,
            rewardTokenAddress,
            stakingStarts,
            stakingEnds,
            withdrawStarts,
            withdrawEnds,
            stakingCap
        );
        require(
            isPool[address(stakePool)] == false,
            "StakePoolFactory: pool already exists"
        );
        allPools.push(address(stakePool));
        isPool[address(stakePool)] = true;
        ratios[address(stakePool)] = ratio;
        emit StakePoolCreated(address(stakePool), msg.sender);
        return address(stakePool);
    }

    function addTokensTo(
        address to,
        uint256 amount
    ) public onlyPool returns (uint256) {
        if (amount == 0 || to == address(0) || ratios[msg.sender] == 0) {
            return 0;
        }

        uint256 amountToTransfer = (amount * ratios[msg.sender]) / BP_DIVISOR;
        balanceOf[to] += amountToTransfer;
        totalSupply += amountToTransfer;
        emit Transfer(address(0), to, amountToTransfer);
        return amountToTransfer;
    }

    function removeTokensFrom(
        address from,
        uint256 amount
    ) public onlyPool returns (uint256) {
        if (amount == 0 || from == address(0) || ratios[msg.sender] == 0) {
            return 0;
        }

        uint256 amountToRemove = (amount * ratios[msg.sender]) / BP_DIVISOR;
        balanceOf[from] -= amountToRemove;
        totalSupply -= amountToRemove;
        emit Transfer(from, address(0), amountToRemove);
        return amountToRemove;
    }

    function emergencyWithdraw(address _token) public onlyOwner {
        if (_token == address(0)) {
            payable(msg.sender).transfer(address(this).balance);
        } else {
            uint256 balance = IERC20(_token).balanceOf(address(this));
            IERC20(_token).transfer(msg.sender, balance);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./interfaces/IStakePool.sol";
import "./libraries/StakeLibrary.sol";

abstract contract StakePoolOptimized is IStakePool {
    string private _name;
    address public override tokenAddress;
    uint public override stakingStarts;
    uint public override stakingEnds;
    uint public withdrawStarts;
    uint public withdrawEnds;
    uint public stakingCap;
    StakeLibrary.StakeState public stakeState;
    uint constant LIB_VERSION = 2001;

    constructor(
        string memory name_,
        address tokenAddress_,
        uint stakingStarts_,
        uint stakingEnds_,
        uint withdrawStarts_,
        uint withdrawEnds_,
        uint256 stakingCap_
    ) {
        require(
            StakeLibrary.VERSION() == LIB_VERSION,
            "Bad linked library version"
        );

        _name = name_;

        require(tokenAddress_ != address(0), "StakingPool: 0 address");
        tokenAddress = tokenAddress_;

        if (stakingStarts_ < block.timestamp) {
            stakingStarts = block.timestamp;
        } else {
            stakingStarts = stakingStarts_;
        }

        require(
            stakingEnds_ >= stakingStarts,
            "StakingPool: staking end must be after staking starts"
        );
        stakingEnds = stakingEnds_;

        require(
            withdrawStarts_ >= stakingEnds,
            "StakingPool: withdrawStarts must be after staking ends"
        );
        withdrawStarts = withdrawStarts_;

        require(
            withdrawEnds_ >= withdrawStarts,
            "StakingPool: withdrawEnds must be after withdraw starts"
        );
        withdrawEnds = withdrawEnds_;

        require(stakingCap_ >= 0, "StakingPool: stakingCap cannot be negative");
        stakingCap = stakingCap_;
    }

    function name() external view returns (string memory) {
        return _name;
    }

    function stakedTotal() external view override returns (uint256) {
        return stakeState.stakedTotal;
    }

    function stakedBalance() public view override returns (uint256) {
        return stakeState.stakedBalance;
    }

    function stakeOf(address account) external view override returns (uint256) {
        return stakeState._stakes[account];
    }

    function _stake(
        address payer,
        address staker,
        uint256 amount
    ) internal virtual returns (uint256) {
        return
            StakeLibrary.stake(
                payer,
                staker,
                amount,
                stakingStarts,
                stakingEnds,
                stakingCap,
                tokenAddress,
                stakeState
            );
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./interfaces/IStakePool.sol";
import "./libraries/StakeLibrary.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

abstract contract StakePoolRewardable is IStakePool {
    using SafeERC20 for IERC20;
    address public rewardTokenAddress;
    StakeLibrary.StakeRewardState public rewardState;

    function earlyWithdrawReward() external view returns (uint256) {
        return rewardState.earlyWithdrawReward;
    }

    function rewardBalance() external view returns (uint256) {
        return rewardState.rewardBalance;
    }

    function rewardsTotal() external view returns (uint256) {
        return rewardState.rewardsTotal;
    }
}

{
  "compilationTarget": {
    "contracts/StakePoolFactory.sol": "StakePoolFactory"
  },
  "evmVersion": "paris",
  "libraries": {
    "contracts/libraries/StakeLibrary.sol:StakeLibrary": "0x611fbdead231cce1481565d6dd9ec9c8f4c052f9"
  },
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}