// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.23;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IMoonshotToken is IERC20 {
    enum CurveType {
        ConstantProductV1
    }

    struct ConstructorParams {
        string name;
        string symbol;
        address creator;
        uint256 totalSupply;
        uint256 virtualTokenReserves;
        uint256 virtualCollateralReserves;
        uint256 feeBasisPoints;
        uint256 dexFeeBasisPoints;
        uint256 migrationFeeFixed;
        uint256 poolCreationFee;
        uint256 mcLowerLimit;
        uint256 mcUpperLimit;
        uint256 tokensMigrationThreshold;
        address treasury;
        address uniV2Router;
        address dexTreasury;
    }

    error NotEnoughETHReserves();
    error InsufficientTokenReserves();
    error FailedToSendETH();
    error NotEnoughtETHToBuyTokens();
    error SlippageCheckFailed();
    error MarketcapThresholdReached();
    error SendingToPairIsNotAllowedBeforeMigration();
    error TradingStopped();
    error OnlyFactory();

    function buyExactOut(
        uint256 _tokenAmount,
        uint256 _maxCollateralAmount
    ) external payable returns (uint256 collateralToPayWithFee, uint256 helioFee, uint256 dexFee);

    function buyExactIn(
        uint256 _amountOutMin
    ) external payable returns (uint256 collateralToPayWithFee, uint256 helioFee, uint256 dexFee);

    function sellExactIn(
        uint256 _tokenAmount,
        uint256 _amountOutMin
    ) external payable returns (uint256 collateralToReceiveMinusFee, uint256 helioFee, uint256 dexFee);

    function sellExactOut(
        uint256 _tokenAmountMax,
        uint256 _amountCollateral
    )
        external
        payable
        returns (uint256 collateralToReceiveMinusFee, uint256 tokensOut, uint256 helioFee, uint256 dexFee);

    function getAmountOutAndFee(
        uint256 _amountIn,
        uint256 _reserveIn,
        uint256 _reserveOut,
        bool _paymentTokenIsIn
    ) external view returns (uint256 amountOut, uint256 fee);

    function getAmountInAndFee(
        uint256 _amountOut,
        uint256 _reserveIn,
        uint256 _reserveOut,
        bool _paymentTokenIsOut
    ) external view returns (uint256 amountIn, uint256 fee);

    function migrate() external returns (uint256 tokensToMigrate, uint256 tokensToBurn, uint256 collateralAmount);

    function getCurveProgressBps() external view returns (uint256);

    function getMarketCap() external view returns (uint256);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.23;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function createPair(address tokenA, address tokenB) external returns (address pair);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity >=0.6.2;

