// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {Strings} from "openzeppelin-contracts/utils/Strings.sol";
import {GenArt721CoreV3_Engine_Flex_PROOF} from "artblocks-contracts/GenArt721CoreV3_Engine_Flex_PROOF.sol";

import {ERC721A, ERC721ACommon, BaseTokenURI, ERC721ACommonBaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";
import {OperatorFilterOS} from "ethier/erc721/OperatorFilterOS.sol";

import {artblocksTokenID} from "proof/artblocks/TokenIDMapping.sol";
import {IGenArt721CoreContractV3_Mintable} from "proof/artblocks/IGenArt721CoreContractV3_Mintable.sol";
import {SellableERC721ACommon} from "proof/sellers/sellable/SellableERC721ACommon.sol";

import {ProjectsConfig} from "./ProjectsConfig.sol";
import {TokenInfoManager} from "./TokenInfoManager.sol";

/**
 * @notice Library for encoding and decoding purchase data for the Diamond Exhibition sellers.
 */
library DiamondExhibitionLib {
    function encodePurchaseData(uint8[] memory projectIds) internal pure returns (bytes memory) {
        return abi.encode(projectIds);
    }

    function dencodePurchaseData(bytes memory data) internal pure returns (uint8[] memory) {
        return abi.decode(data, (uint8[]));
    }
}

/**
 * @notice Diamond Exhibition
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract DiamondExhibition is
    ERC721ACommonBaseTokenURI,
    OperatorFilterOS,
    SellableERC721ACommon,
    ProjectsConfig,
    TokenInfoManager
{
    // =================================================================================================================
    //                          Errors
    // =================================================================================================================

    /**
     * @notice Thrown if the number of requested purchases exceeds the number of remaining tokens.
     */
    error ExceedingMaxTotalSupply(uint256 num, uint256 numLeft);

    /**
     * @notice Thrown if a user attempts to purchase tokens from an exhausted project.
     */
    error ProjectExhausted(uint8 projectId);

    /**
     * @notice Thrown if a user attempts to purchase tokens from an invalid project.
     */
    error InvalidProject(uint8 projectId);

    // =================================================================================================================
    //                          Constants
    // =================================================================================================================

    /**
     * @notice The ArtBlocks engine flex contract.
     */
    GenArt721CoreV3_Engine_Flex_PROOF public immutable flex;

    /**
     * @notice The ArtBlocks engine flex contract or a minter multiplexer.
     */
    IGenArt721CoreContractV3_Mintable public immutable flexMintGateway;

    /**
     * @notice The maximum total number of tokens that can be minted.
     * @dev This is intentionally not a compile-time constant for the sake of testing.
     */
    uint256 public immutable maxTotalSupply;

    // =========================================================================
    //                          Storage
    // =================================================================================================================

    /**
     * @notice The number of tokens minted per project.
     */
    uint16[NUM_PROJECTS] internal _numPurchasedPerProject;

    // =================================================================================================================
    //                          Storage
    // =================================================================================================================

    struct ConstructorParams {
        address admin;
        address steerer;
        address payable secondaryReceiver;
        GenArt721CoreV3_Engine_Flex_PROOF flex;
        IGenArt721CoreContractV3_Mintable flexMintGateway;
    }

    constructor(ConstructorParams memory params)
        ERC721ACommon(params.admin, params.steerer, "Diamond Exhibition", "DIAMOND", params.secondaryReceiver, 500)
        BaseTokenURI("https://metadata.proof.xyz/diamond-exhibition/")
    {
        uint256 total;
        uint256[NUM_PROJECTS] memory maxNumPerProject_ = _maxNumPerProject();
        for (uint256 i = 0; i < NUM_PROJECTS; i++) {
            total += maxNumPerProject_[i];
        }
        maxTotalSupply = total;

        flex = params.flex;
        flexMintGateway = params.flexMintGateway;
    }

    // =================================================================================================================
    //                          Selling
    // =================================================================================================================

    /**
     * @notice Assigns a project to a token.
     * @dev Mints from the associated ArtBlocks project if the project is a longform project.
     */
    function _assignProject(uint256 tokenId, uint8 projectId, uint256[NUM_PROJECTS] memory maxNumPerProject_)
        internal
    {
        if (projectId >= NUM_PROJECTS) {
            revert InvalidProject(projectId);
        }

        uint16 numPurchased = _numPurchasedPerProject[projectId];
        if (numPurchased >= maxNumPerProject_[projectId]) {
            revert ProjectExhausted(projectId);
        }
        _numPurchasedPerProject[projectId] = numPurchased + 1;

        if (_isLongformProject(projectId)) {
            flexMintGateway.mint_Ecf(address(this), _artblocksProjectId(projectId), address(this));
        }
        _setTokenInfo(tokenId, projectId, numPurchased /* edition */ );
    }

    /**
     * @inheritdoc SellableERC721ACommon
     */
    function _handleSale(address to, uint64 num, bytes calldata data) internal virtual override {
        if (num + _totalMinted() > maxTotalSupply) {
            revert ExceedingMaxTotalSupply(num, maxTotalSupply - _totalMinted());
        }

        uint8[] memory projectIds = DiamondExhibitionLib.dencodePurchaseData(data);
        assert(projectIds.length == num);

        uint256 tokenId = _nextTokenId();
        uint256[NUM_PROJECTS] memory maxNumPerProject_ = _maxNumPerProject();
        for (uint256 i = 0; i < num; ++i) {
            _assignProject(tokenId++, projectIds[i], maxNumPerProject_);
        }

        SellableERC721ACommon._handleSale(to, num, data);
    }

    /**
     * @inheritdoc ERC721A
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        TokenInfo memory info = _tokenInfo(tokenId);

        if (projectType(info.projectId) == ProjectType.Curated) {
            return string.concat(_baseURI(), Strings.toString(tokenId));
        }

        return flex.tokenURI(artblocksTokenID(_artblocksProjectId(info.projectId), info.edition));
    }

    /**
     * @notice Returns all tokenIds for a given project.
     * @dev Intended for front-end consumption and not optimised for gas.
     */
    function tokenIdsByProjectId(uint8 projectId) external view returns (uint256[] memory) {
        uint256[] memory tokenIds = new uint256[](_numPurchasedPerProject[projectId]);

        uint256 cursor;
        uint256 supply = totalSupply();
        for (uint256 tokenId = 0; tokenId < supply; ++tokenId) {
            if (_tokenInfo(tokenId).projectId == projectId) {
                tokenIds[cursor++] = tokenId;
            }
        }

        return tokenIds;
    }

    /**
     * @notice Returns the number of tokens purchased for each project.
     * @dev Intended for front-end consumption and not optimised for gas.
     */
    function numPurchasedPerProject() external view returns (uint16[NUM_PROJECTS] memory) {
        return _numPurchasedPerProject;
    }

    // =================================================================================================================
    //                          Inheritance resolution
    // =================================================================================================================

    /**
     * @notice Helper function that returns true if the token belongs to a longform project.
     */
    function _isLongformToken(uint256 tokenId) internal view virtual returns (bool) {
        return _isLongformProject(_tokenInfo(tokenId).projectId);
    }

    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(ERC721ACommon, ERC721ACommonBaseTokenURI, SellableERC721ACommon)
        returns (bool)
    {
        return ERC721ACommonBaseTokenURI.supportsInterface(interfaceId);
    }

    function _baseURI() internal view virtual override(ERC721A, ERC721ACommonBaseTokenURI) returns (string memory) {
        return ERC721ACommonBaseTokenURI._baseURI();
    }

    function setApprovalForAll(address operator, bool approved) public virtual override(ERC721A, OperatorFilterOS) {
        ERC721A.setApprovalForAll(operator, approved);
    }

    function approve(address operator, uint256 tokenId) public payable virtual override(ERC721A, OperatorFilterOS) {
        if (_isLongformToken(tokenId)) {
            ERC721A.approve(operator, tokenId);
        } else {
            OperatorFilterOS.approve(operator, tokenId);
        }
    }

    function transferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        if (_isLongformToken(tokenId)) {
            ERC721A.transferFrom(from, to, tokenId);
        } else {
            OperatorFilterOS.transferFrom(from, to, tokenId);
        }
    }

    function safeTransferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        if (_isLongformToken(tokenId)) {
            ERC721A.safeTransferFrom(from, to, tokenId);
        } else {
            OperatorFilterOS.safeTransferFrom(from, to, tokenId);
        }
    }

    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        if (_isLongformToken(tokenId)) {
            ERC721A.safeTransferFrom(from, to, tokenId, data);
        } else {
            OperatorFilterOS.safeTransferFrom(from, to, tokenId, data);
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {ERC721ACommon, BaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";

import {RoleGatedFreeOfCharge} from "proof/sellers/presets/RoleGatedFreeOfCharge.sol";

import {SellableRedeemableRestrictableERC721} from "./SellableRedeemableRestrictableERC721.sol";

/**
 * @title Diamond Exhibition: Choice Pass
 * @notice A redeemable token airdropped to all day-1 nested Moonbirds that allows mints with preferences from the diamond exhibition.
 */
contract DiamondExhibitionChoicePass is SellableRedeemableRestrictableERC721 {
    /**
     * @notice The seller handling the airdrop.
     */
    RoleGatedFreeOfCharge public airdropper;

    constructor(address admin, address steerer, address payable secondaryReceiver, uint64 numDayOneBirds)
        ERC721ACommon(admin, steerer, "Diamond Exhibition: Day One Pass", "DAY1PASS", secondaryReceiver, 500)
        BaseTokenURI("https://metadata.proof.xyz/diamond-exhibition-pass/day-one/")
    {
        airdropper = new RoleGatedFreeOfCharge(admin , steerer, this, numDayOneBirds);
        _grantRole(AUTHORISED_SELLER_ROLE, address(airdropper));
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {ERC721ACommon, BaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";

import {SellableRedeemableRestrictableERC721} from "./SellableRedeemableRestrictableERC721.sol";

/**
 * @title Diamond Exhibition: Regular Pass
 * @notice A token claimable by all diamond nested Moonbirds that did not receive a Day One Pass, redeemable for
 * diamond exhibition artworks.
 */
contract DiamondExhibitionRegularPass is SellableRedeemableRestrictableERC721 {
    constructor(address admin, address steerer, address payable secondaryReceiver)
        ERC721ACommon(admin, steerer, "Diamond Exhibition: Regular Pass", "REGULAR", secondaryReceiver, 500)
        BaseTokenURI("https://metadata.proof.xyz/diamond-exhibition-pass/regular/")
    {}
}

// SPDX-License-Identifier: MIT
// Copyright (c) 2021 the ethier authors (github.com/divergencetech/ethier)
pragma solidity >=0.8.0 <0.9.0;

import {SellableCallbacker} from "proof/sellers/base/SellableCallbacker.sol";
import {Seller} from "proof/sellers/base/Seller.sol";

import {DiamondExhibitionLib, DiamondExhibition} from "../exhibition/DiamondExhibition.sol";

/**
 * @notice Seller module to purchase Diamond Exhibition tokens.
 */
abstract contract DiamondExhibitionSeller is Seller, SellableCallbacker {
    constructor(DiamondExhibition exhibition) SellableCallbacker(exhibition) {}

    /**
     * @notice Convenience function for inheriting sellers. Purchases tokens of given project IDs free-of-charge.
     */
    function _purchase(address to, uint8[] memory projectIds) internal {
        _purchase(
            to, uint64(projectIds.length), /* total cost */ 0, DiamondExhibitionLib.encodePurchaseData(projectIds)
        );
    }
}

// SPDX-License-Identifier: MIT
// Copyright (c) 2021 the ethier authors (github.com/divergencetech/ethier)
pragma solidity >=0.8.0 <0.9.0;

import {IRedeemableToken} from "proof/redemption/interfaces/IRedeemableToken.sol";
import {DiamondExhibition} from "../exhibition/DiamondExhibition.sol";
import {DiamondExhibitionRegularPass} from "../passes/DiamondExhibitionRegularPass.sol";
import {DiamondExhibitionChoicePass} from "../passes/DiamondExhibitionChoicePass.sol";
import {DiamondExhibitionSeller} from "./DiamondExhibitionSeller.sol";

/**
 * @notice Seller that redeems a Diamond Pass (either a Day One or Regular pass) for a piece in the Diamond Exhibition.
 */
contract DiamondPassRedeemer is DiamondExhibitionSeller {
    /**
     * @notice Emitted when the callback to the `IRedeemableToken` contract fails.
     */
    error RedeemableCallbackFailed(IRedeemableToken token, bytes reason);

    /**
     * @notice Emitted when the `IRedeemableToken` contract is not a valid pass.
     */
    error InvalidRedeemableToken(IRedeemableToken token);

    /**
     * @notice The regular Diamond Exhibition pass.
     */
    DiamondExhibitionRegularPass public immutable regularPass;

    /**
     * @notice The Day One Diamond Exhibition pass.
     */
    DiamondExhibitionChoicePass public immutable dayOnePass;

    constructor(
        DiamondExhibition exhibition,
        DiamondExhibitionRegularPass regularPass_,
        DiamondExhibitionChoicePass dayOnePass_
    ) DiamondExhibitionSeller(exhibition) {
        dayOnePass = dayOnePass_;
        regularPass = regularPass_;
    }

    /**
     * @notice Encodes a purchase.
     * @param redeemable The `IRedeemableToken` contract to redeem.
     * @param passId The tokenId of the pass to redeem.
     * @param projectId The project ID to purchase.
     */
    struct Purchase {
        IRedeemableToken redeemable;
        uint256 passId;
        uint8 projectId;
    }

    /**
     * @notice Redeems the given passes and purchases pieces in the Diamond Exhibition.
     */
    function purchase(Purchase[] calldata purchases) external {
        uint8[] memory projectIds = new uint8[](purchases.length);

        for (uint256 i = 0; i < purchases.length; ++i) {
            if (purchases[i].redeemable != regularPass && purchases[i].redeemable != dayOnePass) {
                revert InvalidRedeemableToken(purchases[i].redeemable);
            }

            try purchases[i].redeemable.redeem(msg.sender, purchases[i].passId) {}
            catch (bytes memory reason) {
                revert RedeemableCallbackFailed(purchases[i].redeemable, reason);
            }
            projectIds[i] = purchases[i].projectId;
        }

        _purchase(msg.sender, projectIds);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 Proof Holdings Inc.
pragma solidity >=0.8.17;

/**
 * @notice Diamond Exhibition - Projects configuration.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract ProjectsConfig {
    /**
     * @notice The number of longform projects.
     */
    uint8 internal constant _NUM_LONGFORM_PROJECTS = 11;

    /**
     * @notice The number of pre-curated projects.
     */
    uint8 internal constant _NUM_CURATED_PROJECTS = 10;

    /**
     * @notice The total number of projects.
     */
    uint8 public constant NUM_PROJECTS = _NUM_LONGFORM_PROJECTS + _NUM_CURATED_PROJECTS;

    /**
     * @notice Returns the number of projects than can be minted per project.
     */
    function _maxNumPerProject() internal pure virtual returns (uint256[NUM_PROJECTS] memory sizes) {
        return [
            // Longform
            uint256(600), // Impossible Distance
            600, // cathedral study
            600, // Deja Vu
            800, // WaveShapes
            1000, // Ephemeral Tides
            600, // StackSlash
            450, // Viridaria
            1000, // Windwoven
            256, // Memory Loss
            1000, // The Collector's Room
            1000, // Extrañezas
            // Pre-curated
            100, // Everydays: Group Effort
            100, // Kid Heart
            100, // BEHEADED (SELF PORTRAIT)
            1127, // End Transmissions
            77, // DES CHOSES™
            100, // A Wintry Night in Chinatown
            100, // Penthouse
            200, // Hands of Umbra
            100, // Solitaire
            100 // Remnants of a Distant Dream
        ];
    }

    /**
     * @notice Returns the number of projects than can be minted per project.
     */
    function maxNumPerProject() external pure returns (uint256[NUM_PROJECTS] memory) {
        return _maxNumPerProject();
    }

    // =========================================================================
    //                          Project Types
    // =========================================================================

    /**
     * @notice The different types of projects.
     */
    enum ProjectType {
        Longform,
        Curated
    }

    /**
     * @notice Returns the project type for a given project ID.
     */
    function projectType(uint8 projectId) public pure returns (ProjectType) {
        return projectId < _NUM_LONGFORM_PROJECTS ? ProjectType.Longform : ProjectType.Curated;
    }

    /**
     * @notice Returns true iff the project is a longform project.
     */
    function _isLongformProject(uint8 projectId) internal pure virtual returns (bool) {
        return projectType(projectId) == ProjectType.Longform;
    }

    // =========================================================================
    //                          Artblocks
    // =========================================================================

    /**
     * @notice Returns the ArtBlocks engine project IDs for the longform projects.
     */
    function _artblocksProjectIds() internal pure virtual returns (uint8[_NUM_LONGFORM_PROJECTS] memory) {
        return [5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15];
    }

    /**
     * @notice Returns the ArtBlocks engine project IDs for the longform projects.
     */
    function artblocksProjectIds() external pure returns (uint8[_NUM_LONGFORM_PROJECTS] memory) {
        return _artblocksProjectIds();
    }

    /**
     * @notice Returns the ArtBlocks engine project ID for a given project ID.
     * @dev Reverts if the project is not long-form.
     */
    function _artblocksProjectId(uint8 projectId) internal pure returns (uint256) {
        assert(_isLongformProject(projectId));
        return _artblocksProjectIds()[projectId];
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {ERC721A, ERC721ACommon, BaseTokenURI, ERC721ACommonBaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";
import {OperatorFilterOS} from "ethier/erc721/OperatorFilterOS.sol";

import {
    TransferRestrictedRedeemableERC721ACommon,
    TransferRestriction
} from "proof/redemption/voucher/TransferRestrictedRedeemableERC721ACommon.sol";
import {SellableERC721ACommon} from "proof/sellers/sellable/SellableERC721ACommon.sol";

/**
 * @notice A redeemable and sellable ERC721 token with operator filtering and transfer restrictions.
 * @dev The contract name should be sung to the tune of "Modern Major-General"
 */
abstract contract SellableRedeemableRestrictableERC721 is
    ERC721ACommonBaseTokenURI,
    OperatorFilterOS,
    SellableERC721ACommon,
    TransferRestrictedRedeemableERC721ACommon
{
    // =================================================================================================================
    //                          Inheritance Resolution
    // =================================================================================================================

    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(ERC721ACommon, ERC721ACommonBaseTokenURI, SellableERC721ACommon, TransferRestrictedRedeemableERC721ACommon)
        returns (bool)
    {
        return TransferRestrictedRedeemableERC721ACommon.supportsInterface(interfaceId)
            || SellableERC721ACommon.supportsInterface(interfaceId)
            || ERC721ACommonBaseTokenURI.supportsInterface(interfaceId);
    }

    function _beforeTokenTransfers(address from, address to, uint256 startTokenId, uint256 quantity)
        internal
        virtual
        override(ERC721ACommon, TransferRestrictedRedeemableERC721ACommon)
    {
        TransferRestrictedRedeemableERC721ACommon._beforeTokenTransfers(from, to, startTokenId, quantity);
    }

    function _baseURI() internal view virtual override(ERC721A, ERC721ACommonBaseTokenURI) returns (string memory) {
        return ERC721ACommonBaseTokenURI._baseURI();
    }

    function setApprovalForAll(address operator, bool approved) public virtual override(ERC721A, OperatorFilterOS) {
        OperatorFilterOS.setApprovalForAll(operator, approved);
    }

    function approve(address operator, uint256 tokenId) public payable virtual override(ERC721A, OperatorFilterOS) {
        OperatorFilterOS.approve(operator, tokenId);
    }

    function transferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.transferFrom(from, to, tokenId);
    }

    function safeTransferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.safeTransferFrom(from, to, tokenId);
    }

    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.safeTransferFrom(from, to, tokenId, data);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 Proof Holdings Inc.
pragma solidity >=0.8.17;

/**
 * @notice Token information module for Diamond Exhibition.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract TokenInfoManager {
    /**
     * @notice Encodes token information.
     * @param projectId the ID of the project associated with the token.
     * @param edition the edition of the token within the given project.
     */
    struct TokenInfo {
        uint8 projectId;
        uint16 edition;
    }

    /**
     * @notice Max numbers of tokens that this contract can store.
     * @dev This constant is intentionally very large so we never have to worry about it.
     */
    uint256 internal constant _NUM_MAX_TOKEN_INFO = (1 << 32);

    /**
     * @notice Stores token information.
     */
    TokenInfo[_NUM_MAX_TOKEN_INFO] private _infos;

    /**
     * @notice Returns the token information for the given token IDs.
     * @dev Intended for off-chain use only.
     */
    function tokenInfos(uint256[] calldata tokenIds) external view returns (TokenInfo[] memory) {
        TokenInfo[] memory infos = new TokenInfo[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            infos[i] = _tokenInfo(tokenIds[i]);
        }
        return infos;
    }

    /**
     * @notice Returns the token information for the given token ID.
     */
    function _tokenInfo(uint256 tokenId) internal view returns (TokenInfo memory) {
        return _infos[tokenId];
    }

    /**
     * @notice Sets the token information for the given token ID.
     */
    function _setTokenInfo(uint256 tokenId, uint8 projectId, uint16 edition) internal {
        _infos[tokenId] = TokenInfo({projectId: projectId, edition: edition});
    }
}

{
  "compilationTarget": {
    "src/sellers/DiamondPassRedeemer.sol": "DiamondPassRedeemer"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 9999
  },
  "remappings": [
    ":@divergencetech/ethier/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ethier_0-55-0/",
    ":@openzeppelin-4-7-0/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-7-0_exact_remap/",
    ":@openzeppelin-4.7/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-7-0_exact_remap/",
    ":@openzeppelin/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-8-1/",
    ":ERC721A/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ERC721A_4-2-3/contracts/",
    ":ERC721A_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ERC721A_4-2-3/",
    ":artblocks-contracts/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/artblocks-contracts_fa1dc466/contracts/",
    ":artblocks-contracts_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/artblocks-contracts_fa1dc466/",
    ":delegation-registry/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/delegation-registry_2d1a158b/src/",
    ":delegation-registry_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/delegation-registry_2d1a158b/",
    ":ds-test/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ds-test_013e6c64/src/",
    ":ds-test_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ds-test_013e6c64/",
    ":erc721a/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ERC721A_4-2-3/",
    ":ethier/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ethier_0-55-0/contracts/",
    ":ethier_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/ethier_0-55-0/",
    ":forge-std/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/forge-std_1-4-0/src/",
    ":openzeppelin-contracts-4-7-0/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-7-0_exact_remap/contracts/",
    ":openzeppelin-contracts/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-8-1/contracts/",
    ":openzeppelin-contracts/contracts/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-8-1/contracts/",
    ":openzeppelin-contracts_root-4-7-0/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-7-0_exact_remap/",
    ":openzeppelin-contracts_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/openzeppelin-contracts_4-8-1/",
    ":operator-filter-registry/src/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/operator-filter-registry_1-4-1/src/",
    ":operator-filter-registry_root/=/home/dave/.cache/bazel/_bazel_dave/b9a57168317213f9241a484d2ee2d038/external/operator-filter-registry_1-4-1/",
    ":proof/artblocks/=/home/dave/proof/proof-seller/contracts/artblocks/src/",
    ":proof/constants/=/home/dave/proof/proof-seller/contracts/constants/src/",
    ":proof/redemption/=/home/dave/proof/proof-seller/contracts/redemption/src/",
    ":proof/sellers/=/home/dave/proof/proof-seller/contracts/sellers/src/"
  ]
}