QRyou

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Counters.sol)

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./IERC721Metadata.sol";
import "./Address.sol";
import "./Context.sol";
import "./Strings.sol";
import "./ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits a {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

// from: https://eips.ethereum.org/EIPS/eip-2981#simple-summary

import "./IERC165.sol";

///
/// @dev Interface for the NFT Royalty Standard
///
interface IERC2981 is IERC165 {
    /// ERC165 bytes to add to interface array - set in parent contract
    /// implementing this standard
    ///
    /// bytes4(keccak256("royaltyInfo(uint256,uint256)")) == 0x2a55205a
    /// bytes4 private constant _INTERFACE_ID_ERC2981 = 0x2a55205a;
    /// _registerInterface(_INTERFACE_ID_ERC2981);

    /// @notice Called with the sale price to determine how much royalty
    //          is owed and to whom.
    /// @param _tokenId - the NFT asset queried for royalty information
    /// @param _salePrice - the sale price of the NFT asset specified by _tokenId
    /// @return receiver - address of who should be sent the royalty payment
    /// @return royaltyAmount - the royalty payment amount for _salePrice
    function royaltyInfo(
        uint256 _tokenId,
        uint256 _salePrice
    ) external view returns (
        address receiver,
        uint256 royaltyAmount
    );
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

// from: https://eips.ethereum.org/EIPS/eip-4906

import "./IERC165.sol";
import "./IERC721.sol";

// interface id for IERC4906: '0x49064906'

/// @title EIP-721 Metadata Update Extension
interface IERC4906 is IERC165, IERC721 {
    /// @dev This event emits when the metadata of a token is changed.
    /// So that the third-party platforms such as NFT market could
    /// timely update the images and related attributes of the NFT.
    event MetadataUpdate(uint256 _tokenId);

