DRP Member OG

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

library HoldersHelper {
	
	struct TokenHolders {
		address[] holders;
		mapping(address => uint256) holdersIndex;
	}

	function addHolder(TokenHolders storage tokenHolders, address newHolder) internal {
		tokenHolders.holders.push(newHolder);
		tokenHolders.holdersIndex[newHolder] = tokenHolders.holders.length;
	}

	function swapHolders(TokenHolders storage tokenHolders, address holder) internal {
		uint256 knownIndex = tokenHolders.holdersIndex[holder] - 1;
		uint256 knownLastIndex = tokenHolders.holders.length - 1;

		if (knownIndex != knownLastIndex) { 
			address knownLastAddress = tokenHolders.holders[knownLastIndex];

			tokenHolders.holders[knownIndex] = knownLastAddress;
			tokenHolders.holdersIndex[knownLastAddress] = knownIndex + 1;

			tokenHolders.holders[knownLastIndex] = holder;
			tokenHolders.holdersIndex[holder] = knownLastIndex + 1; 
		}
	}

	function removeHolder(TokenHolders storage tokenHolders, address holderToRemove) internal {
		tokenHolders.holdersIndex[holderToRemove] = 0; 
		tokenHolders.holders.pop();
	}
	
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;
import "@openzeppelin/contracts/token/ERC1155/extensions/ERC1155Supply.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import { HoldersHelper } from "./DRPLibraries.sol";

//                                                            %@(
//                                                        (@&   @@  @@.    /@@.
//                                                          /@@.  ,           @#
//              @@#                                            @&       ,@@, (@@
//               @@%@@&                                        @&      &@
//                @@   *@@@                                   @@   &  @@
//                 @@      @&     (@@@@@@%#(/(#%&@@@@@&.    (@/   # .@%
//                  @@      @@@@@                       &@@@@   &. @@
//                   @@      @@                           @@   @  @@
//                    @@      @@        *@@%@@@         #@/  @@ .@%
//                    ,@@       @@@@@@@&@@   @@&&@@&@@@@*  .@/ &@@&
//                   *@.@@.        .@@ .@@.  @@&  @@     ,@@  @@  @@
//           .%      @@   @@%     ,@@@,          %@@@@@@/  /@@ @@ ,@*
//         &@& @@&  *@  /@@@&%@@@@@@@@@,        %@@@@@@@@@@@@@, @* @@  %@&
//       @@.      @@/@@@ @@  *@@   @@@  *@,  @@   @@%  %@@   (/@@@ @@@&  .@@.
//    &@&           %@@  &&,@@@@@#, %@@&,@   @@*@@@ .#@@@@@*.@@  @@%        @@&
//  @@.               .@@@%             *@@@@@@             ,@@@@             .@@
//    &@@            @@     /&@@@@@@@@@@@@@@@@@@@@@@@@@@@&*      @@             &@@
//       @@%        @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@(@@         @@&
//         *@@      /@@@@@&.       @@%                 *@@  *@@@@%.@@     &@&
//           .@@  @@@@ @@          @@    &@@@@          @(    @@@@@@    @@
//            @@@@@@@@@ @@         @.  @@(   ,@@       @@   @@.@@%@@@@@@@%
//          ,@#@@@@@@ @@.,@@     #@  @@/ #@@@@ ,@@    @( .@@. @@ /@@@@&  @@.
//          @@  @@@@@&  @@  @@@@@@@@@. (@& @.,@@  @@@@@@@* ,@@   @@@@@   .@@@
//        /@@&   &@@@@@@@.%@@%    ,&@@@& % @,%**@@@@@&//@@@, *@@@@@@      @%#@,
//        @&%@     .@@@@@(@@&   .  .@@  @% @,#@ .(@%      #@@ @@@@       @@  @@
//        @/ (@%       (@@@ /@&   @@ @@ @%.@.#@ @@ @@   *@& %@@@@*     .@@   &@
//        @@   @@@@((@@@@@@@, @@  @%                @* @@  @@@@@@@@@@@@@     @@
//         @@    .@@@@@@@@@@@@ &@ #@               @@ @@ (@@@@@@@@@@@%      @@
//          ,@@      (@@@@@@@@@ @@ @@ @ @%.@.%@ @ @@ #@ @@@@@@@@@&        @@
//             @@@         @@@@@&@@ @@  @%.@.%@ .@@  @@@@@@@/          &@@
//                @@@@@@@@@@@@@@@@@& @# @%.@.%@ /@. @@@@@@@@@@@@@@@@@@@
//                    %@@@@@@@@@@@@@ *@,       .@* *@@@@@@@@@@@@@@(
//                          ,&@@@@@@@              @@@@@@@@%,
//                                 .@@@@@@@@@@@@@@@@.
//
//
//     DRP + Pellar 2022

contract DRPMember is ERC1155Supply, Ownable {
	using HoldersHelper for HoldersHelper.TokenHolders;
	struct Token {
		bool salesActive;
		bool whitelistSalesActive;
		uint16 tokenId;
		uint16 mintableMax; // public mintable
		uint16 maxSupply; // team claim
		uint256 price;
		uint16 maxPerClaim;
		uint16 maxPerWallet;
		string uri;
		uint16[] drops;
	}

	uint16 public membershipTokens;
	uint16 public nDrops;
	string public constant name = "DRPMember";
	string public constant symbol = "DRPM";

	mapping(uint16 => bool) _teamClaimed;
	mapping(uint16 => address) public indexToDrop;
	mapping(uint16 => mapping(address => bool)) public tokenWhitelist;
	mapping(uint16 => Token) public tokens;
	mapping(uint16 => HoldersHelper.TokenHolders) tokenHolders;

	event TokenRegistered(uint16 indexed id, uint16 maxMintable, uint16 maxSupply, uint256 price, uint16[] drops);
	event TokenInformationUpdated(uint16 indexed id, uint16 maxMintable, uint16 maxSupply, uint256 price, uint16[] drops);
	event TokenDropPrerequisitesUpdated(uint16 indexed id, uint16[] drops);
	event TokenDropAddressUpdated(uint16 indexed dropIndex, address newAddress);

	constructor () ERC1155 ("") {}

	modifier validTokenId (uint16 tokenId) {
		require(tokens[tokenId].maxSupply > 0, "Query for non-existent token");
		_;
	}

	function getHolders(uint16 tokenId) public view validTokenId(tokenId) returns (address[] memory) {
		return tokenHolders[tokenId].holders;
	}

	function getTokenPrerequisiteDropAddresses(uint16 tokenId) public view validTokenId(tokenId) returns (address[] memory) {
		Token memory token = tokens[tokenId];
		address[] memory drops = new address[](token.drops.length);
		for (uint256 i = 0; i < token.drops.length; i++) {
			drops[i] = indexToDrop[token.drops[i]];
		}
		return drops;
	}

	// check if you satisfy the drop prerequisites
	function eligibleToMint(uint16 tokenId) external view validTokenId(tokenId) returns (bool) {
		return _checkDropsWhitelist(tokens[tokenId]);
	}

	function registerToken(
		uint16 _mintableMax,
		uint16 _maxSupply,
		uint256 _price,
		uint16 _maxPerClaim,
		uint16 _maxPerWallet,
		string calldata _uri,
		uint16[] calldata _drops
	) public onlyOwner {
		_setTokenData(
			membershipTokens,
			_mintableMax,
			_maxSupply,
			_price,
			_maxPerClaim,
			_maxPerWallet,
			false,
			false,
			_uri,
			_drops
		);
		emit TokenRegistered(membershipTokens, _mintableMax, _maxSupply, _price, _drops);
		membershipTokens++;
	}

	function updateToken(
		uint16 tokenId,
		uint16 _mintableMax,
		uint16 _maxSupply,
		uint256 _price,
		uint16 _maxPerClaim,
		uint16 _maxPerWallet,
		string calldata _uri,
		uint16[] calldata _drops
	) public onlyOwner validTokenId (tokenId){
		require(!tokens[tokenId].salesActive, "Cannot update when sales are active");
		require(!tokens[tokenId].whitelistSalesActive, "Cannot update when whitelist sales are active");
		require(totalSupply(tokenId) < _mintableMax, "Cannot update mintable amount below current supply");
		require(totalSupply(tokenId) < _maxSupply, "Cannot update max supply below current supply");

		// preserve current sales status
		bool salesStatus = tokens[tokenId].salesActive;
		bool whitelistSalesStatus = tokens[tokenId].whitelistSalesActive;
		_setTokenData(
			tokenId,
			_mintableMax,
			_maxSupply,
			_price,
			_maxPerClaim,
			_maxPerWallet,
			salesStatus,
			whitelistSalesStatus,
			_uri,
			_drops
		);
		emit TokenInformationUpdated(tokenId, _mintableMax, _maxSupply, _price, _drops);
	}

	function claim(
		uint16 tokenId,
		uint16 amount
	) public payable validTokenId (tokenId){
		Token memory tokenToMint = tokens[tokenId];
		require(tokenToMint.salesActive, "Token sales not active");
		require(_checkDropsWhitelist(tokenToMint), "Sender doesnt own token in prerequisite contracts");

		require((tokenToMint.maxPerWallet == 0) || (balanceOf(msg.sender, tokenId) < tokenToMint.maxPerWallet), "Cannot claim more tokens than you already own");
		require((tokenToMint.maxPerClaim == 0) || (amount <= tokenToMint.maxPerClaim), "Amount exceeds claim limit");
		require(totalSupply(tokenId) < tokenToMint.mintableMax, "Supply exhausted");
		require(totalSupply(tokenId) + amount <= tokenToMint.mintableMax, "Not enough tokens to mint");
		tokenToMint.price == 0 ? require(msg.value == 0, "ETH sent for free token") : require(msg.value >= tokenToMint.price * amount, "Insufficient ETH sent");
		_mint(msg.sender, tokenId, amount, "");
	}

	function whitelistClaim(
		uint16 tokenId,
		uint16 amount
	) public payable validTokenId (tokenId){
		Token memory tokenToMint = tokens[tokenId];
		require(tokenToMint.whitelistSalesActive, "Whitelist sales not active");
		require(tokenWhitelist[tokenId][msg.sender], "Not whitelisted");

		require((tokenToMint.maxPerWallet == 0) || (balanceOf(msg.sender, tokenId) < tokenToMint.maxPerWallet), "Cannot claim more tokens than you already own");
		require((tokenToMint.maxPerClaim == 0) || (amount <= tokenToMint.maxPerClaim), "Amount exceeds claim limit");
		require(totalSupply(tokenId) < tokenToMint.mintableMax, "Supply exhausted");
		require(totalSupply(tokenId) + amount <= tokenToMint.mintableMax, "Not enough tokens to mint");
		tokenToMint.price == 0 ? require(msg.value == 0, "ETH sent for free token") : require(msg.value >= tokenToMint.price * amount, "Insufficient ETH sent");

		_mint(msg.sender, tokenId, amount, "");
	}


	function teamClaim(uint16 tokenId) external onlyOwner validTokenId(tokenId) {
		require(!_teamClaimed[tokenId], "Already claimed");
		require(totalSupply(tokenId) >= tokens[tokenId].mintableMax, "Claimable tokens not exhausted yet");
		_mint(msg.sender, tokenId, tokens[tokenId].maxSupply - tokens[tokenId].mintableMax, "");
		_teamClaimed[tokenId] = true;
	}

	// e.g. if there were 0 drops and we add 1, index 0 wil be 1
	// we check if an address exists by if index > 0 (to reserve -1)
	function addNewDrops(uint16[] calldata indexes, address[] calldata drops) external onlyOwner {
		require(indexes.length > 0 && drops.length > 0, "Cannot send empty array");
		require(indexes.length == drops.length, "Both arrays must be of same length");
		for (uint16 i = 0; i < indexes.length; i++) {
			indexToDrop[indexes[i]] = drops[i];
		}
	}

	function updateDropAddresses(uint16[] calldata indexes, address[] calldata newAddresses) external onlyOwner {
		require(indexes.length == newAddresses.length, "Both arrays not the same length");
		for (uint16 i = 0; i < indexes.length; i++) {
			indexToDrop[indexes[i]] = newAddresses[i];
			if(newAddresses[i] == address(0)){
				nDrops--;
			}
			emit TokenDropAddressUpdated(indexes[i], newAddresses[i]);
		}

	}

	function setWalletWhitelist(
		uint16 tokenId,
		address[] calldata whitelist,
		bool status
	) public onlyOwner validTokenId (tokenId) {
		for (uint16 i = 0; i < whitelist.length; i++) {
			tokenWhitelist[tokenId][whitelist[i]] = status;
		}
	}

	function setTokenDropsWhitelist(
		uint16 tokenId,
		uint16[] calldata drops
	) public onlyOwner validTokenId (tokenId) {
		Token storage tokenInfo = tokens[tokenId];
		for(uint16 i = 0; i < drops.length; i++){
			require(indexToDrop[drops[i]] != address(0), "Must be valid DRP project");
		}
		tokenInfo.drops = drops;
		emit TokenDropPrerequisitesUpdated(tokenId, drops);

	}

	function toggleSalesActive(uint16[] calldata ids) external onlyOwner{
		for (uint16 i = 0; i < ids.length; i++) {
			require(tokens[ids[i]].maxSupply > 0, "Query for non-existent token");
		}
		for (uint16 i = 0; i < ids.length; i++) {
			tokens[ids[i]].salesActive = !tokens[ids[i]].salesActive;
		}
	}

	function toggleWhitelistSalesActive(uint16[] calldata ids) external onlyOwner {
		for (uint16 i = 0; i < ids.length; i++) {
			require(tokens[ids[i]].maxSupply > 0, "Query for non-existent token");
		}
		for (uint16 i = 0; i < ids.length; i++) {
			tokens[ids[i]].whitelistSalesActive = !tokens[ids[i]].whitelistSalesActive;
		}
	}

	function uri(uint256 tokenId) public view override validTokenId(uint16(tokenId)) returns (string memory)  {
		return tokens[uint16(tokenId)].uri;
	}

	function setURI(uint16[] calldata ids, string[] calldata uris) external {
		require(ids.length == uris.length, "Arrays mismatched");
		for (uint16 i = 0; i < ids.length; i++) {
			require(tokens[ids[i]].maxSupply > 0, "Query for non-existent token");
		}
		for (uint16 i = 0; i < ids.length; i++) {
			tokens[ids[i]].uri = uris[i];
		}
	}

	function withdraw() external onlyOwner {
		uint256 balance = address(this).balance;
		address owner = owner();
		payable(owner).transfer(balance);
	}

	function _beforeTokenTransfer(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual override {
		super._beforeTokenTransfer(operator, from, to, ids, amounts, data);
		for (uint16 i = 0; i < ids.length; ++i) {
			uint16 tokenId = uint16(ids[i]);
			if (from != address(0)) {
				if (balanceOf(from, tokenId) == 0){
					tokenHolders[tokenId].swapHolders(from);
				}
				tokenHolders[tokenId].removeHolder(from);
			}
			if (to != address(0)) {
				if (tokenHolders[tokenId].holdersIndex[to] == 0) {
					tokenHolders[tokenId].addHolder(to);
				}
			}
		}
	}

	function _setTokenData(
		uint16 _tokenId,
		uint16 _mintableMax,
		uint16 _maxSupply,
		uint256 _price,
		uint16 _maxPerClaim,
		uint16 _maxPerWallet,
		bool _salesActive,
		bool _whitelistSalesActive,
		string calldata _uri,
		uint16[] calldata _drops
	) internal {
		require(_mintableMax > 0, "Mintable amount must be more than 0");
		require(_maxSupply > _mintableMax, "Total supply must be greater than or equal to mintable amount");
		for(uint16 i = 0; i < _drops.length; i++) {
			require(indexToDrop[_drops[i]] != address(0), "Invalid project index");
		}
		tokens[_tokenId] = Token(
			_salesActive, // by default this is false
			_whitelistSalesActive, // by default this is false
			_tokenId,
			_mintableMax,
			_maxSupply,
			_price,
			_maxPerClaim,
			_maxPerWallet,
			_uri,
			_drops
		);
	}

	// checks the project whitelist
	function _checkDropsWhitelist(Token memory tokenToMint) internal view returns(bool) {
		if (tokenToMint.drops.length == 0 ) {
			return true;
		} else {
			for (uint16 i = 0; i < tokenToMint.drops.length; i++) {
				uint16 dropNo = tokenToMint.drops[i];
				uint256 _amount = ERC721(indexToDrop[dropNo]).balanceOf(msg.sender);
				if (_amount > 0){ // if one of them has balance greater than 0
					return true;
				}
			}
			return false;
		}
	}
}

interface ERC721 {
	function balanceOf(address owner) external view returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC1155.sol";
import "./IERC1155Receiver.sol";
import "./extensions/IERC1155MetadataURI.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of the basic standard multi-token.
 * See https://eips.ethereum.org/EIPS/eip-1155
 * Originally based on code by Enjin: https://github.com/enjin/erc-1155
 *
 * _Available since v3.1._
 */
contract ERC1155 is Context, ERC165, IERC1155, IERC1155MetadataURI {
    using Address for address;

    // Mapping from token ID to account balances
    mapping(uint256 => mapping(address => uint256)) private _balances;

    // Mapping from account to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    // Used as the URI for all token types by relying on ID substitution, e.g. https://token-cdn-domain/{id}.json
    string private _uri;

    /**
     * @dev See {_setURI}.
     */
    constructor(string memory uri_) {
        _setURI(uri_);
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC1155).interfaceId ||
            interfaceId == type(IERC1155MetadataURI).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC1155MetadataURI-uri}.
     *
     * This implementation returns the same URI for *all* token types. It relies
     * on the token type ID substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * Clients calling this function must replace the `\{id\}` substring with the
     * actual token type ID.
     */
    function uri(uint256) public view virtual override returns (string memory) {
        return _uri;
    }

    /**
     * @dev See {IERC1155-balanceOf}.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) public view virtual override returns (uint256) {
        require(account != address(0), "ERC1155: balance query for the zero address");
        return _balances[id][account];
    }

    /**
     * @dev See {IERC1155-balanceOfBatch}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] memory accounts, uint256[] memory ids)
        public
        view
        virtual
        override
        returns (uint256[] memory)
    {
        require(accounts.length == ids.length, "ERC1155: accounts and ids length mismatch");

        uint256[] memory batchBalances = new uint256[](accounts.length);

        for (uint256 i = 0; i < accounts.length; ++i) {
            batchBalances[i] = balanceOf(accounts[i], ids[i]);
        }

        return batchBalances;
    }

    /**
     * @dev See {IERC1155-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(_msgSender() != operator, "ERC1155: setting approval status for self");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC1155-isApprovedForAll}.
     */
    function isApprovedForAll(address account, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[account][operator];
    }

    /**
     * @dev See {IERC1155-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) public virtual override {
        require(
            from == _msgSender() || isApprovedForAll(from, _msgSender()),
            "ERC1155: caller is not owner nor approved"
        );
        _safeTransferFrom(from, to, id, amount, data);
    }

    /**
     * @dev See {IERC1155-safeBatchTransferFrom}.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) public virtual override {
        require(
            from == _msgSender() || isApprovedForAll(from, _msgSender()),
            "ERC1155: transfer caller is not owner nor approved"
        );
        _safeBatchTransferFrom(from, to, ids, amounts, data);
    }

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function _safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) internal virtual {
        require(to != address(0), "ERC1155: transfer to the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, from, to, _asSingletonArray(id), _asSingletonArray(amount), data);

        uint256 fromBalance = _balances[id][from];
        require(fromBalance >= amount, "ERC1155: insufficient balance for transfer");
        unchecked {
            _balances[id][from] = fromBalance - amount;
        }
        _balances[id][to] += amount;

        emit TransferSingle(operator, from, to, id, amount);

        _doSafeTransferAcceptanceCheck(operator, from, to, id, amount, data);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function _safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual {
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");
        require(to != address(0), "ERC1155: transfer to the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, from, to, ids, amounts, data);

        for (uint256 i = 0; i < ids.length; ++i) {
            uint256 id = ids[i];
            uint256 amount = amounts[i];

            uint256 fromBalance = _balances[id][from];
            require(fromBalance >= amount, "ERC1155: insufficient balance for transfer");
            unchecked {
                _balances[id][from] = fromBalance - amount;
            }
            _balances[id][to] += amount;
        }

        emit TransferBatch(operator, from, to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(operator, from, to, ids, amounts, data);
    }

    /**
     * @dev Sets a new URI for all token types, by relying on the token type ID
     * substitution mechanism
     * https://eips.ethereum.org/EIPS/eip-1155#metadata[defined in the EIP].
     *
     * By this mechanism, any occurrence of the `\{id\}` substring in either the
     * URI or any of the amounts in the JSON file at said URI will be replaced by
     * clients with the token type ID.
     *
     * For example, the `https://token-cdn-domain/\{id\}.json` URI would be
     * interpreted by clients as
     * `https://token-cdn-domain/000000000000000000000000000000000000000000000000000000000004cce0.json`
     * for token type ID 0x4cce0.
     *
     * See {uri}.
     *
     * Because these URIs cannot be meaningfully represented by the {URI} event,
     * this function emits no events.
     */
    function _setURI(string memory newuri) internal virtual {
        _uri = newuri;
    }

    /**
     * @dev Creates `amount` tokens of token type `id`, and assigns them to `account`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - If `account` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function _mint(
        address account,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) internal virtual {
        require(account != address(0), "ERC1155: mint to the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, address(0), account, _asSingletonArray(id), _asSingletonArray(amount), data);

        _balances[id][account] += amount;
        emit TransferSingle(operator, address(0), account, id, amount);

        _doSafeTransferAcceptanceCheck(operator, address(0), account, id, amount, data);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_mint}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function _mintBatch(
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual {
        require(to != address(0), "ERC1155: mint to the zero address");
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, address(0), to, ids, amounts, data);

        for (uint256 i = 0; i < ids.length; i++) {
            _balances[ids[i]][to] += amounts[i];
        }

        emit TransferBatch(operator, address(0), to, ids, amounts);

        _doSafeBatchTransferAcceptanceCheck(operator, address(0), to, ids, amounts, data);
    }

    /**
     * @dev Destroys `amount` tokens of token type `id` from `account`
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens of token type `id`.
     */
    function _burn(
        address account,
        uint256 id,
        uint256 amount
    ) internal virtual {
        require(account != address(0), "ERC1155: burn from the zero address");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, account, address(0), _asSingletonArray(id), _asSingletonArray(amount), "");

        uint256 accountBalance = _balances[id][account];
        require(accountBalance >= amount, "ERC1155: burn amount exceeds balance");
        unchecked {
            _balances[id][account] = accountBalance - amount;
        }

        emit TransferSingle(operator, account, address(0), id, amount);
    }

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {_burn}.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     */
    function _burnBatch(
        address account,
        uint256[] memory ids,
        uint256[] memory amounts
    ) internal virtual {
        require(account != address(0), "ERC1155: burn from the zero address");
        require(ids.length == amounts.length, "ERC1155: ids and amounts length mismatch");

        address operator = _msgSender();

        _beforeTokenTransfer(operator, account, address(0), ids, amounts, "");

        for (uint256 i = 0; i < ids.length; i++) {
            uint256 id = ids[i];
            uint256 amount = amounts[i];

            uint256 accountBalance = _balances[id][account];
            require(accountBalance >= amount, "ERC1155: burn amount exceeds balance");
            unchecked {
                _balances[id][account] = accountBalance - amount;
            }
        }

        emit TransferBatch(operator, account, address(0), ids, amounts);
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning, as well as batched variants.
     *
     * The same hook is called on both single and batched variants. For single
     * transfers, the length of the `id` and `amount` arrays will be 1.
     *
     * Calling conditions (for each `id` and `amount` pair):
     *
     * - When `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * of token type `id` will be  transferred to `to`.
     * - When `from` is zero, `amount` tokens of token type `id` will be minted
     * for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens of token type `id`
     * will be burned.
     * - `from` and `to` are never both zero.
     * - `ids` and `amounts` have the same, non-zero length.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual {}

    function _doSafeTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) private {
        if (to.isContract()) {
            try IERC1155Receiver(to).onERC1155Received(operator, from, id, amount, data) returns (bytes4 response) {
                if (response != IERC1155Receiver.onERC1155Received.selector) {
                    revert("ERC1155: ERC1155Receiver rejected tokens");
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                revert("ERC1155: transfer to non ERC1155Receiver implementer");
            }
        }
    }

    function _doSafeBatchTransferAcceptanceCheck(
        address operator,
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) private {
        if (to.isContract()) {
            try IERC1155Receiver(to).onERC1155BatchReceived(operator, from, ids, amounts, data) returns (
                bytes4 response
            ) {
                if (response != IERC1155Receiver.onERC1155BatchReceived.selector) {
                    revert("ERC1155: ERC1155Receiver rejected tokens");
                }
            } catch Error(string memory reason) {
                revert(reason);
            } catch {
                revert("ERC1155: transfer to non ERC1155Receiver implementer");
            }
        }
    }

    function _asSingletonArray(uint256 element) private pure returns (uint256[] memory) {
        uint256[] memory array = new uint256[](1);
        array[0] = element;

        return array;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../ERC1155.sol";

/**
 * @dev Extension of ERC1155 that adds tracking of total supply per id.
 *
 * Useful for scenarios where Fungible and Non-fungible tokens have to be
 * clearly identified. Note: While a totalSupply of 1 might mean the
 * corresponding is an NFT, there is no guarantees that no other token with the
 * same id are not going to be minted.
 */
abstract contract ERC1155Supply is ERC1155 {
    mapping(uint256 => uint256) private _totalSupply;

    /**
     * @dev Total amount of tokens in with a given id.
     */
    function totalSupply(uint256 id) public view virtual returns (uint256) {
        return _totalSupply[id];
    }

    /**
     * @dev Indicates weither any token exist with a given id, or not.
     */
    function exists(uint256 id) public view virtual returns (bool) {
        return ERC1155Supply.totalSupply(id) > 0;
    }

    /**
     * @dev See {ERC1155-_mint}.
     */
    function _mint(
        address account,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) internal virtual override {
        super._mint(account, id, amount, data);
        _totalSupply[id] += amount;
    }

    /**
     * @dev See {ERC1155-_mintBatch}.
     */
    function _mintBatch(
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) internal virtual override {
        super._mintBatch(to, ids, amounts, data);
        for (uint256 i = 0; i < ids.length; ++i) {
            _totalSupply[ids[i]] += amounts[i];
        }
    }

    /**
     * @dev See {ERC1155-_burn}.
     */
    function _burn(
        address account,
        uint256 id,
        uint256 amount
    ) internal virtual override {
        super._burn(account, id, amount);
        _totalSupply[id] -= amount;
    }

    /**
     * @dev See {ERC1155-_burnBatch}.
     */
    function _burnBatch(
        address account,
        uint256[] memory ids,
        uint256[] memory amounts
    ) internal virtual override {
        super._burnBatch(account, ids, amounts);
        for (uint256 i = 0; i < ids.length; ++i) {
            _totalSupply[ids[i]] -= amounts[i];
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids)
        external
        view
        returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must be have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes calldata data
    ) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC1155.sol";

/**
 * @dev Interface of the optional ERC1155MetadataExtension interface, as defined
 * in the https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155MetadataURI is IERC1155 {
    /**
     * @dev Returns the URI for token type `id`.
     *
     * If the `\{id\}` substring is present in the URI, it must be replaced by
     * clients with the actual token type ID.
     */
    function uri(uint256 id) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev _Available since v3.1._
 */
interface IERC1155Receiver is IERC165 {
    /**
        @dev Handles the receipt of a single ERC1155 token type. This function is
        called at the end of a `safeTransferFrom` after the balance has been updated.
        To accept the transfer, this must return
        `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
        (i.e. 0xf23a6e61, or its own function selector).
        @param operator The address which initiated the transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param id The ID of the token being transferred
        @param value The amount of tokens being transferred
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
    */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    ) external returns (bytes4);

    /**
        @dev Handles the receipt of a multiple ERC1155 token types. This function
        is called at the end of a `safeBatchTransferFrom` after the balances have
        been updated. To accept the transfer(s), this must return
        `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
        (i.e. 0xbc197c81, or its own function selector).
        @param operator The address which initiated the batch transfer (i.e. msg.sender)
        @param from The address which previously owned the token
        @param ids An array containing ids of each token being transferred (order and length must match values array)
        @param values An array containing amounts of each token being transferred (order and length must match ids array)
        @param data Additional data with no specified format
        @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
    */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/DRPMember.sol": "DRPMember"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}