// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;

abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(
        address owner,
        address spender
    ) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(
        address account
    ) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(
        address owner,
        address spender
    ) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(
        address spender,
        uint256 amount
    ) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(
        address spender,
        uint256 addedValue
    ) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(
        address spender,
        uint256 subtractedValue
    ) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(
            currentAllowance >= subtractedValue,
            "ERC20: decreased allowance below zero"
        );
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(
            fromBalance >= amount,
            "ERC20: transfer amount exceeds balance"
        );
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(
                currentAllowance >= amount,
                "ERC20: insufficient allowance"
            );
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    constructor() {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    function owner() public view returns (address) {
        return _owner;
    }

    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    function renounceOwnership() external virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

contract CbyEth is ERC20 {
    event SetPair(address indexed, bool indexed);
    event SetRouter(address indexed, bool indexed);
    event SetWhiteList(address indexed, bool indexed);

    address public owner;

    // Mapping for router and pair  addresses
    mapping(address => bool) private isPair;
    mapping(address => bool) private isRouter;

    // Tax white list mapping (Liquidity Providers)
    mapping(address => bool) private isWhitelisted;

    // Equivalent to 2 percent. the last 2 0s is added to change the fee to 2 digit decimal in future if required
    uint256 public buyFees = 200; // = 2 percent
    uint256 public sellFees = 200;

    // Company's treasury wallet
    address public TREASURY_WALLET = 0x6D12d1E76eac827228F19EFd531914Df78B5BEBc;

    // MAX TAX PERCENTAGE = 2%
    uint256 constant MAX_TAX = 200;

    modifier onlyOwner() {
        require(
            _msgSender() == owner,
            "Only the contract owner can call this function."
        );
        _;
    }

    modifier addrNotNull(address addr) {
        require(addr != address(0), "Address parameter cannot be null.");
        _;
    }

    /**
     * @dev Initializes the contract with an initial supply of tokens and sets the contract owner as the initial token holder.
     * @param totalSupply The total supply of tokens to mint and assign to the contract owner.
     * @notice The contract owner will be added to the whitelist automatically upon initialization.
     */
    constructor(
        uint256 totalSupply,
        address vaultAddress
    ) ERC20("Carbify", "CBY") {
        _mint(vaultAddress, totalSupply);
        owner = _msgSender();
        isWhitelisted[owner] = true;
    }

    /**
     * @dev Sets the status of a pair address.
     * @param addr The address of the pair to set the status for.
     * @param status The status to set for the pair address.
     * @notice Only the contract owner can call this function.
     * @notice The pair address must not be null.
     * @notice Emits a {SetPair} event with the updated pair address and status.
     */
    function setPairAddress(
        address addr,
        bool status
    ) external onlyOwner addrNotNull(addr) {
        isPair[addr] = status;

        emit SetPair(addr, status);
    }

    /**
     * @dev Returns true if the given address is a pair address, false otherwise.
     * @param addr The address to check.
     * @return A boolean indicating whether the address is a pair address or not.
     */
    function isPairAddress(address addr) external view returns (bool) {
        return isPair[addr];
    }

    /**
     * @dev Sets the status of a router address.
     * @param addr The address of the router to set the status for.
     * @param status The status to set for the router address.
     * @notice Only the contract owner can call this function.
     * @notice The router address must not be null.
     * @notice Emits a {SetRouter} event with the updated router address and status.
     */
    function setRouterAddress(
        address addr,
        bool status
    ) external onlyOwner addrNotNull(addr) {
        isRouter[addr] = status;

        emit SetRouter(addr, status);
    }

    /**
     * @dev Returns true if the given address is a router address, false otherwise.
     * @param addr The address to check.
     * @return A boolean indicating whether the address is a router address or not.
     */
    function isRouterAddress(address addr) external view returns (bool) {
        return isRouter[addr];
    }

    /**
     * @dev Sets the status of a whitelist address.
     * @param addr The address of the whitelist to set the status for.
     * @param status The status to set for the whitelist address.
     * @notice Only the contract owner can call this function.
     * @notice The whitelist address must not be null.
     * @notice Emits a {SetWhiteList} event with the updated whitelist address and status.
     */
    function setWhiteListAddress(
        address addr,
        bool status
    ) external onlyOwner addrNotNull(addr) {
        isWhitelisted[addr] = status;

        emit SetWhiteList(addr, status);
    }

    /**
     * @dev Returns a boolean indicating whether an address is whitelisted.
     * @param addr The address to check.
     * @return A boolean indicating whether the address is whitelisted or not.
     */
    function isWhitelistAddress(address addr) external view returns (bool) {
        return isWhitelisted[addr];
    }

    /**
     * @dev Change the treasury wallet address to a new wallet address.
     * @param addr The address of new treasury wallet.
     * @notice Only the contract owner can call this function.
     */
    function setTreasuryWallet(address addr) external onlyOwner addrNotNull(addr) {
        TREASURY_WALLET = addr;
    }

    /**
     * @dev Sets the buy fees percentage.
     * @param amount The new buy fees percentage.
     * @notice Only the contract owner can call this function.
     * @notice The entered amount must not exceed the MAX_TAX limit.
     */
    function setBuyPercentage(uint256 amount) external onlyOwner {
        require(amount <= MAX_TAX, "Entered amount exceeds MAX Tax Limit.");
        buyFees = amount;
    }

    /**
     * @dev Sets the sell fees percentage.
     * @param amount The new sell fees percentage.
     * @notice Only the contract owner can call this function.
     * @notice The entered amount must not exceed the MAX_TAX limit.
     */
    function setSellPercentage(uint256 amount) external onlyOwner {
        require(amount <= MAX_TAX, "Entered amount exceeds MAX Tax Limit.");
        sellFees = amount;
    }

    /**
     * @dev Transfers tokens from the sender's account to another account with a 2% fee added for buy and sell transactions on DEX.
     * @param to The address to transfer the tokens to.
     * @param amount The amount of tokens to transfer.
     * @return A boolean indicating whether the transfer was successful.
     * @notice Only addresses that are not whitelisted and are a pair or router on the DEX will be charged the fee.
     */
    function transfer(
        address to,
        uint256 amount
    ) public override returns (bool) {
        uint256 fee = 0;
        bool excludedAccount = isWhitelisted[_msgSender()] || isWhitelisted[to];
        if (!excludedAccount) {
            if (isPair[_msgSender()] || isRouter[_msgSender()]) {
                fee = (buyFees * amount) / 10000;
                if (fee > 0) {
                    _transfer(_msgSender(), TREASURY_WALLET, fee);
                }
            }
        }

        _transfer(_msgSender(), to, amount - fee);
        return true;
    }

    /**
     * @dev Allows a spender to transfer tokens from the specified owner's account to another account with a 2% fee added for sell transactions on DEX.
     * @param from The address of the owner of the tokens.
     * @param to The address to transfer the tokens to.
     * @param amount The amount of tokens to transfer.
     * @return A boolean indicating whether the transfer was successful.
     * @notice Only addresses that are not whitelisted and are a router on the DEX and the recipient address is a pair on the DEX will be charged the fee.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        uint256 fee = 0;
        bool excludedAccount = isWhitelisted[from] || isWhitelisted[to];
        if (!excludedAccount) {
            if (isRouter[_msgSender()] && isPair[to]) {
                fee = (sellFees * amount) / 10000;
                if (fee > 0) {
                    _transfer(from, TREASURY_WALLET, fee);
                }
            }
        }
        _transfer(from, to, amount - fee);

        return true;
    }

    function burn(uint256 amount) external {
        _burn(_msgSender(), amount);
    }
}

{
  "compilationTarget": {
    "Project Ethereum/Ethereum_contract.sol": "CbyEth"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}