// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC1155.sol";
import "./IERC1155MetadataURI.sol";
import "./IERC1155Receiver.sol";
import "./Context.sol";
import "./ERC165.sol";
import "./safemath.sol";
import "./Address.sol";

/**
 *
 * @dev Implementation of the basic standard multi-token.
 * See https://eips.ethereum.org/EIPS/eip-1155
 * Originally based on code by Enjin: https://github.com/enjin/erc-1155
 *
 * _Available since v3.1._
 */
contract ERC1155 is Context, ERC165, IERC1155, IERC1155MetadataURI {
    using SafeMath for uint256;
    using Address for address;

    // Mapping from token ID to account balances
    mapping (uint256 => mapping(address => uint256)) private _balances;

    // Mapping from account to operator approvals
    mapping (address => mapping(address => bool)) private _operatorApprovals;

    // Used as the URI for all token types by relying on ID substitution, e.g. https://token-cdn-domain/{id}.json
    string private _uri;

    /*
     *     bytes4(keccak256('balanceOf(address,uint256)')) == 0x00fdd58e
     *     bytes4(keccak256('balanceOfBatch(address[],uint256[])')) == 0x4e1273f4
     *     bytes4(keccak256('setApprovalForAll(address,bool)')) == 0xa22cb465
     *     bytes4(keccak256('isApprovedForAll(address,address)')) == 0xe985e9c5
     *     bytes4(keccak256('safeTransferFrom(address,address,uint256,uint256,bytes)')) == 0xf242432a
     *     bytes4(keccak256('safeBatchTransferFrom(address,address,uint256[],uint256[],bytes)')) == 0x2eb2c2d6
     *
     *     => 0x00fdd58e ^ 0x4e1273f4 ^ 0xa22cb465 ^
     *        0xe985e9c5 ^ 0xf242432a ^ 0x2eb2c2d6 == 0xd9b67a26
     */
    bytes4 private constant _INTERFACE_ID_ERC1155 = 0xd9b67a26;

    /*
     *     bytes4(keccak256('uri(uint256)')) == 0x0e89341c
     */
    bytes4 private constant _INTERFACE_ID_ERC1155_METADATA_URI = 0x0e89341c;

    /**
     * @dev See {_setURI}.
     */
    constructor (string memory uri_) {
        _setURI(uri_);

        // register the supported interfaces to conform to ERC1155 via ERC165
        _registerInterface(_INTERFACE_ID_ERC1155);

        // register the supported interfaces to conform to ERC1155MetadataURI via ERC165
        _registerInterface(_INTERFACE_ID_ERC1155_METADATA_URI);
    }

    /**
     * @dev See {IERC1155MetadataURI-uri}.
     *
     * This implementation returns the same URI for *all* token types. It relies
     * on the token type ID substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * Clients calling this function must replace the `\{id\}` substring with the
     * actual token type ID.
     */
    function uri(uint256) external view virtual override returns (string memory) {
        return _uri;
    }

    /**
     * @dev See {IERC1155-balanceOf}.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) public view virtual override returns (uint256) {
        require(account != address(0), "ERC1155: balance query for the zero address");
        return _balances[id][account];
    }

    /**
     * @dev See {IERC1155-balanceOfBatch}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] memory accounts,
        uint256[] memory ids
    )
        public
        view
        virtual
        override
        returns (uint256[] memory)
    {
        require(accounts.length == ids.length, "ERC1155: accounts and ids length mismatch");

        uint256[] memory batchBalances = new uint256[](accounts.length);

        for (uint256 i = 0; i < accounts.length; ++i) {
            batchBalances[i] = balanceOf(accounts[i], ids[i]);
        }

        return batchBalances;
    }

    /**
     * @dev See {IERC1155-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(_msgSender() != operator, "ERC1155: setting approval status for self");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC1155-isApprovedForAll}.
     */
    function isApprovedForAll(address account, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[account][operator];
    }

    /**
     * @dev See {IERC1155-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    )
        public
        virtual
        override
    {
        require(to != address(0), "ERC1155: transfer to the zero address");
        require(
            from == _msgSender() || isApprovedForAll(from, _msgSender()),
            "ERC1155: caller is not owner nor approved"
        );

        address operator = _msgSender();

        _beforeTokenTransfer(operator, from, to, _asSingletonArray(id), _asSingletonArray(amount), data);

        _balances[id][from] = _balances[id][from].sub(amount, "ERC1155: insufficient balance for transfer");
        _balances[id][to] = _balances[id][to].add(amount);

        emit TransferSingle(operator, from, to, id, amount);

        _doSafeTransferAcceptanceCheck(operator, from, to, id, amount, data);
    }

    /**
     * @dev See {IERC1155-safeBatchTransferFrom}.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    )
        public
        virtual
        override
    {
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");
        require(to != address(0), "ERC1155: transfer to the zero address");
        require(
            from == _msgSender() || isApprovedForAll(from, _msgSender()),
            "ERC1155: transfer caller is not owner nor approved"
        );

        address operator = _msgSender();

        _beforeTokenTransfer(operator, from, to, ids, amounts, data);

        for (uint256 i = 0; i < ids.length; ++i) {
            uint256 id = ids[i];
            uint256 amount = amounts[i];

            _balances[id][from] = _balances[id][from].sub(
                amount,
                "ERC1155: insufficient balance for transfer"
            );
            _balances[id][to] = _balances[id][to].add(amount);
        }

        emit TransferBatch(operator, from, to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(operator, from, to, ids, amounts, data);
    }

    /**
     * @dev Sets a new URI for all token types, by relying on the token type ID
     * substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * By this mechanism, any occurrence of the `\{id\}` substring in either the
     * URI or any of the amounts in the JSON file at said URI will be replaced by
     * clients with the token type ID.
     *
     * For example, the `https://token-cdn-domain/\{id\}.json` URI would be
     * interpreted by clients as
     * `https://token-cdn-domain/000000000000000000000000000000000000000000000000000000000004cce0.json`
     * for token type ID 0x4cce0.
     *
     * See {uri}.
     *
     * Because these URIs cannot be meaningfully represented by the {URI} event,
     * this function emits no events.
     */
    function _setURI(string memory newuri) internal virtual {
        _uri = newuri;
    }

    /**
     * @dev Creates `amount` tokens of token type `id`, and assigns them to `account`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - If `account` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function _mint(address account, uint256 id, uint256 amount, bytes memory data) internal virtual {
        require(account != address(0), "ERC1155: mint to the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, address(0), account, _asSingletonArray(id), _asSingletonArray(amount), data);

        _balances[id][account] = _balances[id][account].add(amount);
        emit TransferSingle(operator, address(0), account, id, amount);

        _doSafeTransferAcceptanceCheck(operator, address(0), account, id, amount, data);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_mint}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function _mintBatch(address to, uint256[] memory ids, uint256[] memory amounts, bytes memory data) internal virtual {
        require(to != address(0), "ERC1155: mint to the zero address");
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, address(0), to, ids, amounts, data);

        for (uint i = 0; i < ids.length; i++) {
            _balances[ids[i]][to] = amounts[i].add(_balances[ids[i]][to]);
        }

        emit TransferBatch(operator, address(0), to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(operator, address(0), to, ids, amounts, data);
    }

    /**
     * @dev Destroys `amount` tokens of token type `id` from `account`
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens of token type `id`.
     */
    function _burn(address account, uint256 id, uint256 amount) internal virtual {
        require(account != address(0), "ERC1155: burn from the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, account, address(0), _asSingletonArray(id), _asSingletonArray(amount), "");

        _balances[id][account] = _balances[id][account].sub(
            amount,
            "ERC1155: burn amount exceeds balance"
        );

        emit TransferSingle(operator, account, address(0), id, amount);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_burn}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     */
    function _burnBatch(address account, uint256[] memory ids, uint256[] memory amounts) internal virtual {
        require(account != address(0), "ERC1155: burn from the zero address");
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, account, address(0), ids, amounts, "");

        for (uint i = 0; i < ids.length; i++) {
            _balances[ids[i]][account] = _balances[ids[i]][account].sub(
                amounts[i],
                "ERC1155: burn amount exceeds balance"
            );
        }

        emit TransferBatch(operator, account, address(0), ids, amounts);
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning, as well as batched variants.
     *
     * The same hook is called on both single and batched variants. For single
     * transfers, the length of the `id` and `amount` arrays will be 1.
     *
     * Calling conditions (for each `id` and `amount` pair):
     *
     * - When `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * of token type `id` will be  transferred to `to`.
     * - When `from` is zero, `amount` tokens of token type `id` will be minted
     * for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens of token type `id`
     * will be burned.
     * - `from` and `to` are never both zero.
     * - `ids` and `amounts` have the same, non-zero length.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    )
        internal
        virtual
    { }

    function _doSafeTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    )
        private
    {
        if (to.isContract()) {
            try IERC1155Receiver(to).onERC1155Received(operator, from, id, amount, data) returns (bytes4 response) {
                if (response != IERC1155Receiver(to).onERC1155Received.selector) {
                    revert("ERC1155: ERC1155Receiver rejected tokens");
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                revert("ERC1155: transfer to non ERC1155Receiver implementer");
            }
        }
    }

    function _doSafeBatchTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    )
        private
    {
        if (to.isContract()) {
            try IERC1155Receiver(to).onERC1155BatchReceived(operator, from, ids, amounts, data) returns (bytes4 response) {
                if (response != IERC1155Receiver(to).onERC1155BatchReceived.selector) {
                    revert("ERC1155: ERC1155Receiver rejected tokens");
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                revert("ERC1155: transfer to non ERC1155Receiver implementer");
            }
        }
    }

    function _asSingletonArray(uint256 element) private pure returns (uint256[] memory) {
        uint256[] memory array = new uint256[](1);
        array[0] = element;

        return array;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts may inherit from this and call {_registerInterface} to declare
 * their support of an interface.
 */
abstract contract ERC165 is IERC165 {
    /*
     * bytes4(keccak256('supportsInterface(bytes4)')) == 0x01ffc9a7
     */
    bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;

    /**
     * @dev Mapping of interface ids to whether or not it's supported.
     */
    mapping(bytes4 => bool) private _supportedInterfaces;

    constructor () {
        // Derived contracts need only register support for their own interfaces,
        // we register support for ERC165 itself here
        _registerInterface(_INTERFACE_ID_ERC165);
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     *
     * Time complexity O(1), guaranteed to always use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return _supportedInterfaces[interfaceId];
    }

    /**
     * @dev Registers the contract as an implementer of the interface defined by
     * `interfaceId`. Support of the actual ERC165 interface is automatic and
     * registering its interface id is not required.
     *
     * See {IERC165-supportsInterface}.
     *
     * Requirements:
     *
     * - `interfaceId` cannot be the ERC165 invalid interface (`0xffffffff`).
     */
    function _registerInterface(bytes4 interfaceId) internal virtual {
        require(interfaceId != 0xffffffff, "ERC165: invalid interface id");
        _supportedInterfaces[interfaceId] = true;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(address indexed operator, address indexed from, address indexed to, uint256[] ids, uint256[] values);

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must be have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 amount, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(address from, address to, uint256[] calldata ids, uint256[] calldata amounts, bytes calldata data) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC1155.sol";

/**
 * @dev Interface of the optional ERC1155MetadataExtension interface, as defined
 * in the https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155MetadataURI is IERC1155 {
    /**
     * @dev Returns the URI for token type `id`.
     *
     * If the `\{id\}` substring is present in the URI, it must be replaced by
     * clients with the actual token type ID.
     */
    function uri(uint256 id) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC165.sol";

/**
 * _Available since v3.1._
 */
interface IERC1155Receiver is IERC165 {

    /**
        @dev Handles the receipt of a single ERC1155 token type. This function is
        called at the end of a `safeTransferFrom` after the balance has been updated.
        To accept the transfer, this must return
        `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
        (i.e. 0xf23a6e61, or its own function selector).
        @param operator The address which initiated the transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param id The ID of the token being transferred
        @param value The amount of tokens being transferred
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
    */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    )
        external
        returns(bytes4);

    /**
        @dev Handles the receipt of a multiple ERC1155 token types. This function
        is called at the end of a `safeBatchTransferFrom` after the balances have
        been updated. To accept the transfer(s), this must return
        `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
        (i.e. 0xbc197c81, or its own function selector).
        @param operator The address which initiated the batch transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param ids An array containing ids of each token being transferred (order and length must match values array)
        @param values An array containing amounts of each token being transferred (order and length must match ids array)
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
    */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    )
        external
        returns(bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT

  /**
   * LYNC Network
   * https://lync.network
   *
   * Additional details for contract and wallet information:
   * https://lync.network/tracking/
   *
   * The cryptocurrency network designed for passive token rewards for its community.
   */

pragma solidity ^0.7.0;

import "./ERC1155.sol";

contract LYNCCrafter is ERC1155 {

    address public owner;
    address public rewardContract;
    uint256 public cardID = 1;
    uint256 public cardCountETH = 9950;
    uint256 public cardCountLYNC = 9975;

    //Card statistics
    struct CardStats {
        string collectionName;
        uint256 cardType;
        uint256 boostAmount;
        uint256 redeemInitial;
        uint256 redeemLeft;
        uint256 redeemInterval;
        uint256 useLastTimeStamp;
        uint256 tokenReward;
        uint256 percentageReward;
    }

    //Events
    event BulkCardCrafted(address indexed _to, uint256 cardID, uint256 _amountOfCards, uint256 _tokenReward, uint256 _percentageReward);
    event CollectionCardCrafted(address indexed _to, uint256 cardID, uint256 _redeemInitial, uint256 _redeemInterval, uint256 _tokenReward, uint256 _percentageReward);
    event BoosterCardCrafted(address indexed _to, uint256 cardID, uint256 _amountOfCards, uint256 _boostAmount);
    event BulkBoosterCardIncreased(address indexed _to, uint256 _amountOfCards, uint256 _cardID);
    event RewardCardCrafted(address indexed _to, uint256 _cardCounter);
    event CardStatsUpdated(uint256 _cardID);
    event BoosterCardApplied(uint256 _cardID, uint256 _newRedeemTotal);
    event CardBurned(uint256 _cardID, uint256 _amount);
    event CardBurnedByOwner(address indexed _cardholder, uint256 _cardID, uint256 _amount);
    event RewardContractAddressUpdated(address indexed _previousRewardAddress, address indexed _newRewardAddress);
    event OwnershipTransferred(address indexed _previousOwner, address indexed _newOwner);
    event OwnershipRenounced(address indexed _previousOwner, address indexed _newOwner);

    //Mappings
    mapping(uint256 => CardStats) public cards;
    mapping(string => mapping(uint256 => uint256)) public collections;

    //Constructor
    constructor(string memory _uri) ERC1155(_uri) {
        owner = msg.sender;
    }

    //Craft a destructable / bulk card
    function craftBulkCard(address _to, uint256 _amountOfCards, uint256 _tokenReward, uint256 _percentageReward) public onlyOwner {

        //Craft and add stats
        _mint(_to, cardID, _amountOfCards, "");
        cards[cardID].cardType = 1;
        cards[cardID].tokenReward = _tokenReward;
        cards[cardID].percentageReward = _percentageReward;
        emit BulkCardCrafted(_to, cardID,  _amountOfCards, _tokenReward, _percentageReward);

        //Update cardID
        cardID += 1;
    }

    //Craft a collection card
    function craftCollectionCard(address _to, string memory _collectionName, uint256 _amountOfCards, uint256 _redeemInitial, uint256 _redeemInterval, uint256 _tokenReward, uint256 _percentageReward) public onlyOwner {

        //Make sure collection name is unique
        require(collections[_collectionName][0] == 0, "This collection name aready exists!");

        //Record the size of the collection
        collections[_collectionName][0] = _amountOfCards;

        //Loop to create multiple cards
        for (uint256 i = 1; i <= _amountOfCards; i++) {

            //Add this card into the collection
            collections[_collectionName][i] = cardID;

            //Mint the card and add stats to card
            _mint(_to, cardID, 1, "");
            cards[cardID].collectionName = _collectionName;
            cards[cardID].cardType = 2;
            cards[cardID].redeemInitial = _redeemInitial;
            cards[cardID].redeemLeft = _redeemInitial;
            cards[cardID].redeemInterval = _redeemInterval;
            cards[cardID].tokenReward = _tokenReward;
            cards[cardID].percentageReward = _percentageReward;
            emit CollectionCardCrafted(_to, cardID, _redeemInitial, _redeemInterval, _tokenReward, _percentageReward);

            //Update the cardID
            cardID += 1;
        }
    }

    //Craft a booster card
    function craftBoosterCard(address _to, uint256 _amountOfCards, uint256 _boostAmount) public onlyOwner {
        _mint(_to, cardID, _amountOfCards, "");
        cards[cardID].cardType = 3;
        cards[cardID].boostAmount = _boostAmount;
        emit BoosterCardCrafted(_to, cardID, _amountOfCards, _boostAmount);

        //Update the cardID
        cardID += 1;
    }

    //Increase a destructable / booster card quantity
    function increaseBulkBoosterCard(address _to, uint256 _amountOfCards, uint256 _cardID) public onlyOwner {

        //Check card type and cardID count
        require(cards[_cardID].cardType != 2, "Cannot increase a collection / unique card");
        require(_cardID > 0 && _cardID < cardID, "Card ID has not been crafted yet");

        //Increase cards
        _mint(_to, _cardID, _amountOfCards, "");
        emit BulkBoosterCardIncreased(_to, _amountOfCards, _cardID);
    }

    //Craft a reward card
    function craftRewardCard(address _to, uint256 _cardID, string memory _collectionName) public onlyRewardContract {

        //Set counters
        uint256 _cardCounter;

        if(_cardID < 3) {
            _cardCounter = cardCountETH;
            cardCountETH += 1;
        } else {
            _cardCounter = cardCountLYNC;
            cardCountLYNC += 1;
        }

        //Increase the size of the collection
        collections[_collectionName][0] += 1;

        //Crafter the card and add stats
        _mint(_to, _cardCounter, 1, "");
        cards[_cardCounter].collectionName = _collectionName;
        cards[_cardCounter].cardType = 2;
        cards[_cardCounter].redeemInitial = 6;
        cards[_cardCounter].redeemLeft = 6;
        cards[_cardCounter].redeemInterval = 28;
        cards[_cardCounter].tokenReward = 400;
        cards[_cardCounter].percentageReward = 4;
        emit RewardCardCrafted(_to, _cardCounter);
    }

    //Update collection / unique card redeem count and timestamp
    function updateCardStats(uint256 _cardID) public onlyRewardContract {
        cards[_cardID].redeemLeft -= 1;
        cards[_cardID].useLastTimeStamp = block.timestamp;
        emit CardStatsUpdated(_cardID);
    }

    //Apply booster card to collection / unique card
    function applyCardBooster(uint256 _cardID, uint256 _newRedeemTotal) public onlyRewardContract {
        cards[_cardID].redeemLeft += _newRedeemTotal;
        emit BoosterCardApplied(_cardID, _newRedeemTotal);
    }

    //Burn card
    function burnCard(address _cardholder, uint256 _cardID, uint256 _amount) public onlyRewardContract {
        _burn(_cardholder, _cardID, _amount);
        emit CardBurned(_cardID, _amount);
    }

    //Owner burn card overide
    function ownerBurnCard(address _cardholder, uint256 _cardID, uint256 _amount) public onlyOwner {
        _burn(_cardholder, _cardID, _amount);
        emit CardBurnedByOwner(_cardholder, _cardID, _amount);
    }

    //Update the reward contract address
    function updateRewardContractAddress(address _newRewardContractAddress) public onlyOwner {
        require(_newRewardContractAddress != address(0), "New reward contract address cannot be a zero address");
        emit RewardContractAddressUpdated(rewardContract, _newRewardContractAddress);
        rewardContract = _newRewardContractAddress;
    }

    //Transfer ownership to new owner
    function transferOwnership(address _newOwner) public onlyOwner {
        require(_newOwner != address(0), "New owner cannot be a zero address");
        emit OwnershipTransferred(owner, _newOwner);
        owner = _newOwner;
    }

    //Remove owner from the contract
    function renounceOwnership() public onlyOwner {
        emit OwnershipRenounced(owner, address(0));
        owner = address(0);
    }

    //Modifiers
    modifier onlyOwner() {
        require(owner == msg.sender, "Only the owner of the crafter contract can call this function");
        _;
    }

    modifier onlyRewardContract() {
        require(rewardContract == msg.sender, "Only the reward contract address can call this function");
        _;
    }
}

// SPDX-License-Identifier: MIT

  /**
   * LYNC Network
   * https://lync.network
   *
   * Additional details for contract and wallet information:
   * https://lync.network/tracking/
   *
   * The cryptocurrency network designed for passive token rewards for its community.
   */

pragma solidity ^0.7.0;

import "./lynctoken.sol";
import "./lyncstakingv1.sol";
import "./lynccrafter.sol";

contract LYNCNFTRewardsV1 {

    //Enable SafeMath
    using SafeMath for uint256;

    address payable public owner;
    uint256 public oneDay = 86400;          // in seconds
    uint256 public SCALAR = 1e18;           // multiplier

    LYNCToken public tokenContract;
    LYNCStakingV1 public stakingContract;
    LYNCCrafter public crafterContract;

    //Events
    event OwnershipTransferred(address indexed _previousOwner, address indexed _newOwner);
    event OwnershipRenounced(address indexed _previousOwner, address indexed _newOwner);

    //On deployment
    constructor(LYNCToken _tokenContract, LYNCStakingV1 _stakingContract, LYNCCrafter _crafterContract) {
        owner = msg.sender;
        tokenContract = _tokenContract;
        stakingContract = _stakingContract;
        crafterContract = _crafterContract;
    }

    //MulDiv functions : source https://medium.com/coinmonks/math-in-solidity-part-3-percents-and-proportions-4db014e080b1
    function mulDiv(uint x, uint y, uint z) public pure returns (uint) {
          (uint l, uint h) = fullMul (x, y);
          assert (h < z);
          uint mm = mulmod(x, y, z);
          if (mm > l) h -= 1;
          l -= mm;
          uint pow2 = z & -z;
          z /= pow2;
          l /= pow2;
          l += h * ((-pow2) / pow2 + 1);
          uint r = 1;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          return l * r;
    }

    //Required for MulDiv
    function fullMul(uint x, uint y) private pure returns (uint l, uint h) {
          uint mm = mulmod(x, y, uint (-1));
          l = x * y;
          h = mm - l;
          if (mm < l) h -= 1;
    }

    //Redeem lotto cards
    function redeemLotto(uint256 _cardID) public {

        //Check ownership of card
        require(crafterContract.balanceOf(msg.sender, _cardID) > 0, "You do not own this card");
        //Make sure card is a lotto card
        require(_cardID < 5, "Card is not a lotto card");

        uint256 _cardAmount = 1;
        string memory _collectionName;

        if(_cardID < 3) {
            _collectionName = "Ethereum Lotto";
            if(_cardID == 1) {
                _cardAmount = 10;
                require(crafterContract.balanceOf(msg.sender, _cardID) >= _cardAmount, "10 common cards required to craft");
            } else {
                require(crafterContract.balanceOf(msg.sender, _cardID) >= _cardAmount, "1 rare card required to craft");
            }
        } else {
            _collectionName = "LYNC Token Lotto";
            if(_cardID ==  3) {
                _cardAmount = 10;
                require(crafterContract.balanceOf(msg.sender, _cardID) >= _cardAmount, "10 common cards required to craft");
            } else {
                require(crafterContract.balanceOf(msg.sender, _cardID) >= _cardAmount, "1 rare card required to craft");
            }
        }

        //Craft reward card
        crafterContract.craftRewardCard(msg.sender, _cardID, _collectionName);
        //Burn card(s)
        crafterContract.burnCard(msg.sender, _cardID, _cardAmount);
    }

    //Redeem reward card
    function redeemReward(uint256 _cardID) public {

        //Check ownership of card
        require(crafterContract.balanceOf(msg.sender, _cardID) > 0, "You do not own this card");

        //Grab card data
        (,uint256 cardType,,,uint256 _redeemLeft,uint256 _redeemInterval,uint256 _redeemLastTimeStamp,uint256 _tokenReward,uint256 _percentageRedeem) = crafterContract.cards(_cardID);

        //Check card last redeem timestamp against its interval
        require(block.timestamp > (_redeemLastTimeStamp + _redeemInterval.mul(oneDay)), "This card has already been redeemed this interval, wait until reset");
         //Make sure this is is not a booster card
        require(cardType != 3, "Booster cards do not have any rewards associated with them");

        //Update or burn card
        if(cardType != 2) {
            //Burn the card
            crafterContract.burnCard(msg.sender, _cardID, 1);
        } else {
            require(_redeemLeft > 0, "No redeems available on this card");
            crafterContract.updateCardStats(_cardID);
        }

        //Token redeem
        if(_tokenReward > 0) {
            //Send token reward
            require(tokenContract.transfer(msg.sender, _tokenReward.mul(SCALAR)));
        }

        //Percentage redeem
        if(_percentageRedeem > 0) {

            //Get balance from staking contract
            (uint256 _stakedTokens,,) = stakingContract.stakerInformation(msg.sender);
            //Calculate percentage
            uint256 _percentageReward = mulDiv(_stakedTokens, _percentageRedeem, 100);
            //Send token reward
            require(tokenContract.transfer(msg.sender, _percentageReward));
        }
    }

    function redeemBoosterCard(uint256 _cardID, uint256 _cardToBoost) public {

        //Check ownership of card
        require(crafterContract.balanceOf(msg.sender, _cardID) > 0, "You do not own this card");

        //Grab data from booster card
        (,uint256 _cardType, uint256 boostAmount,,,,,,) = crafterContract.cards(_cardID);

        //Make sure this is a booster card
        require(_cardType == 3, "This is not a booster card");

        //Grab data from card to boost
        (,uint256 _cardTypeToBoost,,uint256 _intialRedeems,,,,,) = crafterContract.cards(_cardToBoost);

        //Check card being boosted is not a destructable / bulk card or another booster card
        require(_cardTypeToBoost == 2, "Destructable and booster cards cannot be boosted");

        //Check card being boosted had initial redeems
        require(_intialRedeems > 0, "Collectable cards with no rewards cannot be boosted");

        //Boost and burn
        crafterContract.applyCardBooster(_cardToBoost, boostAmount);
        crafterContract.burnCard(msg.sender,_cardID,1);
    }

    //Transfer ownership to new owner
    function transferOwnership(address payable _newOwner) public onlyOwner {
        require(_newOwner != address(0), "New owner cannot be a zero address");
        emit OwnershipTransferred(owner, _newOwner);
        owner = _newOwner;
    }

    //Remove owner from the contract
    function renounceOwnership() public onlyOwner {
        emit OwnershipRenounced(owner, address(0));
        owner = address(0);
    }

    //Close the contract and transfer any balances to the owner
    function closeContract() public payable onlyOwner {
        require(tokenContract.transfer(owner, tokenContract.balanceOf(address(this))));
        selfdestruct(owner);
    }

    //Modifiers
    modifier onlyOwner() {
        require(owner == msg.sender, "Only the owner of the rewards contract can call this function");
        _;
    }
}

// SPDX-License-Identifier: MIT

    /**
     * LYNC Network
     * https://lync.network
     *
     * Additional details for contract and wallet information:
     * https://lync.network/tracking/
     *
     * The cryptocurrency network designed for passive token rewards for its community.
     */

pragma solidity ^0.7.0;

import "./lynctoken.sol";

contract LYNCStakingV1 {

  //Enable SafeMath
  using SafeMath for uint256;

    address public owner;
    address public contractAddress;
    uint256 public totalRewards = 0;
    uint256 public totalRewardsClaimed = 0;
    uint256 public totalStakedV1 = 0;
    uint256 public oneDay = 86400;          // in seconds
    uint256 public SCALAR = 1e18;           // multiplier
    uint256 public minimumTokenStake = 98;  // takes into account transfer fee
    uint256 public endOfStakeFee = 4;       // 4% including 1% tx fee = approx 5%

    LYNCToken public tokenContract;

    //Events
	event Stake(address _from, uint256 tokens);
	event Unstake(address _to, uint256 tokens);
	event UnstakeFee(address _to, uint256 tokens);
	event CollectRewards(address _to, uint256 tokens);

	//User data
	struct Staker {
		uint256 staked;
		uint256 poolAtLastClaim;
		uint256 userTimeStamp;
	}

    //Mappings
    mapping(address => Staker) stakers;

    //On deployment
    constructor(LYNCToken _tokenContract) {
        owner = msg.sender;
        tokenContract = _tokenContract;
        contractAddress = address(this);
    }

    //MulDiv functions : source https://medium.com/coinmonks/math-in-solidity-part-3-percents-and-proportions-4db014e080b1
    function mulDiv(uint x, uint y, uint z) public pure returns (uint) {
          (uint l, uint h) = fullMul (x, y);
          assert (h < z);
          uint mm = mulmod(x, y, z);
          if (mm > l) h -= 1;
          l -= mm;
          uint pow2 = z & -z;
          z /= pow2;
          l /= pow2;
          l += h * ((-pow2) / pow2 + 1);
          uint r = 1;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          r *= 2 - z * r;
          return l * r;
    }

    //Required for MulDiv
    function fullMul(uint x, uint y) private pure returns (uint l, uint h) {
          uint mm = mulmod(x, y, uint (-1));
          l = x * y;
          h = mm - l;
          if (mm < l) h -= 1;
    }

    //Return current reward pool unclaimed
    function rewardPoolBalance() public view returns(uint256) {
        return tokenContract.balanceOf(address(this)).sub(totalStakedV1);
    }

    //Return staker information
    function stakerInformation(address _stakerAddress) public view returns(uint256, uint256, uint256) {
        return (stakers[_stakerAddress].staked, stakers[_stakerAddress].poolAtLastClaim, stakers[_stakerAddress].userTimeStamp);
    }

    //Stake tokens
    function stakeTokens(uint256 _numberOfTokens) external returns (bool) {

        //Check if user is already staking
        if(stakers[msg.sender].staked == 0) {

            //Require minimum stake
            require(_numberOfTokens > (minimumTokenStake * SCALAR), "Not enough tokens to start staking");

            //Transfer tokens and update data
            require(tokenContract.transferFrom(msg.sender, address(this), _numberOfTokens));
            stakers[msg.sender].poolAtLastClaim = totalRewards;
            stakers[msg.sender].userTimeStamp = block.timestamp;
        } else {

            //Transfer tokens
            require(tokenContract.transferFrom(msg.sender, address(this), _numberOfTokens));
        }

        //Update staking totals
        uint256 _feeAmount = (_numberOfTokens.mul(tokenContract.feePercent())).div(100);
        uint256 _stakedAfterFee = _numberOfTokens.sub(_feeAmount);

        //Update data
        stakers[msg.sender].staked = (stakers[msg.sender].staked).add(_stakedAfterFee);
        totalStakedV1 = totalStakedV1.add(_stakedAfterFee);
        totalRewards = rewardPoolBalance().add(totalRewardsClaimed);

        emit Stake(msg.sender, _numberOfTokens);
        return true;
    }

    //Unstake tokens
    function unstakeTokens() external returns (bool) {

        //Minus 4% fee for unstaking
        uint256 _stakedTokens = stakers[msg.sender].staked;
        uint256 _feeAmount = (_stakedTokens.mul(endOfStakeFee)).div(100);
        uint256 _unstakeTokens = (stakers[msg.sender].staked).sub(_feeAmount);

        //Send stakers tokens and remove from total staked
        require(tokenContract.transfer(msg.sender, _unstakeTokens));
        totalStakedV1 = totalStakedV1.sub(_stakedTokens);

        //Update data
        stakers[msg.sender].staked = 0;
        stakers[msg.sender].poolAtLastClaim = 0;
        stakers[msg.sender].userTimeStamp = 0;
        totalRewards = rewardPoolBalance().add(totalRewardsClaimed);

        emit Unstake(msg.sender, _unstakeTokens);
        emit UnstakeFee(msg.sender, _feeAmount);
        return true;
    }

    //Claim current token rewards
    function claimRewards() external returns (bool) {

        totalRewards = rewardPoolBalance().add(totalRewardsClaimed);
        require(stakers[msg.sender].staked > 0, "You do not have any tokens staked");
        require(block.timestamp > (stakers[msg.sender].userTimeStamp + oneDay), "You can only claim 24 hours after staking and once every 24 hours");

        //Calculated user share of reward pool since last claim
        uint256 _poolSinceLastClaim = totalRewards.sub(stakers[msg.sender].poolAtLastClaim);
        uint256 _rewardPercent = mulDiv(stakers[msg.sender].staked, 10000, totalStakedV1);
        uint256 _rewardToClaim = mulDiv(_poolSinceLastClaim, _rewardPercent, 10000);

        //Send tokens
        require(tokenContract.transfer(msg.sender, _rewardToClaim));

        //Update data
        stakers[msg.sender].poolAtLastClaim = totalRewards;
        stakers[msg.sender].userTimeStamp = block.timestamp;
        totalRewardsClaimed = totalRewardsClaimed.add(_rewardToClaim);
        totalRewards = rewardPoolBalance().add(totalRewardsClaimed);

        emit CollectRewards(msg.sender, _rewardToClaim);
        return true;
    }

    //Update the minimum tokens to start staking
    function updateStakeMinimum(uint256 _minimumTokenStake) public onlyOwner {
        minimumTokenStake = _minimumTokenStake;
    }

    //Modifiers
    modifier onlyOwner() {
        require(owner == msg.sender, "Only current owner can call this function");
        _;
    }
}

// SPDX-License-Identifier: MIT

    /**
     * LYNC Network
     * https://lync.network
     *
     * Additional details for contract and wallet information:
     * https://lync.network/tracking/
     *
     * The cryptocurrency network designed for passive token rewards for its community.
     */

pragma solidity ^0.7.0;

import "./safemath.sol";

contract LYNCToken {

    //Enable SafeMath
    using SafeMath for uint256;

    //Token details
    string constant public name = "LYNC Network";
    string constant public symbol = "LYNC";
    uint8 constant public decimals = 18;

    //Reward pool and owner address
    address public owner;
    address public rewardPoolAddress;

    //Supply and tranasction fee
    uint256 public maxTokenSupply = 1e24;   // 1,000,000 tokens
    uint256 public feePercent = 1;          // initial transaction fee percentage
    uint256 public feePercentMax = 10;      // maximum transaction fee percentage

    //Events
    event Transfer(address indexed _from, address indexed _to, uint256 _tokens);
    event Approval(address indexed _owner,address indexed _spender, uint256 _tokens);
    event TranserFee(uint256 _tokens);
    event UpdateFee(uint256 _fee);
    event RewardPoolUpdated(address indexed _rewardPoolAddress, address indexed _newRewardPoolAddress);
    event OwnershipTransferred(address indexed _previousOwner, address indexed _newOwner);
    event OwnershipRenounced(address indexed _previousOwner, address indexed _newOwner);

    //Mappings
    mapping(address => uint256) public balanceOf;
    mapping(address => mapping(address => uint256)) private allowances;

    //On deployment
    constructor () {
        owner = msg.sender;
        rewardPoolAddress = address(this);
        balanceOf[msg.sender] = maxTokenSupply;
        emit Transfer(address(0), msg.sender, maxTokenSupply);
    }

    //ERC20 totalSupply
    function totalSupply() public view returns (uint256) {
        return maxTokenSupply;
    }

    //ERC20 transfer
    function transfer(address _to, uint256 _tokens) public returns (bool) {
        transferWithFee(msg.sender, _to, _tokens);
        return true;
    }

    //ERC20 transferFrom
    function transferFrom(address _from, address _to, uint256 _tokens) public returns (bool) {
        require(_tokens <= balanceOf[_from], "Not enough tokens in the approved address balance");
        require(_tokens <= allowances[_from][msg.sender], "token amount is larger than the current allowance");
        transferWithFee(_from, _to, _tokens);
        allowances[_from][msg.sender] = allowances[_from][msg.sender].sub(_tokens);
        return true;
    }

    //ERC20 approve
    function approve(address _spender, uint256 _tokens) public returns (bool) {
        allowances[msg.sender][_spender] = _tokens;
        emit Approval(msg.sender, _spender, _tokens);
        return true;
    }

    //ERC20 allowance
    function allowance(address _owner, address _spender) public view returns (uint256) {
        return allowances[_owner][_spender];
    }

    //Transfer with transaction fee applied
    function transferWithFee(address _from, address _to, uint256 _tokens) internal returns (bool) {
        require(balanceOf[_from] >= _tokens, "Not enough tokens in the senders balance");
        uint256 _feeAmount = (_tokens.mul(feePercent)).div(100);
        balanceOf[_from] = balanceOf[_from].sub(_tokens);
        balanceOf[_to] = balanceOf[_to].add(_tokens.sub(_feeAmount));
        balanceOf[rewardPoolAddress] = balanceOf[rewardPoolAddress].add(_feeAmount);
        emit Transfer(_from, _to, _tokens.sub(_feeAmount));
        emit Transfer(_from, rewardPoolAddress, _feeAmount);
        emit TranserFee(_tokens);
        return true;
    }

    //Update transaction fee percentage
    function updateFee(uint256 _updateFee) public onlyOwner {
        require(_updateFee <= feePercentMax, "Transaction fee cannot be greater than 10%");
        feePercent = _updateFee;
        emit UpdateFee(_updateFee);
    }

    //Update the reward pool address
    function updateRewardPool(address _newRewardPoolAddress) public onlyOwner {
        require(_newRewardPoolAddress != address(0), "New reward pool address cannot be a zero address");
        rewardPoolAddress = _newRewardPoolAddress;
        emit RewardPoolUpdated(rewardPoolAddress, _newRewardPoolAddress);
    }

    //Transfer current token balance to the reward pool address
    function rewardPoolBalanceTransfer() public onlyOwner returns (bool) {
        uint256 _currentBalance = balanceOf[address(this)];
        transferWithFee(address(this), rewardPoolAddress, _currentBalance);
        return true;
    }

    //Transfer ownership to new owner
    function transferOwnership(address _newOwner) public onlyOwner {
        require(_newOwner != address(0), "New owner cannot be a zero address");
        emit OwnershipTransferred(owner, _newOwner);
        owner = _newOwner;
    }

    //Remove owner from the contract
    function renounceOwnership() public onlyOwner {
        emit OwnershipRenounced(owner, address(0));
        owner = address(0);
    }

    //Modifiers
    modifier onlyOwner() {
        require(owner == msg.sender, "Only current owner can call this function");
        _;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
 
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

{
  "compilationTarget": {
    "lyncnftrewards.sol": "LYNCNFTRewardsV1"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}