// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false
library TransferHelper {
    function safeTransfer(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transfer(address,uint256)')));
        (bool success, bytes memory data) =
            token.call(abi.encodeWithSelector(0xa9059cbb, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            "TransferHelper: TRANSFER_FAILED"
        );
    }

    function safeTransferFrom(
        address token,
        address from,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transferFrom(address,address,uint256)')));
        (bool success, bytes memory data) =
            token.call(abi.encodeWithSelector(0x23b872dd, from, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            "TransferHelper: TRANSFER_FROM_FAILED"
        );
    }
}

interface IQLF {
    function ifQualified(address addr) external view returns (bool qualified);
}

contract Stake is Ownable {
    using SafeERC20 for IERC20;
    using Address for address;
    using SafeMath for uint256;

    uint256 private constant ONE_YEAR = 365;
    uint256 private MIN_STAKE_TIME = 1 days;

    // Info of each user.
    struct UserInfo {
        uint256 pid; // Pool id
        uint256 index; // Deposit index
        string name; // name
        uint256 amount; // How many tokens the user has provided.
        uint256 depositAt; // User deposit block timestamp.
        uint256 expireAt; // User deposit expire timestamp.
        bool compound; // User compound to demand deposit
        bool settled; // User settle flag.
    }

    struct WithdrawInfo {
        uint256 pid; // pool id
        uint256 dIndex; // index for deposit record
        uint256 wIndex; // index for withdraw record
        uint256 depositAt; // deposit at timestamp
        uint256 withdrawAt; // withdraw at timestamp
        uint256 dAmount; // user deposit amount
        uint256 wAmount; // withdraw amount
        uint256 reward; // withdraw reward
        uint256 rAmount; // remain amount
    }

    struct RecurringAPY {
        uint256 recurringDuration; // pool recurring reward duration
        uint256 recurringRewardNumerator; // recurring reward apy numerator
        uint256 recurringRewardDenominator; // recurring reward apy denominator
    }

    struct APY {
        uint256 duration; // Demand deposit duration
        uint256 rewardNumerator; // Demand deposit reward apy numerator
        uint256 rewardDenominator; // Demand deposit reward apy denominator
    }

    // Info of each pool
    struct PoolInfo {
        uint256 pid; // pool id
        IERC20 pToken; // pool deposit token
        string name; // pool name
        bool isDepositPaused; // is pool paused
        bool isWithdrawPaused; // is withdraw paused
        bool isWhiteList; // is whitelist
        bool isRecurring; // is pool recurring stake
        uint256 startTime; // pool start timestamp
        uint256 totalStake; // total stake
        uint256 settledReward; // already settled reward
        RecurringAPY recurringAPY; // pool recurring apy
        APY apy; // pool apy
    }

    IQLF public addressQLF;
    // Info of each user that stakes tokens.
    mapping(uint256 => mapping(address => UserInfo[])) public userInfo;

    // Info of each user that withdraw.
    mapping(uint256 => mapping(address => WithdrawInfo[])) public withdrawInfos;

    // User join pool ids
    mapping(address => uint256[]) public userPids;

    // Each pool info
    PoolInfo[] public poolInfo;

    // All participant address
    address[] public participants;

    // Allow emergency withdraw if needed
    bool private allowEmergencyWithdraw;

    event AddPool(uint256 pid, string name, uint256 startTime);

    event Deposit(
        uint256 pid,
        address indexed user,
        uint256 amount,
        uint256 index
    );
    event Withdraw(
        address indexed user,
        uint256 pid,
        uint256 index,
        uint256 amount,
        uint256 reward
    );
    event EmergencyWithdraw(
        address indexed user,
        uint256 pid,
        uint256 index,
        uint256 amount
    );

    // receive ethers
    receive() external payable {}

    // Add a new round. Can only be called by the owner.
    function addPool(
        IERC20 _pToken,
        string memory _name,
        bool _isWhiteList,
        bool _isRecurring,
        uint256 _startTime,
        uint256 _recurringDuration,
        uint256 _recurringRewardNumerator,
        uint256 _recurringRewardDenominator,
        uint256 _duration,
        uint256 _rewardNumerator,
        uint256 _rewardDenominator
    ) external onlyOwner {
        require(
            _recurringRewardNumerator > 0,
            "reward denominator can't be zero"
        );
        require(_recurringDuration >= MIN_STAKE_TIME, "at least one day");
        uint256 pid = poolInfo.length;
        poolInfo.push(
            PoolInfo({
                pid: pid,
                name: _name,
                pToken: _pToken,
                isDepositPaused: false,
                isWithdrawPaused: false,
                isWhiteList: _isWhiteList,
                isRecurring: _isRecurring,
                startTime: _startTime,
                totalStake: 0,
                settledReward: 0,
                recurringAPY: RecurringAPY({
                    recurringDuration: _recurringDuration,
                    recurringRewardNumerator: _recurringRewardNumerator,
                    recurringRewardDenominator: _recurringRewardDenominator
                }),
                apy: APY({
                    duration: _duration,
                    rewardNumerator: _rewardNumerator,
                    rewardDenominator: _rewardDenominator
                })
            })
        );

        emit AddPool(pid, _name, _startTime);
    }

    function setEmergencyWithdraw(bool _allow) external onlyOwner {
        allowEmergencyWithdraw = _allow;
    }

    function setMinStakeTime(uint256 _time) external onlyOwner {
        MIN_STAKE_TIME = _time;
    }

    function setPoolPaused(
        uint256 _pid,
        bool _isDepositPaused,
        bool _isWithdrawPaused
    ) external onlyOwner {
        PoolInfo storage pool = poolInfo[_pid];
        pool.isDepositPaused = _isDepositPaused;
        pool.isWithdrawPaused = _isWithdrawPaused;
    }

    function setPoolName(uint256 _pid, string memory _name) external onlyOwner {
        PoolInfo storage pool = poolInfo[_pid];
        pool.name = _name;
    }

    function getPoolName(uint256 _pid) external view returns (string memory) {
        PoolInfo storage pool = poolInfo[_pid];
        return pool.name;
    }

    function setPoolWhiteList(uint256 _pid, bool _isWhiteList)
        external
        onlyOwner
    {
        PoolInfo storage pool = poolInfo[_pid];
        pool.isWhiteList = _isWhiteList;
    }

    function updatePoolAPY(
        uint256 _pid,
        bool _isRecurring,
        uint256 _recurringDuration,
        uint256 _recurringRewardNumerator,
        uint256 _recurringRewardDenominator,
        uint256 _duration,
        uint256 _rewardNumerator,
        uint256 _rewardDenominator
    ) external onlyOwner {
        PoolInfo storage pool = poolInfo[_pid];
        pool.isRecurring = _isRecurring;
        pool.recurringAPY.recurringDuration = _recurringDuration;
        pool.recurringAPY.recurringRewardNumerator = _recurringRewardNumerator;
        pool
            .recurringAPY
            .recurringRewardDenominator = _recurringRewardDenominator;
        pool.apy.duration = _duration;
        pool.apy.rewardNumerator = _rewardNumerator;
        pool.apy.rewardDenominator = _rewardDenominator;
    }

    function getAllPools() external view returns (PoolInfo[] memory) {
        return poolInfo;
    }

    function allPoolsLength() external view returns (uint256) {
        return poolInfo.length;
    }

    function allParticipantsLength() external view returns (uint256) {
        return participants.length;
    }

    function getAllParticipants() external view returns (address[] memory) {
        return participants;
    }

    function getUserDepositLength(uint256 _pid, address _user)
        external
        view
        returns (uint256)
    {
        return userInfo[_pid][_user].length;
    }

    function getPoolTotalStake(uint256 _pid) external view returns (uint256) {
        PoolInfo storage pool = poolInfo[_pid];
        return pool.totalStake;
    }

    function setAddressQLF(IQLF _qlf) public onlyOwner returns (bool) {
        addressQLF = _qlf;
        return true;
    }

    function deposit(
        uint256 _pid,
        uint256 _amount,
        bool _compound
    ) external {
        require(_amount > 0, "invalid amount");
        require(_pid < poolInfo.length, "invalid pool");
        PoolInfo storage pool = poolInfo[_pid];
        require(!pool.isDepositPaused, "pool is paused");
        bool qualified =
            !pool.isWhiteList || addressQLF.ifQualified(msg.sender);
        require(qualified, "user not in whitelist");

        // deposit to pool
        TransferHelper.safeTransferFrom(
            address(pool.pToken),
            address(msg.sender),
            address(this),
            _amount
        );

        pool.totalStake = pool.totalStake.add(_amount);

        uint256 index = userInfo[_pid][msg.sender].length;
        if (index == 0) {
            participants.push(msg.sender);
            userPids[msg.sender].push(_pid);
        }

        uint256 expiredAt = 0;
        if (pool.isRecurring) {
            expiredAt = block.timestamp.add(
                pool.recurringAPY.recurringDuration
            );
        }
        userInfo[_pid][msg.sender].push(
            UserInfo({
                pid: _pid,
                name: pool.name,
                index: index,
                amount: _amount,
                compound: _compound,
                settled: false,
                depositAt: block.timestamp,
                expireAt: expiredAt
            })
        );

        emit Deposit(_pid, msg.sender, _amount, index);
    }

    function withdraw(
        uint256 _pid,
        uint256 _index,
        address _receiver,
        uint256 _amount
    ) public {
        require(
            allowWithdraw(_pid, _index, block.timestamp),
            "withdraw isn't allow"
        );

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender][_index];

        uint256 reward = getReward(_pid, _index, msg.sender, block.timestamp);

        uint256 totalAmount = reward.add(user.amount);
        require(
            pool.pToken.balanceOf(address(this)) > totalAmount,
            "insufficient balance"
        );
        require(totalAmount >= _amount, "insufficient amount");
        if (_amount == 0) {
            _amount = totalAmount;
        }
        emit Withdraw(msg.sender, _pid, _index, _amount, reward);
        TransferHelper.safeTransfer(
            address(pool.pToken),
            address(_receiver),
            _amount
        );

        uint256 wIndex = withdrawInfos[_pid][msg.sender].length;
        // deposit amount is user's amount
        uint256 dAmount = user.amount;
        uint256 wAmount = 0;
        uint256 wReward = 0;

        pool.totalStake = pool.totalStake.sub(user.amount);
        pool.settledReward = pool.settledReward.add(reward);
        if (totalAmount == _amount) {
            wAmount = user.amount;
            wReward = reward;
            user.settled = true;
            user.amount = 0;
        } else {
            user.amount = totalAmount.sub(_amount);
            pool.totalStake = pool.totalStake.add(user.amount);
            if (_amount <= reward) {
                wReward = _amount;
            } else {
                wReward = reward;
                wAmount = _amount.sub(reward);
            }
        }

        // remain deposit amount is the new user's amount
        uint256 rAmount = user.amount;
        withdrawInfos[_pid][msg.sender].push(
            WithdrawInfo({
                pid: _pid,
                dIndex: _index,
                wIndex: wIndex,
                depositAt: user.depositAt,
                withdrawAt: block.timestamp,
                dAmount: dAmount,
                wAmount: wAmount,
                reward: wReward,
                rAmount: rAmount
            })
        );
    }

    function getUserAllDepositLength(address _user)
        public
        view
        returns (uint256)
    {
        uint256[] memory pids = userPids[_user];

        uint256 count = 0;
        for (uint256 i = 0; i < pids.length; i++) {
            uint256 depositLength = userInfo[pids[i]][_user].length;
            count = count.add(depositLength);
        }

        return count;
    }

    function getUserAllPoolDeposit(address _user)
        public
        view
        returns (UserInfo[] memory)
    {
        uint256[] memory pids = userPids[_user];

        UserInfo[] memory infos =
            new UserInfo[](getUserAllDepositLength(_user));

        uint256 index = 0;
        for (uint256 i = 0; i < pids.length; i++) {
            uint256 depositLength = userInfo[pids[i]][_user].length;
            for (uint256 j = 0; j < depositLength; j++) {
                infos[index] = userInfo[pids[i]][_user][j];
                index++;
            }
        }
        return infos;
    }

    // getUserAllPoolDepositAndReward. get user all pool deposit, and sum all reward.
    function getUserAllPoolDepositAndReward(address _user, uint256 _curTime)
        external
        view
        returns (uint256, uint256)
    {
        UserInfo[] memory infos = getUserAllPoolDeposit(_user);
        uint256 totalAmount = 0;
        uint256 totalReward = 0;

        for (uint256 i = 0; i < infos.length; i++) {
            if (infos[i].settled) {
                continue;
            }
            totalAmount = totalAmount.add(infos[i].amount);
            totalReward = totalReward.add(
                getReward(infos[i].pid, infos[i].index, _user, _curTime)
            );
        }

        return (totalAmount, totalReward);
    }

    // allWithdrawablePoolDepositAndReward. get user all withdrawable pool deposit, and sum all reward.
    function allWithdrawablePoolDepositAndReward(
        address _user,
        uint256 _curTime
    ) external view returns (uint256, uint256) {
        UserInfo[] memory infos = getUserAllPoolDeposit(_user);
        uint256 totalAmount = 0;
        uint256 totalReward = 0;
        for (uint256 i = 0; i < infos.length; i++) {
            if (infos[i].settled) {
                continue;
            }
            uint256 pid = infos[i].pid;
            uint256 index = infos[i].index;
            if (poolInfo[pid].isWithdrawPaused) {
                continue;
            }
            if (poolInfo[pid].isWhiteList) {
                if (!addressQLF.ifQualified(_user)) {
                    continue;
                }
            }
            if (
                !_allowWithdraw(
                    _curTime,
                    infos[i].depositAt,
                    poolInfo[pid].startTime,
                    poolInfo[pid].recurringAPY.recurringDuration,
                    poolInfo[pid].isRecurring
                )
            ) {
                continue;
            }
            totalAmount = totalAmount.add(infos[i].amount);
            totalReward = totalReward.add(
                getReward(pid, index, _user, _curTime)
            );
        }
        return (totalAmount, totalReward);
    }

    function withdrawAll(address _receiver) external {
        UserInfo[] memory infos = getUserAllPoolDeposit(msg.sender);
        for (uint256 i = 0; i < infos.length; i++) {
            if (infos[i].settled) {
                continue;
            }
            if (poolInfo[infos[i].pid].isWithdrawPaused) {
                continue;
            }
            if (poolInfo[infos[i].pid].isWhiteList) {
                if (!addressQLF.ifQualified(msg.sender)) {
                    continue;
                }
            }
            if (!allowWithdraw(infos[i].pid, infos[i].index, block.timestamp)) {
                continue;
            }
            withdraw(infos[i].pid, infos[i].index, _receiver, 0);
        }
    }

    // allowWithdraw. check if allow user to withdraw staked token
    function allowWithdraw(
        uint256 _pid,
        uint256 _index,
        uint256 _curTime
    ) public view returns (bool) {
        require(_pid < poolInfo.length, "invalid pool");
        require(_index < userInfo[_pid][msg.sender].length, "invalid index");

        UserInfo storage user = userInfo[_pid][msg.sender][_index];
        require(!user.settled, "already settled");

        PoolInfo storage pool = poolInfo[_pid];
        require(!pool.isWithdrawPaused, "pool is paused");

        bool qualified =
            !pool.isWhiteList || addressQLF.ifQualified(msg.sender);
        require(qualified, "user not in whitelist");

        // If user deposit before pool start, use pool start timestamp to calculate
        uint256 startTime =
            user.depositAt > pool.startTime ? user.depositAt : pool.startTime;

        if (_curTime < startTime) {
            return false;
        }

        if (pool.isRecurring) {
            if (_curTime.sub(startTime) < pool.recurringAPY.recurringDuration) {
                return false;
            }
        } else {
            return true;
        }

        return true;
    }

    function _allowWithdraw(
        uint256 _curTime,
        uint256 _depositAt,
        uint256 _poolStartTime,
        uint256 _recurringDuration,
        bool _isRecurring
    ) internal pure returns (bool) {
        uint256 _statTime =
            _depositAt > _poolStartTime ? _depositAt : _poolStartTime;
        if (_curTime < _statTime) {
            return false;
        }
        if (_isRecurring) {
            if (_curTime.sub(_statTime) < _recurringDuration) {
                return false;
            }
        } else {
            return true;
        }
        return true;
    }

    function getAllRewards(address _user, uint256 _curTime)
        external
        view
        returns (uint256[] memory)
    {
        UserInfo[] memory infos = getUserAllPoolDeposit(_user);
        uint256[] memory rewards = new uint256[](infos.length);
        for (uint256 i = 0; i < infos.length; i++) {
            uint256 reward =
                getReward(infos[i].pid, infos[i].index, _user, _curTime);
            rewards[i] = reward;
        }
        return rewards;
    }

    // getReward. get user stake reward
    function getReward(
        uint256 _pid,
        uint256 _index,
        address _user,
        uint256 _curTime
    ) public view returns (uint256) {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage info = userInfo[_pid][_user][_index];
        if (info.amount == 0) {
            return 0;
        }
        uint256 startTime =
            info.depositAt > pool.startTime ? info.depositAt : pool.startTime;
        if (startTime >= _curTime) {
            return 0;
        }

        uint256 recurringReward = 0;

        if (pool.isRecurring) {
            if (_curTime.sub(startTime) < pool.recurringAPY.recurringDuration) {
                return 0;
            }
            uint256 recurringDepositDay =
                pool.recurringAPY.recurringDuration.div(MIN_STAKE_TIME);
            recurringReward = info
                .amount
                .mul(recurringDepositDay)
                .mul(pool.recurringAPY.recurringRewardNumerator)
                .div(pool.recurringAPY.recurringRewardDenominator)
                .div(ONE_YEAR);

            if (!info.compound) {
                // User only care about recurring reward;
                return recurringReward;
            }

            // Calculate demand deposit reward
            uint256 demandDepositDay =
                _curTime
                    .sub(startTime)
                    .sub(pool.recurringAPY.recurringDuration)
                    .div(pool.apy.duration);
            if (demandDepositDay == 0) {
                return recurringReward;
            }
            uint256 demandDepositReward =
                info
                    .amount
                    .add(recurringReward)
                    .mul(demandDepositDay)
                    .mul(pool.apy.rewardNumerator)
                    .div(pool.apy.rewardDenominator)
                    .div(ONE_YEAR);
            return recurringReward.add(demandDepositReward);
        } else {
            if (_curTime.sub(startTime) < pool.apy.duration) {
                return 0;
            }
            uint256 demandDepositDay =
                _curTime.sub(startTime).div(pool.apy.duration);

            uint256 demandDepositReward =
                info
                    .amount
                    .mul(demandDepositDay)
                    .mul(pool.apy.rewardNumerator)
                    .div(pool.apy.rewardDenominator)
                    .div(ONE_YEAR);
            return demandDepositReward;
        }
    }

    // Withdraw without caring about rewards. EMERGENCY ONLY.
    function emergencyWithdraw(uint256 _pid, uint256 _index) external {
        require(allowEmergencyWithdraw, "emergency withdraw disallowed");
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender][_index];
        TransferHelper.safeTransfer(
            address(pool.pToken),
            address(msg.sender),
            user.amount
        );
        emit EmergencyWithdraw(msg.sender, _pid, _index, user.amount);

        uint256 wIndex = withdrawInfos[_pid][msg.sender].length;
        withdrawInfos[_pid][msg.sender].push(
            WithdrawInfo({
                pid: _pid,
                dIndex: _index,
                wIndex: wIndex,
                depositAt: user.depositAt,
                withdrawAt: block.timestamp,
                dAmount: user.amount,
                wAmount: user.amount,
                reward: 0,
                rAmount: 0
            })
        );

        pool.totalStake = pool.totalStake.sub(user.amount);
        user.settled = true;
        user.amount = 0;
    }

    function settleReward(
        uint256 _pid,
        uint256 _index,
        address _user,
        uint256 _curTime
    ) public view returns (uint256) {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage info = userInfo[_pid][_user][_index];
        if (info.amount == 0) {
            return 0;
        }
        uint256 startTime =
            info.depositAt > pool.startTime ? info.depositAt : pool.startTime;
        if (startTime >= _curTime) {
            return 0;
        }

        if (pool.isRecurring) {
            uint256 recurringDepositDay = 0;
            if (_curTime.sub(startTime) < pool.recurringAPY.recurringDuration) {
                recurringDepositDay = _curTime.sub(startTime).div(
                    MIN_STAKE_TIME
                );
            } else {
                recurringDepositDay = pool.recurringAPY.recurringDuration.div(
                    MIN_STAKE_TIME
                );
            }
            if (recurringDepositDay == 0) {
                return 0;
            }
            uint256 recurringReward =
                info
                    .amount
                    .mul(recurringDepositDay)
                    .mul(pool.recurringAPY.recurringRewardNumerator)
                    .div(pool.recurringAPY.recurringRewardDenominator)
                    .div(ONE_YEAR);

            if (!info.compound) {
                // User only care about recurring reward;
                return recurringReward;
            }

            if (_curTime.sub(startTime) < pool.recurringAPY.recurringDuration) {
                return recurringReward;
            }

            // Calculate demand deposit reward
            uint256 demandDepositDay =
                _curTime
                    .sub(startTime)
                    .sub(pool.recurringAPY.recurringDuration)
                    .div(pool.apy.duration);
            if (demandDepositDay == 0) {
                return recurringReward;
            }
            uint256 demandDepositReward =
                info
                    .amount
                    .add(recurringReward)
                    .mul(demandDepositDay)
                    .mul(pool.apy.rewardNumerator)
                    .div(pool.apy.rewardDenominator)
                    .div(ONE_YEAR);
            return recurringReward.add(demandDepositReward);
        } else {
            if (_curTime.sub(startTime) < pool.apy.duration) {
                return 0;
            }
            uint256 demandDepositDay =
                _curTime.sub(startTime).div(pool.apy.duration);

            uint256 demandDepositReward =
                info
                    .amount
                    .mul(demandDepositDay)
                    .mul(pool.apy.rewardNumerator)
                    .div(pool.apy.rewardDenominator)
                    .div(ONE_YEAR);
            return demandDepositReward;
        }
    }

    // Admin settle all deposit and return user fund and income
    function settle(address _admin) external onlyOwner {
        for (uint256 i = 0; i < participants.length; i++) {
            address addr = participants[i];
            UserInfo[] memory infos = getUserAllPoolDeposit(addr);

            for (uint256 j = 0; j < infos.length; j++) {
                if (infos[j].settled) {
                    continue;
                }
                uint256 pid = infos[j].pid;
                uint256 index = infos[j].index;
                uint256 reward =
                    settleReward(pid, index, addr, block.timestamp);

                // settle and refund user's token and income
                uint256 totalAmount = reward.add(infos[j].amount);
                poolInfo[pid].settledReward = poolInfo[pid].settledReward.add(
                    reward
                );

                TransferHelper.safeTransfer(
                    address(poolInfo[pid].pToken),
                    address(addr),
                    totalAmount
                );

                uint256 wIndex = withdrawInfos[pid][addr].length;
                withdrawInfos[pid][addr].push(
                    WithdrawInfo({
                        pid: pid,
                        dIndex: index,
                        wIndex: wIndex,
                        depositAt: infos[j].depositAt,
                        withdrawAt: block.timestamp,
                        dAmount: infos[j].amount,
                        wAmount: infos[j].amount,
                        reward: reward,
                        rAmount: 0
                    })
                );

                userInfo[pid][addr][index].settled = true;
                userInfo[pid][addr][index].amount = 0;
            }
        }

        // refund all remain pool token to admin
        for (uint256 i = 0; i < poolInfo.length; i++) {
            // reset total stake amount
            poolInfo[i].totalStake = 0;
            // check remain balance
            uint256 remain =
                IERC20(poolInfo[i].pToken).balanceOf(address(this));
            if (remain == 0) {
                continue;
            }
            TransferHelper.safeTransfer(
                address(poolInfo[i].pToken),
                _admin,
                remain
            );
        }
    }

    // getAllSettledReward. get all pool settled reward
    function getAllSettledReward() external view returns (uint256) {
        uint256 poolLength = poolInfo.length;
        uint256 totalSettledReward = 0;
        for (uint256 i = 0; i < poolLength; i++) {
            totalSettledReward.add(poolInfo[i].settledReward);
        }
        return totalSettledReward;
    }

    // getUserAllPoolWithdraw. get all withdraw infos
    function getUserAllPoolWithdraw(address _user)
        external
        view
        returns (WithdrawInfo[] memory)
    {
        uint256[] memory pids = userPids[_user];

        uint256 count = 0;
        for (uint256 i = 0; i < pids.length; i++) {
            uint256 len = withdrawInfos[pids[i]][_user].length;
            count = count.add(len);
        }

        WithdrawInfo[] memory infos = new WithdrawInfo[](count);

        uint256 index = 0;
        for (uint256 i = 0; i < pids.length; i++) {
            uint256 len = withdrawInfos[pids[i]][_user].length;
            for (uint256 j = 0; j < len; j++) {
                infos[index] = withdrawInfos[pids[i]][_user][j];
                index++;
            }
        }
        return infos;
    }

    // getRemainTokenBalance. calculate user debt, and returns remain balance
    function getRemainTokenBalance(address _token, uint256 _curTime)
        external
        view
        returns (
            uint256,
            uint256,
            uint256
        )
    {
        uint256 debt = 0;
        for (uint256 i = 0; i < participants.length; i++) {
            address addr = participants[i];
            UserInfo[] memory infos = getUserAllPoolDeposit(addr);

            for (uint256 j = 0; j < infos.length; j++) {
                if (infos[j].settled) {
                    continue;
                }
                if (address(poolInfo[infos[j].pid].pToken) != _token) {
                    continue;
                }
                uint256 reward =
                    settleReward(infos[j].pid, infos[j].index, addr, _curTime);
                debt = debt.add(infos[j].amount).add(reward);
            }
        }

        uint256 balance = IERC20(_token).balanceOf(address(this));
        if (balance >= debt) {
            return (balance, debt, balance.sub(debt));
        }
        return (balance, debt, 0);
    }
}

{
  "compilationTarget": {
    "stake.sol": "Stake"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}