GigaToken

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        _spendAllowance(account, _msgSender(), amount);
        _burn(account, amount);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

/**
 *    GigaToken
 *    Utility Token of the Gigaconomy, powering GigaBots!
 *
 *    Website: https://www.gigabots.ai
 *    Twitter: https://twitter.com/gigabots_ai
 *    Telegram: https://t.me/GigaBotsCommunity
 *    Bot: https://t.me/OfficialGigaTraderBot
 *
 */
import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {ERC20Burnable} from "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IUniswapV2Router} from "./interfaces/IUniswapV2Router.sol";
import {IUniswapV2Factory} from "./interfaces/IUniswapV2Factory.sol";

/**
 * @title GigaToken
 * @author GigaDev
 * @notice This contract represents the GigaToken ERC20 token.
 * It inherits from ERC20, ERC20Burnable, and Ownable contracts from OpenZeppelin.
 * @custom:security-contact gigadev@gigabots.ai
 */
contract GigaToken is ERC20, ERC20Burnable, Ownable {
    address public marketingWallet;
    address public operationsWallet;

    uint8 public buyFee = 50;
    uint8 public sellFee = 50;

    uint8 public liquidityFeePercent = 20;
    uint8 public marketingFeePercent = 20;
    uint8 public operationsFeePercent = 60;

    uint256 public swapTokensAtAmount = 50_000 * 1e18; // 0.05% of TS
    bool private _distributingFees;

    mapping(address => bool) private _excludedFromFees;

    bool public limitsInEffect = true;
    uint256 public maxWalletBalance = 1_000_000 * 1e18; // 1% of TS
    uint256 public maxTransactionAmount = 1_000_000 * 1e18; // 1% of TS
    mapping(address => bool) private _excludedFromMaxTransaction;

    address public immutable uniV2Pair;
    mapping(address => bool) public ammPairs;
    IUniswapV2Router public constant uniV2Router = IUniswapV2Router(0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D);

    bool public tradingEnabled;

    event LimitsRemoved();
    event TradingEnabled();
    event BuyFeeSet(uint8 newBuyFee);
    event SellFeeSet(uint8 newSellFee);
    event AMMPairSet(address pair, bool isSet);
    event MarketingWalletUpdated(address newAddress);
    event OperationsWalletUpdated(address newAddress);
    event MaxWalletBalanceUpdated(uint256 newMaxWalletBalance);
    event MaxTransactionAmountUpdated(uint256 newMaxTransactionAmount);
    event SwapTokensAtAmountSet(uint256 newSwapTokensAtAmount);
    event FeesDistributionSet(
        uint8 newLiquidityFeePercent, uint8 newMarketingFeePercent, uint8 newOperationsFeePercent
    );
    event FeesDistributed(
        uint256 totalTokensDistributed,
        uint256 tokensToLiquidity,
        uint256 ethToLiquidity,
        uint256 ethToMarketing,
        uint256 ethToOperations
    );

    /**
     * @notice Constructor function for the GigaToken contract.
     * It initializes the contract by setting the token name and symbol,
     * creates a Uniswap V2 pair for the token, sets initial values for marketing and operations wallets and
     * mints total token supply.
     * It also approves the Uniswap V2 router to spend an unlimited amount of tokens on behalf of the contract.
     */
    constructor() ERC20("GigaToken", "GIGA") {
        uniV2Pair = IUniswapV2Factory(uniV2Router.factory()).createPair(address(this), uniV2Router.WETH());
        ammPairs[uniV2Pair] = true;
        _excludedFromMaxTransaction[uniV2Pair] = true;

        _excludedFromFees[owner()] = true;
        marketingWallet = owner();
        operationsWallet = owner();

        _mint(owner(), 100_000_000 * 1e18);

        _approve(address(this), address(uniV2Router), type(uint256).max);
    }

    receive() external payable {}

    /**
     * @notice This function is used to transfer tokens internally within the contract.
     * It performs various checks such as trading enablement, maximum transaction and balance limits,
     * fee distribution, and fee deduction.
     * It then calls the _transfer function from the parent contract to perform the actual token transfer.
     * @param from The address to transfer tokens from.
     * @param to The address to transfer tokens to.
     * @param amount The amount of tokens to transfer.
     */
    function _transfer(address from, address to, uint256 amount) internal override {
        require(amount > 0, "GigaToken: transfer amount must be greater than 0");

        // Check if trading has been enabled
        if (!tradingEnabled) {
            require(from == owner() || to == owner(), "GigaToken: trading has not been enabled yet");
        }

        // Max TX and Max Balance Limits
        if (limitsInEffect) {
            if (from != owner() && to != owner() && to != address(0) && to != address(0xdead) && !_distributingFees) {
                // On Buys
                if (ammPairs[from] && !_excludedFromMaxTransaction[to]) {
                    require(amount <= maxTransactionAmount, "GigaToken: amount exceeds max transaction amount");
                    require(
                        amount + balanceOf(to) <= maxWalletBalance, "GigaToken: balance would exceed max wallet balance"
                    );
                }
                // On Sells
                else if (ammPairs[to] && !_excludedFromMaxTransaction[from]) {
                    require(amount <= maxTransactionAmount, "GigaToken: amount exceeds max transaction amount");
                }
                // On Transfers to non-excluded "to" address
                else if (!_excludedFromMaxTransaction[to]) {
                    require(
                        amount + balanceOf(to) <= maxWalletBalance, "GigaToken: balance would exceed max wallet balance"
                    );
                }
            }
        }

        // Swap any tokens held as fees for ETH and distribute
        bool shouldSwap = balanceOf(address(this)) >= swapTokensAtAmount;
        if (shouldSwap && !_distributingFees && !ammPairs[from] && !_excludedFromFees[from] && !_excludedFromFees[to]) {
            _distributingFees = true;
            _distributeFees();
            _distributingFees = false;
        }

        // Determine if we should take fees
        bool takeFees = !_distributingFees;
        if (_excludedFromFees[from] || _excludedFromFees[to]) {
            takeFees = false;
        }

        uint256 fees = 0;
        // Take Fees if necessary
        if (takeFees) {
            // Fees on buys
            if (ammPairs[from] && buyFee > 0) {
                fees = (amount * buyFee) / 1_000;
            }
            // Fees on sells
            else if (ammPairs[to] && sellFee > 0) {
                fees = (amount * sellFee) / 1_000;
            }

            // If there are fees to be taken, transfer and substract from amount
            if (fees > 0) {
                super._transfer(from, address(this), fees);
                amount -= fees;
            }
        }

        // Make final transfer
        super._transfer(from, to, amount);
    }

    /**
     * @notice Distributes fees collected by the contract.
     * The function calculates the amount of fees to distribute based on the balance of the contract.
     * It then swaps a portion of the fees for ETH and adds liquidity to the token.
     * The remaining ETH is distributed to the marketing and operations wallets.
     * @dev Emits a `FeesDistributed` event with the details of the distribution.
     */
    function _distributeFees() private {
        // Determine amount of held fees to distribute
        uint256 tokensToDistribute = balanceOf(address(this));
        if (tokensToDistribute > swapTokensAtAmount * 20) {
            tokensToDistribute = swapTokensAtAmount * 20;
        }

        // Calculate how many tokens we should swap for ETH (some will be used for liquidity)
        uint256 tokensForLiquidityHalf = ((tokensToDistribute * liquidityFeePercent) / 100) / 2;
        uint256 tokensToSwapForEth = tokensToDistribute - tokensForLiquidityHalf;

        // Swap tokens for ETH
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = uniV2Router.WETH();
        try uniV2Router.swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokensToSwapForEth, 0, path, address(this), block.timestamp
        ) {} catch {}

        // Distribute ETH and add liquidity
        uint256 ethBalance = address(this).balance;
        if (ethBalance > 0) {
            // Add Liquidity
            uint256 ethForLiquidity = (ethBalance * tokensForLiquidityHalf) / tokensToSwapForEth;
            if (ethForLiquidity > 0) {
                try uniV2Router.addLiquidityETH{value: ethForLiquidity}(
                    address(this), tokensForLiquidityHalf, 0, 0, address(0), block.timestamp
                ) {} catch {}
            }

            bool success;

            // Send ETH to Marketing
            uint256 tokensForMarketing = (tokensToDistribute * marketingFeePercent) / 100;
            uint256 ethForMarketing = (ethBalance * tokensForMarketing) / tokensToSwapForEth;
            if (ethForMarketing > 0) {
                (success,) = marketingWallet.call{value: ethForMarketing}("");
            }

            // Send ETH to Operations
            uint256 ethForOperations = 0;
            if (operationsFeePercent != 0) {
                ethForOperations = address(this).balance;
                (success,) = operationsWallet.call{value: ethForOperations}("");
            }

            emit FeesDistributed(
                tokensToDistribute, tokensForLiquidityHalf, ethForLiquidity, ethForMarketing, ethForOperations
            );
        }
    }

    /**
     * @notice Returns whether the specified account is excluded from fees.
     * @param account The address to check.
     * @return A boolean indicating whether the account is excluded from fees.
     */
    function isExcludedFromFees(address account) public view returns (bool) {
        return _excludedFromFees[account];
    }

    /**
     * @notice Returns whether the specified account is excluded from the maximum transaction limit.
     * @param account The address to check.
     * @return A boolean indicating whether the account is excluded from the maximum transaction limit.
     */
    function isExcludedFromMaxTransaction(address account) public view returns (bool) {
        return _excludedFromMaxTransaction[account];
    }

    /**
     * @notice Enables trading of the token.
     * @dev Can only be called by the contract owner.
     * @dev Emits a `TradingEnabled` event.
     */
    function enableTrading() external onlyOwner {
        tradingEnabled = true;
        emit TradingEnabled();
    }

    /**
     * @notice Updates the marketing wallet address.
     * @param newAddress The new address for the marketing wallet.
     * @dev Can only be called by the contract owner.
     * @dev `newAddress` cannot be the zero address.
     * @dev Emits a `MarketingWalletUpdated` event.
     */
    function updateMarketingWallet(address newAddress) external onlyOwner {
        require(newAddress != address(0), "GigaToken: address cannot be 0 address");
        marketingWallet = newAddress;
        emit MarketingWalletUpdated(newAddress);
    }

    /**
     * @notice Updates the operations wallet address.
     * @param newAddress The new address to set as the operations wallet.
     * @dev Can only be called by the contract owner.
     * @dev `newAddress` cannot be the zero address.
     * @dev Emits a `OperationsWalletUpdated` event.
     */
    function updateOperationsWallet(address newAddress) external onlyOwner {
        require(newAddress != address(0), "GigaToken: address cannot be 0 address");
        operationsWallet = newAddress;
        emit OperationsWalletUpdated(newAddress);
    }

    /**
     * @notice Removes the max transcation and max wallet balance limits on the token.
     * @dev Can only be called by the contract owner.
     * @dev Once turned off, the limits cannot be turned back on.
     * @dev Emits a `LimitsRemoved` event.
     */
    function removeLimits() external onlyOwner {
        limitsInEffect = false;
        emit LimitsRemoved();
    }

    /**
     * @notice Sets the amount of tokens required for a fee tokens swap.
     * @param newSwapTokensAtAmount The new amount of tokens required for a swap.
     * @dev Can only be called by the contract owner.
     * @dev The newSwapTokensAtAmount must be greater than or equal to 0.001% of the total supply,
     * and less than or equal to 0.5% of the total supply.
     * @dev Emits a `SwapTokensAtAmountSet` event.
     */
    function setSwapTokensAtAmount(uint256 newSwapTokensAtAmount) external onlyOwner {
        require(
            newSwapTokensAtAmount >= totalSupply() / 100_000,
            "GigaToken: swap tokens at amount cannot be lower than 0.001% of total supply"
        );
        require(
            newSwapTokensAtAmount <= (totalSupply() * 5) / 1_000,
            "GigaToken: swap tokens at amount cannot be higher than 0.5% of total supply"
        );
        swapTokensAtAmount = newSwapTokensAtAmount;
        emit SwapTokensAtAmountSet(newSwapTokensAtAmount);
    }

    /**
     * @notice Sets the buy fee for GigaToken.
     * @param newBuyFee The new buy fee to be set.
     * @dev Can only be called by the contract owner.
     * @dev The new buy fee cannot be greater than 50 (5%).
     * @dev Emits a `BuyFeeSet` event.
     */
    function setBuyFee(uint8 newBuyFee) external onlyOwner {
        require(newBuyFee <= 50, "GigaToken: fee cannot be greater than 5%");
        buyFee = newBuyFee;
        emit BuyFeeSet(newBuyFee);
    }

    /**
     * @notice Sets the sell fee for GigaToken.
     * @param newSellFee The new sell fee to be set.
     * @dev Can only be called by the contract owner.
     * @dev The new sell fee cannot be greater than 50 (5%).
     * @dev Emits a `SellFeeSet` event.
     */
    function setSellFee(uint8 newSellFee) external onlyOwner {
        require(newSellFee <= 50, "GigaToken: fee cannot be greater than 5%");
        sellFee = newSellFee;
        emit SellFeeSet(newSellFee);
    }

    /**
     * @notice Sets the fees distribution for the GigaToken contract.
     * @param newLiquidityFeePercent The new percentage of fees allocated to liquidity.
     * @param newMarketingFeePercent The new percentage of fees allocated to marketing.
     * @param newOperationsFeePercent The new percentage of fees allocated to operations.
     * @dev Can only be called by the contract owner.
     * @dev The sum of `newLiquidityFeePercent`, `newMarketingFeePercent`, and `newOperationsFeePercent` must equal 100.
     * @dev Emits a `FeesDistributionSet` event.
     */
    function setFeesDistribution(
        uint8 newLiquidityFeePercent,
        uint8 newMarketingFeePercent,
        uint8 newOperationsFeePercent
    ) external onlyOwner {
        require(
            newLiquidityFeePercent + newMarketingFeePercent + newOperationsFeePercent == 100,
            "GigaToken: fees distribution total must equal 100"
        );
        liquidityFeePercent = newLiquidityFeePercent;
        marketingFeePercent = newMarketingFeePercent;
        operationsFeePercent = newOperationsFeePercent;
        emit FeesDistributionSet(newLiquidityFeePercent, newMarketingFeePercent, newOperationsFeePercent);
    }

    /**
     * @notice Updates the maximum transaction amount allowed.
     * @dev Only the contract owner can call this function.
     * @dev `newMaxTransactionAmount` must be greater than or equal to 0.1% of the total supply.
     * @dev Emits a `MaxTransactionAmountUpdated` event.
     */
    function updateMaxTransactionAmount(uint256 newMaxTransactionAmount) external onlyOwner {
        require(
            newMaxTransactionAmount >= totalSupply() / 1_000,
            "GigaToken: cannot set max transaction amount below 0.1% of totalSupply"
        );
        maxTransactionAmount = newMaxTransactionAmount;
        emit MaxTransactionAmountUpdated(newMaxTransactionAmount);
    }

    /**
     * @notice Updates the maximum wallet balance allowed for token holders.
     * @param newMaxWalletBalance The new maximum wallet balance to be set.
     * @dev Only the contract owner can call this function.
     * @dev The new maximum wallet balance must be greater than or equal to 0.1% of the total supply.
     * @dev Emits a `MaxWalletBalanceUpdated` event.
     */
    function updateMaxWalletBalance(uint256 newMaxWalletBalance) external onlyOwner {
        require(
            newMaxWalletBalance >= totalSupply() / 1_000,
            "GigaToken: cannot set max wallet balance below 0.1% of totalSupply"
        );
        maxWalletBalance = newMaxWalletBalance;
        emit MaxWalletBalanceUpdated(newMaxWalletBalance);
    }

    /**
     * @notice Sets the excluded status of an account from fees.
     * @param account The address of the account.
     * @param excluded The excluded status to be set.
     * @dev Only the contract owner can call this function.
     */
    function setExcludedFromFees(address account, bool excluded) external onlyOwner {
        _excludedFromFees[account] = excluded;
    }

    /**
     * @notice Sets whether an account is excluded from the maximum transaction limit.
     * @param account The address of the account to be excluded or included.
     * @param excluded A boolean indicating whether the account should be excluded or included.
     * @dev Only the contract owner can call this function.
     */
    function setExcludedFromMaxTransaction(address account, bool excluded) external onlyOwner {
        _excludedFromMaxTransaction[account] = excluded;
    }

    /**
     * @notice Sets the AMM pair for the GigaToken contract.
     * @param pair The address of the AMM pair.
     * @param isSet A boolean indicating whether the pair is set or not.
     * @dev Only the contract owner can call this function.
     * @dev The original uniV2Pair cannot be altered.
     * @dev Emits an `AMMPairSet` event.
     */
    function setAMMPair(address pair, bool isSet) external onlyOwner {
        require(pair != uniV2Pair, "GigaToken: original uniV2Pair cannot be altered");
        ammPairs[pair] = isSet;
        emit AMMPairSet(pair, isSet);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.23;

interface IUniswapV2Factory {
    function getPair(address tokenA, address tokenB) external view returns (address pair);

    function createPair(address tokenA, address tokenB) external returns (address pair);
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.23;

interface IUniswapV2Router {
    function factory() external pure returns (address);

    function WETH() external pure returns (address);

    function getAmountsIn(uint256 amountOut, address[] calldata path)
        external
        view
        returns (uint256[] memory amounts);

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    ) external payable returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);

    function swapExactTokensForETH(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "src/GigaToken.sol": "GigaToken"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":openzeppelin/=lib/openzeppelin-contracts/contracts/"
  ]
}