// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Pausable.sol";
import "./interfaces/ITreasury.sol";

contract CasStakingPool is Ownable, Pausable {
    ITreasury public treasury;
    mapping(address reward => bool) private _activeRewards;
    mapping(address user => mapping(address token => uint256))
        private _userRewards;
    address[] private _rewardTokens;

    error CasStakingPool_RewardNotExists(address reward);
    error CasStakingPool_RewardAlreadyExists(address reward);
    error CasStakingPool_InvalidArrayLength(
        uint256 userLength,
        uint256 rewardLength
    );

    event Claim(address indexed token, address indexed user, uint256 amount);
    event AddReward(address indexed token);
    event RemoveReward(address indexed token);
    event RewardUpdate(
        address indexed token,
        address indexed user,
        uint256 amount
    );
    event RewardDistribution();

    modifier isActiveReward(address rewardToken) {
        if (!_activeRewards[rewardToken]) {
            revert CasStakingPool_RewardNotExists(rewardToken);
        }
        _;
    }

    constructor(address _owner, ITreasury _treasury) Ownable(_owner) {
        treasury = _treasury;
    }

    function pause() external onlyOwner {
        _pause();
    }

    function unpause() external onlyOwner {
        _unpause();
    }

    function changeTreasury(ITreasury _treasury) external onlyOwner {
        treasury = _treasury;
    }

    function addReward(address rewardToken) external onlyOwner {
        if (_activeRewards[rewardToken]) {
            revert CasStakingPool_RewardAlreadyExists(rewardToken);
        }

        _activeRewards[rewardToken] = true;
        _rewardTokens.push(rewardToken);

        emit AddReward(rewardToken);
    }

    function removeReward(
        address rewardToken
    ) external onlyOwner isActiveReward(rewardToken) {
        _activeRewards[rewardToken] = false;

        uint256 length = _rewardTokens.length;

        for (uint256 i; i < length; ) {
            address reward = _rewardTokens[i];

            if (reward == rewardToken) {
                _rewardTokens[i] = _rewardTokens[length - 1];
                _rewardTokens.pop();
                break;
            }

            unchecked {
                ++i;
            }
        }

        emit RemoveReward(rewardToken);
    }

    function updateUsersRewardsBatch(
        address[] calldata rewardTokens,
        address[] calldata users,
        uint256[][] memory rewardAmounts
    ) external onlyOwner {
        uint256 userLength = users.length;
        uint256 rewardAmountsLength = rewardAmounts.length;

        if (userLength != rewardAmountsLength) {
            revert CasStakingPool_InvalidArrayLength(
                userLength,
                rewardAmountsLength
            );
        }

        uint256 rewardsLength = rewardTokens.length;

        for (uint256 i; i < userLength; ) {
            uint256[] memory amounts = rewardAmounts[i];

            if (rewardsLength != amounts.length) {
                revert CasStakingPool_InvalidArrayLength(
                    rewardsLength,
                    amounts.length
                );
            }

            for (uint256 j; j < rewardsLength; ) {
                _updateUserReward(
                    users[i],
                    rewardTokens[j],
                    rewardAmounts[i][j]
                );

                unchecked {
                    ++j;
                }
            }

            unchecked {
                ++i;
            }
        }

        emit RewardDistribution();
    }

    function updateUsersRewards(
        address rewardToken,
        address[] calldata users,
        uint256[] calldata rewardAmounts
    ) external onlyOwner {
        uint256 userLength = users.length;
        uint256 rewardLength = rewardAmounts.length;

        if (userLength != rewardLength) {
            revert CasStakingPool_InvalidArrayLength(userLength, rewardLength);
        }

        for (uint256 i; i < userLength; ) {
            _updateUserReward(users[i], rewardToken, rewardAmounts[i]);

            unchecked {
                ++i;
            }
        }

        emit RewardDistribution();
    }

    function _updateUserReward(
        address user,
        address rewardToken,
        uint256 amount
    ) internal {
        _userRewards[user][rewardToken] += amount;

        emit RewardUpdate(rewardToken, user, amount);
    }

    function claimRewards() external whenNotPaused {
        uint256 length = _rewardTokens.length;

        for (uint256 i; i < length; ) {
            address rewardToken = _rewardTokens[i];
            uint256 reward = _userRewards[msg.sender][rewardToken];

            _userRewards[msg.sender][rewardToken] = 0;

            treasury.sendToken(rewardToken, msg.sender, reward);

            emit Claim(rewardToken, msg.sender, reward);

            unchecked {
                ++i;
            }
        }
    }

    function getRewardTokens() external view returns (address[] memory) {
        return _rewardTokens;
    }

    function getUserRewardAmount(
        address user,
        address reward
    ) external view returns (uint256) {
        return _userRewards[user][reward];
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface ITreasury {
    function sendToken(address token, address to, uint256 amount) external;

    function sendNative(uint256 amount, address to) external;

    function whiteslists(address) external view returns (bool);

    function withdraw(address token, uint256 amount) external;

    function withdrawNative(uint256 amount) external;

    receive() external payable;

    fallback() external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

{
  "compilationTarget": {
    "contracts/CasStakingPool.sol": "CasStakingPool"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}