//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;


library Address {

    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // According to EIP-1052, 0x0 is the value returned for not-yet created accounts
        // and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned
        // for accounts without code, i.e. `keccak256('')`
        bytes32 codehash;
        bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470;
        // solhint-disable-next-line no-inline-assembly
        assembly { codehash := extcodehash(account) }
        return (codehash != accountHash && codehash != 0x0);
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return _functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        return _functionCallWithValue(target, data, value, errorMessage);
    }

    function _functionCallWithValue(address target, bytes memory data, uint256 weiValue, string memory errorMessage) private returns (bytes memory) {
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: weiValue }(data);
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }

}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

import "../GovernanceManager/PVPOwnable.sol";
import "./IClaimManager.sol";
import "../lib/TransferHelper.sol";
import "../lib/Address.sol";
import "../GameMasterclass/IGame.sol";
import "../House/IHouseManager.sol";

// interface IOldClaimManager {
//     function totalWonForToken(address user, address token, uint256[] calldata GAME_IDs) external view returns (uint256[] memory);
//     function totalValueEarned(address user) external view returns (uint256);
//     function totalClaimed(address user) external view returns (uint256);
// }

contract ClaimManager is PVPOwnable, IClaimManager {

    struct UserInfo {
        uint256 pendingClaim;
        uint256 totalClaimed;
        mapping ( uint256 => mapping ( address => uint256 ) ) totalWonByGame;
    }

    mapping ( address => UserInfo ) private userInfo;

    // address private oldClaimManager;

    modifier onlyCreditor() {
        require(
            manager.isGame(msg.sender) || 
            msg.sender == manager.house() ||
            IHouseManager(IProjectTokensManager(manager.projectTokens()).houseManager()).isHouse(msg.sender),
            'UnAuthorized'
        );
        _;
    }

    // constructor(
    //     address oldClaimManager_
    // ) {
    //     oldClaimManager = oldClaimManager_;
    // }

    function credit(
        uint256 GAME_ID,
        address user
    ) external payable override onlyCreditor {
        
        unchecked {
            userInfo[user].pendingClaim += msg.value;
            userInfo[user].totalWonByGame[GAME_ID][address(0)] += msg.value;
        }
    }

    function creditToken(
        address user,
        address token,
        uint256 GAME_ID,
        uint256 amount
    ) external override onlyCreditor {
        unchecked {
            userInfo[user].totalWonByGame[GAME_ID][token] += amount;
        }
    }

    function claimFor(address[] calldata users) external onlyOwner {
        for (uint256 i = 0; i < users.length;) {
            _claim(users[i]);
            unchecked { ++i; }
        }
    }

    function claim() external {
        _claim(msg.sender);
    }

    function claimAndCall(address to, uint256 amount, bytes calldata data) external payable {
        require(
            manager.isGame(to),
            'Can Only Call Games'
        );

        // fetch remaining amount to claim
        uint256 pending = userInfo[msg.sender].pendingClaim;
        require(pending > 0, 'Zero Claimable Amount');
        if (amount > pending) {
            amount = pending; // fixes front end round off issues
        }

        // add to user's total claimed
        unchecked {
            userInfo[msg.sender].totalClaimed += amount;
            userInfo[msg.sender].pendingClaim -= amount;
        }

        // if pending claim exists, send the rest of it
        if (userInfo[msg.sender].pendingClaim > 0) {
            _claim(msg.sender);
        }

        // call game
        IGame(to).play{value: ( amount + msg.value )}(msg.sender, address(0), 0, data);
    }

    function _claim(address user) internal {

        // fetch remaining amount to claim
        uint256 pending = userInfo[user].pendingClaim;
        if (pending == 0) {
            return;
        }

        // add to user's total claimed
        unchecked {
            userInfo[user].totalClaimed += pending;
        }

        // delete users pendingClaim
        delete userInfo[user].pendingClaim;

        // send reward to user
        TransferHelper.safeTransferETH(user, pending);
    }

    function getTotalWonByGame(address user, uint256 GAME_ID, address token) external view returns (uint256) {
        return userInfo[user].totalWonByGame[GAME_ID][token];
    }

    function pendingClaim(address user) external view returns (uint256) {
        return userInfo[user].pendingClaim;
    }

    function totalClaimed(address user) external view returns (uint256) {
        return userInfo[user].totalClaimed;// + IOldClaimManager(oldClaimManager).totalClaimed(user);
    }

    function totalValueEarned(address user) external view returns (uint256) {
        return userInfo[user].pendingClaim + userInfo[user].totalClaimed;// + IOldClaimManager(oldClaimManager).totalValueEarned(user);
    }

    function totalWonForToken(address user, address token, uint256[] calldata GAME_IDs) external view returns (uint256[] memory) {
        uint256[] memory wonByGames = new uint256[](GAME_IDs.length);
        for (uint i = 0; i < GAME_IDs.length; i++) {
            wonByGames[i] = userInfo[user].totalWonByGame[GAME_IDs[i]][token];
        }
        // uint256[] memory oldWonByGames = IOldClaimManager(oldClaimManager).totalWonForToken(user, token, GAME_IDs);
        // for (uint i = 0; i < GAME_IDs.length; i++) {
        //     unchecked {
        //         wonByGames[i] += oldWonByGames[i];
        //     }
        // }

        return wonByGames;
    }
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IClaimManager {
    function credit(
        uint256 GAME_ID,
        address user
    ) external payable;
    function creditToken(
        address user,
        address token,
        uint256 GAME_ID,
        uint256 amount
    ) external;
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IFeeRecipient {
    function takeFee(address token, uint256 amount, uint256 partner, address ref) external payable;
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IGame {
    /**
        Callback to provide us with randomness
     */
    function fulfillRandomWords(
        uint256 requestId,
        uint256[] calldata randomWords
    ) external;

    function play(address user, address token, uint256 amount, bytes calldata gameData) external payable;
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IGovernanceManager {
    function RNG() external view returns (address);
    function owner() external view returns (address);
    function chainlinkFeeReceiver() external view returns (address);
    function chainlinkSubscriptionOwner() external view returns (address);
    function referralManager() external view returns (address);
    function projectTokens() external view returns (address);
    function feeReceiver() external view returns (address);
    function claimManager() external view returns (address);
    function house() external view returns (address);
    function isGame(address game) external view returns (bool);
    function userInfoTracker() external view returns (address);
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IHouseManager {

    function isHouse(address house) external view returns (bool);
    function houseFor(address token) external view returns (address);
    function createHouse(address token) external returns (address house);
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IProjectTokensManager {
    function isValidPartner(uint256 partnerNonce) external view returns (bool);
    function getFundReceiver(uint256 partner) external view returns (address);
    function isListedToken(address token) external view returns (bool);
    function getWrapper(address token) external view returns (address);
    function getHouse(address token) external view returns (address);
    function getViewer(address token) external view returns (address);
    function isWrappedAsset(address wrapper) external view returns (bool);
    function canPlayForOthers(address addr) external view returns (bool);
    function wrappedAssetManager() external view returns (address);
    function houseManager() external view returns (address);
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

interface IRNG {
    function requestRandom(uint32 gas, uint32 numResults) external returns (uint256 requestId);
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

import "./IFeeRecipient.sol";
import "./IGovernanceManager.sol";
import "../ProjectTokens/IProjectTokensManager.sol";
import "../RNGTracker/IRNG.sol";

contract PVPOwnable {

    // Governance Manager
    IGovernanceManager public constant manager = IGovernanceManager(0x22164a57446aD5dE1DBE831784D8029773941678);

    modifier onlyOwner() {
        require(
            msg.sender == manager.owner(),
            'Only Owner'
        );
        _;
    }

    modifier onlyGame() {
        require(
            manager.isGame(msg.sender),
            'UnAuthorized'
        );
        _;
    }

    modifier onlyRNG() {
        require(
            msg.sender == manager.RNG(),
            'Only RNG Contract'
        );
        _;
    }

    modifier onlyValidToken(address token_) {
        require(
            IProjectTokensManager(manager.projectTokens()).isWrappedAsset(token_),
            'Invalid Token'
        );
        _;
    }

    modifier validGameToken(address token_) {
        require(
            token_ == address(0) || IProjectTokensManager(manager.projectTokens()).isWrappedAsset(token_),
            'Invalid Token'
        );
        _;
    }

    modifier validatePlayer(address player) {
        if (player != msg.sender) {
            require(
                IProjectTokensManager(manager.projectTokens()).canPlayForOthers(msg.sender),
                'UnAuthorized To Play For Others'
            );
        }
        _;
    }
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.14;

// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false
library TransferHelper {
    function safeApprove(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('approve(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x095ea7b3, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeApprove: approve failed'
        );
    }

    function safeTransfer(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transfer(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0xa9059cbb, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeTransfer: transfer failed'
        );
    }

    function safeTransferFrom(
        address token,
        address from,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transferFrom(address,address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x23b872dd, from, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::transferFrom: transferFrom failed'
        );
    }

    function safeTransferETH(address to, uint256 value) internal {
        (bool success, ) = to.call{value: value}(new bytes(0));
        require(success, 'TransferHelper::safeTransferETH: ETH transfer failed');
    }
}

{
  "compilationTarget": {
    "contracts/ClaimManager/ClaimManager.sol": "ClaimManager"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}