interface IUniswapV2Router02 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);
    function swapTokensForExactETH(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactTokensForETH(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapETHForExactTokens(
        uint amountOut,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.23;

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {ERC20Burnable} from "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";

import {IUniswapV2Router02} from "./interfaces/IUniswapV2Router02.sol";
import {IUniswapV2Factory} from "./interfaces/IUniswapV2Factory.sol";
import {IMoonshotToken} from "./interfaces/IMoonshotToken.sol";

contract MoonshotToken is ERC20Burnable, IMoonshotToken, ReentrancyGuard {
    CurveType public constant curveType = CurveType.ConstantProductV1;

    uint256 public initalTokenSupply;
    uint256 public virtualTokenReserves;
    uint256 public virtualCollateralReserves;
    uint256 public immutable virtualCollateralReservesInitial;

    uint256 public immutable feeBPS;
    uint256 public immutable dexFeeBPS;

    uint256 public immutable mcLowerLimit;
    uint256 public immutable mcUpperLimit;
    uint256 public immutable tokensMigrationThreshold;

    uint256 public immutable fixedMigrationFee;
    uint256 public immutable poolCreationFee;

    address public immutable creator;
    address public immutable pair;
    address public immutable treasury;
    address public immutable dexTreasury;
    address public immutable factory;

    bool public tradingStopped;
    bool public sendingToPairNotAllowed = true;

    uint256 public constant MAX_BPS = 10_000;

    IUniswapV2Router02 public immutable uniswapV2Router;

    modifier buyChecks() {
        if (tradingStopped) revert TradingStopped();
        _;
        _checkMcLower();
        _checkMcUpperLimit();
    }

    modifier sellChecks() {
        if (tradingStopped) revert TradingStopped();
        _;
    }

    modifier onlyFactory() {
        if (msg.sender != factory) revert OnlyFactory();
        _;
    }

    constructor(ConstructorParams memory _params) ERC20(_params.name, _params.symbol) {
        _mint(address(this), _params.totalSupply);

        initalTokenSupply = _params.totalSupply;
        virtualCollateralReserves = _params.virtualCollateralReserves;
        virtualCollateralReservesInitial = _params.virtualCollateralReserves;
        virtualTokenReserves = _params.virtualTokenReserves;

        creator = _params.creator;

        feeBPS = _params.feeBasisPoints;
        dexFeeBPS = _params.dexFeeBasisPoints;

        treasury = _params.treasury;
        dexTreasury = _params.dexTreasury;

        fixedMigrationFee = _params.migrationFeeFixed;
        poolCreationFee = _params.poolCreationFee;

        mcLowerLimit = _params.mcLowerLimit;
        mcUpperLimit = _params.mcUpperLimit;
        tokensMigrationThreshold = _params.tokensMigrationThreshold;

        uniswapV2Router = IUniswapV2Router02(_params.uniV2Router);
        factory = msg.sender;
        (address token0, address token1) = address(this) < uniswapV2Router.WETH()
            ? (address(this), uniswapV2Router.WETH())
            : (uniswapV2Router.WETH(), address(this));

        pair = address(
            uint160(
                uint256(
                    keccak256(
                        abi.encodePacked(
                            hex"ff",
                            address(uniswapV2Router.factory()),
                            keccak256(abi.encodePacked(token0, token1)),
                            hex"96e8ac4277198ff8b6f785478aa9a39f403cb768dd02cbee326c3e7da348845f" // init code hash
                        )
                    )
                )
            )
        );
    }

    /**
     * @dev Buys tokenAmount of tokens for eth, refunding excess eth
     *
     * @param _tokenAmount - amount of tokens to buy
     * @param _maxCollateralAmount - maximum amount of collateral a caller is willing to spend
     */
    function buyExactOut(
        uint256 _tokenAmount,
        uint256 _maxCollateralAmount
    )
        external
        payable
        onlyFactory
        buyChecks
        returns (uint256 collateralToPayWithFee, uint256 helioFee, uint256 dexFee)
    {
        if (balanceOf(address(this)) <= _tokenAmount) revert InsufficientTokenReserves();

        uint256 collateralToSpend = (_tokenAmount * virtualCollateralReserves) / (virtualTokenReserves - _tokenAmount);
        (helioFee, dexFee) = _calculateFee(collateralToSpend);

        collateralToPayWithFee = collateralToSpend + helioFee + dexFee;

        if (collateralToPayWithFee > _maxCollateralAmount) revert SlippageCheckFailed();
        _transferCollateral(treasury, helioFee);
        _transferCollateral(dexTreasury, dexFee);

        virtualTokenReserves -= _tokenAmount;
        virtualCollateralReserves += collateralToSpend;

        uint256 refund;
        if (msg.value > collateralToPayWithFee) {
            // refund the user
            refund = msg.value - collateralToPayWithFee;
            _transferCollateral(msg.sender, refund);
        } else if (msg.value < collateralToPayWithFee) {
            revert NotEnoughtETHToBuyTokens();
        }

        _transfer(address(this), msg.sender, _tokenAmount);
    }

    /**
     * @dev Buys tokens specifing minimal amount of tokens a caller gets
     *
     * @param _amountOutMin - minimal amount of tokens a caller will get
     */
    function buyExactIn(
        uint256 _amountOutMin
    )
        external
        payable
        onlyFactory
        buyChecks
        returns (uint256 collateralToPayWithFee, uint256 helioFee, uint256 dexFee)
    {
        if (balanceOf(address(this)) <= _amountOutMin) revert InsufficientTokenReserves();

        collateralToPayWithFee = msg.value;
        (helioFee, dexFee) = _calculateFee(collateralToPayWithFee);
        uint256 collateralToSpendMinusFee = collateralToPayWithFee - helioFee - dexFee;

        _transferCollateral(treasury, helioFee);
        _transferCollateral(dexTreasury, dexFee);

        uint256 tokensOut = (collateralToSpendMinusFee * virtualTokenReserves) /
            (virtualCollateralReserves + collateralToSpendMinusFee);

        if (tokensOut < _amountOutMin) revert SlippageCheckFailed();

        virtualTokenReserves -= tokensOut;
        virtualCollateralReserves += collateralToSpendMinusFee;

        _transfer(address(this), msg.sender, tokensOut);
    }

    /**
     * @dev Sells given amount of tokens for eth
     *
     * @param _tokenAmount - amount of tokens a caller wants to sell
     * @param _amountCollateralMin - minimum amount of collateral a seller will get
     */
    function sellExactIn(
        uint256 _tokenAmount,
        uint256 _amountCollateralMin
    )
        external
        payable
        onlyFactory
        sellChecks
        returns (uint256 collateralToReceiveMinusFee, uint256 helioFee, uint256 dexFee)
    {
        uint256 collaterallToReceive = (_tokenAmount * virtualCollateralReserves) /
            (virtualTokenReserves + _tokenAmount);
        (helioFee, dexFee) = _calculateFee(collaterallToReceive);
        collateralToReceiveMinusFee = collaterallToReceive - helioFee - dexFee;
        _transferCollateral(treasury, helioFee);
        _transferCollateral(dexTreasury, dexFee);

        if (collateralToReceiveMinusFee < _amountCollateralMin) revert SlippageCheckFailed();

        virtualTokenReserves += _tokenAmount;
        virtualCollateralReserves -= collaterallToReceive;

        _transferCollateral(msg.sender, collateralToReceiveMinusFee);
        _transfer(msg.sender, address(this), _tokenAmount);
    }

    /**
     * @dev Sells given amount of tokens for eth
     *
     * @param _tokenAmountMax - max amount of tokens a caller wants to sell
     */
    function sellExactOut(
        uint256 _tokenAmountMax,
        uint256 _amountCollateral
    )
        external
        payable
        onlyFactory
        sellChecks
        returns (uint256 collateralToReceiveMinusFee, uint256 tokensOut, uint256 helioFee, uint256 dexFee)
    {
        (helioFee, dexFee) = _calculateFee(_amountCollateral);
        collateralToReceiveMinusFee = _amountCollateral - helioFee - dexFee;

        _transferCollateral(treasury, helioFee);
        _transferCollateral(dexTreasury, dexFee);

        tokensOut = (_amountCollateral * virtualTokenReserves) / (virtualCollateralReserves - _amountCollateral);

        if (tokensOut > _tokenAmountMax) revert SlippageCheckFailed();
        _transfer(msg.sender, address(this), tokensOut);

        virtualTokenReserves += tokensOut;
        virtualCollateralReserves -= _amountCollateral;

        _transferCollateral(msg.sender, collateralToReceiveMinusFee);
    }

    /**
     * @dev Calculates amountOut for a given amountIn
     *
     * @param _amountIn - amount in which will be transfered to the contract
     * @param _reserveIn - reserve in
     * @param _reserveOut - reserve out
     * @param _paymentTokenIsIn - if token in is a collateral token
     */
    function getAmountOutAndFee(
        uint256 _amountIn,
        uint256 _reserveIn,
        uint256 _reserveOut,
        bool _paymentTokenIsIn
    ) external view returns (uint256 amountOut, uint256 fee) {
        if (_paymentTokenIsIn) {
            (uint256 helioFee, uint256 dexFee) = _calculateFee(_amountIn);
            fee = helioFee + dexFee;

            amountOut = (_amountIn * _reserveOut) / (_reserveIn + _amountIn);
        } else {
            amountOut = (_amountIn * _reserveOut) / (_reserveIn + _amountIn);

            (uint256 helioFee, uint256 dexFee) = _calculateFee(amountOut);
            fee = helioFee + dexFee;
        }
    }

    /**
     * @dev Calculates amountIn for a given amountOut
     *
     * @param _amountOut - amount out which will be transfered from the contract
     * @param _reserveIn - reserve in
     * @param _reserveOut - reserve out
     * @param _paymentTokenIsOut - if token out is a payment token
     */
    function getAmountInAndFee(
        uint256 _amountOut,
        uint256 _reserveIn,
        uint256 _reserveOut,
        bool _paymentTokenIsOut
    ) external view returns (uint256 amountIn, uint256 fee) {
        if (_paymentTokenIsOut) {
            (uint256 helioFee, uint256 dexFee) = _calculateFee(_amountOut);
            fee = helioFee + dexFee;

            amountIn = (_amountOut * _reserveIn) / (_reserveOut - _amountOut);
        } else {
            amountIn = (_amountOut * _reserveIn) / (_reserveOut - _amountOut);
            (uint256 helioFee, uint256 dexFee) = _calculateFee(amountIn);

            fee = helioFee + dexFee;
        }
    }

    /**
     * @dev migrates tokens and collateral to uniswap-v2 and burns LP tokens
     */
    function migrate()
        external
        onlyFactory
        returns (uint256 tokensToMigrate, uint256 tokensToBurn, uint256 collateralAmount)
    {
        sendingToPairNotAllowed = false;

        if (IUniswapV2Factory(uniswapV2Router.factory()).getPair(address(this), uniswapV2Router.WETH()) == address(0)) {
            IUniswapV2Factory(uniswapV2Router.factory()).createPair(address(this), uniswapV2Router.WETH());
        }

        uint256 tokensRemaining = balanceOf(address(this));
        this.approve(address(uniswapV2Router), tokensRemaining);

        tokensToMigrate = _tokensToMigrate();
        tokensToBurn = tokensRemaining - tokensToMigrate;

        (uint256 treasuryFee, uint256 dexFee) = _splitFee(fixedMigrationFee);
        _transferCollateral(treasury, treasuryFee + poolCreationFee);
        _transferCollateral(dexTreasury, dexFee);

        _burn(address(this), tokensToBurn);
        collateralAmount =
            virtualCollateralReserves -
            virtualCollateralReservesInitial -
            treasuryFee -
            dexFee -
            poolCreationFee;

        (, , uint256 liquidity) = uniswapV2Router.addLiquidityETH{value: collateralAmount}(
            address(this),
            tokensToMigrate,
            tokensToMigrate,
            collateralAmount,
            address(this),
            block.timestamp + 10
        );

        if (address(this).balance > 0) {
            _transferCollateral(treasury, address(this).balance);
        }

        IERC20(pair).transfer(address(0), liquidity);
    }

    function getMarketCap() public view returns (uint256) {
        uint256 mc = (virtualCollateralReserves * 10 ** 18 * totalSupply()) / virtualTokenReserves;
        return mc / 10 ** 18;
    }

    function getCurveProgressBps() external view returns (uint256) {
        uint256 progress = ((initalTokenSupply - balanceOf(address(this))) * MAX_BPS) / tokensMigrationThreshold;
        return progress < 100 ? 100 : (progress > MAX_BPS ? MAX_BPS : progress);
    }

    function _tokensToMigrate() internal view returns (uint256) {
        uint256 collateralDeductedFee = address(this).balance - fixedMigrationFee - poolCreationFee;
        return (virtualTokenReserves * collateralDeductedFee) / virtualCollateralReserves;
    }

    function _calculateFee(uint256 _amount) internal view returns (uint256 treasuryFee, uint256 dexFee) {
        treasuryFee = (_amount * feeBPS) / MAX_BPS;
        dexFee = (treasuryFee * dexFeeBPS) / MAX_BPS;
        treasuryFee -= dexFee;
    }

    function _splitFee(uint256 _feeAmount) internal view returns (uint256 treasuryFee, uint256 dexFee) {
        dexFee = (_feeAmount * dexFeeBPS) / MAX_BPS;
        treasuryFee = _feeAmount - dexFee;
    }

    function _transferCollateral(address _to, uint256 _amount) internal {
        (bool sent, ) = _to.call{value: _amount}("");
        if (!sent) revert FailedToSendETH();
    }

    function _checkMcUpperLimit() internal view {
        uint256 mc = getMarketCap();

        if (mc > mcUpperLimit) revert MarketcapThresholdReached();
    }

    function _checkMcLower() internal {
        uint256 mc = getMarketCap();

        if (mc > mcLowerLimit) {
            tradingStopped = true;
        }
    }

    function transfer(address to, uint256 amount) public override(ERC20, IERC20) returns (bool) {
        if (to == pair && sendingToPairNotAllowed) revert SendingToPairIsNotAllowedBeforeMigration();
        return super.transfer(to, amount);
    }

    function transferFrom(address from, address to, uint256 amount) public override(ERC20, IERC20) returns (bool) {
        if (to == pair && sendingToPairNotAllowed) revert SendingToPairIsNotAllowedBeforeMigration();
        return super.transferFrom(from, to, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/MoonshotToken.sol": "MoonshotToken"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [],
  "viaIR": true
}