// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;
// BCCOIN Tester

import {Ownable} from "./Ownable.sol";

interface EndpointV1 {
    struct MsgSendParameter {
        uint32 dstChain;
        address dstAddress;
        bytes payload;
    }

    function msgSend(MsgSendParameter calldata) external payable;
    function getMsgDeliveryParams() external view returns (uint32, address);
}

interface BlackCardCoin {
    function stakingMint(address user, uint amount) external;
    function stakingBurn(address user, uint amount) external;
}

contract BCCOINBridge is Ownable {
    EndpointV1 public endpoint;
    BlackCardCoin public BCCOIN;

    bool public bridgeEnabled;

    mapping(uint32 => address) public omniContract;
    mapping(uint32 => bool) public authorizedChain;

    constructor(address _endpoint, address _BCCOIN) Ownable(msg.sender) {
        endpoint = EndpointV1(_endpoint);
        BCCOIN = BlackCardCoin(_BCCOIN);
        bridgeEnabled = true;
    }

    modifier onlyBridgeCall() {
        (uint32 _srcChain, address _srcCaller) = endpoint
            .getMsgDeliveryParams();

        require(msg.sender == address(endpoint), "Unauthorized direct caller.");
        require(
            omniContract[_srcChain] == _srcCaller,
            "Unauthorized source caller."
        );

        _;
    }

    function setOmniContract(
        uint32 _chain,
        address _contract
    ) external onlyOwner {
        omniContract[_chain] = _contract;
    }

    function setAuthorizedChain(
        uint32 _dstChain,
        bool _authorized
    ) external onlyOwner {
        authorizedChain[_dstChain] = _authorized;
    }

    function setEndpoint(address _endpoint) external onlyOwner {
        endpoint = EndpointV1(_endpoint);
    }

    function switchBridgeStatus() external onlyOwner {
        bridgeEnabled = !bridgeEnabled;
    }

    function mint(address _to, uint _amount) external onlyBridgeCall {
        BCCOIN.stakingMint(_to, _amount);
    }

    function bridge(uint _amount, uint32 _dstChain) external payable {
        require(bridgeEnabled, "Bridge not enabled.");
        require(authorizedChain[_dstChain], "Unauthorized chain.");
        BCCOIN.stakingBurn(msg.sender, _amount);

        endpoint.msgSend{value: msg.value}(
            EndpointV1.MsgSendParameter(
                _dstChain,
                omniContract[_dstChain],
                abi.encodeCall(this.mint, (msg.sender, _amount))
            )
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "BCCOINBridge.sol": "BCCOINBridge"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}