pragma solidity ^0.5.0;

/**
 * @dev Collection of functions related to the address type,
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * This test is non-exhaustive, and there may be false-negatives: during the
     * execution of a contract's constructor, its address will be reported as
     * not containing a contract.
     *
     * > It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies in extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }
}

pragma solidity ^0.5.6;

import "./rapm-contracts/token/ERC20/IERC20.sol";
import "./rapm-contracts/token/ERC20/SafeERC20.sol";
import "./rapm-contracts/utils/ReentrancyGuard.sol";
import "./ManagerRole.sol";

contract ApmLockup is ManagerRole, ReentrancyGuard {
  using SafeMath for uint256;
  using SafeERC20 for IERC20;

  IERC20 private _lockToken;
  IERC20 private _rewardToken;
  uint256 private _startTimestamp;
  uint256 private _endTimestamp;
  
  uint256 private _duration;
  uint256 private _totalRewardAmount;
  uint256 private _totalLockedBalance;
  mapping(address => uint256) private _lockedBalances;

  uint256 private _denominator;
  mapping(address => uint256) private _numerators;
  mapping(address => bool) private _claimed;

  address[] private _lockerAddressList;

  constructor(
    address lockToken, 
    address rewardToken, 
    uint256 startTimestamp, 
    uint256 duration  // second
  ) public {
    require(startTimestamp >= now, "startTimestamp cannot be smaller than now");
    require(duration > 0, "duration must be larger than 0");

    _lockToken = IERC20(lockToken);
    _rewardToken = IERC20(rewardToken);
    _startTimestamp = startTimestamp;
    _endTimestamp = startTimestamp.add(duration);
    _duration = duration;
  }

  function lockToken() external view returns(address) {
    return address(_lockToken);
  }

  function rewardToken() external view returns(address) {
    return address(_rewardToken);
  }

  function startTimestamp() external view returns(uint256) {
    return _startTimestamp;
  }

  function endTimestamp() external view returns(uint256) {
    return _endTimestamp;
  }

  function totalRewardAmount() external view returns(uint256) {
    return _totalRewardAmount;
  }

  function totalLockedBalance() external view returns(uint256) {
    return _totalLockedBalance;
  }

  function lockedBalance(address user) external view returns(uint256) {
    return _lockedBalances[user];
  }

  function totalWeightedBalance() external view returns(uint256) {
    return _denominator;
  }

  function weightedBalance(address user) external view returns(uint256) {
    return _numerators[user];
  }

  function lockers() external view returns(address[] memory) {
    return _lockerAddressList;
  }

  function claimed(address user) external view returns(bool) {
    return _claimed[user];
  }

  function lockedBalances(address[] calldata users) external view returns(uint256[] memory) {
    uint256[] memory result = new uint256[](users.length);
    for(uint256 i = 0; i < users.length; i++) {
      result[i] = _lockedBalances[users[i]];
    }
    return result;
  }

  function points(address[] calldata users) external view returns(uint256[] memory) {
    uint256[] memory result = new uint256[](users.length);
    for(uint256 i = 0; i < users.length; i++) {
      result[i] = _numerators[users[i]];
    }
    return result;
  }

  /** ===== main functions ===== */

  function calculateReward(address user) public view returns(uint256) {
    return _totalRewardAmount.mul(_numerators[user]).div(_denominator);
  }

  function addRewardAmount(uint256 rewardAmount) external onlyManager {
    require(_rewardToken.allowance(msg.sender, address(this)) >= rewardAmount, "Not enough allowance");

    _totalRewardAmount = _totalRewardAmount.add(rewardAmount);
    _rewardToken.safeTransferFrom(msg.sender, address(this), rewardAmount);

    emit RewardAdded(rewardAmount);
  }

  /**
   * lock 참여자가 없는 채로 만료된 경우 reward를 회수 
   * */
  function removeRewardAmount() external onlyManager expired {
    require(_denominator == 0, "Locker exists");

    _rewardToken.transfer(msg.sender, _totalRewardAmount);
    _totalRewardAmount = 0;

    emit RewardRemoved(_totalRewardAmount);
  }

  function lock(uint256 amount) external nonReentrant notExpired {
    require(amount > 0, "Cannot lock 0");
    require(_lockToken.allowance(msg.sender, address(this)) >= amount, "Not enough allowance");

    _totalLockedBalance = _totalLockedBalance.add(amount);
    _lockedBalances[msg.sender] = _lockedBalances[msg.sender].add(amount);
    _lockToken.safeTransferFrom(msg.sender, address(this), amount);

    if(_numerators[msg.sender] == 0) {
      _lockerAddressList.push(msg.sender);
    }

    uint256 numerator = amount.mul(_endTimestamp.sub(block.timestamp)).div(_duration);
    _numerators[msg.sender] = _numerators[msg.sender].add(numerator);
    _denominator = _denominator.add(numerator);

    emit Locked(msg.sender, amount);
  }

  function unlock() external {
    if (block.timestamp < _endTimestamp) {
      _leave(msg.sender);
      
      uint256 _lockedBalance = _lockedBalances[msg.sender];
      _totalLockedBalance = _totalLockedBalance.sub(_lockedBalance);
      _lockedBalances[msg.sender] = _lockedBalances[msg.sender].sub(_lockedBalance);
      _lockToken.safeTransfer(msg.sender, _lockedBalance);

      emit Withdrawn(msg.sender, _lockedBalance); 
    } else {
      require(!_claimed[msg.sender], "already claimed");
      _getReward(msg.sender);
      _lockToken.safeTransfer(msg.sender, _lockedBalances[msg.sender]);
      _claimed[msg.sender] = true;
    }
  }

  function _leave(address user) private nonReentrant notExpired {
    uint256 numerator = _numerators[user];
    require(numerator > 0, "Locked token's amount is 0");

    _denominator = _denominator.sub(numerator);
    _numerators[user] = 0;

    emit Leaved(user);
  }
  
  function _getReward(address user) private nonReentrant expired {
    require(_numerators[user] > 0, "reward zero");
    
    uint256 reward = calculateReward(user);
    _rewardToken.safeTransfer(user, reward);

    emit RewardPaid(user, reward);
  }

 /** ===== modifiers ===== */
 
  modifier notExpired {
    require(block.timestamp >= _startTimestamp, 'The lock period has not yet come');
    require(block.timestamp < _endTimestamp, 'The lock period expired');
    _;
  }

  modifier expired {
    require(block.timestamp >= _endTimestamp, 'The lock period has not expired');
    _;
  }

  event RewardAdded(uint256 rewardAmount);
  event RewardRemoved(uint256 rewardAmount);
  event Locked(address indexed user, uint256 amount);
  event Leaved(address indexed user);
  event Withdrawn(address indexed user, uint256 amount);
  event RewardPaid(address indexed user, uint256 reward);
}