    /// @dev This event emits when the metadata of a range of tokens is changed.
    /// So that the third-party platforms such as NFT market could
    /// timely update the images and related attributes of the NFTs.
    event BatchMetadataUpdate(uint256 _fromTokenId, uint256 _toTokenId);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.26;

/// @title QRyou: a collection of on-chain writable qrcodes
/// @author germyjohn

import "./ERC721.sol";
import "./Counters.sol";
import "./Ownable.sol";
import "./IERC2981.sol";
import "./IERC4906.sol";

interface IstorageTools{
  function read(address) external view returns (bytes memory);
  function bytesToUint16Array(bytes memory) external pure returns(uint16[] memory);
  function b64encode(bytes memory) external pure returns(string memory);
}

interface IgifBuilder{
  function getImageBlock(uint8[] memory) external view returns(bytes memory);
}

interface IcensoredText{
  function getCensoredText(bytes10) external view returns(string memory);
}

contract QRyou is ERC721, IERC2981, IERC4906, Ownable {
  using Counters for Counters.Counter;

  struct Token {
    bytes10 salt;
    bool locked;
    address writer;
    uint8 writeCount;
    bytes message;
  }

  address internal constant censoredTextAddress = 0x2aDF11840B50e4019b81F8AbC5F7de7E86A4337E;
  address internal constant toolsAddress = 0x744F25b06DEbc03a909c8CED93Fa121C6c47B773;
  address internal constant positionsAddress = 0x88462a7c26b8F9f88C7f8472E2bB1B76775964E0;
  address internal constant stencilAddress = 0xB3956Fa40418c5282f0D15881Ac374f6a7c371Fa;
  address internal constant gifLzwAddress = 0x4563C42456CA63f68e0dE8bc84dc7988F9D6950D;

  mapping(uint256 => Token) internal tokens;
  /// @notice the number of mints by given address
  mapping(address => uint256) public mintsBy;

  Counters.Counter private supply;
  /// @notice the value to be sent for each mint
  uint256 public mintFee = 0.0069 ether;
  /// @notice the number of mints allowed per address
  uint256 public constant maxMints = 10;
  /// @notice the max supply for this collection. may changed to a lower value by calling lockMint.
  uint256 public maxSupply = 4200;
  /// @notice minting state. toggled by toggleMint.
  bool public mintEnabled = false;
  uint256 royaltyPercent = 2;
  string public externalURL = "https://nometa.online/qryou";
  string public constant description = "Writable qrcodes fully on-chained";
  string internal constant nameStart = "QRyou #";

  constructor() payable ERC721('QRyou','QRU') {}

  /* interface id for IERC2981: '0x2a55205a' */
  /* interface id for IERC4906: '0x49064906' */
  function supportsInterface(bytes4 interfaceId)
        public view override(IERC165, ERC721) returns (bool) {
    return
        interfaceId == type(IERC721).interfaceId ||
        interfaceId == type(IERC721Metadata).interfaceId ||
        interfaceId == type(IERC2981).interfaceId ||
        interfaceId == bytes4(0x49064906) ||
        super.supportsInterface(interfaceId);
  }

  receive() external payable {}

  // token logic ===================================================

  modifier tokenExists(uint256 _tokenId) {
    require(_exists(_tokenId), "token does not exist");
    _;
  }

  /// @notice returns the number of tokens in the collection
  function totalSupply() external view returns (uint256) {
      return supply.current();
  }

  /// @notice Mint given number of tokens
  /// @param _mints The number of tokens to mint. Max 10.
  function mint(uint256 _mints) external payable {
    address msgSender = msg.sender;
    uint256 mints = _mints;
    unchecked {
      require((supply.current() + mints) <= maxSupply, "exceeds max supply");
      if (msgSender != owner()) {
        require(msg.value == mints * mintFee, "invald value for tranasction");
        require(mintEnabled, "minting is disabled");
      }
      require((mintsBy[msgSender] + mints) <= maxMints, "mint limit of 10");
      mintsBy[msgSender] += mints;
      for (uint256 count = 1; count <= mints; count++) {
        supply.increment();
        uint256 tokenId = supply.current();
        tokens[tokenId].salt = bytes10(keccak256(abi.encodePacked(
                                                      tokenId,
                                                      block.prevrandao
                                                      )));
        _safeMint(msgSender, tokenId);
      }
    }
  }

  /// @notice encode a message into a qrcode. a holder can write to any unlocked token
  /// @param _tokenId the token id to write to
  /// @param _message the message to encode. max 78 characters.
  function writeMessage(uint256 _tokenId, string memory _message) external tokenExists(_tokenId) {
    uint256 tokenId = _tokenId;
    bytes memory messageBytes = bytes(_message);
    Token storage thisToken = tokens[tokenId];
    address writer = msg.sender;
    address tokenOwner = ownerOf(tokenId);
    require(messageBytes.length <= 78, "message too long");
    if (thisToken.locked) {
      require(writer == tokenOwner, "only owner can write");
    } else {
      require(balanceOf(writer) > 0, "only holders can write");
    }
    thisToken.writer = (writer == tokenOwner) ? address(0) : writer;
    unchecked { thisToken.writeCount += 1; }
    thisToken.message = messageBytes;

    emit MetadataUpdate(tokenId);
  }

  /// @notice lock a token from being written by other token holders. this can not be undone.
  function lockPublicWrite(uint256 _tokenId) external tokenExists(_tokenId) {
    uint256 tokenId = _tokenId;
    Token storage thisToken = tokens[tokenId];
    require(msg.sender == ownerOf(tokenId), "not the owner");
    require(! thisToken.locked, "token is locked");
    thisToken.locked = true;

    emit MetadataUpdate(tokenId);
  }

  /// @notice builds attributes to include in meatdata
  function getAttributes(uint256 _tokenId) internal view returns (string memory) {
    Token memory thisToken = tokens[_tokenId];
    string memory attributes = '","attributes":[{"trait_type":"state","value":';
    string memory lockedStr = thisToken.locked ? '"locked"}' : '"unlocked"}';
    attributes = string.concat(
                            attributes,
                            lockedStr
                            );
    if (thisToken.writeCount > 0) {
      attributes = string.concat(
                            attributes,
                            ',{"trait_type":"writeCount","value":',
                            Strings.toString(thisToken.writeCount),
                            '}'
                            );
    }
    if (thisToken.writer != address(0)) {
      attributes = string.concat(
                            attributes,
                            ',{"trait_type":"messageFrom","value":"',
                            string(getbyteStringAddress(thisToken.writer)),
                            '"}'
                            );
    }
    return string.concat(attributes, "]" );
  }

  /// @notice returns metadata for the token
  function tokenURI(uint256 _tokenId)
        public view virtual override tokenExists(_tokenId) returns (string memory) {
    uint256 tokenId = _tokenId;
    IstorageTools tools = IstorageTools(toolsAddress);

    return string.concat(
                    'data:application/json;base64,',
                    tools.b64encode(bytes(string.concat(
                      '{"name":"',
                      getName(tokenId),
                      /* nameStart, */
                      /* ' #', */
                      /* Strings.toString(tokenId), */
                      '","description":"',
                      description,
                      '","external_url":"',
                      externalURL,
                      getAttributes(tokenId),
                      ',"image":"',
                      packSvg(tokenId),
                      '"}'
                      )))
                    );
  }

  function packSvg(uint256 _tokenId) internal view returns(string memory) {
    IstorageTools tools = IstorageTools(toolsAddress);
    Token memory thisToken = tokens[_tokenId];
    string memory colour;
    if (thisToken.locked) {
      colour = 'c32';
    } else if (thisToken.writeCount == 0) {
      colour = 'fff';
    } else if (thisToken.writer == address(0)) {
      colour = '000';
    } else {
      string[5] memory colours = ['e82', 'ed2', '0a1', '08d', '85b'];
      colour = colours[(tokens[_tokenId].writeCount - 1) % 5];
    }
    return string.concat(
                  "data:image/svg+xml;base64,",
                  tools.b64encode(bytes(string.concat(
                      '<svg id="q" width="740" height="740" xmlns="http://www.w3.org/2000/svg">',
                      '<style>img{width:100%;height:100%;',
                      'image-rendering:pixelated;border-radius:14px;}</style>',
                      '<rect rx="40" width="740" height="740" fill="#000"></rect>',
                      '<rect rx="28" x="15" y="15" width="710" height="710" stroke="#',
                      colour,
                      '" stroke-width="10"></rect>',
                      '<foreignObject width="656" height="656" x="42" y="42">',
                      '<img xmlns="http://www.w3.org/1999/xhtml" src="data:image/gif;base64,',
                      tools.b64encode(packGif(_tokenId)),
                      '"/></foreignObject>',
                      '<animate attributeName="opacity" dur="2.2s" from="1" to="0.999" ',
                      'repeatCount="indefinite"/>',
                      '<script type="text/javascript"><![CDATA[',
                      'let q=document.getElementById("q");',
                      'q.style=`margin:${(q.parent == undefined)?"',
                      'calc((100vh - 740px)/2)":"0"} auto;background-color:#2e2e2e;`;]]>',
                       '</script></svg>'
                      )))
                    );
  }

  function genImageBlock(uint256 _tokenId) internal view returns(bytes memory) {
    uint256 tokenId = _tokenId;
    bytes memory message = tokens[tokenId].message;
    /* if no message written */
    if (message.length == 0) {
      message = bytes(IcensoredText(censoredTextAddress).getCensoredText(tokens[tokenId].salt));
    }
    if (message.length == 0) {
      message = bytes.concat(
                        bytes(getName(tokenId)),
                        ' ',
                        bytes(getbyteStringAddress(ownerOf(tokenId)))
                        );
    }
    uint8[] memory imageArray = getImageArray(addEcc(encodeMessage(message)));
    return IgifBuilder(gifLzwAddress).getImageBlock(imageArray);
  }

  // public only for testing
  function packGif(uint256 _tokenId) public view returns(bytes memory) {
    (bytes memory light, bytes memory dark, uint8[] memory glitches) = parseSalt(_tokenId);
    bytes memory imageBlock = genImageBlock(_tokenId);
    bytes1 bigTime = bytes1((glitches[0] % 3) + 1);
    return bytes.concat(
                        hex'47494638396129002900f00000',
                        light,
                        dark,
                        // aeb: repeat indefinitely
                        hex'21FF0B4E45545343415045322E300301000000',
                        // gce: 3 sec (2c01), disposal (packed 04)
                        // 5 sec => f401
                        /* hex'21F90404f4010000', */
                        hex'21F90404',
                        bytes1(glitches[0] << 4),
                        bigTime,
                        hex'0000',
                        /* hex'010000', */
                        // id + code size
                        hex'2C00000000290029000002',
                        imageBlock,
                        hex'00',

                        // long invert 1st

                        // gce: 0.4 sec (2800), disposal (packed 04)
                        /* hex'21F9040428000000', */
                        hex'21F90404',
                        bytes1((glitches[1] % 50) + 10),
                        hex'000000',
                        // id: last byte flags local colour table (80)
                        hex'2C000000002900290080',
                        dark,
                        light,
                        hex'02', // mincode
                        imageBlock,
                        hex'00',

                        // gce: 0.1 sec (0a00), disposal (packed 04)
                        hex'21F904040a000000',
                        // id
                        hex'2C00000000290029000002',
                        this.glitch(imageBlock, glitches[2]),
                        hex'00',

                        // gce: 0.1 sec (0a00), disposal (packed 04)
                        hex'21F904040a000000',
                        // id
                        hex'2C00000000290029000002',
                        this.glitch(imageBlock, glitches[3]),
                        hex'003b'
                        );
  }

  /// @notice this function is external only for the sake of slicing bytes
  function glitch(bytes calldata _imageBlock, uint8 _glitch) external pure returns(bytes memory) {
    uint8 position = (_glitch % 60) + 10;
    return bytes.concat(
                  _imageBlock[:position],
                  // might try ^ 85
                  bytes1(_glitch & 85),
                  /* bytes1(hex'55'), */
                  _imageBlock[position+1:]
                  );
  }

  /// @notice parse stored salt as light, dark colours and values for glitches
  function parseSalt(uint256 _tokenId) internal view
        returns(bytes memory, bytes memory, uint8[] memory) {
    bytes10 salt = tokens[_tokenId].salt;
    uint8[] memory glitches = new uint8[](4);
    bytes memory light = '';
    bytes memory dark = '';
    uint16 contrast;
    //gen light
    uint8 count = 0;
    // saves 2514 gas
    unchecked {
      for (uint256 i=0; i<3; i++) {
        uint8 value =  255 - (uint8(salt[i]) % 90);
        uint8 rgb;
        if (value > 240) {rgb = 255;}
        else if (value < 200 && count < 2) {
          rgb = count == 0 || i == 2 ? 80:160;
          count++;
        }
        else rgb = value;
        contrast += rgb;
        light = bytes.concat(light, bytes1(rgb));
      }
      // gen dark
      // determine black or colour from adding rgb
      count = 0;
      for (uint256 i=0; i<3; i++) {
        uint8 value =  0 + (uint8(salt[i+3]) % 70);
        uint8 rgb;
        if (contrast < 620) {rgb = 0;}
        else if (value > 40 && count < 2) {
          rgb = count == 0 || i == 0 ? 140 : 70;
          count++;
        }
        else rgb = value;
        dark = bytes.concat(dark, bytes1(rgb));
      }
      for (uint256 i=0; i<4; i++) {
        glitches[i] = uint8(salt[i+6]);
      }
    }
    return (light, dark, glitches);
  }

  /// @notice prepares the message with the qrcode mode and appropriate padding
  function encodeMessage(bytes memory message) internal pure returns (uint8[] memory) {
    uint8[] memory md = new uint8[](80);
    uint8 length = uint8(message.length);
    // saves 23574 gas
    unchecked {
      md[0] = uint8((0x04 << 4) + (length >> 4));
      md[1] = uint8((length << 4) + uint8(message[0] >> 4));
      for (uint8 i=0; i<length-1; i++) {
        md[i+2] = uint8(message[i] << 4) + uint8(message[i+1] >> 4);
      }
      md[length+1] = uint8((message[length-1] << 4));
      uint8[2] memory pad = [236,17];
      // need to start with pad[0]
      uint8 padShift = (length+2) % 2;
      for (uint8 i=length+2; i<80; i++) {
        md[i] = pad[(i + padShift) % 2];
      }
    }
    return md;
  }

  /// @notice generates the error correction codes
  function addEcc(uint8[] memory _message) internal pure returns(uint8[] memory) {
    uint256 genLen = 21;
    uint256 msgLen = 80;
    uint8[] memory mc = new uint8[](msgLen + genLen);
    uint8[21] memory ga = [0,17,60,79,50,61,163,26,187,202,180,221,225,83,239,156,164,212,212,188,190];
    // create tables
    uint8[] memory exp = new uint8[](256);
    uint256[] memory log = new uint256[](256);
    // saves 709906 gas
    unchecked {
      // moved next line from above
      for (uint256 i ; i<msgLen; i++) { mc[i] = _message[i]; }
      for (uint8 i=0; i<8; i++) { exp[i] = uint8(1) << i; }
      for (uint256 i=8; i<256; i++) { exp[i] = (((exp[i - 4] ^ exp[i - 5]) ^ exp[i - 6]) ^ exp[i - 8]); }
      for (uint256 i=0; i<255; i++) { log[exp[i]] = i; }
      for (uint8 i=0; i<msgLen; i++) {
        uint8[] memory q = new uint8[](21);
        for (uint8 j; j<genLen; j++) {
          if (mc[i] == 0) break;
          q[j] = exp[(log[mc[i]] + ga[j]) % 255];
        }
        for (uint8 j=1; j<genLen; j++) {
          mc[i+j] ^= q[j];
        }
        // rewrite the original _message code to first position
        mc[i] = _message[i];
      }
    }
    return mc;
  }

  //======================================================

  function getImageArray(uint8[] memory _data) internal view returns(uint8[] memory) {
    IstorageTools tools = IstorageTools(toolsAddress);
    uint16[] memory positions = tools.bytesToUint16Array(tools.read(positionsAddress));
    uint8[] memory imageArray = new uint8[](1681);
    uint16[] memory stencil = tools.bytesToUint16Array(tools.read(stencilAddress));
    uint256 stencilLength = stencil.length; //153
    uint16 count = 807;
    // unpack data bits and add to imageArray using positions
    uint8 bit;
    // saves 306566 gas
    unchecked {
      for (uint256 i=0; i<count; i++) {
        bit = (_data[i/8] >> (7-(i % 8))) % 2;
        // applying mask before placing
        if (positions[i] % 2 == 0) { bit ^= 1; }
        imageArray[positions[i]] = bit;
      }
      // apply stencil
      for (uint256 i=0; i<stencilLength; i++) {
        imageArray[stencil[i]] = 1;
      }
    }
    return imageArray;
  }

  // utilities

  function getName(uint256 _tokenId) internal pure returns(string memory) {
    return string.concat(
                      nameStart,
                      Strings.toString(_tokenId)
                      );
  }

  /// @notice converts an address to a hexadecimal string with leading 0x
  /// @param _address the address to convert
  /// @return address as a string
  function getbyteStringAddress(address _address) internal pure returns(bytes memory) {
    bytes memory addressBytes = abi.encodePacked(_address);
    bytes memory addressStringBytes = '0x';
    bytes memory alphabet = "0123456789abcdef";
    for (uint256 i=0; i<20; i++) {
      addressStringBytes = bytes.concat(
                                    addressStringBytes,
                                    alphabet[uint8(addressBytes[i] >> 4)],
                                    alphabet[uint8(addressBytes[i] & 0x0f)]
                                    );
    }
    return addressStringBytes ;
  }

  /// @notice called with the sale price to determine how much royalty is owed and to whom.
  /// @param _tokenId the NFT asset queried for royalty information
  /// @param _salePrice the sale price of the NFT asset specified by _tokenId
  /// @return receiver address of who should be sent the royalty payment
  /// @return royaltyAmount the royalty payment amount for _salePrice
  function royaltyInfo(uint256 _tokenId, uint256 _salePrice)
                external view tokenExists(_tokenId)
                returns(address receiver, uint256 royaltyAmount) {
    return (owner(), _salePrice * royaltyPercent / 100);
  }

  /* owner control */

  /// @notice Set the external address for metadata. onlyOwner
  /// @param _url The new external url.
  function setExternalURL(string calldata _url) external onlyOwner {
      externalURL = _url;
  }

  /// @notice Toggles bool mintEnabled
  function toggleMint() external onlyOwner {
    require(supply.current() < maxSupply, "minting has ended");
    mintEnabled = !mintEnabled;
  }

  /// @notice will permanently disable minting. This cannot be undone.
  function lockMint() external onlyOwner {
    maxSupply = supply.current();
    mintEnabled = false;
  }


  function withdraw() external onlyOwner {
    (bool success, ) = payable(owner()).call{value: address(this).balance}("");
    require(success, "failed to withdraw");
  }

}

{
  "compilationTarget": {
    "qryou.sol": "QRyou"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}