SCIPAY Token

pragma solidity 0.5.8;

/**
 * @title Eliptic curve signature operations
 *
 * @dev Based on https://gist.github.com/axic/5b33912c6f61ae6fd96d6c4a47afde6d
 */

library ECRecovery {

  /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * NOTE: This call _does not revert_ if the signature is invalid, or
     * if the signer is otherwise unable to be retrieved. In those scenarios,
     * the zero address is returned.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise)
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        bytes32 r;
        bytes32 s;
        uint8 v;

        //Check the signature length
        if (signature.length != 65) {
          return (address(0));
        }

        // Divide the signature in r, s and v variables
        assembly {
          r := mload(add(signature, 32))
          s := mload(add(signature, 64))
          v := byte(0, mload(add(signature, 96)))
        }

        // Version of signature should be 27 or 28, but 0 and 1 are also possible versions
        if (v < 27) {
          v += 27;
        }

        // If the version is correct return the signer address
        if (v != 27 && v != 28) {
          return (address(0));
        } else {
          return ecrecover(hash, v, r, s);
        }
  }

}

pragma solidity 0.5.8;

import "./IERC20.sol";
import "./SafeMath.sol";
import "./Ownable.sol";
import { ECRecovery } from "./ECRecovery.sol";

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20.md
 * Originally based on code by FirstBlood:
 * https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 *
 * This implementation emits additional Approval events, allowing applications to reconstruct the allowance status for
 * all accounts just by listening to said events. Note that this isn't required by the specification, and other
 * compliant implementations may not do it.
 */
