Deadities

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {Initializable} from "openzeppelin-contracts-upgradeable/proxy/utils/Initializable.sol";
import {ISellable} from "proof/sellers/interfaces/ISellable.sol";
import {
    AccessControlEnumerableUpgradeable,
    SteerableAccessControlEnumerableUpgradeable
} from "./SteerableAccessControlEnumerableUpgradeable.sol";

/**
 * @notice A base contract for selling content via authorised sellers.
 */
abstract contract BaseSellableUpgradeable is Initializable, ISellable, SteerableAccessControlEnumerableUpgradeable {
    /**
     * @notice Authorised sellers.
     */
    bytes32 public constant AUTHORISED_SELLER_ROLE = keccak256("AUTHORISED_SELLER_ROLE");

    function __BaseSellable_init() internal onlyInitializing {
        __AccessControlEnumerable_init();
        __BaseSellable_init_unchained();
    }

    function __BaseSellable_init_unchained() internal onlyInitializing {
        _setRoleAdmin(AUTHORISED_SELLER_ROLE, DEFAULT_STEERING_ROLE);
    }

    /**
     * @notice Handles the sale of sellable content via an authorised seller.
     * @dev Delegates the implementation to `_handleSale`.
     */
    function handleSale(address to, uint64 num, bytes calldata data)
        external
        payable
        onlyRole(AUTHORISED_SELLER_ROLE)
    {
        _handleSale(to, num, data);
    }

    /**
     * @notice Handles the sale of sellable content.
     */
    function _handleSale(address to, uint64 num, bytes calldata data) internal virtual;

    /**
     * @notice Revokes approval for all sellers.
     */
    function _revokeAllSellers() internal {
        uint256 num = getRoleMemberCount(AUTHORISED_SELLER_ROLE);
        for (uint256 i = 0; i < num; i++) {
            // Akin to a popFront
            address seller = getRoleMember(AUTHORISED_SELLER_ROLE, 0);
            _revokeRole(AUTHORISED_SELLER_ROLE, seller);
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 Divergence Tech Ltd
pragma solidity ^0.8.19;

import {IERC721TransferListener} from "../Mythics/MythicsV3.sol";
import {SacrificedOddityMythics} from "./SacrificedOddityMythics.sol";
import {AccessControlEnumerable, BaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";
import {IERC721, IERC721Metadata, IERC165} from "openzeppelin-contracts/interfaces/IERC721Metadata.sol";
import {Strings} from "openzeppelin-contracts/utils/Strings.sol";

/**
 * @title Deadities
 * @notice Shadow NFTs that always follow Moonbirds Mythics as they are transferred. Only those Mythics that were minted
 * as a result of the "sacrifice" of an Oddity have an associated Deadity.
 * @dev As these tokens shadow the ownership of others, all transfer-related functionality is disabled.
 * @author Arran Schlosberg (@divergencearran)
 * @custom:reviewer David Huber (@cxkoda)
 */
contract Deadities is IERC721Metadata, IERC721TransferListener, BaseTokenURI {
    using Strings for uint256;

    /**
     * @notice Throw by functions that have been disabled. See contract-level @notice + @dev for rationale.
     */
    error FunctionDisabled();

    /**
     * @notice Thrown if a token doesn't exist.
     */
    error NonExistentToken(uint256 tokenId);

    /**
     * @notice Thrown by onTransfer() if called by any address other than the Mythics contract.
     */
    error OnlyMythicsContract(address caller);

    /**
     * @dev Guess.
     */
    IERC721 private immutable mythics;

    /**
     * @dev Number of bitmaps (encoding Mythic IDs) that have been processed by mint().
     */
    uint256 private _bitmapsMinted;

    constructor(IERC721 mythics_, address admin) BaseTokenURI("") {
        mythics = mythics_;

        _grantRole(DEFAULT_ADMIN_ROLE, admin);
        _grantRole(DEFAULT_STEERING_ROLE, msg.sender);
    }

    /**
     * @notice Mints the next batch of tokens.
     * @dev We rely entirely on the respective Mythics token for ownership so there is no storage bookkeeping, there is
     * only a Transfer(0, …) event emitted.
     * @param numBitmaps Mythic IDs for which a Deadity exists are stored in bitmaps of up to 256 IDs; specifies how
     * many bitmaps of IDs to process. Note that not all encode the same number of IDs.
     */
    function mint(uint256 numBitmaps) external {
        uint256 mapId = _bitmapsMinted;
        uint256 end = mapId + numBitmaps;
        IERC721 _mythics = mythics;

        unchecked {
            // This takes approximately 13M gas when the mythics.ownerOf() is stubbed out with a pure
            // function. It will be more in production because of the storage reads.
            for (; mapId < end; ++mapId) {
                uint256 offset = 0;
                for (uint256 map = SacrificedOddityMythics._bitmap(mapId); map > 0; map >>= 1) {
                    if ((map & uint256(1)) == 1) {
                        uint256 tokenId = mapId * 256 + offset;
                        emit IERC721.Transfer(address(0), _mythics.ownerOf(tokenId), tokenId);
                    }
                    ++offset;
                }
            }
        }

        _bitmapsMinted = end;
    }

    modifier tokenExists(uint256 tokenId) {
        if (!SacrificedOddityMythics._fromOddity(tokenId)) {
            revert NonExistentToken(tokenId);
        }
        _;
    }

    /**
     * @dev See mint() for rationale re naked emit.
     */
    function _transfer(address from, address to, uint256 tokenId) private {
        emit IERC721.Transfer(from, to, tokenId);
    }

    /**
     * @dev Hook called by the Mythics contract when token(s) are transferred, resulting in respective Transfer events
     * for those Mythics that were created due to the sacrifice of an Oddity.
     */
    function onTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize) external {
        if (msg.sender != address(mythics)) {
            revert OnlyMythicsContract(msg.sender);
        }
        uint256 end = firstTokenId + batchSize;
        for (uint256 tokenId = firstTokenId; tokenId < end; ++tokenId) {
            if (SacrificedOddityMythics._fromOddity(tokenId)) {
                _transfer(from, to, tokenId);
            }
        }
    }

    /**
     * @dev Returns the token collection name.
     */
    function name() external pure returns (string memory) {
        return "Deadities";
    }

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external pure returns (string memory) {
        return "DEAD";
    }

    /**
     * @dev Returns the owner of the `tokenId` token.
     */
    function ownerOf(uint256 tokenId) external view tokenExists(tokenId) returns (address) {
        return mythics.ownerOf(tokenId);
    }

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view tokenExists(tokenId) returns (string memory) {
        return string(abi.encodePacked(baseTokenURI(), tokenId.toString()));
    }

    /**
     * @notice Returns the total number of tokens.
     */
    function totalSupply() external pure returns (uint256) {
        return SacrificedOddityMythics.NUM_BITS_SET;
    }

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     * @dev Implementation is O(max(tokenId)) so is only suitable for off-chain indexing.
     */
    function balanceOf(address owner) external view returns (uint256) {
        IERC721 _mythics = mythics;
        uint256 balance;

        unchecked {
            for (uint256 mapId = 0; mapId < SacrificedOddityMythics.NUM_BITMAPS; ++mapId) {
                uint256 offset = 0;

                for (uint256 map = SacrificedOddityMythics._bitmap(mapId); map > 0; map >>= 1) {
                    if ((map & uint256(1)) == 1 && _mythics.ownerOf(mapId * 256 + offset) == owner) {
                        ++balance;
                    }

                    ++offset;
                }
            }
        }

        return balance;
    }

    /**
     * @notice Disabled but present to compile as IERC721.
     */
    function safeTransferFrom(address, address, uint256, bytes calldata) external pure {
        revert FunctionDisabled();
    }

    /**
     * @notice Disabled but present to compile as IERC721.
     */
    function safeTransferFrom(address, address, uint256) external pure {
        revert FunctionDisabled();
    }

    /**
     * @notice Disabled but present to compile as IERC721.
     */
    function transferFrom(address, address, uint256) external pure {
        revert FunctionDisabled();
    }

    /**
     * @notice Disabled but present to compile as IERC721.
     */
    function approve(address, uint256) external pure {
        revert FunctionDisabled();
    }

    /**
     * @notice Disabled but present to compile as IERC721.
     */
    function setApprovalForAll(address, bool) external pure {
        revert FunctionDisabled();
    }

    /**
     * @notice Always returns 0;
     */
    function getApproved(uint256) external pure returns (address) {
        return address(0);
    }

    /**
     * @notice Always returns false;
     */
    function isApprovedForAll(address, address) external pure returns (bool) {
        return false;
    }

    function supportsInterface(bytes4 interfaceId)
        public
        view
        override(AccessControlEnumerable, IERC165)
        returns (bool)
    {
        return interfaceId == type(IERC721).interfaceId || interfaceId == type(IERC165).interfaceId
            || interfaceId == type(IERC721Metadata).interfaceId || AccessControlEnumerable.supportsInterface(interfaceId);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {BitMaps} from "openzeppelin-contracts/utils/structs/BitMaps.sol";
import {ERC4906} from "ethier/erc721/ERC4906.sol";

import {MythicsEggErrors} from "./MythicsEggErrors.sol";

interface MythicEggActivatorEvents {
    /**
     * @notice Emitted when an egg has been activated.
     */
    event EggActivated(uint256 indexed tokenId);
}

/**
 * @title Mythics: Egg activation module
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
abstract contract MythicEggActivator is ERC4906, MythicsEggErrors, MythicEggActivatorEvents {
    using BitMaps for BitMaps.BitMap;

    /**
     * @notice Throws if activating an egg that has already been activated.
     */
    error EggAlreadyActivated(uint256);

    /**
     * @notice Thrown if one tries to activate too many eggs at once.
     */
    error ActivatingTooManyEggs(uint256 requested, uint256 numLeft);

    /**
     * @notice Keeps track of eggs that have already been activated.
     */
    BitMaps.BitMap private _activated;

    /**
     * @notice The maximum number of eggs that can be activated during one day.
     */
    uint32 internal _maxNumActivationsPerDay = 50;

    /**
     * @notice The last day on which an egg was activated.
     */
    uint32 private _lastActivationDay;

    /**
     * @notice The number of eggs that have been activated today.
     * @dev Will be reset to 0 in `_activate` at the start of each day.
     */
    uint32 private _numActivatedToday;

    /**
     * @notice Helper function to get the current day number.
     */
    function _currentDay() private view returns (uint32) {
        return uint32(block.timestamp / (1 days));
    }

    /**
     * @notice Sets the maximum number of activations per day.
     */
    function _setMaxNumActivationsPerDay(uint32 maxNumActivationsPerDay) internal {
        _maxNumActivationsPerDay = maxNumActivationsPerDay;
    }

    /**
     * @notice Activates an array of eggs.
     * @dev Will revert if the number of eggs to activate exceeds the maximum number of activations per day.
     */
    function _activate(uint256[] calldata tokenIds) internal {
        if (_currentDay() > _lastActivationDay) {
            _numActivatedToday = 0;
            _lastActivationDay = _currentDay();
        }

        uint256 numLeft = _maxNumActivationsPerDay - _numActivatedToday;
        if (tokenIds.length > numLeft) {
            revert ActivatingTooManyEggs(tokenIds.length, numLeft);
        }

        for (uint256 i; i < tokenIds.length; ++i) {
            uint256 tokenId = tokenIds[i];

            if (activated(tokenId)) {
                revert EggAlreadyActivated(tokenId);
            }

            if (!_exists(tokenId)) {
                revert NonexistentEgg(tokenId);
            }

            _activated.set(tokenId);
            _refreshMetadata(tokenId);
            emit EggActivated(tokenId);
        }
        _numActivatedToday += uint32(tokenIds.length);
    }

    /**
     * @notice Returns whether an egg has already been activated.
     */
    function activated(uint256 tokenId) public view returns (bool) {
        if (!_exists(tokenId)) {
            revert NonexistentEgg(tokenId);
        }

        return _activated.get(tokenId);
    }

    /**
     * @notice Returns whether a token exists.
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool);
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {IEntropyOracle} from "proof/entropy/IEntropyOracle.sol";

import {MythicsEggErrors} from "./MythicsEggErrors.sol";
import {
    StochasticSampler, StochasticSamplerWithCDFStorage, StochasticSamplerWithOracle
} from "./StochasticSampling.sol";

/**
 * @title Mythics: Egg type sampling module
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
abstract contract MythicEggSampler is StochasticSamplerWithCDFStorage, StochasticSamplerWithOracle, MythicsEggErrors {
    /**
     * @notice The different types of eggs.
     */
    enum EggType {
        Stone,
        Runic,
        Legendary
    }

    /**
     * @notice Number of egg types
     */
    uint8 public constant NUM_EGG_TYPES = 3;

    /**
     * @notice Trait ID for the egg type
     */
    uint8 private constant _EGG_TYPE_TRAIT_ID = 0;

    /**
     * @notice Token-specific parameters for sampling the egg type
     * @dev Will be determined at mint.
     * @param revealBlockNumber Number of the block whose entropy will be used to reaveal the egg type.
     * @param distributionVersion The version/index of probability distribution to sample the egg type.
     * @param mixHash Part of the block mixHash to blind the entropy oracle.
     */
    struct SamplingParams {
        uint64 revealBlockNumber;
        uint16 distributionVersion;
        uint128 mixHash;
    }

    /**
     * @notice Egg-type sampling parameters keyed by token ID.
     */
    mapping(uint256 => SamplingParams) private _samplingParams;

    /**
     * @dev Constructor helper function.
     */
    function _numPerTrait() private pure returns (uint256[] memory) {
        uint256[] memory numPerTrait = new uint256[](1);
        numPerTrait[_EGG_TYPE_TRAIT_ID] = NUM_EGG_TYPES;
        return numPerTrait;
    }

    constructor(IEntropyOracle oracle)
        StochasticSamplerWithCDFStorage(_numPerTrait())
        StochasticSamplerWithOracle(oracle)
    {}

    /**
     * @notice Returns the egg-type sampling parameters for a given token ID.
     */
    function samplingParams(uint256 tokenId) public view returns (SamplingParams memory) {
        if (!_exists(tokenId)) {
            revert NonexistentEgg(tokenId);
        }

        return _samplingParams[tokenId];
    }

    /**
     * @inheritdoc StochasticSamplerWithCDFStorage
     * @dev Reads the token-specific parameters.
     */
    function _distributionVersion(uint256 tokenId, uint256 traitId) internal view virtual override returns (uint256) {
        assert(traitId == _EGG_TYPE_TRAIT_ID);
        return _samplingParams[tokenId].distributionVersion;
    }

    /**
     * @inheritdoc StochasticSamplerWithOracle
     * @dev Reads the token-specific parameters.
     */
    function _revealBlockNumber(uint256 tokenId) internal view virtual override returns (uint256) {
        return _samplingParams[tokenId].revealBlockNumber;
    }

    /**
     * @notice Registers a token for egg-type sampling using the currently set probability distribution.
     * @dev Must be called upon token mint.
     */
    function _registerForSampling(uint256 tokenId) internal {
        uint256 revealBlockNumber = block.number;

        _samplingParams[tokenId] = SamplingParams({
            revealBlockNumber: uint64(revealBlockNumber),
            distributionVersion: uint16(_latestDistributionVersion(_EGG_TYPE_TRAIT_ID)),
            // Smearing out single-bit-of-influence from the prevrandao since we're just using 128 bits (mainly to
            // prevent the forge fuzzer from finding breaking runs which would force us to add circular testing logic).
            mixHash: uint128(uint256(keccak256(abi.encode(block.prevrandao))))
        });
        entropyOracle.requestEntropy(revealBlockNumber);
    }

    /**
     * @notice Sets the probability distribution for egg types.
     */
    function _setEggProbabilities(uint64[NUM_EGG_TYPES] memory pdf) internal {
        uint64[] memory p = new uint64[](NUM_EGG_TYPES);
        for (uint256 i = 0; i < NUM_EGG_TYPES; i++) {
            p[i] = pdf[i];
        }
        _pushProbabilities(_EGG_TYPE_TRAIT_ID, p);
    }

    /**
     * @inheritdoc StochasticSamplerWithOracle
     * @dev Mixes the seed with the token-specific parameters to blind the EntropyOracle.
     */
    function _seed(uint256 tokenId)
        internal
        view
        virtual
        override(StochasticSampler, StochasticSamplerWithOracle)
        returns (bytes32, bool)
    {
        (bytes32 seed, bool revealed) = StochasticSamplerWithOracle._seed(tokenId);
        return (keccak256(abi.encode(seed, samplingParams(tokenId))), revealed);
    }

    /**
     * @notice Returns the egg type of a given token ID and a boolean flag to indicate whether it was already revealed.
     */
    function eggType(uint256 tokenId) public view returns (EggType, bool) {
        (uint256 sample, bool revealed) = _sampleTrait(tokenId, _EGG_TYPE_TRAIT_ID);
        return (EggType(sample), revealed);
    }

    /**
     * @notice Returns whether a token exists.
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool);
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {Initializable} from "openzeppelin-contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "openzeppelin-contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {ERC721Upgradeable} from "openzeppelin-contracts-upgradeable/token/ERC721/ERC721Upgradeable.sol";
import {ERC721RoyaltyUpgradeable} from
    "openzeppelin-contracts-upgradeable/token/ERC721/extensions/ERC721RoyaltyUpgradeable.sol";
import {ERC721PausableUpgradeable} from
    "openzeppelin-contracts-upgradeable/token/ERC721/extensions/ERC721PausableUpgradeable.sol";

import {
    SteerableAccessControlEnumerableUpgradeable,
    AccessControlEnumerableUpgradeable
} from "./SteerableAccessControlEnumerableUpgradeable.sol";

/**
 * @notice Base contract for Mythics implementations.
 * @dev This contract is intended be inherited by all implementations and thus MUST NOT be changed.
 */
contract MythicsBase is
    Initializable,
    SteerableAccessControlEnumerableUpgradeable,
    ERC721Upgradeable,
    ERC721RoyaltyUpgradeable,
    ERC721PausableUpgradeable,
    UUPSUpgradeable
{
    constructor() {
        _disableInitializers();
    }

    function __MythicsBase_init() internal onlyInitializing {
        __AccessControlEnumerable_init();
        __ERC721_init("Moonbirds: Mythics", "MYTHICS");
        __ERC721Royalty_init();
        __ERC721Pausable_init();
        __UUPSUpgradeable_init();
    }

    function __MythicsBase_init_unchained() internal onlyInitializing {}

    /**
     * @notice Only the admin is authorised to upgrade the implementation.
     */
    function _authorizeUpgrade(address newImplementation) internal virtual override onlyRole(DEFAULT_ADMIN_ROLE) {}

    /**
     * @dev Needed for inheritance resolution.
     */
    function _beforeTokenTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize)
        internal
        virtual
        override(ERC721Upgradeable, ERC721PausableUpgradeable)
    {
        ERC721PausableUpgradeable._beforeTokenTransfer(from, to, firstTokenId, batchSize);
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(ERC721Upgradeable, AccessControlEnumerableUpgradeable, ERC721RoyaltyUpgradeable)
        returns (bool)
    {
        return ERC721Upgradeable.supportsInterface(interfaceId)
            || ERC721RoyaltyUpgradeable.supportsInterface(interfaceId)
            || AccessControlEnumerableUpgradeable.supportsInterface(interfaceId);
    }

    function _burn(uint256 tokenId) internal virtual override(ERC721Upgradeable, ERC721RoyaltyUpgradeable) {
        ERC721RoyaltyUpgradeable._burn(tokenId);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {ERC721A, ERC721ACommon, BaseTokenURI, ERC721ACommonBaseTokenURI} from "ethier/erc721/BaseTokenURI.sol";
import {OperatorFilterOS} from "ethier/erc721/OperatorFilterOS.sol";
import {ERC4906} from "ethier/erc721/ERC4906.sol";

import {IEntropyOracle} from "proof/entropy/IEntropyOracle.sol";
import {RedeemableERC721ACommon} from "proof/redemption/voucher/RedeemableERC721ACommon.sol";
import {SellableERC721ACommon} from "proof/sellers/sellable/SellableERC721ACommon.sol";

import {MythicEggSampler} from "./MythicEggSampler.sol";
import {MythicEggActivator} from "./MythicEggActivator.sol";

/**
 * @title Mythics: Egg
 * @notice A redeemable token claimable by all diamond nested Moonbirds.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract MythicsEgg is
    ERC721ACommonBaseTokenURI,
    OperatorFilterOS,
    SellableERC721ACommon,
    RedeemableERC721ACommon,
    MythicEggSampler,
    MythicEggActivator
{
    constructor(address admin, address steerer, address payable secondaryReceiver, IEntropyOracle oracle)
        ERC721ACommon(admin, steerer, "Mythics: Egg", "EGG", secondaryReceiver, 500)
        BaseTokenURI("https://metadata.proof.xyz/mythics/egg/")
        MythicEggSampler(oracle)
    {
        _setEggProbabilities([uint64(0), uint64(40), uint64(60)]);
    }

    // =================================================================================================================
    //                          Information Getter
    // =================================================================================================================

    /**
     * @notice Encodes information about a token.
     * @dev Intended to be used off-chain.
     */
    struct TokenInfo {
        bool revealed;
        EggType eggType;
        bool activated;
    }

    /**
     * @notice Returns information about given egg token.
     * @dev Not optimised, intended to be used off-chain only.
     */
    function tokenInfos(uint256[] calldata tokenIds) external view returns (TokenInfo[] memory) {
        TokenInfo[] memory infos = new TokenInfo[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; i++) {
            (EggType eggT, bool revealed) = eggType(tokenIds[i]);
            infos[i] = TokenInfo({revealed: revealed, eggType: eggT, activated: activated(tokenIds[i])});
        }
        return infos;
    }

    // =================================================================================================================
    //                          Steering
    // =================================================================================================================

    /**
     * @notice Sets the probability distribution for egg types.
     */
    function setEggProbabilities(uint64[NUM_EGG_TYPES] memory pdf) external onlyRole(DEFAULT_STEERING_ROLE) {
        _setEggProbabilities(pdf);
    }

    /**
     * @notice Sets the entropy oracle.
     */
    function setEntropyOracle(IEntropyOracle newOracle) external onlyRole(DEFAULT_STEERING_ROLE) {
        entropyOracle = newOracle;
    }

    /**
     * @notice Sets the maximum number of activations per day.
     */
    function setMaxNumActivationsPerDay(uint32 maxNumActivationsPerDay) external onlyRole(DEFAULT_STEERING_ROLE) {
        _setMaxNumActivationsPerDay(maxNumActivationsPerDay);
    }

    /**
     * @notice Activates an array of eggs.
     */
    function activate(uint256[] calldata tokenIds) external onlyRole(DEFAULT_STEERING_ROLE) {
        _activate(tokenIds);
    }

    // =================================================================================================================
    //                          Inheritance Resolution
    // =================================================================================================================

    /**
     * @inheritdoc SellableERC721ACommon
     * @dev Registers the minted tokens for sampling.
     */
    function _handleSale(address to, uint64 num, bytes calldata data) internal virtual override {
        uint256 startTokenId = _nextTokenId();
        for (uint256 i; i < num; ++i) {
            _registerForSampling(startTokenId + i);
        }

        super._handleSale(to, num, data);
    }

    function _exists(uint256 tokenId)
        internal
        view
        virtual
        override(ERC721A, MythicEggActivator, MythicEggSampler)
        returns (bool)
    {
        return ERC721A._exists(tokenId);
    }

    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(ERC721ACommon, ERC721ACommonBaseTokenURI, SellableERC721ACommon, RedeemableERC721ACommon, ERC4906)
        returns (bool)
    {
        return RedeemableERC721ACommon.supportsInterface(interfaceId)
            || SellableERC721ACommon.supportsInterface(interfaceId) || ERC4906.supportsInterface(interfaceId)
            || ERC721ACommonBaseTokenURI.supportsInterface(interfaceId);
    }

    function _baseURI() internal view virtual override(ERC721A, ERC721ACommonBaseTokenURI) returns (string memory) {
        return ERC721ACommonBaseTokenURI._baseURI();
    }

    function setApprovalForAll(address operator, bool approved) public virtual override(ERC721A, OperatorFilterOS) {
        OperatorFilterOS.setApprovalForAll(operator, approved);
    }

    function approve(address operator, uint256 tokenId) public payable virtual override(ERC721A, OperatorFilterOS) {
        OperatorFilterOS.approve(operator, tokenId);
    }

    function transferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.transferFrom(from, to, tokenId);
    }

    function safeTransferFrom(address from, address to, uint256 tokenId)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.safeTransferFrom(from, to, tokenId);
    }

    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data)
        public
        payable
        virtual
        override(ERC721A, OperatorFilterOS)
    {
        OperatorFilterOS.safeTransferFrom(from, to, tokenId, data);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

interface MythicsEggErrors {
    /**
     * @notice Thrown if one attempts an action on a nonexistent egg.
     */
    error NonexistentEgg(uint256 tokenId);
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity >=0.8.0 <0.9.0;

import {IRedeemableToken} from "proof/redemption/interfaces/IRedeemableToken.sol";
import {MythicsV1} from "./MythicsV1.sol";
import {MythicsEgg, MythicEggSampler} from "../Egg/MythicsEgg.sol";

import {ISellable, ImmutableSellableCallbacker, SellableCallbacker} from "proof/sellers/base/SellableCallbacker.sol";
import {Seller} from "proof/sellers/base/Seller.sol";
import {RedeemableTokenRedeemer} from "proof/redemption/RedeemableTokenRedeemer.sol";

/**
 * @notice Helper library to encode/decode the purchase payload sent to the Mythics seller interface.
 */
library MythicsEggRedemptionLib {
    struct PurchasePayload {
        uint256 eggId;
        MythicEggSampler.EggType eggType;
    }

    function encode(PurchasePayload[] memory redemptions) internal pure returns (bytes memory) {
        return abi.encode(redemptions);
    }

    function decode(bytes memory data) internal pure returns (PurchasePayload[] memory) {
        return abi.decode(data, (PurchasePayload[]));
    }
}

/**
 * @title Mythics: Egg redeemer
 * @notice Redeems activated mythic eggs for a Mythic (either a token in the case of a stone egg or an open choice for
 * non-stone eggs).
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract MythicsEggRedeemer is Seller, ImmutableSellableCallbacker, RedeemableTokenRedeemer {
    using MythicsEggRedemptionLib for MythicsEggRedemptionLib.PurchasePayload[];

    error EggNotActivated(uint256 eggId);
    error EggNotRevealed(uint256 eggId);

    MythicsEgg public immutable eggs;

    constructor(ISellable mythics, MythicsEgg eggs_) ImmutableSellableCallbacker(mythics) {
        eggs = eggs_;
    }

    /**
     * @notice Redeems the given passes and purchases pieces in the Diamond Exhibition.
     */
    function redeem(uint256[] calldata eggIds) external {
        MythicsEggRedemptionLib.PurchasePayload[] memory payloads =
            new MythicsEggRedemptionLib.PurchasePayload[](eggIds.length);

        for (uint256 i = 0; i < eggIds.length; ++i) {
            if (!eggs.activated(eggIds[i])) {
                revert EggNotActivated(eggIds[i]);
            }

            (MythicEggSampler.EggType eggType, bool revealed) = eggs.eggType(eggIds[i]);
            if (!revealed) {
                revert EggNotRevealed(eggIds[i]);
            }

            _redeem(eggs, eggIds[i]);
            payloads[i] = MythicsEggRedemptionLib.PurchasePayload({eggId: eggIds[i], eggType: eggType});
        }

        _purchase(msg.sender, uint64(eggIds.length), /* total cost */ 0, payloads.encode());
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {DefaultOperatorFiltererUpgradeable} from
    "operator-filter-registry/src/upgradeable/DefaultOperatorFiltererUpgradeable.sol";
import {MythicsBase} from "./MythicsBase.sol";
import {
    BaseSellableUpgradeable,
    AccessControlEnumerableUpgradeable,
    SteerableAccessControlEnumerableUpgradeable
} from "./BaseSellableUpgradeable.sol";

import {Oddsoleum} from "../Oddsoleum/Oddsoleum.sol";
import {MythicsEggRedeemer, MythicsEggRedemptionLib} from "./MythicsEggRedeemer.sol";
import {MythicEggSampler} from "../Egg/MythicEggSampler.sol";

library MythicsStorage {
    /**
     * @notice Encodes an open choice that the stored user can submit for a given purchase ID.
     * @dev A zero-address as `chooser` indicates that this choice is no longer available.
     * @param chooser the address of the user that is eligible to submit the choice.
     * @param numChoices the number of choices.
     */
    struct OpenChoice {
        address chooser;
        uint8 numChoices;
    }

    /**
     * @notice Encodes a final choice for a given mythics token ID.
     * @param numChoicesMinusOne the number of choices minus one (optimisation).
     * @param choice the choice submitted by the user
     */
    struct FinalChoice {
        uint8 numChoicesMinusOne;
        uint8 choice;
    }

    bytes32 internal constant STORAGE_SLOT = keccak256("Mythics.storage.location");

    /**
     * @notice This is the storage layout for the Mythics contract.
     * @dev The fields in this struct MUST NOT be removed, renamed, or reordered. Only additionas are allowed to keep
     * the storage layout compatible between upgrades.
     */
    struct Layout {
        /**
         * @notice The number of tokens that have been minted.
         */
        uint256 numMinted;
        /**
         * @notice The base URI for the token metadata.
         */
        string baseTokenURI;
        /**
         * @notice The number of purchases handled by the seller interface.
         * @dev Counter to get sequential purchaseIDs
         */
        uint64 numPurchases;
        /**
         * @notice The MythicsEggRedeemer contract.
         */
        MythicsEggRedeemer eggRedeemer;
        /**
         * @notice Open choices added on purchase.
         * @dev Elements MUST be deleted after locking in a choice.
         */
        mapping(uint256 purchaseId => OpenChoice) openChoices;
        /**
         * @notice Locked-in choices for the given tokenId.
         * @dev Elements MUST and MUST ONLY be added for minted tokens.
         */
        mapping(uint256 tokenId => FinalChoice) finalChoices;
    }

    function layout() internal pure returns (Layout storage l) {
        bytes32 slot = STORAGE_SLOT;
        assembly {
            l.slot := slot
        }
    }
}

interface MythicsV1Events {
    /**
     * @notice Emitted when a Mythic is purchased (not minted) to draw random choices for the buyer off-chain.
     */
    event RandomiseMythics(uint256 indexed purchaseId, address indexed chooser, uint8 indexed numChoices);

    /**
     * @notice Emitted when the Mythics choice was locked in for a given purchase (and the Mythic was minted).
     */
    event MythicChosen(uint256 indexed purchaseId, address indexed chooser, uint256 indexed tokenId, uint8 choice);
}

/**
 * @title Mythics V1
 * @notice Mythics V1 allowing tokens to be purchased by redeeming MythicEgss through the MythicsEggRedeemer or by
 * burning Oddities through the Oddsoleum.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract MythicsV1 is MythicsBase, BaseSellableUpgradeable, DefaultOperatorFiltererUpgradeable, MythicsV1Events {
    /**
     * @notice Thrown if a user attempt to lock in a choice that exceeds the number of available choices.
     */
    error ChoiceOutOfBounds(uint256 purchaseId, uint8 numChoices, uint8 choice);

    /**
     * @notice Thrown if a user attempts to submit a choice for a purchase that was already locked in.
     */
    error PurchaseChoiceAlreadyLockedIn(uint256 purchaseId);

    /**
     * @notice Thrown if the caller attempts to lock in an open choice they are not eligible for.
     */
    error CallerIsNotChooser(uint256 purchaseId, address chooser, address caller);

    struct InitArgsV1 {
        address mainAdmin;
        address secondaryAdmin;
        address steerer;
        string baseTokenURI;
        MythicsEggRedeemer eggRedeemer;
        address royaltyReceiver;
    }

    function initializeV1(InitArgsV1 memory init) public virtual reinitializer(2) {
        __MythicsBase_init();
        __BaseSellable_init();
        __DefaultOperatorFilterer_init();

        _grantRole(DEFAULT_ADMIN_ROLE, init.mainAdmin);
        _grantRole(DEFAULT_ADMIN_ROLE, init.secondaryAdmin);
        _changeAdmin(init.mainAdmin);
        _grantRole(DEFAULT_STEERING_ROLE, init.steerer);

        MythicsStorage.layout().baseTokenURI = init.baseTokenURI;
        MythicsStorage.layout().eggRedeemer = init.eggRedeemer;

        _setDefaultRoyalty(init.royaltyReceiver, 500);
    }

    /**
     * @notice Pauses all ERC721 transfers.
     * @dev This includes mints and hence also purchases throught the Seller interface.
     */
    function pause() public virtual onlyRole(DEFAULT_STEERING_ROLE) {
        _pause();
    }

    /**
     * @notice Unpauses paused ERC721 transfers.
     */
    function unpause() public virtual onlyRole(DEFAULT_STEERING_ROLE) {
        _unpause();
    }

    /**
     * @notice Loads and returns the base URI for the token metadata according to the v1 storage layout.
     */
    function _baseURI() internal view virtual override returns (string memory) {
        return MythicsStorage.layout().baseTokenURI;
    }

    /**
     * @notice Sets the base tokenURI.
     */
    function setBaseTokenURI(string calldata newBaseTokenURI) public virtual onlyRole(DEFAULT_STEERING_ROLE) {
        MythicsStorage.layout().baseTokenURI = newBaseTokenURI;
    }

    /**
     * @notice Returns the total supply of Mythics.
     */
    function totalSupply() public view virtual returns (uint256) {
        return MythicsStorage.layout().numMinted;
    }

    /**
     * @notice Overriding the OZ's minting hook to increment the numMinted counter.
     * @dev Must not be called directly as this would mess with sequential token IDs. Use _mintNextTokenId instead.
     */
    function _mint(address to, uint256 tokenId) internal virtual override {
        unchecked {
            // Impossible to overflow in practice, the amount of gas required to mint more than 2**256 is prohibitive.
            MythicsStorage.layout().numMinted++;
        }
        super._mint(to, tokenId);
    }

    /**
     * @notice Convenience function to mint the next tokenId.
     */
    function _mintNextTokenId(address to) internal virtual returns (uint256) {
        uint256 tokenId = MythicsStorage.layout().numMinted;
        _mint(to, tokenId);
        return tokenId;
    }

    /**
     * @notice Tracks purchases and emits an event to randomise mythic choices off-chain.
     */
    function _trackPurchaseAndRandomiseMythics(address chooser, uint8 numChoices) internal returns (uint256) {
        assert(numChoices > 0);
        MythicsStorage.Layout storage layout = MythicsStorage.layout();
        uint256 purchaseId = layout.numPurchases++;

        // Optimisation: Not tracking the purchase in `openChoices` for `numChoices == 1` since there is only one choice
        // and we will lock it in immediately after this call in `_setChoice` deleting the entry again.
        if (numChoices > 1) {
            layout.openChoices[purchaseId] = MythicsStorage.OpenChoice({chooser: chooser, numChoices: numChoices});
        }
        emit RandomiseMythics(purchaseId, chooser, numChoices);

        return purchaseId;
    }

    /**
     * @notice Locks in a choice for a given purchase and mythic token ID.
     */
    function _setChoice(address chooser, uint256 purchaseId, uint256 tokenId, uint8 numChoices, uint8 choice)
        internal
    {
        assert(numChoices > 0);
        MythicsStorage.Layout storage layout = MythicsStorage.layout();

        if (choice >= numChoices) {
            revert ChoiceOutOfBounds(purchaseId, numChoices, choice);
        }

        if (numChoices > 1) {
            // Optimisation: Not deleting `openChoices` for `numChoices == 1` since we did not store anything in that
            // case. See also `_trackPurchaseAndRandomiseMythics`.
            delete layout.openChoices[purchaseId];
        }

        layout.finalChoices[tokenId] = MythicsStorage.FinalChoice({numChoicesMinusOne: numChoices - 1, choice: choice});
        emit MythicChosen(purchaseId, chooser, tokenId, choice);
    }

    /**
     * @notice Convenience wrapper functions for purchases without choices, i.e. `numChoices = 1`, e.g. used for
     * Oddities and stone eggs.
     */
    function _mintWithoutChoice(address to) internal {
        uint8 numChoices = 1;
        uint256 purchaseId = _trackPurchaseAndRandomiseMythics(to, numChoices);
        uint256 tokenId = _mintNextTokenId(to);
        _setChoice(to, purchaseId, tokenId, numChoices, 0);
    }

    /**
     * @notice Encode as choice submission.
     * @param purchaseId the purchase ID the choice should be submitted for
     * @param choice the chosen Mythic for the given purchase ID
     */
    struct ChoiceSubmission {
        uint256 purchaseId;
        uint8 choice;
    }

    /**
     * @notice Locks in the choice for a given purchase with an open choice and mints the Mythics token.
     * @dev Reverts if the caller is not the stored chooser or if a choice was already submitted for the given purchase.
     */
    function _chooseAndMint(ChoiceSubmission calldata submission) internal {
        MythicsStorage.Layout storage layout = MythicsStorage.layout();
        MythicsStorage.OpenChoice memory openChoice = layout.openChoices[submission.purchaseId];

        if (openChoice.chooser == address(0)) {
            revert PurchaseChoiceAlreadyLockedIn(submission.purchaseId);
        }

        if (msg.sender != openChoice.chooser) {
            revert CallerIsNotChooser(submission.purchaseId, openChoice.chooser, msg.sender);
        }

        uint8 numChoices = openChoice.numChoices;
        uint256 tokenId = _mintNextTokenId(msg.sender);
        _setChoice(msg.sender, submission.purchaseId, tokenId, numChoices, submission.choice);
    }

    /**
     * @notice Locks in choices for given purchases and mints the Mythics tokens.
     */
    function chooseAndMint(ChoiceSubmission[] calldata choices) public whenNotPaused {
        for (uint256 i; i < choices.length; ++i) {
            _chooseAndMint(choices[i]);
        }
    }

    /**
     * @inheritdoc BaseSellableUpgradeable
     * @dev Mints Mythics tokens for standard sales (e.g. through the Oddsoleum) or stone egg redemptions or records
     * open choices for non-stone eggs.
     */
    function _handleSale(address to, uint64 num, bytes calldata data) internal virtual override whenNotPaused {
        if (msg.sender != address(MythicsStorage.layout().eggRedeemer)) {
            for (uint256 i; i < num; ++i) {
                _mintWithoutChoice(to);
            }
            return;
        }

        MythicsEggRedemptionLib.PurchasePayload[] memory payloads = MythicsEggRedemptionLib.decode(data);
        assert(num == payloads.length);

        for (uint256 i; i < num; ++i) {
            MythicEggSampler.EggType eggType = payloads[i].eggType;

            if (eggType == MythicEggSampler.EggType.Stone) {
                _mintWithoutChoice(to);
                continue;
            }

            assert(uint8(eggType) <= 2);
            uint8 numChoices = uint8(eggType) + 1;
            _trackPurchaseAndRandomiseMythics(to, numChoices);
        }
    }

    /**
     * @notice Sets the egg redeemer contract.
     */
    function setEggRedeemer(MythicsEggRedeemer newRedeemer) public onlyRole(DEFAULT_STEERING_ROLE) {
        MythicsStorage.layout().eggRedeemer = newRedeemer;
    }

    /**
     * @notice Returns the egg redeemer contract.
     */
    function eggRedeemer() public view returns (MythicsEggRedeemer) {
        return MythicsStorage.layout().eggRedeemer;
    }

    /**
     * @notice Sets the default royalty receiver and fee in basis points.
     */
    function setDefaultRoyalty(address receiver, uint96 feeBasisPoints)
        public
        virtual
        onlyRole(DEFAULT_STEERING_ROLE)
    {
        _setDefaultRoyalty(receiver, feeBasisPoints);
    }

    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(MythicsBase, AccessControlEnumerableUpgradeable)
        returns (bool)
    {
        return MythicsBase.supportsInterface(interfaceId);
    }

    // =========================================================================
    //                           Operator filtering
    // =========================================================================

    /**
     * @dev See {IERC721-setApprovalForAll}.
     *      In this example the added modifier ensures that the operator is allowed by the OperatorFilterRegistry.
     */
    function setApprovalForAll(address operator, bool approved) public override onlyAllowedOperatorApproval(operator) {
        super.setApprovalForAll(operator, approved);
    }

    /**
     * @dev See {IERC721-approve}.
     *      In this example the added modifier ensures that the operator is allowed by the OperatorFilterRegistry.
     */
    function approve(address operator, uint256 tokenId) public override onlyAllowedOperatorApproval(operator) {
        super.approve(operator, tokenId);
    }

    /**
     * @dev See {IERC721-transferFrom}.
     *      In this example the added modifier ensures that the operator is allowed by the OperatorFilterRegistry.
     */
    function transferFrom(address from, address to, uint256 tokenId) public override onlyAllowedOperator(from) {
        super.transferFrom(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     *      In this example the added modifier ensures that the operator is allowed by the OperatorFilterRegistry.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) public override onlyAllowedOperator(from) {
        super.safeTransferFrom(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     *      In this example the added modifier ensures that the operator is allowed by the OperatorFilterRegistry.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data)
        public
        override
        onlyAllowedOperator(from)
    {
        super.safeTransferFrom(from, to, tokenId, data);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {Address} from "@openzeppelin/contracts/utils/Address.sol";
import {DefaultOperatorFiltererUpgradeable} from
    "operator-filter-registry/src/upgradeable/DefaultOperatorFiltererUpgradeable.sol";

import {MythicsV1} from "./MythicsV1.sol";

/**
 * @title Mythics V2
 * @notice Adding capabilities to interact with the operator filter registry.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract MythicsV2 is MythicsV1 {
    using Address for address;

    /**
     * @notice Calling the operator filter registry with given calldata.
     * @dev The registry contract did not foresee role-based contract access
     * control -- only the contract itself, or its (EIP-173) owner is allowed to
     * change subscription settings. To work around this, we enforce
     * authorisation here and forward arbitrary calldata to the registry.
     * Use with care!
     */
    function callOperatorFilterRegistry(bytes calldata cdata)
        external
        onlyRole(DEFAULT_STEERING_ROLE)
        returns (bytes memory)
    {
        return address(OPERATOR_FILTER_REGISTRY).functionCall(cdata);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {Address} from "openzeppelin-contracts/utils/Address.sol";
import {MythicsV2} from "./MythicsV2.sol";

/**
 * @notice ERC721 Transfer Listener
 */
interface IERC721TransferListener {
    /**
     * @notice Hook called upon token transfers.
     */
    function onTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize) external;
}

library MythicsV3Storage {
    bytes32 internal constant STORAGE_SLOT = keccak256("Mythics.V3.storage.location");

    /**
     * @notice This is the storage layout for the Mythics V3 contract.
     * @dev The fields in this struct MUST NOT be removed, renamed, or reordered. Only additionas are allowed to keep
     * the storage layout compatible between upgrades.
     */
    struct Layout {
        IERC721TransferListener transferListener;
    }

    function layout() internal pure returns (Layout storage l) {
        bytes32 slot = STORAGE_SLOT;
        assembly {
            l.slot := slot
        }
    }
}

/**
 * @title Mythics V3
 * @notice Adding notifications on transfer
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract MythicsV3 is MythicsV2 {
    using Address for address;

    struct InitArgsV3 {
        IERC721TransferListener listener;
    }

    function initializeV3(InitArgsV3 memory init) public virtual reinitializer(3) {
        MythicsV3Storage.layout().transferListener = init.listener;
    }

    function _afterTokenTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize)
        internal
        virtual
        override
    {
        super._afterTokenTransfer(from, to, firstTokenId, batchSize);

        IERC721TransferListener listener = MythicsV3Storage.layout().transferListener;

        // Trying to notify EOAs would result in reverts that would block transfers. We therefore return early in this
        // case.
        if (!address(listener).isContract()) {
            return;
        }

        try listener.onTransfer{gas: 30_000}(from, to, firstTokenId, batchSize) {} catch {}
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

/**
 * @notice Module to rate limit a certain action per discrete block of time.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract NonRollingRateLimited {
    /**
     * @notice Thrown if on attempts to exceed the rate limit.
     */
    error ExceedingRateLimit(uint256 requested, uint256 numLeft);

    /**
     * @notice The duration of a period in seconds.
     */
    uint64 private immutable _periodLength;

    /**
     * @notice The index of the last period for which an action has been performed.
     */
    uint64 private _lastPeriod;

    /**
     * @notice The maximum number of actions that can be performed in a period.
     */
    uint64 private __maxActionsPerPeriod;

    /**
     * @notice The number of actions that have been performed in the current period.
     * @dev Will automatically be reset to 0 in `rateLimited` at the start of each period.
     */
    uint64 private __performedCurrentPeriod;

    constructor(uint64 maxActionsPerPeriod, uint64 periodLength) {
        _periodLength = periodLength;
        _setMaxActionsPerPeriod(maxActionsPerPeriod);
    }

    /**
     * @notice Helper function to get the index of the current period.
     */
    function _currentPeriod() private view returns (uint64) {
        return uint64(block.timestamp / _periodLength);
    }

    /**
     * @notice Sets the maximum number of actions per period.
     */
    function _setMaxActionsPerPeriod(uint64 maxActionsPerPeriod) internal {
        __maxActionsPerPeriod = maxActionsPerPeriod;
    }

    /**
     * @notice Returns the maximum number of actions per period.
     */
    function _maxActionsPerPeriod() internal view returns (uint64) {
        return __maxActionsPerPeriod;
    }

    /**
     * @notice Keeps track of the number of performed actions.
     * @dev Reverts if the maximum number of actions per period is exceeded.
     */
    function _checkAndTrackRateLimit(uint64 requested) internal {
        uint64 performed = _performedCurrentPeriod();
        uint64 left = __maxActionsPerPeriod - performed;
        if (requested > left) {
            revert ExceedingRateLimit(requested, left);
        }
        __performedCurrentPeriod = performed + requested;
        _lastPeriod = _currentPeriod();
    }

    /**
     * @notice The number of actions performed in the current period.
     */
    function _performedCurrentPeriod() internal view returns (uint64) {
        if (_currentPeriod() > _lastPeriod) {
            return 0;
        }
        return __performedCurrentPeriod;
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import {SettableCallbackerWithAccessControl} from "proof/sellers/presets/CallbackerWithAccessControl.sol";
import {Seller} from "proof/sellers/base/Seller.sol";

import {MythicEggSampler} from "../Egg/MythicEggSampler.sol";
import {NonRollingRateLimited} from "./NonRollingRateLimited.sol";

interface OddsoleumEvents {
    event OdditySacrificed(address indexed owner, uint256 tokenId);

    /**
     * @notice Emitted if a burner attempts to sacrifice an Oddity that is not in the queue or was not approved to be
     * transferred by the Oddsoleum contract.
     * @dev This will likely only happen in the case of a race condition, where Oddity nomination is revoked after
     * selecting it to be burned.
     */
    event CannotBurnIneligibleOddity(uint256 indexed tokenId, bool queued, bool approved);
}

/**
 * @title Oddsoleum
 * @notice Allows Oddities to enter a queue for being sacrificed on the altar of the Oddgod.
 * @author David Huber (@cxkoda)
 * @custom:reviewer Arran Schlosberg (@divergencearran)
 */
contract Oddsoleum is Seller, SettableCallbackerWithAccessControl, OddsoleumEvents, NonRollingRateLimited {
    /**
     * @notice The role allowed to burn oddities.
     */
    bytes32 public constant BURNER_ROLE = keccak256("BURNER_ROLE");

    /**
     * @notice The receiver of burned Oddities.
     * @dev The original Oddities contract does not allow burning, so we send the tokens to the dead address instead.
     */
    address public constant BURN_ADDRESS = 0x000000000000000000000000000000000000dEaD;

    /**
     * @notice The Oddities contract.
     */
    IERC721 public immutable oddities;

    /**
     * @notice Keeps track of Oddities that are in the queue to be sacrificed.
     * @dev Keyed by owner to automatically unqueue Oddities if they are transferred. Consequently, tokens will still
     * be queued after a round-trip, which can't be avoided as it would require a callback from the Oddities contract
     * upon transfer.
     */
    mapping(address owner => mapping(uint256 tokenId => bool)) private _queued;

    constructor(address admin, address steerer, IERC721 oddities_)
        SettableCallbackerWithAccessControl(admin, steerer)
        NonRollingRateLimited(50, 1 days)
    {
        _setRoleAdmin(BURNER_ROLE, DEFAULT_STEERING_ROLE);
        oddities = oddities_;
    }

    /**
     * @notice Adds the given Oddities to the senders queue.
     * @dev Oddity ownership is not relevant here as senders only have access to their own flag set. Upon burn, the
     * contract will only consider the flag of the current owner of the given Oddity.
     */
    function addToQueue(uint256[] calldata tokenIds) external {
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            _queued[msg.sender][tokenIds[i]] = true;
        }
    }

    /**
     * @notice Removes the given Oddities from the senders queue.
     * @dev Oddity ownership is not relevant here as senders only have access to their own flag set. Upon burn, the
     * contract will only consider the flag of the current owner of the given Oddity.
     */
    function removeFromQueue(uint256[] calldata tokenIds) external {
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            _queued[msg.sender][tokenIds[i]] = false;
        }
    }

    /**
     * @notice Returns whether the given Oddities are in the queue.
     * @dev This does not imply that they can be sacrificed, as the owner may not have approved this contract to burn
     * them.
     */
    function queued(uint256[] calldata tokenIds) public view returns (bool[] memory) {
        bool[] memory queued_ = new bool[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            address owner = oddities.ownerOf(tokenIds[i]);
            queued_[i] = _queued[owner][tokenIds[i]];
        }
        return queued_;
    }

    /**
     * @notice Returns whether the given Oddities can be sacrificed.
     * @dev True iff the Oddity is in the queue and the owner has approved this contract to burn it.
     */
    function burnable(uint256[] calldata tokenIds) external view returns (bool[] memory) {
        bool[] memory burnable_ = new bool[](tokenIds.length);
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            address owner = oddities.ownerOf(tokenIds[i]);
            burnable_[i] = _burnable(owner, tokenIds[i]);
        }
        return burnable_;
    }

    /**
     * @notice Returns whether the given Oddities can be sacrificed.
     */
    function _burnable(address owner, uint256 tokenId) internal view returns (bool) {
        return _queued[owner][tokenId] && _approved(owner, tokenId);
    }

    /**
     * @notice Returns whether the given Oddities can be sacrificed.
     */
    function _approved(address owner, uint256 tokenId) internal view returns (bool) {
        return (oddities.isApprovedForAll(owner, address(this)) || oddities.getApproved(tokenId) == address(this));
    }

    /**
     * @notice Burns the given Oddity by sending it to a burn address.
     */
    function _burn(address owner, uint256 tokenId) internal returns (bool) {
        bool queued_ = _queued[owner][tokenId];
        bool approved = _approved(owner, tokenId);

        if (!(queued_ && approved)) {
            emit CannotBurnIneligibleOddity(tokenId, queued_, approved);
            return false;
        }

        oddities.transferFrom(owner, BURN_ADDRESS, tokenId);
        emit OdditySacrificed(owner, tokenId);
        return true;
    }

    /**
     * @notice Sacrifices the given Oddity by burning it and awards a Mythic to the original owner in return.
     */
    function _sacrifice(uint256 tokenId) internal returns (bool) {
        address owner = oddities.ownerOf(tokenId);
        bool burned = _burn(owner, tokenId);
        if (!burned) {
            return false;
        }
        _purchase(owner, 1, /* total cost */ 0, "");
        return true;
    }

    /**
     * @notice Sacrifices the given Oddities by burning them and awards Mythics to the original owners in return.
     */
    function sacrifice(uint256[] calldata tokenIds) external onlyRole(BURNER_ROLE) {
        uint64 numSacrificed;
        for (uint256 i = 0; i < tokenIds.length; ++i) {
            bool sacrificed = _sacrifice(tokenIds[i]);

            unchecked {
                if (sacrificed) {
                    ++numSacrificed;
                }
            }
        }
        _checkAndTrackRateLimit(numSacrificed);
    }

    /**
     * @notice Sets the maximum number of activations per day.
     */
    function setMaxSacrificesPerPeriod(uint32 maxSacrificesPerPeriod) external onlyRole(DEFAULT_STEERING_ROLE) {
        _setMaxActionsPerPeriod(maxSacrificesPerPeriod);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2023 Divergence Tech Ltd
pragma solidity ^0.8.19;

// Generated Code - DO NOT EDIT

library SacrificedOddityMythics {
    uint256 internal constant NUM_BITMAPS = 25;
    
    uint256 internal constant NUM_BITS_SET = 3617;

    function _bitmap(uint256 id) internal pure returns (uint256 bitmap) {
        if (id >= NUM_BITMAPS) {
            return 0;
        }
        assembly {
            switch id
            case 0 {
                bitmap := 115792089237315784048216292424100703509555863858832249713185853195729623842815
            }
            case 1 {
                bitmap := 113982865449968517032308318179027504998096168217306150269379887640075470635011
            }
            case 2 {
                bitmap := 115792089237105571041101126167665677834686322290959825413008695683431652130815
            }
            case 3 {
                bitmap := 112173614055635451478815021543382012168546980377358680286683472713984818284543
            }
            case 4 {
                bitmap := 115792089237105571241968381700039283871472648852314729737099496265188730994687
            }
            case 5 {
                bitmap := 115792089237312904414459407587685329689899327723318629418425842846152041433087
            }
            case 6 {
                bitmap := 115679011240849952163682580764399248937639501696991653643124636415141229887519
            }
            case 7 {
                bitmap := 115792089233946202491911666099101743040959878075793414362551275626348540854271
            }
            case 8 {
                bitmap := 441711766194595690076966096205886555582734539942871422419006199917740031
            }
            case 9 {
                bitmap := 115792089021636724930400699226638077990523808862022708858695834449781467381728
            }
            case 10 {
                bitmap := 115763819792119527942900115646418449313208210896779290360694816403175346536447
            }
            case 11 {
                bitmap := 115792089237309613408480251052212625570864500807933680928934320435481179848703
            }
            case 12 {
                bitmap := 115735550239083073793626782886452234543121561830058017218305547259287586209855
            }
            case 13 {
                bitmap := 115792089237312904414848661455065265114195483845727525271529183431796149190655
            }
            case 14 {
                bitmap := 108555085385420519907237212809158388702171340794820489674619758837999444426783
            }
            case 15 {
                bitmap := 115792089236894946357330384028083038760929798041186650002004608523928896274431
            }
            case 16 {
                bitmap := 86844508639753341163368316096573868228552523284398553072539662106409444577279
            }
            case 17 {
                bitmap := 2588154892901967303862341165498953769500217641890097615919225963020287
            }
            case 18 {
                bitmap := 380058894137238120340422404666724666522574284817682128896
            }
            case 19 {
                bitmap := 431359147377445631077980486941922672330952424291990423561480796372992
            }
            case 20 {
                bitmap := 27606985387162230629810415266812534666927630529678916506709465801687040
            }
            case 21 {
                bitmap := 115792089237263540081205728544468711375301041754031835095422641935697880023024
            }
            case 22 {
                bitmap := 115792089183396302089269752561550691424835253869979900275526434382664777597183
            }
            case 23 {
                bitmap := 904625683686970817741383290710736681721806396387499427736909327769553862655
            }
            case 24 {
                bitmap := 2199014866944
            }
            
        }
        return bitmap;
    }

    function _fromOddity(uint256 mythicId) internal pure returns (bool) {
        uint256 map = _bitmap(mythicId/256);
        return (
            (map >> (mythicId % 256))
            & uint256(1)
        ) == 1;
    }
}

library SacrificedOddityMythicsIDs {
    function mythicIds() internal pure returns (uint16[3617] memory ids) {
        return [uint16(0), 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84, 85, 86, 87, 88, 89, 90, 91, 92, 93, 94, 95, 96, 97, 98, 99, 100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110, 111, 112, 113, 114, 115, 116, 117, 139, 140, 141, 142, 143, 144, 145, 146, 147, 148, 149, 150, 151, 152, 153, 154, 155, 156, 157, 158, 159, 160, 161, 162, 163, 164, 165, 166, 167, 168, 169, 170, 171, 172, 173, 174, 175, 176, 177, 178, 179, 180, 181, 182, 183, 184, 185, 186, 187, 188, 208, 209, 210, 211, 212, 213, 214, 215, 216, 217, 218, 219, 220, 221, 222, 223, 224, 225, 226, 227, 228, 229, 230, 231, 232, 233, 234, 235, 236, 237, 238, 239, 240, 241, 242, 243, 244, 245, 246, 247, 248, 249, 250, 251, 252, 253, 254, 255, 256, 257, 286, 287, 288, 289, 290, 291, 292, 293, 294, 295, 296, 297, 298, 299, 300, 301, 302, 303, 304, 305, 306, 307, 308, 309, 310, 311, 312, 313, 314, 315, 316, 317, 318, 319, 320, 321, 322, 323, 324, 325, 326, 327, 328, 329, 330, 331, 332, 333, 334, 335, 365, 366, 367, 368, 369, 370, 371, 372, 373, 374, 375, 376, 377, 378, 379, 380, 381, 382, 383, 384, 385, 386, 387, 388, 389, 390, 391, 392, 393, 394, 395, 396, 397, 398, 399, 400, 401, 402, 403, 404, 405, 406, 407, 408, 409, 410, 411, 412, 413, 414, 440, 441, 442, 443, 444, 445, 446, 447, 448, 449, 450, 451, 452, 453, 454, 455, 456, 457, 458, 459, 460, 461, 462, 463, 464, 465, 466, 467, 468, 469, 470, 471, 472, 473, 474, 475, 476, 477, 478, 479, 480, 481, 482, 483, 484, 485, 486, 487, 488, 489, 506, 507, 508, 509, 510, 511, 512, 513, 514, 515, 516, 517, 518, 519, 520, 521, 522, 523, 524, 525, 526, 527, 528, 529, 530, 531, 532, 533, 534, 535, 536, 537, 538, 539, 540, 541, 542, 543, 544, 545, 546, 547, 548, 549, 550, 551, 552, 553, 554, 555, 574, 575, 576, 577, 578, 579, 580, 581, 582, 583, 584, 585, 586, 587, 588, 589, 590, 591, 592, 593, 594, 595, 596, 597, 598, 599, 600, 601, 602, 603, 604, 605, 606, 607, 608, 609, 610, 611, 612, 613, 614, 615, 616, 617, 618, 619, 620, 621, 622, 623, 659, 660, 661, 662, 663, 664, 665, 666, 667, 668, 669, 670, 671, 672, 673, 674, 675, 676, 677, 678, 679, 680, 681, 682, 683, 684, 685, 686, 687, 688, 689, 690, 691, 692, 693, 694, 695, 696, 697, 698, 699, 700, 701, 702, 703, 704, 705, 706, 707, 708, 729, 730, 731, 732, 733, 734, 735, 736, 737, 738, 739, 740, 741, 742, 743, 744, 745, 746, 747, 748, 749, 750, 751, 752, 753, 754, 755, 756, 757, 758, 759, 760, 761, 762, 763, 764, 765, 766, 767, 768, 769, 770, 771, 772, 773, 774, 775, 776, 777, 778, 802, 803, 804, 805, 806, 807, 808, 809, 810, 811, 812, 813, 814, 815, 816, 817, 818, 819, 820, 821, 822, 823, 824, 825, 826, 827, 828, 829, 830, 831, 832, 833, 834, 835, 836, 837, 838, 839, 840, 841, 842, 843, 844, 845, 846, 847, 848, 849, 850, 851, 880, 881, 882, 883, 884, 885, 886, 887, 888, 889, 890, 891, 892, 893, 894, 895, 896, 897, 898, 899, 900, 901, 902, 903, 904, 905, 906, 907, 908, 909, 910, 911, 912, 913, 914, 915, 916, 917, 918, 919, 920, 921, 922, 923, 924, 925, 926, 927, 928, 929, 952, 953, 954, 955, 956, 957, 958, 959, 960, 961, 962, 963, 964, 965, 966, 967, 968, 969, 970, 971, 972, 973, 974, 975, 976, 977, 978, 979, 980, 981, 982, 983, 984, 985, 986, 987, 988, 989, 990, 991, 992, 993, 994, 995, 996, 997, 998, 999, 1000, 1001, 1019, 1020, 1021, 1022, 1023, 1024, 1025, 1026, 1027, 1028, 1029, 1030, 1031, 1032, 1033, 1034, 1035, 1036, 1037, 1038, 1039, 1040, 1041, 1042, 1043, 1044, 1045, 1046, 1047, 1048, 1049, 1050, 1051, 1052, 1053, 1054, 1055, 1056, 1057, 1058, 1059, 1060, 1061, 1062, 1063, 1064, 1065, 1066, 1067, 1068, 1095, 1096, 1097, 1098, 1099, 1100, 1101, 1102, 1103, 1104, 1105, 1106, 1107, 1108, 1109, 1110, 1111, 1112, 1113, 1114, 1115, 1116, 1117, 1118, 1119, 1120, 1121, 1122, 1123, 1124, 1125, 1126, 1127, 1128, 1129, 1130, 1131, 1132, 1133, 1134, 1135, 1136, 1137, 1138, 1139, 1140, 1141, 1142, 1143, 1144, 1172, 1173, 1174, 1175, 1176, 1177, 1178, 1179, 1180, 1181, 1182, 1183, 1184, 1185, 1186, 1187, 1188, 1189, 1190, 1191, 1192, 1193, 1194, 1195, 1196, 1197, 1198, 1199, 1200, 1201, 1202, 1203, 1204, 1205, 1206, 1207, 1208, 1209, 1210, 1211, 1212, 1213, 1214, 1215, 1216, 1217, 1218, 1219, 1220, 1221, 1241, 1242, 1243, 1244, 1245, 1246, 1247, 1248, 1249, 1250, 1251, 1252, 1253, 1254, 1255, 1256, 1257, 1258, 1259, 1260, 1261, 1262, 1263, 1264, 1265, 1266, 1267, 1268, 1269, 1270, 1271, 1272, 1273, 1274, 1275, 1276, 1277, 1278, 1279, 1280, 1281, 1282, 1283, 1284, 1285, 1286, 1287, 1288, 1289, 1290, 1320, 1321, 1322, 1323, 1324, 1325, 1326, 1327, 1328, 1329, 1330, 1331, 1332, 1333, 1334, 1335, 1336, 1337, 1338, 1339, 1340, 1341, 1342, 1343, 1344, 1345, 1346, 1347, 1348, 1349, 1350, 1351, 1352, 1353, 1354, 1355, 1356, 1357, 1358, 1359, 1360, 1361, 1362, 1363, 1364, 1365, 1366, 1367, 1368, 1369, 1411, 1412, 1413, 1414, 1415, 1416, 1417, 1418, 1419, 1420, 1421, 1422, 1423, 1424, 1425, 1426, 1427, 1428, 1429, 1430, 1431, 1432, 1433, 1434, 1435, 1436, 1437, 1438, 1439, 1440, 1441, 1442, 1443, 1444, 1445, 1446, 1447, 1448, 1449, 1450, 1451, 1452, 1453, 1454, 1455, 1456, 1457, 1458, 1459, 1460, 1491, 1492, 1493, 1494, 1495, 1496, 1497, 1498, 1499, 1500, 1501, 1502, 1503, 1504, 1505, 1506, 1507, 1508, 1509, 1510, 1511, 1512, 1513, 1514, 1515, 1516, 1517, 1518, 1519, 1520, 1521, 1522, 1523, 1524, 1525, 1526, 1527, 1528, 1529, 1530, 1531, 1532, 1533, 1534, 1535, 1536, 1537, 1538, 1539, 1540, 1562, 1563, 1564, 1565, 1566, 1567, 1568, 1569, 1570, 1571, 1572, 1573, 1574, 1575, 1576, 1577, 1578, 1579, 1580, 1581, 1582, 1583, 1584, 1585, 1586, 1587, 1588, 1589, 1590, 1591, 1592, 1593, 1594, 1595, 1596, 1597, 1598, 1599, 1600, 1601, 1602, 1603, 1604, 1605, 1606, 1607, 1608, 1609, 1610, 1611, 1644, 1645, 1646, 1647, 1648, 1649, 1650, 1651, 1652, 1653, 1654, 1655, 1656, 1657, 1658, 1659, 1660, 1661, 1662, 1663, 1664, 1665, 1666, 1667, 1668, 1669, 1670, 1671, 1672, 1673, 1674, 1675, 1676, 1677, 1678, 1679, 1680, 1681, 1682, 1683, 1684, 1685, 1686, 1687, 1688, 1689, 1690, 1691, 1692, 1693, 1713, 1714, 1715, 1716, 1717, 1718, 1719, 1720, 1721, 1722, 1723, 1724, 1725, 1726, 1727, 1728, 1729, 1730, 1731, 1732, 1733, 1734, 1735, 1736, 1737, 1738, 1739, 1740, 1741, 1742, 1743, 1744, 1745, 1746, 1747, 1748, 1749, 1750, 1751, 1752, 1753, 1754, 1755, 1756, 1757, 1758, 1759, 1760, 1761, 1762, 1782, 1783, 1784, 1785, 1786, 1787, 1788, 1789, 1790, 1791, 1792, 1793, 1794, 1795, 1796, 1797, 1798, 1799, 1800, 1801, 1802, 1803, 1804, 1805, 1806, 1807, 1808, 1809, 1810, 1811, 1812, 1813, 1814, 1815, 1816, 1817, 1818, 1819, 1820, 1821, 1822, 1823, 1824, 1825, 1826, 1827, 1828, 1829, 1830, 1831, 1851, 1852, 1853, 1854, 1855, 1856, 1857, 1858, 1859, 1860, 1861, 1862, 1863, 1864, 1865, 1866, 1867, 1868, 1869, 1870, 1871, 1872, 1873, 1874, 1875, 1876, 1877, 1878, 1879, 1880, 1881, 1882, 1883, 1884, 1885, 1886, 1887, 1888, 1889, 1890, 1891, 1892, 1893, 1894, 1895, 1896, 1897, 1898, 1899, 1900, 1940, 1941, 1942, 1943, 1944, 1945, 1946, 1947, 1948, 1949, 1950, 1951, 1952, 1953, 1954, 1955, 1956, 1957, 1958, 1959, 1960, 1961, 1962, 1963, 1964, 1965, 1966, 1967, 1968, 1969, 1970, 1971, 1972, 1973, 1974, 1975, 1976, 1977, 1978, 1979, 1980, 1981, 1982, 1983, 1984, 1985, 1986, 1987, 1988, 1989, 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020, 2021, 2022, 2023, 2024, 2025, 2026, 2027, 2028, 2029, 2030, 2031, 2032, 2033, 2034, 2035, 2036, 2037, 2038, 2039, 2040, 2041, 2042, 2043, 2044, 2045, 2046, 2047, 2048, 2049, 2050, 2051, 2052, 2053, 2054, 2055, 2056, 2057, 2058, 2059, 2060, 2061, 2062, 2082, 2083, 2084, 2085, 2086, 2087, 2088, 2089, 2090, 2091, 2092, 2093, 2094, 2095, 2096, 2097, 2098, 2099, 2100, 2101, 2102, 2103, 2104, 2105, 2106, 2107, 2108, 2109, 2110, 2111, 2112, 2113, 2114, 2115, 2116, 2117, 2118, 2119, 2120, 2121, 2122, 2123, 2124, 2125, 2126, 2127, 2128, 2129, 2130, 2131, 2155, 2156, 2157, 2158, 2159, 2160, 2161, 2162, 2163, 2164, 2165, 2166, 2167, 2168, 2169, 2170, 2171, 2172, 2173, 2174, 2175, 2176, 2177, 2178, 2179, 2180, 2181, 2182, 2183, 2184, 2185, 2186, 2187, 2188, 2189, 2190, 2191, 2192, 2193, 2194, 2195, 2196, 2197, 2198, 2199, 2200, 2201, 2202, 2203, 2204, 2236, 2237, 2238, 2239, 2240, 2241, 2242, 2243, 2244, 2245, 2246, 2247, 2248, 2249, 2250, 2251, 2252, 2253, 2254, 2255, 2256, 2257, 2258, 2259, 2260, 2261, 2262, 2263, 2264, 2265, 2266, 2267, 2268, 2269, 2270, 2271, 2272, 2273, 2274, 2275, 2276, 2277, 2278, 2279, 2280, 2281, 2282, 2283, 2284, 2285, 2309, 2310, 2311, 2312, 2313, 2314, 2315, 2316, 2317, 2318, 2319, 2320, 2321, 2322, 2323, 2324, 2325, 2326, 2327, 2328, 2329, 2330, 2331, 2332, 2333, 2334, 2335, 2336, 2337, 2338, 2339, 2340, 2341, 2342, 2343, 2344, 2345, 2346, 2347, 2348, 2349, 2350, 2351, 2352, 2353, 2354, 2355, 2356, 2357, 2358, 2381, 2382, 2383, 2384, 2385, 2386, 2387, 2388, 2389, 2390, 2391, 2392, 2393, 2394, 2395, 2396, 2397, 2398, 2399, 2400, 2401, 2402, 2403, 2404, 2405, 2406, 2407, 2408, 2409, 2410, 2411, 2412, 2413, 2414, 2415, 2416, 2417, 2418, 2419, 2420, 2421, 2422, 2423, 2424, 2425, 2426, 2427, 2428, 2429, 2430, 2460, 2461, 2462, 2463, 2464, 2465, 2466, 2467, 2468, 2469, 2470, 2471, 2472, 2473, 2474, 2475, 2476, 2477, 2478, 2479, 2480, 2481, 2482, 2483, 2484, 2485, 2486, 2487, 2488, 2489, 2490, 2491, 2492, 2493, 2494, 2495, 2496, 2497, 2498, 2499, 2500, 2501, 2502, 2503, 2504, 2505, 2506, 2507, 2508, 2509, 2531, 2532, 2533, 2534, 2535, 2536, 2537, 2538, 2539, 2540, 2541, 2542, 2543, 2544, 2545, 2546, 2547, 2548, 2549, 2550, 2551, 2552, 2553, 2554, 2555, 2556, 2557, 2558, 2559, 2560, 2561, 2562, 2563, 2564, 2565, 2566, 2567, 2568, 2569, 2570, 2571, 2572, 2573, 2574, 2575, 2576, 2577, 2578, 2579, 2580, 2598, 2599, 2600, 2601, 2602, 2603, 2604, 2605, 2606, 2607, 2608, 2609, 2610, 2611, 2612, 2613, 2614, 2615, 2616, 2617, 2618, 2619, 2620, 2621, 2622, 2623, 2624, 2625, 2626, 2627, 2628, 2629, 2630, 2631, 2632, 2633, 2634, 2635, 2636, 2637, 2638, 2639, 2640, 2641, 2642, 2643, 2644, 2645, 2646, 2647, 2665, 2666, 2667, 2668, 2669, 2670, 2671, 2672, 2673, 2674, 2675, 2676, 2677, 2678, 2679, 2680, 2681, 2682, 2683, 2684, 2685, 2686, 2687, 2688, 2689, 2690, 2691, 2692, 2693, 2694, 2695, 2696, 2697, 2698, 2699, 2700, 2701, 2702, 2703, 2704, 2705, 2706, 2707, 2708, 2709, 2710, 2711, 2712, 2713, 2714, 2736, 2737, 2738, 2739, 2740, 2741, 2742, 2743, 2744, 2745, 2746, 2747, 2748, 2749, 2750, 2751, 2752, 2753, 2754, 2755, 2756, 2757, 2758, 2759, 2760, 2761, 2762, 2763, 2764, 2765, 2766, 2767, 2768, 2769, 2770, 2771, 2772, 2773, 2774, 2775, 2776, 2777, 2778, 2779, 2780, 2781, 2782, 2783, 2784, 2785, 2804, 2805, 2806, 2807, 2808, 2809, 2810, 2811, 2812, 2813, 2814, 2815, 2816, 2817, 2818, 2819, 2820, 2821, 2822, 2823, 2824, 2825, 2826, 2827, 2828, 2829, 2830, 2831, 2832, 2833, 2834, 2835, 2836, 2837, 2838, 2839, 2840, 2841, 2842, 2843, 2844, 2845, 2846, 2847, 2848, 2849, 2850, 2851, 2852, 2853, 2875, 2876, 2877, 2878, 2879, 2880, 2881, 2882, 2883, 2884, 2885, 2886, 2887, 2888, 2889, 2890, 2891, 2892, 2893, 2894, 2895, 2896, 2897, 2898, 2899, 2900, 2901, 2902, 2903, 2904, 2905, 2906, 2907, 2908, 2909, 2910, 2911, 2912, 2913, 2914, 2915, 2916, 2917, 2918, 2919, 2920, 2921, 2922, 2923, 2924, 2957, 2958, 2959, 2960, 2961, 2962, 2963, 2964, 2965, 2966, 2967, 2968, 2969, 2970, 2971, 2972, 2973, 2974, 2975, 2976, 2977, 2978, 2979, 2980, 2981, 2982, 2983, 2984, 2985, 2986, 2987, 2988, 2989, 2990, 2991, 2992, 2993, 2994, 2995, 2996, 2997, 2998, 2999, 3000, 3001, 3002, 3003, 3004, 3005, 3006, 3028, 3029, 3030, 3031, 3032, 3033, 3034, 3035, 3036, 3037, 3038, 3039, 3040, 3041, 3042, 3043, 3044, 3045, 3046, 3047, 3048, 3049, 3050, 3051, 3052, 3053, 3054, 3055, 3056, 3057, 3058, 3059, 3060, 3061, 3062, 3063, 3064, 3065, 3066, 3067, 3068, 3069, 3070, 3071, 3072, 3073, 3074, 3075, 3076, 3077, 3100, 3101, 3102, 3103, 3104, 3105, 3106, 3107, 3108, 3109, 3110, 3111, 3112, 3113, 3114, 3115, 3116, 3117, 3118, 3119, 3120, 3121, 3122, 3123, 3124, 3125, 3126, 3127, 3128, 3129, 3130, 3131, 3132, 3133, 3134, 3135, 3136, 3137, 3138, 3139, 3140, 3141, 3142, 3143, 3144, 3145, 3146, 3147, 3148, 3149, 3178, 3179, 3180, 3181, 3182, 3183, 3184, 3185, 3186, 3187, 3188, 3189, 3190, 3191, 3192, 3193, 3194, 3195, 3196, 3197, 3198, 3199, 3200, 3201, 3202, 3203, 3204, 3205, 3206, 3207, 3208, 3209, 3210, 3211, 3212, 3213, 3214, 3215, 3216, 3217, 3218, 3219, 3220, 3221, 3222, 3223, 3224, 3225, 3226, 3227, 3248, 3249, 3250, 3251, 3252, 3253, 3254, 3255, 3256, 3257, 3258, 3259, 3260, 3261, 3262, 3263, 3264, 3265, 3266, 3267, 3268, 3269, 3270, 3271, 3272, 3273, 3274, 3275, 3276, 3277, 3278, 3279, 3280, 3281, 3282, 3283, 3284, 3285, 3286, 3287, 3288, 3289, 3290, 3291, 3292, 3293, 3294, 3295, 3296, 3297, 3317, 3318, 3319, 3320, 3321, 3322, 3323, 3324, 3325, 3326, 3327, 3328, 3329, 3330, 3331, 3332, 3333, 3334, 3335, 3336, 3337, 3338, 3339, 3340, 3341, 3342, 3343, 3344, 3345, 3346, 3347, 3348, 3349, 3350, 3351, 3352, 3353, 3354, 3355, 3356, 3357, 3358, 3359, 3360, 3361, 3362, 3363, 3364, 3365, 3366, 3392, 3393, 3394, 3395, 3396, 3397, 3398, 3399, 3400, 3401, 3402, 3403, 3404, 3405, 3406, 3407, 3408, 3409, 3410, 3411, 3412, 3413, 3414, 3415, 3416, 3417, 3418, 3419, 3420, 3421, 3422, 3423, 3424, 3425, 3426, 3427, 3428, 3429, 3430, 3431, 3432, 3433, 3434, 3435, 3436, 3437, 3438, 3439, 3440, 3441, 3466, 3467, 3468, 3469, 3470, 3471, 3472, 3473, 3474, 3475, 3476, 3477, 3478, 3479, 3480, 3481, 3482, 3483, 3484, 3485, 3486, 3487, 3488, 3489, 3490, 3491, 3492, 3493, 3494, 3495, 3496, 3497, 3498, 3499, 3500, 3501, 3502, 3503, 3504, 3505, 3506, 3507, 3508, 3509, 3510, 3511, 3512, 3513, 3514, 3515, 3539, 3540, 3541, 3542, 3543, 3544, 3545, 3546, 3547, 3548, 3549, 3550, 3551, 3552, 3553, 3554, 3555, 3556, 3557, 3558, 3559, 3560, 3561, 3562, 3563, 3564, 3565, 3566, 3567, 3568, 3569, 3570, 3571, 3572, 3573, 3574, 3575, 3576, 3577, 3578, 3579, 3580, 3581, 3582, 3583, 3584, 3585, 3586, 3587, 3588, 3613, 3614, 3615, 3616, 3617, 3618, 3619, 3620, 3621, 3622, 3623, 3624, 3625, 3626, 3627, 3628, 3629, 3630, 3631, 3632, 3633, 3634, 3635, 3636, 3637, 3638, 3639, 3640, 3641, 3642, 3643, 3644, 3645, 3646, 3647, 3648, 3649, 3650, 3651, 3652, 3653, 3654, 3655, 3656, 3657, 3658, 3659, 3660, 3661, 3662, 3692, 3693, 3694, 3695, 3696, 3697, 3698, 3699, 3700, 3701, 3702, 3703, 3704, 3705, 3706, 3707, 3708, 3709, 3710, 3711, 3712, 3713, 3714, 3715, 3716, 3717, 3718, 3719, 3720, 3721, 3722, 3723, 3724, 3725, 3726, 3727, 3728, 3729, 3730, 3731, 3732, 3733, 3734, 3735, 3736, 3737, 3738, 3739, 3740, 3741, 3764, 3765, 3766, 3767, 3768, 3769, 3770, 3771, 3772, 3773, 3774, 3775, 3776, 3777, 3778, 3779, 3780, 3781, 3782, 3783, 3784, 3785, 3786, 3787, 3788, 3789, 3790, 3791, 3792, 3793, 3794, 3795, 3796, 3797, 3798, 3799, 3800, 3801, 3802, 3803, 3804, 3805, 3806, 3807, 3808, 3809, 3810, 3811, 3812, 3813, 3836, 3837, 3838, 3839, 3840, 3841, 3842, 3843, 3844, 3845, 3846, 3847, 3848, 3849, 3850, 3851, 3852, 3853, 3854, 3855, 3856, 3857, 3858, 3859, 3860, 3861, 3862, 3863, 3864, 3865, 3866, 3867, 3868, 3869, 3870, 3871, 3872, 3873, 3874, 3875, 3876, 3877, 3878, 3879, 3880, 3881, 3882, 3883, 3884, 3885, 3911, 3912, 3913, 3914, 3915, 3916, 3917, 3918, 3919, 3920, 3921, 3922, 3923, 3924, 3925, 3926, 3927, 3928, 3929, 3930, 3931, 3932, 3933, 3934, 3935, 3936, 3937, 3938, 3939, 3940, 3941, 3942, 3943, 3944, 3945, 3946, 3947, 3948, 3949, 3950, 3951, 3952, 3953, 3954, 3955, 3956, 3957, 3958, 3959, 3960, 3986, 3987, 3988, 3989, 3990, 3991, 3992, 3993, 3994, 3995, 3996, 3997, 3998, 3999, 4000, 4001, 4002, 4003, 4004, 4005, 4006, 4007, 4008, 4009, 4010, 4011, 4012, 4013, 4014, 4015, 4016, 4017, 4018, 4019, 4020, 4021, 4022, 4023, 4024, 4025, 4026, 4027, 4028, 4029, 4030, 4031, 4032, 4033, 4034, 4035, 4058, 4059, 4060, 4061, 4062, 4063, 4064, 4065, 4066, 4067, 4068, 4069, 4070, 4071, 4072, 4073, 4074, 4075, 4076, 4077, 4078, 4079, 4080, 4081, 4082, 4083, 4084, 4085, 4086, 4087, 4088, 4089, 4090, 4091, 4092, 4093, 4094, 4095, 4096, 4097, 4098, 4099, 4100, 4101, 4102, 4103, 4104, 4105, 4106, 4107, 4130, 4131, 4132, 4133, 4134, 4135, 4136, 4137, 4138, 4139, 4140, 4141, 4142, 4143, 4144, 4145, 4146, 4147, 4148, 4149, 4150, 4151, 4152, 4153, 4154, 4155, 4156, 4157, 4158, 4159, 4160, 4161, 4162, 4163, 4164, 4165, 4166, 4167, 4168, 4169, 4170, 4171, 4172, 4173, 4174, 4175, 4176, 4177, 4178, 4179, 4214, 4215, 4216, 4217, 4218, 4219, 4220, 4221, 4222, 4223, 4224, 4225, 4226, 4227, 4228, 4229, 4230, 4231, 4232, 4233, 4234, 4235, 4236, 4237, 4238, 4239, 4240, 4241, 4242, 4243, 4244, 4245, 4246, 4247, 4248, 4249, 4250, 4251, 4252, 4253, 4254, 4255, 4256, 4257, 4258, 4259, 4260, 4261, 4262, 4263, 4284, 4285, 4286, 4287, 4288, 4289, 4290, 4291, 4292, 4293, 4294, 4295, 4296, 4297, 4298, 4299, 4300, 4301, 4302, 4303, 4304, 4305, 4306, 4307, 4308, 4309, 4310, 4311, 4312, 4313, 4314, 4315, 4316, 4317, 4318, 4319, 4320, 4321, 4322, 4323, 4324, 4325, 4326, 4327, 4328, 4329, 4330, 4331, 4332, 4333, 4350, 4351, 4352, 4353, 4354, 4355, 4356, 4357, 4358, 4359, 4360, 4361, 4362, 4363, 4364, 4365, 4366, 4367, 4368, 4369, 4370, 4371, 4372, 4373, 4374, 4375, 4376, 4377, 4378, 4379, 4380, 4381, 4382, 4383, 4384, 4385, 4386, 4387, 4388, 4389, 4390, 4391, 4392, 4393, 4394, 4395, 4396, 4397, 4398, 4399, 4421, 4422, 4423, 4424, 4425, 4426, 4427, 4428, 4429, 4430, 4431, 4432, 4433, 4434, 4435, 4436, 4437, 4438, 4439, 4440, 4441, 4442, 4443, 4444, 4445, 4446, 4447, 4448, 4449, 4450, 4451, 4452, 4453, 4454, 4455, 4476, 4477, 4478, 4479, 4480, 4481, 4482, 4483, 4484, 4485, 4486, 4487, 4488, 4523, 4524, 4525, 4526, 4527, 4528, 4529, 4530, 4531, 4555, 4581, 4582, 4621, 4622, 4623, 4624, 4625, 4626, 4627, 4628, 4629, 4630, 4631, 4632, 4633, 4634, 4635, 4636, 4656, 4657, 4658, 4659, 4660, 4661, 4662, 4663, 4664, 4665, 4666, 4667, 4668, 4669, 4670, 4671, 4705, 4730, 4756, 4757, 4758, 4791, 4792, 4793, 4794, 4795, 4895, 4896, 4926, 4943, 4944, 4981, 5060, 5061, 5062, 5092, 5180, 5181, 5182, 5183, 5184, 5185, 5186, 5187, 5188, 5225, 5226, 5227, 5228, 5229, 5230, 5231, 5232, 5233, 5234, 5235, 5236, 5237, 5238, 5239, 5240, 5241, 5242, 5243, 5244, 5245, 5246, 5247, 5248, 5249, 5250, 5251, 5252, 5253, 5254, 5255, 5256, 5257, 5258, 5259, 5260, 5261, 5262, 5263, 5264, 5265, 5266, 5267, 5268, 5269, 5270, 5271, 5272, 5273, 5274, 5304, 5305, 5306, 5307, 5308, 5309, 5310, 5311, 5312, 5313, 5314, 5315, 5316, 5317, 5318, 5319, 5320, 5321, 5322, 5323, 5324, 5325, 5326, 5327, 5328, 5329, 5330, 5331, 5332, 5333, 5334, 5335, 5336, 5337, 5338, 5339, 5340, 5341, 5342, 5343, 5344, 5345, 5346, 5347, 5348, 5349, 5350, 5351, 5352, 5353, 5380, 5381, 5382, 5383, 5384, 5385, 5386, 5387, 5388, 5389, 5390, 5391, 5392, 5393, 5394, 5395, 5396, 5397, 5398, 5399, 5400, 5401, 5402, 5403, 5404, 5405, 5406, 5407, 5408, 5409, 5410, 5411, 5412, 5413, 5414, 5415, 5416, 5417, 5418, 5419, 5420, 5421, 5422, 5423, 5424, 5425, 5426, 5427, 5428, 5429, 5463, 5464, 5465, 5466, 5467, 5468, 5469, 5470, 5471, 5472, 5473, 5474, 5475, 5476, 5477, 5478, 5479, 5480, 5481, 5482, 5483, 5484, 5485, 5486, 5487, 5488, 5489, 5490, 5491, 5492, 5493, 5494, 5495, 5496, 5497, 5498, 5499, 5500, 5501, 5502, 5503, 5504, 5505, 5506, 5507, 5508, 5509, 5510, 5511, 5512, 5534, 5535, 5536, 5537, 5538, 5539, 5540, 5541, 5542, 5543, 5544, 5545, 5546, 5547, 5548, 5549, 5550, 5551, 5552, 5553, 5554, 5555, 5556, 5557, 5558, 5559, 5560, 5561, 5562, 5563, 5564, 5565, 5566, 5567, 5568, 5569, 5570, 5571, 5572, 5573, 5574, 5591, 5592, 5593, 5594, 5595, 5596, 5597, 5598, 5599, 5600, 5601, 5602, 5603, 5604, 5605, 5606, 5607, 5608, 5609, 5610, 5611, 5612, 5613, 5614, 5615, 5616, 5617, 5618, 5619, 5620, 5621, 5622, 5623, 5624, 5625, 5626, 5627, 5628, 5629, 5630, 5631, 5632, 5633, 5634, 5635, 5636, 5637, 5638, 5639, 5665, 5666, 5667, 5668, 5669, 5670, 5671, 5672, 5673, 5674, 5675, 5676, 5677, 5678, 5679, 5680, 5681, 5682, 5683, 5684, 5685, 5686, 5687, 5688, 5689, 5690, 5691, 5692, 5693, 5694, 5695, 5696, 5697, 5698, 5699, 5700, 5701, 5702, 5703, 5704, 5740, 5741, 5801, 5802, 5803, 5804, 5805, 5806, 5857, 5858, 5859, 5860, 5861, 5862, 5863, 5864, 5865, 5866, 5867, 5868, 5869, 5870, 5871, 5872, 5873, 5874, 5875, 5876, 5877, 5878, 5879, 5880, 5881, 5882, 5883, 5884, 5885, 5886, 5887, 5888, 5889, 5890, 5891, 5892, 5893, 5894, 5895, 5896, 5897, 5898, 5899, 5900, 5901, 5902, 5903, 5904, 5905, 5906, 5949, 5950, 5951, 5952, 5953, 5954, 5955, 5956, 5957, 5958, 5959, 5960, 5961, 5962, 5963, 5964, 5965, 5966, 5967, 5968, 5969, 5970, 5971, 5972, 5973, 5974, 5975, 5976, 6010, 6011, 6012, 6013, 6014, 6015, 6016, 6017, 6018, 6019, 6020, 6021, 6022, 6023, 6024, 6025, 6026, 6027, 6078, 6079, 6080, 6081, 6082, 6083, 6084, 6085, 6086, 6087, 6088, 6089, 6090, 6091, 6092, 6093, 6094, 6095, 6111, 6112, 6113, 6114, 6115, 6116, 6117, 6118, 6119, 6120, 6121, 6122, 6123, 6124, 6125, 6126, 6127, 6128, 6129, 6130, 6131, 6132, 6133, 6134, 6135, 6136, 6167, 6168, 6169, 6170, 6171, 6172, 6173, 6174, 6175, 6176, 6177, 6178, 6179, 6180, 6181, 6182, 6183, 6184];
    }
}

// SPDX-License-Identifier: MIT
// Copyright (c) 2023 the ethier authors (github.com/divergencetech/ethier)
pragma solidity >=0.8.0 <0.9.0;

import {AccessControlEnumerableUpgradeable} from
    "openzeppelin-contracts-upgradeable/access/AccessControlEnumerableUpgradeable.sol";

contract SteerableAccessControlEnumerableUpgradeable is AccessControlEnumerableUpgradeable {
    /// @notice The default role intended to perform access-restricted actions.
    /// @dev We are using this instead of DEFAULT_ADMIN_ROLE because the latter
    /// is intended to grant/revoke roles and will be secured differently.
    bytes32 public constant DEFAULT_STEERING_ROLE = keccak256("DEFAULT_STEERING_ROLE");
}

// SPDX-License-Identifier: MIT
// Copyright 2023 PROOF Holdings Inc
pragma solidity ^0.8.15;

import {IEntropyOracle} from "proof/entropy/IEntropyOracle.sol";

/**
 * @notice Helper libray for sampling from a discrete probability distribution.
 */
library StochasticSamplingLib {
    /**
     * @notice Computes the cumulative probability distribution from a discrete probability distribution.
     */
    function computeCDF(uint64[] memory pdf) internal pure returns (uint64[] memory) {
        uint64[] memory cdf = new uint64[](pdf.length);
        cdf[0] = pdf[0];
        for (uint256 i = 1; i < pdf.length; ++i) {
            cdf[i] = cdf[i - 1] + pdf[i];
        }

        return cdf;
    }

    /**
     * @notice Samples from a discrete cumulative probability distribution.
     * @dev This function assumes that rand is uniform in [0,2^256) and that `cdf[cdf.length - 1] << 2^256`. If not the
     * outcome will be biased
     */
    function sampleWithCDF(uint256 rand, uint64[] memory cdf) internal pure returns (uint256) {
        rand = rand % cdf[cdf.length - 1];

        for (uint256 i; i < cdf.length; ++i) {
            if (rand < cdf[i]) {
                return i;
            }
        }

        // This will never be reached given the above bounds of rand.
        assert(false);
        return 0;
    }
}

/**
 * @notice A contract that can sample token traits from discrete probability distributions.
 * @dev The probability distributions and seed derivation functions are implemented in the inheriting contracts.
 * @dev The functions defined here might be gas-heavy and are therefore intended to be used in view-calls only.
 */
abstract contract StochasticSampler {
    /**
     * @notice Returns a random seed for a given token and a boolean indicating whether the seed is available.
     */
    function _seed(uint256 tokenId) internal view virtual returns (bytes32, bool);

    /**
     * @notice Returns the cumulative probability distribution for a given trait of a given token.
     */
    function _cdf(uint256 tokenId, uint256 traitId) internal view virtual returns (uint64[] memory);

    /**
     * @notice Samples a trait for a given token.
     * @dev Returns the sampled trait and a boolean indicating whether the trait was already revealed (i.e. if the seed
     * for the given token is available).
     */
    function _sampleTrait(uint256 tokenId, uint256 traitId) internal view returns (uint256, bool) {
        (bytes32 seed, bool revealed) = _seed(tokenId);
        seed = keccak256(abi.encodePacked(seed, traitId));
        return (StochasticSamplingLib.sampleWithCDF(uint256(seed), _cdf(tokenId, traitId)), revealed);
    }
}

/**
 * @notice A contract that can sample token traits from discrete probability distributions loaded from storage.
 */
abstract contract StochasticSamplerWithCDFStorage is StochasticSampler {
    using StochasticSamplingLib for uint64[];

    /**
     * @notice Thrown if the traitId is invalid, i.e. if it exceeds the number of traits.
     */
    error InvalidTraitId(uint256 traitId);

    /**
     * @notice Thrown if the length of the given PDF does not match the number of realisations in a given trait.
     */
    error IncorrectPDFLength(uint256 gotLength, uint256 traitId, uint256 wantLength);

    /**
     * @notice Thrown if the given PDF cannot be normalised, i.e. if the sum of the probabilities is zero.
     */
    error ConstantZeroPDF();

    /**
     * @notice The number of realisations for each trait.
     */
    uint256[] private _numPerTrait;

    /**
     * @notice The cumulative probability distributions for each trait.
     * @dev Indexed by traitId, distributionVersion, sample.
     * @dev The distributionVersion is intended to allow having multiple "versions" of the probability distributions.
     */
    uint64[][][] private _cdfs;

    constructor(uint256[] memory numPerTrait) {
        _numPerTrait = numPerTrait;
        for (uint256 i; i < numPerTrait.length; ++i) {
            _cdfs.push(new uint64[][](0));
        }
        assert(_cdfs.length == numPerTrait.length);
    }

    /**
     * @notice Adds a new probability distribution for a given trait.
     */
    function _pushProbabilities(uint256 traitId, uint64[] memory pdf) internal {
        if (traitId >= _numPerTrait.length) {
            revert InvalidTraitId(traitId);
        }

        if (pdf.length != _numPerTrait[traitId]) {
            revert IncorrectPDFLength(pdf.length, traitId, _numPerTrait[traitId]);
        }

        uint64[] memory cdf = pdf.computeCDF();
        if (cdf[cdf.length - 1] == 0) {
            revert ConstantZeroPDF();
        }
        _cdfs[traitId].push(cdf);
    }

    /**
     * @notice Returns the version/index of the latest probability distribution for a given trait.
     */
    function _latestDistributionVersion(uint256 traitId) internal view returns (uint256) {
        return _cdfs[traitId].length - 1;
    }

    /**
     * @notice Returns the version/index of the probability distribution that is used for a given token and trait.
     * @dev This function is intended to be overridden by inheriting contracts.
     */
    function _distributionVersion(uint256 tokenId, uint256 traitId) internal view virtual returns (uint256);

    /**
     * @inheritdoc StochasticSampler
     * @dev Returns the probability distribution that is index by `_distributionVersion`.
     */
    function _cdf(uint256 tokenId, uint256 traitId) internal view virtual override returns (uint64[] memory) {
        if (traitId >= _numPerTrait.length) {
            revert InvalidTraitId(traitId);
        }
        return _cdfs[traitId][_distributionVersion(tokenId, traitId)];
    }
}

/**
 * @notice A contract that can sample token traits from discrete probability distributions using entropy provided by the
 * EntropyOracle.
 */
abstract contract StochasticSamplerWithOracle is StochasticSampler {
    /**
     * @notice The entropy oracle.
     */
    IEntropyOracle public entropyOracle;

    constructor(IEntropyOracle entropyOracle_) {
        entropyOracle = entropyOracle_;
    }

    /**
     * @inheritdoc StochasticSampler
     * @dev Uses the entropy of the block at `_revealBlockNumber(tokenId)`.
     */
    function _seed(uint256 tokenId) internal view virtual override returns (bytes32, bool) {
        bytes32 entropy = entropyOracle.blockEntropy(_revealBlockNumber(tokenId));
        return (keccak256(abi.encode(entropy, tokenId)), entropy != 0);
    }

    /**
     * @notice The blocknumber at which a given token will be revealed.
     * @dev The entropy provided by `entropyOracle` for this block will be used as seed for trait sampling.
     */
    function _revealBlockNumber(uint256 tokenId) internal view virtual returns (uint256);
}