pragma solidity ^0.5.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP. Does not include
 * the optional functions; to access them see `ERC20Detailed`.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a `Transfer` event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through `transferFrom`. This is
     * zero by default.
     *
     * This value changes when `approve` or `transferFrom` are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * > Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an `Approval` event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a `Transfer` event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to `approve`. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

pragma solidity 0.5.6;

import "./rapm-contracts/access/Roles.sol";

contract ManagerRole {
    using Roles for Roles.Role;

    Roles.Role private managers;

    event ManagerAdded(address indexed account);
    event ManagerRemoved(address indexed account);

    modifier onlyManager() {
        require(managers.has(msg.sender), "ManagerRole: caller does not have the Manager role");
        _;
    }

    constructor() public {
        // 계약 생성자가 초기 매니저로 설정됨
        managers.add(msg.sender);
    }

    function addManager(address account) public onlyManager {
        managers.add(account);
        emit ManagerAdded(account);
    }

    function removeManager(address account) public onlyManager {
        managers.remove(account);
        emit ManagerRemoved(account);
    }

    function isManager(address account) public view returns (bool) {
        return managers.has(account);
    }
}

pragma solidity ^0.5.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the `nonReentrant` modifier
 * available, which can be aplied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 */
contract ReentrancyGuard {
    /// @dev counter to allow mutex lock with only one SSTORE operation
    uint256 private _guardCounter;

    constructor () internal {
        // The counter starts at one to prevent changing it from zero to a non-zero
        // value, which is a more expensive operation.
        _guardCounter = 1;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _guardCounter += 1;
        uint256 localCounter = _guardCounter;
        _;
        require(localCounter == _guardCounter, "ReentrancyGuard: reentrant call");
    }
}

pragma solidity ^0.5.0;

/**
 * @title Roles
 * @dev Library for managing addresses assigned to a Role.
 */
library Roles {
    struct Role {
        mapping (address => bool) bearer;
    }

    /**
     * @dev Give an account access to this role.
     */
    function add(Role storage role, address account) internal {
        require(!has(role, account), "Roles: account already has role");
        role.bearer[account] = true;
    }

    /**
     * @dev Remove an account's access to this role.
     */
    function remove(Role storage role, address account) internal {
        require(has(role, account), "Roles: account does not have role");
        role.bearer[account] = false;
    }

    /**
     * @dev Check if an account has this role.
     * @return bool
     */
    function has(Role storage role, address account) internal view returns (bool) {
        require(account != address(0), "Roles: account is the zero address");
        return role.bearer[account];
    }
}

pragma solidity ^0.5.0;

import "./IERC20.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value);
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves.

        // A Solidity high level call has three parts:
        //  1. The target address is checked to verify it contains contract code
        //  2. The call itself is made, and success asserted
        //  3. The return value is decoded, which in turn checks the size of the returned data.
        // solhint-disable-next-line max-line-length
        require(address(token).isContract(), "SafeERC20: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = address(token).call(data);
        require(success, "SafeERC20: low-level call failed");

        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

pragma solidity ^0.5.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, "SafeMath: division by zero");
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b != 0, "SafeMath: modulo by zero");
        return a % b;
    }
}

{
  "compilationTarget": {
    "contracts/ApmLockup.sol": "ApmLockup"
  },
  "evmVersion": "petersburg",
  "libraries": {},
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}