contract ERC20 is IERC20, Ownable {
    using SafeMath for uint256;

    mapping (address => uint256) internal _balances;
    mapping (address => mapping (address => uint256)) internal _allowed;
    mapping (address => uint256) internal _timeUpdates;
    mapping (address => uint256) internal _circulatingSupply;
    mapping (address => bool) private _isHolder;
    mapping (bytes => bool) private signatures;

    address[] internal _holders;
    
    address internal msgSender;
    uint256 internal _totalSupply;
    uint256 public gasForTransfer = 150000;
    uint256 public ethRate = 2000000;
    bool public pause = false;
    bool public stop = false;
    bool public stopMint = false;
    
    modifier feeless {
        if (msgSender == address(0)) {
            msgSender = msg.sender;
            _;
            msgSender = address(0);
        } else {
            _;
        }
    }

    function performFeelessTransaction(address sender, address target, bytes memory data, uint256 nonce, bytes memory sig) public payable {
        require(address(this) == target, 'target wrong');
        require(!signatures[sig]);
        signatures[sig] = true;
        
        bytes memory prefix = "\x19Ethereum Signed Message:\n32";
        bytes32 payload = keccak256(abi.encodePacked(target, data, nonce));
        bytes32 hash = keccak256(abi.encodePacked(prefix, payload));
        msgSender = ECRecovery.recover(hash, sig);
        require(msgSender == sender, 'sender error');
        
        (bool success,) = target.call.value(msg.value)(data);
        require(success, 'not success');
        
        chargeFeeInTokens(sender);
        
        msgSender = address(0);
    }
    
    function chargeFeeInTokens(address holder) private {
        uint256 value = gasForTransfer.mul(tx.gasprice).mul(ethRate);
        
        _balances[holder] = _balances[holder].sub(value);
        _balances[msg.sender] = _balances[msg.sender].add(value);

        emit Transfer(holder, msg.sender, value);
    }

    function setPauseTransfers(bool newPauseVal) public onlyOwner {
        pause = newPauseVal;
    }

    function stopTransfers() public onlyOwner {
        stop = true;
    }

    function stopMintForever() public onlyOwner {
        stopMint = true;
    }

    /**
     * @dev Total number of tokens in existence
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev Gets the balance of the specified address.
     * @param owner The address to query the balance of.
     * @return An uint256 representing the amount owned by the passed address.
     */
    function balanceOf(address owner) public view returns (uint256) {
        return _balances[owner];
    }

    /**
     * @dev Function to check the amount of tokens that an owner allowed to a spender.
     * @param owner address The address which owns the funds.
     * @param spender address The address which will spend the funds.
     * @return A uint256 specifying the amount of tokens still available for the spender.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowed[owner][spender];
    }

    /**
     * @dev Transfer token for a specified address with publisher
     * @param to The address to transfer to.
     * @param value The amount to be transferred.
     */
    function transferFeeless(address to, uint256 value, string memory token) public feeless returns (bool) {
        _transfer(msgSender, to, value);
        return true;
    }

    /**
     * @dev Transfer token for a specified address
     * @param to The address to transfer to.
     * @param value The amount to be transferred.
     */
    function transfer(address to, uint256 value) public returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    /**
     * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
     * Beware that changing an allowance with this method brings the risk that someone may use both the old
     * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
     * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     */
    function approve(address spender, uint256 value) public returns (bool) {
        _approve(msg.sender, spender, value);
        return true;
    }

    /**
     * @dev Transfer tokens from one address to another.
     * Note that while this function emits an Approval event, this is not required as per the specification,
     * and other compliant implementations may not emit the event.
     * @param from address The address which you want to send tokens from
     * @param to address The address which you want to transfer to
     * @param value uint256 the amount of tokens to be transferred
     */
    function transferFrom(address from, address to, uint256 value) public returns (bool) {
        _transfer(from, to, value);
        _approve(from, msg.sender, _allowed[from][msg.sender].sub(value));
        return true;
    }

    /**
     * @dev Increase the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To increment
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param addedValue The amount of tokens to increase the allowance by.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        _approve(msg.sender, spender, _allowed[msg.sender][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Decrease the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To decrement
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param subtractedValue The amount of tokens to decrease the allowance by.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        _approve(msg.sender, spender, _allowed[msg.sender][spender].sub(subtractedValue));
        return true;
    }

    function getHolders() public view returns(address[] memory) {
        return _holders;
    }

    /**
     * @dev Transfer token for a specified addresses
     * @param from The address to transfer from.
     * @param to The address to transfer to.
     * @param value The amount to be transferred.
     */
    function _transfer(address from, address to, uint256 value) internal {
        require(pause == false && stop == false, 'transfers paused or stopped');
        require(to != address(0), 'to address can not be 0');

        _circulatingSupply[to] = _circulatingSupply[to].add(value);
        _circulatingSupply[from] = _circulatingSupply[from].add(value);

        _balances[from] = _balances[from].sub(value);
        _balances[to] = _balances[to].add(value);

        if(!_isHolder[to]) {
            _isHolder[to] = true;
           _holders.push(to);
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Internal function that mints an amount of the token and assigns it to
     * an account. This encapsulates the modification of balances such that the
     * proper events are emitted.
     * @param account The account that will receive the created tokens.
     * @param value The amount that will be created.
     */
    function _mint(address account, uint256 value) internal {
        require(stopMint == false, 'mint stopped');
        require(account != address(0), 'destination address can not be 0');

        _totalSupply = _totalSupply.add(value);
        _balances[account] = _balances[account].add(value);

        if(!_isHolder[account]) {
            _isHolder[account] = true;
           _holders.push(account);
        }

        emit Transfer(address(0), account, value);
    }

    /**
     * @dev Internal function that burns an amount of the token of a given
     * account.
     * @param account The account whose tokens will be burnt.
     * @param value The amount that will be burnt.
     */
    function _burn(address account, uint256 value) internal {
        require(account != address(0), 'destination address can not be 0');

        _totalSupply = _totalSupply.sub(value);
        _balances[account] = _balances[account].sub(value);
        emit Transfer(account, address(0), value);
    }

    /**
     * @dev Approve an address to spend another addresses' tokens.
     * @param owner The address that owns the tokens.
     * @param spender The address that will spend the tokens.
     * @param value The number of tokens that can be spent.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        require(spender != address(0), 'spender can not be 0');
        require(owner != address(0), 'owner can not be 0');

        _allowed[owner][spender] = value;
        emit Approval(owner, spender, value);
    }
}

pragma solidity 0.5.8;

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
interface IERC20 {
    function transfer(address to, uint256 value) external returns (bool);

    function approve(address spender, uint256 value) external returns (bool);

    function transferFrom(address from, address to, uint256 value) external returns (bool);

    function totalSupply() external view returns (uint256);

    function balanceOf(address who) external view returns (uint256);

    function allowance(address owner, address spender) external view returns (uint256);

    event Transfer(address indexed from, address indexed to, uint256 value);

    event Approval(address indexed owner, address indexed spender, uint256 value);
}

pragma solidity 0.5.8;

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev The Ownable constructor sets the original `owner` of the contract to the sender
     * account.
     */
    constructor() internal {
        _owner = msg.sender;
        emit OwnershipTransferred(address(0), _owner);
    }

    /**
     * @return the address of the owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(isOwner(), "Must be owner");
        _;
    }

    /**
     * @return true if `msg.sender` is the owner of the contract.
     */
    function isOwner() public view returns (bool) {
        return msg.sender == _owner;
    }

    /**
     * @dev Allows the current owner to relinquish control of the contract.
     * @notice Renouncing to ownership will leave the contract without an owner.
     * It will not be possible to call the functions with the `onlyOwner`
     * modifier anymore.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Allows the current owner to transfer control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function _transferOwnership(address newOwner) internal {
        require(newOwner != address(0), "Cannot transfer to zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

pragma solidity 0.5.8;

import "./ERC20.sol";

contract PermissionService is ERC20 {

    mapping (address => bool) public mintablePermission;
    mapping (address => bool) public editRightsPermission;
    mapping (address => bool) public recoveryTokensPermission;
    mapping (address => bool) public attributesPermission;
    mapping (address => bool) public burnPermission;
    mapping (address => bool) public ethRatePermission;
    mapping (address => bool) public gasPermission;
    mapping (address => bool) internal _isAdded;

    address[] internal addressesWithPermissions;

    modifier onlyEditRightsPermission() {
        require(editRightsPermission[msg.sender] || isOwner());
        _;
    }
    
    modifier onlyEthRatePermission() {
        require(ethRatePermission[msg.sender] || isOwner());
        _;
    }
    
    modifier onlyGasPermission() {
        require(gasPermission[msg.sender] || isOwner());
        _;
    }

    modifier onlyBurnPermission() {
        require(burnPermission[msg.sender] || isOwner());
        _;
    }

    modifier onlyMintablePermission() {
        require(mintablePermission[msg.sender] || recoveryTokensPermission[msg.sender] || isOwner());
        _;
    }

    modifier onlyRecoveryTokensPermission() {
        require(recoveryTokensPermission[msg.sender] || isOwner());
        _;
    }

    modifier onlyAttributesPermission() {
        require(attributesPermission[msg.sender] || isOwner());
        _;
    }

    function addMintablePermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        mintablePermission[_address] = true;
    }

    function addGasPermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        gasPermission[_address] = true;
    }
    
    function addEthRatePermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        ethRatePermission[_address] = true;
    }

    function addBurnPermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        burnPermission[_address] = true;
    }

    function addEditRightsPermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        editRightsPermission[_address] = true;
    }

    function addRecoveryTokensPermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        recoveryTokensPermission[_address] = true;
    }

    function addAttributesPermission(address _address) public onlyEditRightsPermission {
        if(_isAdded[_address] == false) {
            addressesWithPermissions.push(_address);
            _isAdded[_address] = true;
        }
        attributesPermission[_address] = true;
    }

    function removeMintablePermission(address _address) public onlyEditRightsPermission {
        mintablePermission[_address] = false;
    }
    
    function removeEthRatePermission(address _address) public onlyEditRightsPermission {
        ethRatePermission[_address] = false;
    }
    
    function removeGasPermission(address _address) public onlyEditRightsPermission {
        gasPermission[_address] = false;
    }

    function removeBurnPermission(address _address) public onlyEditRightsPermission {
        burnPermission[_address] = false;
    }

    function removeEditRightsPermission(address _address) public onlyEditRightsPermission {
        editRightsPermission[_address] = false;
    }

    function removeRecoveryTokensPermission(address _address) public onlyEditRightsPermission {
        recoveryTokensPermission[_address] = false;
    }

    function removeAttributesPermission(address _address) public onlyEditRightsPermission {
        attributesPermission[_address] = false;
    }

    function getAddressesWithPermissions() public view returns(address[] memory) {
        return addressesWithPermissions;
    }


}

pragma solidity 0.5.8;

/**
 * @title SafeMath
 * @dev Unsigned math operations with safety checks that revert on error
 */
library SafeMath {
    /**
     * @dev Multiplies two unsigned integers, reverts on overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b);

        return c;
    }

    /**
     * @dev Integer division of two unsigned integers truncating the quotient, reverts on division by zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Subtracts two unsigned integers, reverts on overflow (i.e. if subtrahend is greater than minuend).
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Adds two unsigned integers, reverts on overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a);

        return c;
    }

    /**
     * @dev Divides two unsigned integers and returns the remainder (unsigned integer modulo),
     * reverts when dividing by zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b != 0);
        return a % b;
    }
}

pragma solidity 0.5.8;

import "./PermissionService.sol";

contract ScipayToken is PermissionService {
    string public name = "SCIPAY Token";
    string public symbol = "SCIPAY";
    uint8 public decimals = 18;

    event TokensRecovered(address _from, address _to, uint _amount);

    constructor() public {
        _totalSupply = 0;
    }

    function changeSymbol(string memory _newSymbol) public onlyAttributesPermission {
        symbol = _newSymbol;
    }

    function changename(string memory _newName) public onlyAttributesPermission {
        name = _newName;
    }

    function transfer(address _to, uint _amount) public returns(bool) {
        return super.transfer(_to, _amount);
    }

    function transferFrom(address _from, address _to, uint _amount) public returns(bool) {
        return super.transferFrom(_from, _to, _amount);
    }

    function mint(address _for, uint _amount) public onlyMintablePermission {
        _mint(_for, _amount);
    }

    function burn(address _from, uint _amount) public onlyBurnPermission {
        _burn(_from, _amount);
    }

    function recoveryTokens(address _from, address _to) public onlyRecoveryTokensPermission {
        uint balance = balanceOf(_from);

        _burn(_from, balance);
        mint(_to, balance);

        emit TokensRecovered(_from, _to, balance);
    }

    function setEthRate(uint256 newEthRate) public onlyEthRatePermission {
    	require (newEthRate > 0);
    	ethRate = newEthRate;
    }

    function setGasForTransfer(uint256 newGasForTransfer) public onlyGasPermission {
    	require (newGasForTransfer > 0);
    	gasForTransfer = newGasForTransfer;
    }
}

{
  "compilationTarget": {
    "ScipayToken.sol": "ScipayToken"
  },
  "evmVersion": "petersburg",
  "libraries": {},
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}