// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (access/AccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "./IAccessControlEnumerable.sol";
import "./AccessControl.sol";
import "../utils/structs/EnumerableSet.sol";

/**
 * @dev Extension of {AccessControl} that allows enumerating the members of each role.
 */
abstract contract AccessControlEnumerable is IAccessControlEnumerable, AccessControl {
    using EnumerableSet for EnumerableSet.AddressSet;

    mapping(bytes32 => EnumerableSet.AddressSet) private _roleMembers;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControlEnumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns one of the accounts that have `role`. `index` must be a
     * value between 0 and {getRoleMemberCount}, non-inclusive.
     *
     * Role bearers are not sorted in any particular way, and their ordering may
     * change at any point.
     *
     * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
     * you perform all queries on the same block. See the following
     * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
     * for more information.
     */
    function getRoleMember(bytes32 role, uint256 index) public view virtual override returns (address) {
        return _roleMembers[role].at(index);
    }

    /**
     * @dev Returns the number of accounts that have `role`. Can be used
     * together with {getRoleMember} to enumerate all bearers of a role.
     */
    function getRoleMemberCount(bytes32 role) public view virtual override returns (uint256) {
        return _roleMembers[role].length();
    }

    /**
     * @dev Overload {_grantRole} to track enumerable memberships
     */
    function _grantRole(bytes32 role, address account) internal virtual override {
        super._grantRole(role, account);
        _roleMembers[role].add(account);
    }

    /**
     * @dev Overload {_revokeRole} to track enumerable memberships
     */
    function _revokeRole(bytes32 role, address account) internal virtual override {
        super._revokeRole(role, account);
        _roleMembers[role].remove(account);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        _spendAllowance(account, _msgSender(), amount);
        _burn(account, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/ERC20Pausable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../security/Pausable.sol";

/**
 * @dev ERC20 token with pausable token transfers, minting and burning.
 *
 * Useful for scenarios such as preventing trades until the end of an evaluation
 * period, or having an emergency switch for freezing all token transfers in the
 * event of a large bug.
 *
 * IMPORTANT: This contract does not include public pause and unpause functions. In
 * addition to inheriting this contract, you must define both functions, invoking the
 * {Pausable-_pause} and {Pausable-_unpause} internal functions, with appropriate
 * access control, e.g. using {AccessControl} or {Ownable}. Not doing so will
 * make the contract unpausable.
 */
abstract contract ERC20Pausable is ERC20, Pausable {
    /**
     * @dev See {ERC20-_beforeTokenTransfer}.
     *
     * Requirements:
     *
     * - the contract must not be paused.
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual override {
        super._beforeTokenTransfer(from, to, amount);

        require(!paused(), "ERC20Pausable: token transfer while paused");
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/presets/ERC20PresetMinterPauser.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../extensions/ERC20Burnable.sol";
import "../extensions/ERC20Pausable.sol";
import "../../../access/AccessControlEnumerable.sol";
import "../../../utils/Context.sol";

/**
 * @dev {ERC20} token, including:
 *
 *  - ability for holders to burn (destroy) their tokens
 *  - a minter role that allows for token minting (creation)
 *  - a pauser role that allows to stop all token transfers
 *
 * This contract uses {AccessControl} to lock permissioned functions using the
 * different roles - head to its documentation for details.
 *
 * The account that deploys the contract will be granted the minter and pauser
 * roles, as well as the default admin role, which will let it grant both minter
 * and pauser roles to other accounts.
 *
 * _Deprecated in favor of https://wizard.openzeppelin.com/[Contracts Wizard]._
 */
contract ERC20PresetMinterPauser is Context, AccessControlEnumerable, ERC20Burnable, ERC20Pausable {
    bytes32 public constant MINTER_ROLE = keccak256("MINTER_ROLE");
    bytes32 public constant PAUSER_ROLE = keccak256("PAUSER_ROLE");

    /**
     * @dev Grants `DEFAULT_ADMIN_ROLE`, `MINTER_ROLE` and `PAUSER_ROLE` to the
     * account that deploys the contract.
     *
     * See {ERC20-constructor}.
     */
    constructor(string memory name, string memory symbol) ERC20(name, symbol) {
        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());

        _setupRole(MINTER_ROLE, _msgSender());
        _setupRole(PAUSER_ROLE, _msgSender());
    }

    /**
     * @dev Creates `amount` new tokens for `to`.
     *
     * See {ERC20-_mint}.
     *
     * Requirements:
     *
     * - the caller must have the `MINTER_ROLE`.
     */
    function mint(address to, uint256 amount) public virtual {
        require(hasRole(MINTER_ROLE, _msgSender()), "ERC20PresetMinterPauser: must have minter role to mint");
        _mint(to, amount);
    }

    /**
     * @dev Pauses all token transfers.
     *
     * See {ERC20Pausable} and {Pausable-_pause}.
     *
     * Requirements:
     *
     * - the caller must have the `PAUSER_ROLE`.
     */
    function pause() public virtual {
        require(hasRole(PAUSER_ROLE, _msgSender()), "ERC20PresetMinterPauser: must have pauser role to pause");
        _pause();
    }

    /**
     * @dev Unpauses all token transfers.
     *
     * See {ERC20Pausable} and {Pausable-_unpause}.
     *
     * Requirements:
     *
     * - the caller must have the `PAUSER_ROLE`.
     */
    function unpause() public virtual {
        require(hasRole(PAUSER_ROLE, _msgSender()), "ERC20PresetMinterPauser: must have pauser role to unpause");
        _unpause();
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual override(ERC20, ERC20Pausable) {
        super._beforeTokenTransfer(from, to, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastValue;
                // Update the index for the moved value
                set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.9;

import '@openzeppelin/contracts/token/ERC20/presets/ERC20PresetMinterPauser.sol';
import 'hardhat/console.sol';

contract GenericToken is ERC20PresetMinterPauser {
    constructor(
        string memory _name,
        string memory _symbol,
        uint256 startingSupply
    ) ERC20PresetMinterPauser(_name, _symbol) {
        _mint(msg.sender, startingSupply);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";

/**
 * @dev External interface of AccessControlEnumerable declared to support ERC165 detection.
 */
interface IAccessControlEnumerable is IAccessControl {
    /**
     * @dev Returns one of the accounts that have `role`. `index` must be a
     * value between 0 and {getRoleMemberCount}, non-inclusive.
     *
     * Role bearers are not sorted in any particular way, and their ordering may
     * change at any point.
     *
     * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
     * you perform all queries on the same block. See the following
     * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
     * for more information.
     */
    function getRoleMember(bytes32 role, uint256 index) external view returns (address);

    /**
     * @dev Returns the number of accounts that have `role`. Can be used
     * together with {getRoleMember} to enumerate all bearers of a role.
     */
    function getRoleMemberCount(bytes32 role) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.9;

import '@openzeppelin/contracts/token/ERC20/ERC20.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '@openzeppelin/contracts/access/Ownable.sol';
import '@openzeppelin/contracts/security/ReentrancyGuard.sol';

/**
  @title Abstract contract providing funder related functions in a sale
  @notice To be implemented by IFSale.
 */
abstract contract IFFundable is Ownable, ReentrancyGuard {
    using SafeERC20 for ERC20;

    // --- CONSTANTS

    // number of decimals of sale price
    uint64 constant SALE_PRICE_DECIMALS = 10**18;
    uint64 private constant ONE_HOUR = 3600;
    uint64 private constant ONE_YEAR = 31556926;
    uint64 private constant FIVE_YEARS = 157784630;
    uint64 private constant TEN_YEARS = 315742060;

    // --- OPERATOR ADDRESSES

    address public funder;
    // optional casher (settable by owner)
    address public casher;

    // --- SALE INFO

    // start timestamp when sale is active (inclusive)
    uint256 public immutable startTime;
    // end timestamp when sale is active (inclusive)
    uint256 public immutable endTime;
    // payment token
    ERC20 private immutable paymentToken;
    // sale token
    ERC20 private immutable saleToken;
    // withdraw/cash delay timestamp (inclusive)
    uint24 public withdrawDelay;
    // tracks whether user has already successfully withdrawn
    mapping(address => bool) public hasWithdrawn;

    // --- STATS

    // amount of sale token to sell
    uint256 public saleAmount;
    // tracks whether sale has been cashed
    bool public hasCashed;
    // total payment received for sale
    uint256 public totalPaymentReceived;
    // counter of unique withdrawers (doesn't count "cash"ing)
    uint32 public withdrawerCount;

    // --- CONSTRUCTOR

    constructor(
        ERC20 _paymentToken,
        ERC20 _saleToken,
        uint256 _startTime,
        uint256 _endTime,
        address _funder
    ) {
        // saleToken shouldn't be the same as paymentToken
        require(_saleToken != _paymentToken, 'saleToken = paymentToken');
        // when salePrice != 0, paymentToken and maxTotalPayment shouldn't be 0
        // sale token cannot be 0
        require(address(_saleToken) != address(0), '0x0 saleToken');
        // start timestamp must be in future
        require(block.timestamp < _startTime, 'start timestamp too early');
        require(_startTime - ONE_YEAR < block.timestamp, 'start time has to be within 1 year');
        // end timestamp must be after start timestamp
        require(_startTime < _endTime, 'end timestamp must be after start timestamp');
        require(_endTime - TEN_YEARS < _startTime, 'end time has to be within 10 years');

        require(_funder != address(0), '0x0 funder');
        funder = _funder;

        paymentToken = _paymentToken; // can be 0 (for giveaway)
        saleToken = _saleToken;
        startTime = _startTime;
        endTime = _endTime;
    }

    // --- MODIFIERS

    // Throws if called by any account other than the funder.
    modifier onlyFunder() {
        require(_msgSender() == funder, 'caller not funder');
        _;
    }

    // Throws if called by any account other than the casher.
    modifier onlyCasherOrOwner() {
        require(
            _msgSender() == casher || _msgSender() == owner(),
            'caller not casher or owner'
        );
        _;
    }

    // Throws if called during or after sale
    modifier onlyBeforeSale() {
        require(block.timestamp < startTime, 'sale already started');
        _;
    }

    // Throws if called outside of claim period
    modifier onlyAfterSale {
        require(block.timestamp > endTime + withdrawDelay, "can't withdraw before claim is started");
        _;
    }

    // Throws if called outside of sale period
    modifier onlyDuringSale {
        require(startTime <= block.timestamp, 'sale has not begun');
        require(block.timestamp <= endTime, 'sale over');
        _;
    }

    // --- EVENTS

    event SetCasher(address indexed casher);
    event SetFunder(address indexed funder);
    event Fund(address indexed sender, uint256 amount);
    event SetWithdrawDelay(uint24 indexed withdrawDelay);
    event Cash(
        address indexed sender,
        uint256 paymentTokenBalance,
        uint256 saleTokenBalance
    );
    event EmergencyTokenRetrieve(address indexed sender, uint256 amount);
    event Withdraw(address indexed sender, uint256 amount);

    // --- SETTER

    // Function for owner to set an optional, separate casher
    function setCasher(address _casher) public onlyOwner {
        casher = _casher;

        emit SetCasher(_casher);
    }

    function setFunder(address _funder) public onlyOwner {
        require(_funder != address(0), '0x0 funder');
        funder = _funder;

        emit SetFunder(_funder);
    }

    // Function for owner to set a withdraw delay
    function setWithdrawDelay(uint24 _withdrawDelay) virtual public onlyOwner onlyBeforeSale{
        require(_withdrawDelay < FIVE_YEARS, "withdrawDelay has to be within 5 years");
        withdrawDelay = _withdrawDelay;

        emit SetWithdrawDelay(_withdrawDelay);
    }

    // --- FUNDER'S LOGIC

    // Virtual function to be implemented by IFSale.
    //   To calculate the amount of cashable tokens.
    function getSaleTokensSold() internal virtual returns (uint256 amount);

    // Function for funding sale with sale token (called by project team)
    function fund(uint256 amount) public onlyFunder onlyBeforeSale{
        // transfer specified amount from funder to this contract
        saleToken.safeTransferFrom(_msgSender(), address(this), amount);

        // increase tracked sale amount
        saleAmount += amount;

        emit Fund(_msgSender(), amount);
    }


    // Function for funder to cash in payment token and unsold sale token
    function cash() external onlyCasherOrOwner onlyAfterSale {
        // prevent repeat cash
        require(!hasCashed, 'already cashed');

        hasCashed = true;

        // get amount of payment token received
        uint256 paymentTokenBal = paymentToken.balanceOf(address(this));

        // transfer all
        paymentToken.safeTransfer(_msgSender(), paymentTokenBal);

        // get amount of sale token on contract
        uint256 saleTokenBal = saleToken.balanceOf(address(this));

        // get amount of sold token
        uint256 totalTokensSold = getSaleTokensSold();

        // get principal (whichever is bigger between sale amount or amount on contract)
        uint256 principal = saleAmount < saleTokenBal
            ? saleTokenBal
            : saleAmount;

        // calculate amount of unsold sale token
        uint256 amountUnsold = principal - totalTokensSold;

        // transfer unsold
        saleToken.safeTransfer(_msgSender(), amountUnsold);

        emit Cash(_msgSender(), paymentTokenBal, amountUnsold);
    }

    function cashPaymentToken(uint256 amount) external onlyCasherOrOwner {
        // Get amount of payment token received
        uint256 paymentTokenBal = paymentToken.balanceOf(address(this));

        // Ensure there's enough payment tokens to cash
        require(paymentTokenBal >= amount, "No enough payment tokens to cash");

        // Transfer payment tokens to the caller
        paymentToken.safeTransfer(_msgSender(), amount);

        // Emit an event for this cashing
        emit Cash(_msgSender(), amount, 0);
    }

    function cashAllPaymentToken() external onlyCasherOrOwner {
        // Get amount of payment token received
        uint256 paymentTokenBal = paymentToken.balanceOf(address(this));

        // not to revert if there's no payment token to facilitate operation

        // Transfer payment tokens to the caller
        paymentToken.safeTransfer(_msgSender(), paymentTokenBal);

        // Emit an event for this cashing
        emit Cash(_msgSender(), paymentTokenBal, 0);
    }


    // Retrieve tokens erroneously sent in to this address
    function emergencyTokenRetrieve(address token) public onlyOwner onlyAfterSale {
        // cannot be sale tokens
        require(token != address(saleToken));

        uint256 tokenBalance = ERC20(token).balanceOf(address(this));

        // transfer all
        ERC20(token).safeTransfer(_msgSender(), tokenBalance);

        emit EmergencyTokenRetrieve(_msgSender(), tokenBalance);
    }

    // Function for withdrawing purchased sale token after sale end
    function withdraw() virtual public nonReentrant {}   

    function _withdraw(uint256 saleTokenOwed) virtual internal {
        require(saleTokenOwed != 0, 'no token to be withdrawn');

        // increment withdrawer count
        if (!hasWithdrawn[_msgSender()]) {
            withdrawerCount += 1;
            // set withdrawn to true
            hasWithdrawn[_msgSender()] = true;
        }

        saleToken.safeTransfer(_msgSender(), saleTokenOwed);

        emit Withdraw(_msgSender(), saleTokenOwed);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.9;

import '@openzeppelin/contracts/token/ERC20/ERC20.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '@openzeppelin/contracts/access/Ownable.sol';
import '@openzeppelin/contracts/security/ReentrancyGuard.sol';


/**
  @dev Abstract contract containing sale logics.
        To be implemented by IFSale.
  @notice Include virtual functions for regular and whitelisted purchase
  @notice Include virtual functions for whitelisted free token giveaway
  @notice Include sale state variables
  @notice Implemneted sale state variables changes on purchase and withdraw
 */
abstract contract IFPurchasable is Ownable, ReentrancyGuard {
    using SafeERC20 for ERC20;

    // --- SALE INFO

    // payment token
    ERC20 public immutable paymentToken;
    // price of the sale token
    uint256 public salePrice;
    // max for payment token amount
    uint256 public maxTotalPayment;
    // current purchased amount
    uint256 public saleTokenPurchased;
    // optional min for payment token amount
    uint256 public minTotalPayment;
    // optional max for total purchasable amount, default is 0 if there's no limit
    // assuming all users buy the token on the same price
    uint256 public maxTotalPurchasable;
    // halt purchase if true. default is false
    bool public isPurchaseHalted = false;


    // --- USER INFO

    // tracks amount purchased by each address
    // user address => purchased amount
    mapping(address => uint256) public paymentReceived;
    // track amount purchased with code by each address
    // user address => purchased amount with code
    mapping(address => uint256) public paymentReceivedWithCode;
    // track amount purchased with each code by each address
    // user address => code => purchased amount with each code
    mapping(address => mapping(string => uint256)) public paymentReceivedWithEachCode;
    // track promo code used by each address
    // user address => promo codes
    mapping(address => string[]) public promoCodesPerUser;
    // track if a promo code is used by an address
    // user address => promo code => bool
    mapping(address => mapping(string => bool)) public hasUsedCode;

    // -- PROMO CODE

    // all promo codes  
    string[] public codes;
    // track if a promo code is stored
    mapping(string => bool) isCodeStored;
    // amount received per promo code
    mapping(string => uint256) public amountPerCode;
    // unique use per promo code
    mapping(string => uint256) public uniqueUsePerCode;
    // max amount of promo code per user
    uint256 public maxPromoCodePerUser = 50;


    // --- STAT

    // counter of unique purchasers
    uint32 public purchaserCount;

    event Purchase(address indexed sender, uint256 paymentAmount);
    event PurchaseWithCode(address indexed sender, uint256 paymentAmount, string code);
    event SetMinTotalPayment(uint256 indexed minTotalPayment);
    event SetMaxTotalPurchasable(uint256 indexed _maxTotalPurchasable);
    event SetIsPurchaseHalted(bool indexed isPurchaseHalted);

    constructor(
        ERC20 _paymentToken,
        uint256 _salePrice,
        uint256 _maxTotalPayment
    ) {
        require(
            _salePrice == 0 ||
                (_salePrice != 0 &&
                    address(_paymentToken) != address(0) &&
                    _maxTotalPayment >= _salePrice),
            'paymentToken or maxTotalPayment should not be 0 when salePrice is not 0'
        );
        salePrice = _salePrice; // can be 0 (for giveaway)
        paymentToken = _paymentToken; // can be 0 (for giveaway)
        maxTotalPayment = _maxTotalPayment; // can be 0 (for giveaway)
    }


    function setIsPurchaseHalted(bool _isPurchaseHalted) public onlyOwner {
        isPurchaseHalted = _isPurchaseHalted;

        emit SetIsPurchaseHalted(_isPurchaseHalted);
    }

    // Function for owner to set an optional, minTotalPayment
    function setMinTotalPayment(uint256 _minTotalPayment) public onlyOwner {
        minTotalPayment = _minTotalPayment;

        emit SetMinTotalPayment(_minTotalPayment);
    }


    // Function for owner to set an optional, maxTotalPurchasable
    // The amount is calculated on salePrice. 
    function setMaxTotalPurchasable(uint256 _maxTotalPurchasable) virtual public onlyOwner {
        maxTotalPurchasable = _maxTotalPurchasable * salePrice;

        require(maxTotalPurchasable >= saleTokenPurchased, 'Max purchasable should not be lower than the amount of token purchased');

        emit SetMaxTotalPurchasable(_maxTotalPurchasable);
    }

    // --- PURCHASE

    function purchase(uint256 paymentAmount) virtual public {}

    // Internal function for making purchase
    // Used by public functions `purchase`
    function _purchase(uint256 paymentAmount, uint256 remaining) virtual internal nonReentrant {
        require(!isPurchaseHalted, 'purchase is halted');
        require(salePrice > 0, 'sale price is zero');
        // amount must be greater than minTotalPayment
        // by default, minTotalPayment is 0 unless otherwise set
        require(paymentAmount >= minTotalPayment, 'amount below min');

        // payment must not exceed remaining
        require(paymentAmount <= remaining, 'exceeds max payment');
        require(paymentAmount != 0, 'zero payment amount');

        saleTokenPurchased += paymentAmount;
        require(maxTotalPurchasable == 0 || maxTotalPurchasable >= saleTokenPurchased, 'exceed max purchasable');

        // if user is paying for the first time to this contract, increase counter
        if (paymentReceived[_msgSender()] == 0) purchaserCount += 1;

        // increase payment received amount
        paymentReceived[_msgSender()] += paymentAmount;

        // transfer specified amount from user to this contract
        paymentToken.safeTransferFrom(_msgSender(), address(this), paymentAmount);

        emit Purchase(_msgSender(), paymentAmount);
    }

    function _purchaseWithCode(uint256 paymentAmount, uint256 remaining, string memory code) virtual internal {
        // check if code is not empty
        require(bytes(code).length > 0, 'code is empty');
        // check if code is too long
        require(bytes(code).length <= 64, 'code is too long');

        // This needs to be before anything else
        // ===
        _purchase(paymentAmount, remaining);
        // ====

        if (!isCodeStored[code]) {
            isCodeStored[code] = true;
            codes.push(code);
        }

        if (!hasUsedCode[_msgSender()][code]) {
            require(promoCodesPerUser[_msgSender()].length < maxPromoCodePerUser, 'max promo code per user reached');
            hasUsedCode[_msgSender()][code] = true;
            promoCodesPerUser[_msgSender()].push(code);
        }

        amountPerCode[code] += paymentAmount;

        if (paymentReceivedWithEachCode[_msgSender()][code] == 0) {
            uniqueUsePerCode[code] += 1;
        }
        paymentReceivedWithCode[_msgSender()] += paymentAmount;
        paymentReceivedWithEachCode[_msgSender()][code] += paymentAmount;

        emit PurchaseWithCode(_msgSender(), paymentAmount, code);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.17;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "./IFFundable.sol";

// Contract to manage tiered sales with promotional codes and whitelisting.
contract IFTieredSale is IFFundable, AccessControl {
    using SafeERC20 for ERC20;

    ERC20 public paymentToken;

    ERC20 public saleToken;

    // Tier and promotion management
    string[] public tierIds;
    mapping(string => Tier) public tiers;
    mapping(string => mapping(address => uint256)) public purchasedAmountPerTier; // tierId => address => amount in ether
    mapping(address => uint256) public paymentReceivedFromUser; // address => amount of payment token in wei
    mapping(string => uint256) public codePurchaseAmount; // promo code => total purchased amount in ether
    mapping(string => uint256) public saleTokenPurchasedByTier; // tierId => total purchased amount in ether
    mapping(string => PromoCode) public promoCodes;
    mapping(address => string[]) public ownerPromoCodes; // address => promo code
    string[] public allPromoCodes;

    // Configuration percentages
    // reward percentage
    uint8 public baseOwnerPercentage = 8;
    uint8 public masterOwnerPercentage = 2;
    uint8 public addressPromoCodePercentage = 8;
    uint8 public immutable MAX_BASE_OWNER_PERCENTAGE = 10;
    uint8 public immutable MAX_MASTER_OWNER_PERCENTAGE = 2;
    uint8 public immutable MAX_BONUS_PERCENTAGE = 5;
    // discount percentage
    uint8 public addressPromoCodeDiscountPercentage = 5;

    // Reward claiming management
    bool public claimRewardsEnabled = false;
    uint256 public totalRewardsUnclaimed; // Total unclaimed rewards, assuming all are valid

    // Role constants
    bytes32 public constant OPERATOR_ROLE = keccak256("OPERATOR_ROLE");

    // Structs for managing pricing tiers and promotional codes
    struct Tier {
        uint256 price;  // Price per tier in gwei.
        uint256 maxTotalPurchasable;  // Total limit per tier (0 means no limit), specified in ether.
        uint256 maxAllocationPerWallet;  // Limit per wallet (0 means no limit), specified in ether.
        uint8 bonusPercentage;  // Additional bonus percentage applicable for this tier.
        bytes32 whitelistRootHash;  // Merkle root hash for whitelisting.
        bool isHalt;  // Flag to halt transactions for this tier if set to true.
        bool allowPromoCode;  // Flag to allow promo codes for this tier.
        bool allowWalletPromoCode;  // Flag to allow promo codes specific to wallets.
        uint256 startTime;  // Start time for this tier.
        uint256 endTime;  // End time for this tier.
        bool requireSignature;  // Require signature for public sale or not
    }

    struct PromoCode {
        uint8 discountPercentage;  // Discount provided by the promo code, in percentage (1 - 100).
        address promoCodeOwnerAddress;  // Address of the promo code owner.
        address masterOwnerAddress;  // Address of the master owner who oversees this promo code.
        uint256 promoCodeOwnerEarnings;  // Earnings accrued to the promo code owner, in gwei.
        uint256 masterOwnerEarnings;  // Earnings accrued to the master owner, in gwei.
        uint256 totalPurchased;  // Total value purchased using this promo code, in ether.
        uint8 baseOwnerPercentageOverride; // Base owner percentage override for this promo code.
        uint8 masterOwnerPercentageOverride; // Master owner percentage override for this promo code.
    }


    // State variables

    // Events
    event PurchasedInTier(address indexed buyer, string tierId, uint256 amount, string promoCode);
    event PromoCodeAdded(string code, uint8 discountPercentage, address promoCodeOwnerAddress, address masterOwnerAddress);
    event ReferralRewardWithdrawn(address referrer, uint256 amount);

    // Constructor
    constructor(
        ERC20 _paymentToken,
        ERC20 _saleToken,
        uint256 _startTime,
        uint256 _endTime
    )
        IFFundable(_paymentToken, _saleToken, _startTime, _endTime, msg.sender)
    {
        _setupRole(DEFAULT_ADMIN_ROLE, msg.sender);
        _setupRole(OPERATOR_ROLE, msg.sender);
        paymentToken = _paymentToken;
        saleToken = _saleToken;
    }

    // Access management
    modifier onlyOperator() {
        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender) || hasRole(OPERATOR_ROLE, msg.sender),  "Not authorized");
        _;
    }

    // Override the transferOwnership function
    function transferOwnership(address newOwner) public override onlyOwner {
        require(newOwner != address(0), "Zero address");
        _revokeRole(DEFAULT_ADMIN_ROLE, owner());
        _grantRole(DEFAULT_ADMIN_ROLE, newOwner);
        super.transferOwnership(newOwner);
    }

    // Operator management functions
    function addOperator(address operator) public onlyRole(DEFAULT_ADMIN_ROLE) {
        require(operator!= address(0), "Invalid address");
        grantRole(OPERATOR_ROLE, operator);
    }

    function removeOperator(address operator) public onlyRole(DEFAULT_ADMIN_ROLE) {
        revokeRole(OPERATOR_ROLE, operator);
    }

    // Tier management
    function setTier(
        string memory _tierId,
        uint256 _price,
        uint256 _maxTotalPurchasable,
        uint256 _maxAllocationPerWallet,
        bytes32 _whitelistRootHash,
        uint8 _bonusPercentage,
        bool _isHalt,
        bool _allowPromoCode,
        bool _allowWalletPromoCode,
        uint256 _startTime,
        uint256 _endTime,
        bool requireSignature
    ) public onlyOperator {
        // Validate input data
        require(_price > 0, "Invalid price");
        require(_bonusPercentage <= MAX_BONUS_PERCENTAGE, "Invalid bonus percentage");
        // check starttime is in the future and endtime is greater than start time
        require(_startTime > block.timestamp, "Invalid start time");
        require(_endTime > _startTime, "Invalid end time");


        tiers[_tierId] = Tier({
            price: _price,
            maxTotalPurchasable: _maxTotalPurchasable,
            maxAllocationPerWallet: _maxAllocationPerWallet,
            whitelistRootHash: _whitelistRootHash,
            bonusPercentage: _bonusPercentage,
            isHalt: _isHalt,
            allowPromoCode: _allowPromoCode,
            allowWalletPromoCode: _allowWalletPromoCode,
            startTime: _startTime,
            endTime: _endTime,
            requireSignature: requireSignature

        });

        // iterate through the tierIds array to check if the tierId already exists
        for (uint i = 0; i < tierIds.length; i++) {
            if (keccak256(abi.encodePacked(tierIds[i])) == keccak256(abi.encodePacked(_tierId))) {
                return; // Tier already exists
            }
        }
        tierIds.push(_tierId);
    }


    // Promotion code management
    function addPromoCode(
        string memory _code,
        uint8 _discountPercentage,
        address _promoCodeOwnerAddress,
        address _masterOwnerAddress,
        uint8 _baseOwnerPercentageOverride,
        uint8 _masterOwnerPercentageOverride
    ) public onlyOperator {
        if (promoCodes[_code].discountPercentage != 0 || promoCodes[_code].promoCodeOwnerAddress != address(0)){
            revert("Promo code already exists");
        }
        // Validate the discount percentage and owner addresses
        _validatePromoCodeSetting(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress, _baseOwnerPercentageOverride, _masterOwnerPercentageOverride);
        require(!_isWalletPromoCode(_code), "Address promo codes are not allowed");

        // Add the promo code
        promoCodes[_code] = PromoCode({
            discountPercentage: _discountPercentage,
            promoCodeOwnerAddress: _promoCodeOwnerAddress,
            masterOwnerAddress: _masterOwnerAddress,
            promoCodeOwnerEarnings: 0,
            masterOwnerEarnings: 0,
            totalPurchased: 0,
            baseOwnerPercentageOverride: _baseOwnerPercentageOverride,
            masterOwnerPercentageOverride: _masterOwnerPercentageOverride
        });
        ownerPromoCodes[_promoCodeOwnerAddress].push(_code);
        ownerPromoCodes[_masterOwnerAddress].push(_code);
        allPromoCodes.push(_code);
        emit PromoCodeAdded(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress);
    }

    function _validatePromoCodeSetting(
        string memory code,
        uint8 discountPercentage,
        address promoCodeOwnerAddress,
        address masterOwnerAddress,
        uint8 baseOwnerPercentageOverride,
        uint8 masterOwnerPercentageOverride
    ) internal pure {
        require(bytes(code).length > 0, "Invalid promo code");
        require(discountPercentage <= 100, "Invalid discount percentage");
        require(promoCodeOwnerAddress != address(0), "Invalid promo code owner address");
        require(promoCodeOwnerAddress != masterOwnerAddress, "Promo code owner and master owner cannot be the same");
        require(baseOwnerPercentageOverride <= MAX_BASE_OWNER_PERCENTAGE, "Invalid base owner percentage");
        require(masterOwnerPercentageOverride <= MAX_MASTER_OWNER_PERCENTAGE, "Invalid master owner percentage");
    }

    // Whitelisted purchase functions
    function calculateDiscount(string memory _promoCode) internal view returns (uint8) {
        uint8 discount;
        if (_isWalletPromoCode(_promoCode)) {
            discount = addressPromoCodeDiscountPercentage; // Fixed discount for address-based promo codes
        } else {
            discount = promoCodes[_promoCode].discountPercentage; // Variable discount for other promo codes
        }
        return discount;
    }

    function whitelistedPurchaseInTier(
        string memory _tierId,
        uint256 _amount,
        bytes32[] calldata _merkleProof,
        uint256 _allocation,
        string memory _promoCode,
        address _walletPromoCode
    ) public {
        bytes32 tierWhitelistRootHash = tiers[_tierId].whitelistRootHash;
        if (tierWhitelistRootHash != bytes32(0)) {
            require(checkTierWhitelist(_tierId, msg.sender, _merkleProof, _allocation), "Invalid proof");
            require(purchasedAmountPerTier[_tierId][msg.sender] + _amount <= _allocation, "Purchase exceeds allocation");
        } else {
            require(!tiers[_tierId].requireSignature, "Use signed purchase");
        }

        require((bytes(_promoCode).length == 0 || _walletPromoCode == address(0)), "One promo code only");
        bool isRegularPromoCode = true;
        string memory finalPromoCode;

        if (bytes(_promoCode).length != 0) {
            require(tiers[_tierId].allowPromoCode, "Promo code not allowed");
            _validatePromoCode(_promoCode);
            finalPromoCode = _promoCode;
        }

        if (_walletPromoCode != address(0)) {
            require(tiers[_tierId].allowWalletPromoCode, "Wallet promo code not allowed");
            require(msg.sender != _walletPromoCode, "Cannot use own wallet code");
            require(validateWalletPromoCode(_walletPromoCode), "Unactivated wallet code");
            finalPromoCode = addressToString(_walletPromoCode);
            isRegularPromoCode = false;
        }

        uint256 price = tiers[_tierId].price;

        if (bytes(finalPromoCode).length != 0) {
            uint8 discount = calculateDiscount(finalPromoCode);
            price = price * (100 - discount) / 100;  // in gwei
            if (isRegularPromoCode) {
                _updatePromoCodeRewards(_promoCode, price * _amount, _tierId);
            } else {
                _updateWalletPromoCodeRewards(_walletPromoCode, price * _amount);
            }
        }

        executePurchase(_tierId, _amount, price, finalPromoCode);
    }

    /// Allows a user to purchase tokens in a specific tier of a tiered sale, using a signed purchase request.
    /// The function verifies the signature, checks that the purchase does not exceed the user's allocated payment,
    /// applies any applicable promo code discounts, and then executes the purchase.
    ///
    /// @param _tierId The ID of the tier in which the purchase is being made.
    /// @param _amount The amount of nodes the user wants to purchase.
    /// @param allocatedPayment The maximum amount of payment the user has allocated for this purchase (in wei).
    /// @param signature The signed purchase request.
    /// @param _promoCode An optional promo code to apply to the purchase.
    /// @param _walletPromoCode An optional wallet-based promo code to apply to the purchase.
    function signedPurchaseInTierWithCode(
        string memory _tierId,
        uint256 _amount,
        uint256 allocatedPayment,
        bytes calldata signature,
        string memory _promoCode,
        address _walletPromoCode
    ) public {
        require(tiers[_tierId].requireSignature, "Use whitelisted purchase");
        bytes32 messageHash = keccak256(abi.encodePacked(msg.sender, block.chainid, address(this), _tierId, allocatedPayment));

        bytes32 message = ECDSA.toEthSignedMessageHash(messageHash);

        address signer = ECDSA.recover(message, signature);

        // the message has to be signed by operator
        require(hasRole(OPERATOR_ROLE, signer), "Invalid signature");


        require((bytes(_promoCode).length == 0 || _walletPromoCode == address(0)), "One promo code only");
        bool isRegularPromoCode = true;
        string memory promoCode;

        if (bytes(_promoCode).length != 0) {
            require(tiers[_tierId].allowPromoCode, "Promo code not allowed");
            _validatePromoCode(_promoCode);
            promoCode = _promoCode;
        }
        if (_walletPromoCode != address(0)) {
            require(tiers[_tierId].allowWalletPromoCode, "Wallet promo code not allowed");
            require(msg.sender != _walletPromoCode, "Cannot use own wallet code");
            require(validateWalletPromoCode(_walletPromoCode), "Unactivated wallet code");
            promoCode = addressToString(_walletPromoCode);
            isRegularPromoCode = false;
        }

        uint256 price = tiers[_tierId].price;

        if (bytes(promoCode).length != 0) {
            uint8 discount = calculateDiscount(promoCode);
            price = price * (100 - discount) / 100;  // in gwei
            if (isRegularPromoCode) {
                _updatePromoCodeRewards(_promoCode, price * _amount, _tierId);
            } else {
                _updateWalletPromoCodeRewards(_walletPromoCode, price * _amount);
            }
        }
        require(paymentReceivedFromUser[msg.sender] + (_amount * price) <= allocatedPayment, "Purchase exceeds payment allocation");
        executePurchase(_tierId, _amount, price, promoCode);
    }


    function executePurchase (string memory _tierId, uint256 _amount, uint256 _price, string memory _promoCode) private nonReentrant  {
        Tier storage tier = tiers[_tierId];
        require(!tier.isHalt, "Tier is halted");
        require(tier.startTime <= block.timestamp && block.timestamp <= tier.endTime, "Tier is not active");
        require(_amount > 0, "Amount is 0");
        require(
            tier.maxAllocationPerWallet == 0 || purchasedAmountPerTier[_tierId][msg.sender] + _amount <= tier.maxAllocationPerWallet,
            "Exceed wallet allocation"
        );
        require(
            tier.maxTotalPurchasable == 0 || saleTokenPurchasedByTier[_tierId] + _amount <= tier.maxTotalPurchasable,
            "Exceed tier's total purchasable"
        );

        paymentReceivedFromUser[msg.sender] += _amount * _price;
        totalPaymentReceived += _amount * _price;
        purchasedAmountPerTier[_tierId][msg.sender] += _amount;
        saleTokenPurchasedByTier[_tierId] += _amount;

        uint256 totalCost = _amount * _price;  // in gwei

        paymentToken.safeTransferFrom(msg.sender, address(this), totalCost);

        emit PurchasedInTier(msg.sender, _tierId, _amount, _promoCode);
    }

    function _updateWalletPromoCodeRewards(address _walletPromoCode, uint256 totalCost) internal {
        string memory promoCode = addressToString(_walletPromoCode);
        if (promoCodes[promoCode].promoCodeOwnerAddress == address(0)) {
            promoCodes[promoCode].promoCodeOwnerAddress = _walletPromoCode;
        }
        uint256 ownerRewards = totalCost * addressPromoCodePercentage / 100;
        totalRewardsUnclaimed += ownerRewards;
        promoCodes[promoCode].promoCodeOwnerEarnings += ownerRewards;
        promoCodes[promoCode].totalPurchased += totalCost;
    }

    function _updatePromoCodeRewards(string memory _promoCode, uint256 totalCost, string memory tierId) internal {
        uint8 rewardPercentage = promoCodes[_promoCode].baseOwnerPercentageOverride > 0 ? promoCodes[_promoCode].baseOwnerPercentageOverride : baseOwnerPercentage;
        uint256 baseOwnerRewards = totalCost * rewardPercentage / 100;

        uint8 masterRewardPercentage = promoCodes[_promoCode].masterOwnerPercentageOverride > 0 ? promoCodes[_promoCode].masterOwnerPercentageOverride : masterOwnerPercentage;
        uint256 masterOwnerRewards = totalCost * masterRewardPercentage / 100;
        uint256 bonus = totalCost * tiers[tierId].bonusPercentage / 100;

        baseOwnerRewards += bonus;
        totalRewardsUnclaimed += baseOwnerRewards + masterOwnerRewards;
        promoCodes[_promoCode].promoCodeOwnerEarnings += baseOwnerRewards;
        promoCodes[_promoCode].masterOwnerEarnings += masterOwnerRewards;
        promoCodes[_promoCode].totalPurchased += totalCost;

    }


    function getSaleTokensSold() override internal view returns (uint256 amount) {
        uint256 tokenSold = 0;
        for (uint i = 0; i < tierIds.length; i++) {
            if (tiers[tierIds[i]].price == 0) {
                continue;
            }
            tokenSold += saleTokenPurchasedByTier[tierIds[i]];
        }
        return tokenSold;
    }

    function withdrawAllPromoCodeRewards () public nonReentrant {
        address promoCodeOwner = msg.sender;
        require(claimRewardsEnabled, "Claiming disabled");

        // for each promo code owned by the address, withdraw the rewards
        string[] memory promoCodesOwned = ownerPromoCodes[promoCodeOwner];
        uint256 rewards = 0;
        for (uint i = 0; i < promoCodesOwned.length; i++) {
            PromoCode storage promo = promoCodes[promoCodesOwned[i]];

            // it could be _masterOwnerAddress or _promoCodeOwnerAddress
            if (promo.promoCodeOwnerAddress == promoCodeOwner) {
                rewards += promo.promoCodeOwnerEarnings;
                promo.promoCodeOwnerEarnings = 0;
            }
            if (promo.masterOwnerAddress == promoCodeOwner) {
                rewards += promo.masterOwnerEarnings;
                promo.masterOwnerEarnings = 0;
            }
        }
        require(rewards > 0, "No reward");
        totalRewardsUnclaimed -= rewards;
        paymentToken.safeTransfer(msg.sender, rewards);

        emit ReferralRewardWithdrawn(msg.sender, rewards);
    }


    function withdrawPromoCodeRewards (string memory _promoCode) public nonReentrant {
        require(claimRewardsEnabled, "Claiming disabled");
        string memory promoCode = _promoCode;
        if (_isWalletPromoCode(promoCode)) {
            // can only claim wallet promo code of their own address
            require(validateWalletPromoCode(msg.sender), "Unactivated wallet code");
            promoCode = addressToString(msg.sender);
        }
        PromoCode storage promo = promoCodes[promoCode];
        require(msg.sender == promo.promoCodeOwnerAddress || msg.sender == promo.masterOwnerAddress, "Not code owner");

        uint256 reward = 0;
        if (msg.sender == promo.promoCodeOwnerAddress) {
            reward = promo.promoCodeOwnerEarnings;
            promo.promoCodeOwnerEarnings = 0;
        } else if (msg.sender == promo.masterOwnerAddress) {
            reward = promo.masterOwnerEarnings;
            promo.masterOwnerEarnings = 0;
        }

        require(reward > 0, "No reward");
        totalRewardsUnclaimed -= reward;
        paymentToken.safeTransfer(msg.sender, reward);

        emit ReferralRewardWithdrawn(msg.sender, reward);
    }

    function safeCashPaymentToken() public onlyCasherOrOwner {
        // leave the amount for withdrawalReferenceRewards
        // this function assumes that the rewards are valid
        // to make sure there are enough payment tokens to be withdrawn by the referrers
        uint256 paymentTokenBal = paymentToken.balanceOf(address(this));
        require(paymentTokenBal > totalRewardsUnclaimed, "Not enough payment token");
        uint256 withdrawAmount = paymentTokenBal - totalRewardsUnclaimed;
        paymentToken.safeTransfer(_msgSender(), withdrawAmount);
        emit Cash(_msgSender(), withdrawAmount, 0);
    }

    // Returns true if user's allocation matches the one in merkle root, otherwise false
    function checkTierWhitelist(string memory _tierId, address user, bytes32[] calldata merkleProof, uint256 allocation)
        public
        view
        returns (bool)
    {
        // compute merkle leaf from input
        bytes32 leaf = keccak256(abi.encodePacked(user, allocation));

        // verify merkle proof
        return MerkleProof.verify(merkleProof, tiers[_tierId].whitelistRootHash, leaf);
    }

    function _isWalletPromoCode(string memory _promoCode) internal pure returns (bool) {
        return bytes(_promoCode).length == 42;
    }

    function validateWalletPromoCode(address promoCodeAddress) public view returns (bool) {
        if (promoCodeAddress == address(0)) {
            return false;
        }

        for (uint i = 0; i < tierIds.length; i++) {
            if (tiers[tierIds[i]].price == 0) {
                continue;
            }
            if (purchasedAmountPerTier[tierIds[i]][promoCodeAddress] > 0) {
                // return true if the address has purchased at least one node
                return true;
            }
        }
        return false;
    }

    function _validatePromoCode(string memory _promoCode) internal view {
        require(bytes(_promoCode).length > 0, "Invalid promo code");
        require(promoCodes[_promoCode].promoCodeOwnerAddress != address(0), "Invalid promo code");
    }

    // Override the renounceOwnership function to disable it
    function renounceOwnership() public pure override{
        revert("disabled");
    }

    // ops functions
    function haltAllTiers() external onlyOperator {
        for (uint i = 0; i < tierIds.length; i++) {
            tiers[tierIds[i]].isHalt = true;
        }
    }

    function unhaltAllTiers() external onlyOperator {
        for (uint i = 0; i < tierIds.length; i++) {
            tiers[tierIds[i]].isHalt = false;
        }
    }

    function updateWhitelist(string memory _tierId, bytes32 _whitelistRootHash) external onlyOperator{
        tiers[_tierId].whitelistRootHash = _whitelistRootHash;
    }

    function updateMaxTotalPurchasable(string memory _tierId, uint256 _maxTotalPurchasable) external onlyOperator {
        tiers[_tierId].maxTotalPurchasable = _maxTotalPurchasable;
    }

    function updateWalletPromoCodeAllowance(string memory _tierId, bool _allowWalletPromoCode) external onlyOperator {
        tiers[_tierId].allowWalletPromoCode = _allowWalletPromoCode;
    }

    function updateMaxAllocationPerWallet(string memory _tierId, uint256 _maxAllocationPerWallet) external onlyOperator {
        tiers[_tierId].maxAllocationPerWallet = _maxAllocationPerWallet;
    }

    function updateIsHalt(string memory _tierId, bool _isHalt) external onlyOperator{
        tiers[_tierId].isHalt = _isHalt;
    }

    function updateClaimRewardsEnabled(bool _claimRewardsEnabled) external onlyOperator {
        claimRewardsEnabled = _claimRewardsEnabled;
    }

    // owner only ops functions
    function updateRewards(uint8 _baseOwnerPercentage, uint8 _masterOwnerPercentage) external onlyOwner {
        require(_baseOwnerPercentage <= MAX_BASE_OWNER_PERCENTAGE, "Invalid base owner percentage");
        require(_masterOwnerPercentage <= MAX_MASTER_OWNER_PERCENTAGE, "Invalid master owner percentage");
        baseOwnerPercentage = _baseOwnerPercentage;
        masterOwnerPercentage = _masterOwnerPercentage;
    }

    function updateAddressRewards(uint8 _addressPromoCodePercentage) external onlyOwner {
        require(_addressPromoCodePercentage <= MAX_BASE_OWNER_PERCENTAGE, "Invalid address promo code percentage");
        addressPromoCodePercentage = _addressPromoCodePercentage;
    }

    function updateAddressDiscount(uint8 _addressPromoCodeDiscountPercentage) external onlyOwner {
        require(_addressPromoCodeDiscountPercentage <= 100, "Invalid address promo code discount percentage");
        addressPromoCodeDiscountPercentage = _addressPromoCodeDiscountPercentage;
    }
   function updatePromocode(
       string memory _code,
       uint8 _discountPercentage,
       address _promoCodeOwnerAddress,
       address _masterOwnerAddress,
       uint8 _baseOwnerPercentageOverride,
       uint8 _masterOwnerPercentageOverride
     ) public onlyOwner {
       bool codeExists = false;
       for(uint i = 0; i < allPromoCodes.length; i++) {
           if(keccak256(bytes(allPromoCodes[i])) == keccak256(bytes(_code))) {
               codeExists = true;
               break;
           }
       }
       require(codeExists, "Code not found");
       
       // ok to update address promo code
       _validatePromoCodeSetting(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress, _baseOwnerPercentageOverride, _masterOwnerPercentageOverride);
        
       address oldPromoCodeOwner = promoCodes[_code].promoCodeOwnerAddress;
       address oldMasterOwner = promoCodes[_code].masterOwnerAddress;
        
       if(oldPromoCodeOwner != address(0)) {
           string[] storage oldOwnerCodes = ownerPromoCodes[oldPromoCodeOwner];
           for(uint i = 0; i < oldOwnerCodes.length; i++) {
               if(keccak256(bytes(oldOwnerCodes[i])) == keccak256(bytes(_code))) {
                   oldOwnerCodes[i] = oldOwnerCodes[oldOwnerCodes.length - 1];
                   oldOwnerCodes.pop();
                   break;
               }
           }
       }
        
       if(oldMasterOwner != address(0)) {
           string[] storage oldMasterCodes = ownerPromoCodes[oldMasterOwner];
           for(uint i = 0; i < oldMasterCodes.length; i++) {
               if(keccak256(bytes(oldMasterCodes[i])) == keccak256(bytes(_code))) {
                   oldMasterCodes[i] = oldMasterCodes[oldMasterCodes.length - 1];
                   oldMasterCodes.pop();
                   break;
               }
           }
       }

       promoCodes[_code].discountPercentage = _discountPercentage;
       promoCodes[_code].promoCodeOwnerAddress = _promoCodeOwnerAddress;
       promoCodes[_code].masterOwnerAddress = _masterOwnerAddress;
       promoCodes[_code].baseOwnerPercentageOverride = _baseOwnerPercentageOverride;
       promoCodes[_code].masterOwnerPercentageOverride = _masterOwnerPercentageOverride;
       ownerPromoCodes[_promoCodeOwnerAddress].push(_code);
       ownerPromoCodes[_masterOwnerAddress].push(_code);
    }
    // view function for ops
    function getAllPromoCodeInfo(uint256 fromIdx, uint256 toIdx) external view returns (PromoCode[] memory) {
        if (toIdx > allPromoCodes.length) {
            toIdx = allPromoCodes.length;
        }
        require(fromIdx < toIdx, "Invalid range");
        PromoCode[] memory promoCodeInfos = new PromoCode[](toIdx - fromIdx);
        for (uint i = fromIdx; i < toIdx; i++) {
            promoCodeInfos[i - fromIdx] = promoCodes[allPromoCodes[i]];
        }
        return promoCodeInfos;
    }

    function getPromoCodeLength() external view returns (uint256) {
        return allPromoCodes.length;
    }

    function getAllPromoCodes(uint256 fromIdx, uint256 toIdx) external view returns (string[] memory) {
        if (toIdx > allPromoCodes.length) {
            toIdx = allPromoCodes.length;
        }
        require(fromIdx < toIdx, "Invalid range");
        string[] memory promoCodeList = new string[](toIdx - fromIdx);
        for (uint i = fromIdx; i < toIdx; i++) {
            promoCodeList[i] = allPromoCodes[i];
        }
        return promoCodeList;
    }

    function getOwnerPromoCodes(address owner) external view returns (string[] memory) {
        uint256 length = ownerPromoCodes[owner].length;
        string[] memory promoCodeList = new string[](length);
        for (uint i = 0; i < length; i++) {
            promoCodeList[i] = ownerPromoCodes[owner][i];
        }
        return promoCodeList;
    }


    function getAllTierIds() external view returns (string[] memory) {
        return tierIds;
    }

    // util function
    function addressToString(address _addr) internal pure returns (string memory) {
        return Strings.toHexString(uint256(uint160(_addr)), 20);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.17;

import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "./TieredSaleStructs.sol";


contract IFTieredSaleHelper{
    using ECDSA for bytes32;
    function checkTierWhitelist(address user, bytes32[] calldata merkleProof, uint256 allocation, bytes32 whitelistRootHash)
        external
        pure
        returns (bool)
    {
        bytes32 leaf = keccak256(abi.encodePacked(user, allocation));
        return MerkleProof.verify(merkleProof, whitelistRootHash, leaf);
    }


    function addressToString(address _addr) external pure returns (string memory) {
        return Strings.toHexString(uint256(uint160(_addr)), 20);
    }

    // Function to hash a message and recover the signer
    function getSigner(
        address sender,
        string memory tierId,
        uint256 allocation,
        bytes memory signature
    ) external pure returns (address) {
        // Create the message hash using keccak256
        bytes32 messageHash = keccak256(abi.encodePacked(sender, tierId, allocation));

        // Create an Ethereum signed message hash
        bytes32 ethSignedMessageHash = messageHash.toEthSignedMessageHash();

        // Recover the signer's address from the signature
        return ECDSA.recover(ethSignedMessageHash, signature);
    }

    function getAllPromoCodes(
        string[] memory allPromoCodes,
        uint256 fromIdx,
        uint256 toIdx
    ) external view returns (string[] memory) {
        require(fromIdx < toIdx, "Invalid range");
        if (toIdx > allPromoCodes.length) {
            toIdx = allPromoCodes.length;
        }
        string[] memory promoCodeList = new string[](toIdx - fromIdx);
        for (uint i = fromIdx; i < toIdx; i++) {
            promoCodeList[i] = allPromoCodes[i];
        }
        return promoCodeList;
    }

    function validatePromoCodeSetting(
        string memory code,
        uint8 discountPercentage,
        address promoCodeOwnerAddress,
        address masterOwnerAddress,
        uint8 baseOwnerPercentageOverride,
        uint8 masterOwnerPercentageOverride,
        uint8 max_base_owner_percentage,
        uint8 max_master_owner_percentage
    ) external pure {
        require(bytes(code).length > 0, "Invalid promo code");
        require(discountPercentage <= 100, "Invalid discount percentage");
        require(promoCodeOwnerAddress != masterOwnerAddress, "Promo code owner and master owner cannot be the same");
        require(baseOwnerPercentageOverride <= max_base_owner_percentage, "Invalid base owner percentage");
        require(masterOwnerPercentageOverride <= max_master_owner_percentage, "Invalid master owner percentage");
    }

    function isWalletPromoCode(string memory _promoCode) external pure returns (bool) {
        return bytes(_promoCode).length == 42;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.17;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "./IFFundable.sol";

// Contract to manage tiered sales with promotional codes and whitelisting.
contract IFTieredSaleV2 is IFFundable, AccessControl {
    using SafeERC20 for ERC20;

    ERC20 public paymentToken;

    ERC20 public saleToken;

    // Tier and promotion management
    string[] public tierIds;
    mapping(string => Tier) public tiers;
    mapping(string => mapping(address => uint256)) public purchasedAmountPerTier; // tierId => address => amount in ether
    mapping(address => uint256) public paymentReceivedFromUser; // address => amount of payment token in wei
    mapping(string => uint256) public codePurchaseAmount; // promo code => total purchased amount in ether
    mapping(string => uint256) public saleTokenPurchasedByTier; // tierId => total purchased amount in ether
    mapping(string => PromoCode) public promoCodes;
    mapping(address => string[]) public ownerPromoCodes; // address => promo code
    string[] public allPromoCodes;

    // Configuration percentages
    // reward percentage
    uint8 public baseOwnerPercentage = 8;
    uint8 public masterOwnerPercentage = 2;
    uint8 public addressPromoCodePercentage = 8;
    uint8 public immutable MAX_BASE_OWNER_PERCENTAGE = 10;
    uint8 public immutable MAX_MASTER_OWNER_PERCENTAGE = 2;
    uint8 public immutable MAX_BONUS_PERCENTAGE = 5;
    // discount percentage
    uint8 public addressPromoCodeDiscountPercentage = 5;

    // Reward claiming management
    bool public claimRewardsEnabled = false;
    uint256 public totalRewardsUnclaimed; // Total unclaimed rewards, assuming all are valid

    // Role constants
    bytes32 public constant OPERATOR_ROLE = keccak256("OPERATOR_ROLE");

    // Structs for managing pricing tiers and promotional codes
    struct Tier {
        uint256 price;  // Price per tier in gwei.
        uint256 maxTotalPurchasable;  // Total limit per tier (0 means no limit), specified in ether.
        uint256 maxAllocationPerWallet;  // Limit per wallet (0 means no limit), specified in ether.
        uint8 bonusPercentage;  // Additional bonus percentage applicable for this tier.
        bytes32 whitelistRootHash;  // Merkle root hash for whitelisting.
        bool isHalt;  // Flag to halt transactions for this tier if set to true.
        bool allowPromoCode;  // Flag to allow promo codes for this tier.
        bool allowWalletPromoCode;  // Flag to allow promo codes specific to wallets.
        uint256 startTime;  // Start time for this tier.
        uint256 endTime;  // End time for this tier.
        bool requireSignature;  // Require signature for public sale or not
    }

    struct PromoCode {
        uint8 discountPercentage;  // Discount provided by the promo code, in percentage (1 - 100).
        address promoCodeOwnerAddress;  // Address of the promo code owner.
        address masterOwnerAddress;  // Address of the master owner who oversees this promo code.
        uint256 promoCodeOwnerEarnings;  // Earnings accrued to the promo code owner, in gwei.
        uint256 masterOwnerEarnings;  // Earnings accrued to the master owner, in gwei.
        uint256 totalPurchased;  // Total value purchased using this promo code, in ether.
        uint8 baseOwnerPercentageOverride; // Base owner percentage override for this promo code.
        uint8 masterOwnerPercentageOverride; // Master owner percentage override for this promo code.
    }


    // State variables

    // Events
    event PurchasedInTier(address indexed buyer, string tierId, uint256 amount, string promoCode);
    event PromoCodeAdded(string code, uint8 discountPercentage, address promoCodeOwnerAddress, address masterOwnerAddress);
    event ReferralRewardWithdrawn(address referrer, uint256 amount);

    // Constructor
    constructor(
        ERC20 _paymentToken,
        ERC20 _saleToken,
        uint256 _startTime,
        uint256 _endTime
    )
        IFFundable(_paymentToken, _saleToken, _startTime, _endTime, msg.sender)
    {
        _setupRole(DEFAULT_ADMIN_ROLE, msg.sender);
        _setupRole(OPERATOR_ROLE, msg.sender);
        paymentToken = _paymentToken;
        saleToken = _saleToken;
    }

    // Access management
    modifier onlyOperator() {
        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender) || hasRole(OPERATOR_ROLE, msg.sender),  "Not authorized");
        _;
    }

    // Override the transferOwnership function
    function transferOwnership(address newOwner) public override onlyOwner {
        require(newOwner != address(0), "Zero address");
        _revokeRole(DEFAULT_ADMIN_ROLE, owner());
        _grantRole(DEFAULT_ADMIN_ROLE, newOwner);
        super.transferOwnership(newOwner);
    }

    // Operator management functions
    function addOperator(address operator) public onlyRole(DEFAULT_ADMIN_ROLE) {
        require(operator!= address(0), "Invalid address");
        grantRole(OPERATOR_ROLE, operator);
    }

    function removeOperator(address operator) public onlyRole(DEFAULT_ADMIN_ROLE) {
        revokeRole(OPERATOR_ROLE, operator);
    }

    // Tier management
    function setTier(
        string memory _tierId,
        uint256 _price,
        uint256 _maxTotalPurchasable,
        uint256 _maxAllocationPerWallet,
        bytes32 _whitelistRootHash,
        uint8 _bonusPercentage,
        bool _isHalt,
        bool _allowPromoCode,
        bool _allowWalletPromoCode,
        uint256 _startTime,
        uint256 _endTime,
        bool requireSignature
    ) public onlyOperator {
        // Validate input data
        require(_price > 0, "Invalid price");
        require(_bonusPercentage <= MAX_BONUS_PERCENTAGE, "Invalid bonus percentage");
        // check starttime is in the future and endtime is greater than start time
        require(_startTime > block.timestamp, "Invalid start time");
        require(_endTime > _startTime, "Invalid end time");


        tiers[_tierId] = Tier({
            price: _price,
            maxTotalPurchasable: _maxTotalPurchasable,
            maxAllocationPerWallet: _maxAllocationPerWallet,
            whitelistRootHash: _whitelistRootHash,
            bonusPercentage: _bonusPercentage,
            isHalt: _isHalt,
            allowPromoCode: _allowPromoCode,
            allowWalletPromoCode: _allowWalletPromoCode,
            startTime: _startTime,
            endTime: _endTime,
            requireSignature: requireSignature

        });

        // iterate through the tierIds array to check if the tierId already exists
        for (uint i = 0; i < tierIds.length; i++) {
            if (keccak256(abi.encodePacked(tierIds[i])) == keccak256(abi.encodePacked(_tierId))) {
                return; // Tier already exists
            }
        }
        tierIds.push(_tierId);
    }


    // Promotion code management
    function addPromoCode(
        string memory _code,
        uint8 _discountPercentage,
        address _promoCodeOwnerAddress,
        address _masterOwnerAddress,
        uint8 _baseOwnerPercentageOverride,
        uint8 _masterOwnerPercentageOverride
    ) public onlyOperator {
        if (promoCodes[_code].discountPercentage != 0 || promoCodes[_code].promoCodeOwnerAddress != address(0)){
            revert("Promo code already exists");
        }
        // Validate the discount percentage and owner addresses
        _validatePromoCodeSetting(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress, _baseOwnerPercentageOverride, _masterOwnerPercentageOverride);
        require(!_isWalletPromoCode(_code), "Address promo codes are not allowed");

        // Add the promo code
        promoCodes[_code] = PromoCode({
            discountPercentage: _discountPercentage,
            promoCodeOwnerAddress: _promoCodeOwnerAddress,
            masterOwnerAddress: _masterOwnerAddress,
            promoCodeOwnerEarnings: 0,
            masterOwnerEarnings: 0,
            totalPurchased: 0,
            baseOwnerPercentageOverride: _baseOwnerPercentageOverride,
            masterOwnerPercentageOverride: _masterOwnerPercentageOverride
        });
        ownerPromoCodes[_promoCodeOwnerAddress].push(_code);
        ownerPromoCodes[_masterOwnerAddress].push(_code);
        allPromoCodes.push(_code);
        emit PromoCodeAdded(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress);
    }

    function _validatePromoCodeSetting(
        string memory code,
        uint8 discountPercentage,
        address promoCodeOwnerAddress,
        address masterOwnerAddress,
        uint8 baseOwnerPercentageOverride,
        uint8 masterOwnerPercentageOverride
    ) internal pure {
        require(bytes(code).length > 0, "Invalid promo code");
        require(discountPercentage <= 100, "Invalid discount percentage");
        require(promoCodeOwnerAddress != address(0), "Invalid promo code owner address");
        require(promoCodeOwnerAddress != masterOwnerAddress, "Promo code owner and master owner cannot be the same");
        require(baseOwnerPercentageOverride <= MAX_BASE_OWNER_PERCENTAGE, "Invalid base owner percentage");
        require(masterOwnerPercentageOverride <= MAX_MASTER_OWNER_PERCENTAGE, "Invalid master owner percentage");
    }

    // Whitelisted purchase functions
    function calculateDiscount(string memory _promoCode) internal view returns (uint8) {
        uint8 discount;
        if (_isWalletPromoCode(_promoCode)) {
            discount = addressPromoCodeDiscountPercentage; // Fixed discount for address-based promo codes
        } else {
            discount = promoCodes[_promoCode].discountPercentage; // Variable discount for other promo codes
        }
        return discount;
    }

    function whitelistedPurchaseInTier(
        string memory _tierId,
        uint256 _amount,
        bytes32[] calldata _merkleProof,
        uint256 _allocation,
        string memory _promoCode,
        address _walletPromoCode
    ) public {
        bytes32 tierWhitelistRootHash = tiers[_tierId].whitelistRootHash;
        if (tierWhitelistRootHash != bytes32(0)) {
            require(checkTierWhitelist(_tierId, msg.sender, _merkleProof, _allocation), "Invalid proof");
            require(purchasedAmountPerTier[_tierId][msg.sender] + _amount <= _allocation, "Purchase exceeds allocation");
        } else {
            require(!tiers[_tierId].requireSignature, "Use signed purchase");
        }

        require((bytes(_promoCode).length == 0 || _walletPromoCode == address(0)), "One promo code only");
        bool isRegularPromoCode = true;
        string memory finalPromoCode;

        if (bytes(_promoCode).length != 0) {
            require(tiers[_tierId].allowPromoCode, "Promo code not allowed");
            _validatePromoCode(_promoCode);
            finalPromoCode = _promoCode;
        }

        if (_walletPromoCode != address(0)) {
            require(tiers[_tierId].allowWalletPromoCode, "Wallet promo code not allowed");
            require(msg.sender != _walletPromoCode, "Cannot use own wallet code");
            require(validateWalletPromoCode(_walletPromoCode), "Unactivated wallet code");
            finalPromoCode = addressToString(_walletPromoCode);
            isRegularPromoCode = false;
        }

        uint256 price = tiers[_tierId].price;

        if (bytes(finalPromoCode).length != 0) {
            uint8 discount = calculateDiscount(finalPromoCode);
            price = price * (100 - discount) / 100;  // in gwei
            if (isRegularPromoCode) {
                _updatePromoCodeRewards(_promoCode, price * _amount, _tierId);
            } else {
                _updateWalletPromoCodeRewards(_walletPromoCode, price * _amount);
            }
        }

        executePurchase(_tierId, _amount, price, finalPromoCode);
    }

    /// Allows a user to purchase tokens in a specific tier of a tiered sale, using a signed purchase request.
    /// The function verifies the signature, checks that the purchase does not exceed the user's allocated payment,
    /// applies any applicable promo code discounts, and then executes the purchase.
    ///
    /// @param _tierId The ID of the tier in which the purchase is being made.
    /// @param _amount The amount of nodes the user wants to purchase.
    /// @param allocatedPayment The maximum amount of payment the user has allocated for this purchase (in wei).
    /// @param signature The signed purchase request.
    /// @param _promoCode An optional promo code to apply to the purchase.
    /// @param _walletPromoCode An optional wallet-based promo code to apply to the purchase.
    function signedPurchaseInTierWithCode(
        string memory _tierId,
        uint256 _amount,
        uint256 allocatedPayment,
        bytes calldata signature,
        string memory _promoCode,
        address _walletPromoCode
    ) public {
        require(tiers[_tierId].requireSignature, "Use whitelisted purchase");
        bytes32 messageHash = keccak256(abi.encodePacked(msg.sender, block.chainid, address(this), _tierId, allocatedPayment));

        bytes32 message = ECDSA.toEthSignedMessageHash(messageHash);

        address signer = ECDSA.recover(message, signature);

        // the message has to be signed by operator
        require(hasRole(OPERATOR_ROLE, signer), "Invalid signature");


        require((bytes(_promoCode).length == 0 || _walletPromoCode == address(0)), "One promo code only");
        bool isRegularPromoCode = true;
        string memory promoCode;

        if (bytes(_promoCode).length != 0) {
            require(tiers[_tierId].allowPromoCode, "Promo code not allowed");
            _validatePromoCode(_promoCode);
            promoCode = _promoCode;
        }
        if (_walletPromoCode != address(0)) {
            require(tiers[_tierId].allowWalletPromoCode, "Wallet promo code not allowed");
            require(msg.sender != _walletPromoCode, "Cannot use own wallet code");
            require(validateWalletPromoCode(_walletPromoCode), "Unactivated wallet code");
            promoCode = addressToString(_walletPromoCode);
            isRegularPromoCode = false;
        }

        uint256 price = tiers[_tierId].price;

        if (bytes(promoCode).length != 0) {
            uint8 discount = calculateDiscount(promoCode);
            price = price * (100 - discount) / 100;  // in gwei
            if (isRegularPromoCode) {
                _updatePromoCodeRewards(_promoCode, price * _amount, _tierId);
            } else {
                _updateWalletPromoCodeRewards(_walletPromoCode, price * _amount);
            }
        }
        require(paymentReceivedFromUser[msg.sender] + (_amount * price) <= allocatedPayment, "Purchase exceeds payment allocation");
        executePurchase(_tierId, _amount, price, promoCode);
    }


    function executePurchase (string memory _tierId, uint256 _amount, uint256 _price, string memory _promoCode) private nonReentrant  {
        Tier storage tier = tiers[_tierId];
        require(!tier.isHalt, "Tier is halted");
        require(tier.startTime <= block.timestamp && block.timestamp <= tier.endTime, "Tier is not active");
        require(_amount > 0, "Amount is 0");
        require(
            tier.maxAllocationPerWallet == 0 || purchasedAmountPerTier[_tierId][msg.sender] + _amount <= tier.maxAllocationPerWallet,
            "Exceed wallet allocation"
        );
        require(
            tier.maxTotalPurchasable == 0 || saleTokenPurchasedByTier[_tierId] + _amount <= tier.maxTotalPurchasable,
            "Exceed tier's total purchasable"
        );

        paymentReceivedFromUser[msg.sender] += _amount * _price;
        totalPaymentReceived += _amount * _price;
        purchasedAmountPerTier[_tierId][msg.sender] += _amount;
        saleTokenPurchasedByTier[_tierId] += _amount;

        uint256 totalCost = _amount * _price;  // in gwei

        paymentToken.safeTransferFrom(msg.sender, address(this), totalCost);

        emit PurchasedInTier(msg.sender, _tierId, _amount, _promoCode);
    }

    function _updateWalletPromoCodeRewards(address _walletPromoCode, uint256 totalCost) internal {
        string memory promoCode = addressToString(_walletPromoCode);
        if (promoCodes[promoCode].promoCodeOwnerAddress == address(0)) {
            promoCodes[promoCode].promoCodeOwnerAddress = _walletPromoCode;
        }
        uint256 ownerRewards = totalCost * addressPromoCodePercentage / 100;
        totalRewardsUnclaimed += ownerRewards;
        promoCodes[promoCode].promoCodeOwnerEarnings += ownerRewards;
        promoCodes[promoCode].totalPurchased += totalCost;
    }

    function _updatePromoCodeRewards(string memory _promoCode, uint256 totalCost, string memory tierId) internal {
        uint8 rewardPercentage = promoCodes[_promoCode].baseOwnerPercentageOverride > 0 ? promoCodes[_promoCode].baseOwnerPercentageOverride : baseOwnerPercentage;
        uint256 baseOwnerRewards = totalCost * rewardPercentage / 100;

        uint8 masterRewardPercentage = promoCodes[_promoCode].masterOwnerPercentageOverride > 0 ? promoCodes[_promoCode].masterOwnerPercentageOverride : masterOwnerPercentage;
        uint256 masterOwnerRewards = totalCost * masterRewardPercentage / 100;
        uint256 bonus = totalCost * tiers[tierId].bonusPercentage / 100;

        baseOwnerRewards += bonus;
        totalRewardsUnclaimed += baseOwnerRewards + masterOwnerRewards;
        promoCodes[_promoCode].promoCodeOwnerEarnings += baseOwnerRewards;
        promoCodes[_promoCode].masterOwnerEarnings += masterOwnerRewards;
        promoCodes[_promoCode].totalPurchased += totalCost;

    }


    function getSaleTokensSold() override internal view returns (uint256 amount) {
        uint256 tokenSold = 0;
        for (uint i = 0; i < tierIds.length; i++) {
            if (tiers[tierIds[i]].price == 0) {
                continue;
            }
            tokenSold += saleTokenPurchasedByTier[tierIds[i]];
        }
        return tokenSold;
    }

    function withdrawAllPromoCodeRewards () public nonReentrant {
        address promoCodeOwner = msg.sender;
        require(claimRewardsEnabled, "Claiming disabled");

        // for each promo code owned by the address, withdraw the rewards
        string[] memory promoCodesOwned = ownerPromoCodes[promoCodeOwner];
        uint256 rewards = 0;
        for (uint i = 0; i < promoCodesOwned.length; i++) {
            PromoCode storage promo = promoCodes[promoCodesOwned[i]];

            // it could be _masterOwnerAddress or _promoCodeOwnerAddress
            if (promo.promoCodeOwnerAddress == promoCodeOwner) {
                rewards += promo.promoCodeOwnerEarnings;
                promo.promoCodeOwnerEarnings = 0;
            }
            if (promo.masterOwnerAddress == promoCodeOwner) {
                rewards += promo.masterOwnerEarnings;
                promo.masterOwnerEarnings = 0;
            }
        }
        require(rewards > 0, "No reward");
        totalRewardsUnclaimed -= rewards;
        paymentToken.safeTransfer(msg.sender, rewards);

        emit ReferralRewardWithdrawn(msg.sender, rewards);
    }


    function withdrawPromoCodeRewards (string memory _promoCode) public nonReentrant {
        require(claimRewardsEnabled, "Claiming disabled");
        string memory promoCode = _promoCode;
        if (_isWalletPromoCode(promoCode)) {
            // can only claim wallet promo code of their own address
            require(validateWalletPromoCode(msg.sender), "Unactivated wallet code");
            promoCode = addressToString(msg.sender);
        }
        PromoCode storage promo = promoCodes[promoCode];
        require(msg.sender == promo.promoCodeOwnerAddress || msg.sender == promo.masterOwnerAddress, "Not code owner");

        uint256 reward = 0;
        if (msg.sender == promo.promoCodeOwnerAddress) {
            reward = promo.promoCodeOwnerEarnings;
            promo.promoCodeOwnerEarnings = 0;
        } else if (msg.sender == promo.masterOwnerAddress) {
            reward = promo.masterOwnerEarnings;
            promo.masterOwnerEarnings = 0;
        }

        require(reward > 0, "No reward");
        totalRewardsUnclaimed -= reward;
        paymentToken.safeTransfer(msg.sender, reward);

        emit ReferralRewardWithdrawn(msg.sender, reward);
    }

    function safeCashPaymentToken() public onlyCasherOrOwner {
        // leave the amount for withdrawalReferenceRewards
        // this function assumes that the rewards are valid
        // to make sure there are enough payment tokens to be withdrawn by the referrers
        uint256 paymentTokenBal = paymentToken.balanceOf(address(this));
        require(paymentTokenBal > totalRewardsUnclaimed, "Not enough payment token");
        uint256 withdrawAmount = paymentTokenBal - totalRewardsUnclaimed;
        paymentToken.safeTransfer(_msgSender(), withdrawAmount);
        emit Cash(_msgSender(), withdrawAmount, 0);
    }

    // Returns true if user's allocation matches the one in merkle root, otherwise false
    function checkTierWhitelist(string memory _tierId, address user, bytes32[] calldata merkleProof, uint256 allocation)
        public
        view
        returns (bool)
    {
        // compute merkle leaf from input
        bytes32 leaf = keccak256(abi.encodePacked(user, allocation));

        // verify merkle proof
        return MerkleProof.verify(merkleProof, tiers[_tierId].whitelistRootHash, leaf);
    }

    function _isWalletPromoCode(string memory _promoCode) internal pure returns (bool) {
        return bytes(_promoCode).length == 42;
    }

    function validateWalletPromoCode(address promoCodeAddress) public view returns (bool) {
        if (promoCodeAddress == address(0)) {
            return false;
        }

        for (uint i = 0; i < tierIds.length; i++) {
            if (tiers[tierIds[i]].price == 0) {
                continue;
            }
            if (purchasedAmountPerTier[tierIds[i]][promoCodeAddress] > 0) {
                // return true if the address has purchased at least one node
                return true;
            }
        }
        return false;
    }

    function _validatePromoCode(string memory _promoCode) internal view {
        require(bytes(_promoCode).length > 0, "Invalid promo code");
        require(promoCodes[_promoCode].promoCodeOwnerAddress != address(0), "Invalid promo code");
    }

    // Override the renounceOwnership function to disable it
    function renounceOwnership() public pure override{
        revert("disabled");
    }

    // ops functions
    function haltAllTiers() external onlyOperator {
        for (uint i = 0; i < tierIds.length; i++) {
            tiers[tierIds[i]].isHalt = true;
        }
    }

    function unhaltAllTiers() external onlyOperator {
        for (uint i = 0; i < tierIds.length; i++) {
            tiers[tierIds[i]].isHalt = false;
        }
    }

    function updateWhitelist(string memory _tierId, bytes32 _whitelistRootHash) external onlyOperator{
        tiers[_tierId].whitelistRootHash = _whitelistRootHash;
    }

    function updateMaxTotalPurchasable(string memory _tierId, uint256 _maxTotalPurchasable) external onlyOperator {
        tiers[_tierId].maxTotalPurchasable = _maxTotalPurchasable;
    }

    function updateWalletPromoCodeAllowance(string memory _tierId, bool _allowWalletPromoCode) external onlyOperator {
        tiers[_tierId].allowWalletPromoCode = _allowWalletPromoCode;
    }

    function updateMaxAllocationPerWallet(string memory _tierId, uint256 _maxAllocationPerWallet) external onlyOperator {
        tiers[_tierId].maxAllocationPerWallet = _maxAllocationPerWallet;
    }

    function updateIsHalt(string memory _tierId, bool _isHalt) external onlyOperator{
        tiers[_tierId].isHalt = _isHalt;
    }

    function updateClaimRewardsEnabled(bool _claimRewardsEnabled) external onlyOperator {
        claimRewardsEnabled = _claimRewardsEnabled;
    }

    // owner only ops functions
    function updateRewards(uint8 _baseOwnerPercentage, uint8 _masterOwnerPercentage) external onlyOwner {
        require(_baseOwnerPercentage <= MAX_BASE_OWNER_PERCENTAGE, "Invalid base owner percentage");
        require(_masterOwnerPercentage <= MAX_MASTER_OWNER_PERCENTAGE, "Invalid master owner percentage");
        baseOwnerPercentage = _baseOwnerPercentage;
        masterOwnerPercentage = _masterOwnerPercentage;
    }

    function updateAddressRewards(uint8 _addressPromoCodePercentage) external onlyOwner {
        require(_addressPromoCodePercentage <= MAX_BASE_OWNER_PERCENTAGE, "Invalid address promo code percentage");
        addressPromoCodePercentage = _addressPromoCodePercentage;
    }

    function updateAddressDiscount(uint8 _addressPromoCodeDiscountPercentage) external onlyOwner {
        require(_addressPromoCodeDiscountPercentage <= 100, "Invalid address promo code discount percentage");
        addressPromoCodeDiscountPercentage = _addressPromoCodeDiscountPercentage;
    }
   function updatePromocode(
       string memory _code,
       uint8 _discountPercentage,
       address _promoCodeOwnerAddress,
       address _masterOwnerAddress,
       uint8 _baseOwnerPercentageOverride,
       uint8 _masterOwnerPercentageOverride
     ) public onlyOwner {
       bool codeExists = false;
       for(uint i = 0; i < allPromoCodes.length; i++) {
           if(keccak256(bytes(allPromoCodes[i])) == keccak256(bytes(_code))) {
               codeExists = true;
               break;
           }
       }
       require(codeExists, "Code not found");
       
       // ok to update address promo code
       _validatePromoCodeSetting(_code, _discountPercentage, _promoCodeOwnerAddress, _masterOwnerAddress, _baseOwnerPercentageOverride, _masterOwnerPercentageOverride);
        
       address oldPromoCodeOwner = promoCodes[_code].promoCodeOwnerAddress;
       address oldMasterOwner = promoCodes[_code].masterOwnerAddress;
        
       if(oldPromoCodeOwner != address(0)) {
           string[] storage oldOwnerCodes = ownerPromoCodes[oldPromoCodeOwner];
           for(uint i = 0; i < oldOwnerCodes.length; i++) {
               if(keccak256(bytes(oldOwnerCodes[i])) == keccak256(bytes(_code))) {
                   oldOwnerCodes[i] = oldOwnerCodes[oldOwnerCodes.length - 1];
                   oldOwnerCodes.pop();
                   break;
               }
           }
       }
        
       if(oldMasterOwner != address(0)) {
           string[] storage oldMasterCodes = ownerPromoCodes[oldMasterOwner];
           for(uint i = 0; i < oldMasterCodes.length; i++) {
               if(keccak256(bytes(oldMasterCodes[i])) == keccak256(bytes(_code))) {
                   oldMasterCodes[i] = oldMasterCodes[oldMasterCodes.length - 1];
                   oldMasterCodes.pop();
                   break;
               }
           }
       }

       promoCodes[_code].discountPercentage = _discountPercentage;
       promoCodes[_code].promoCodeOwnerAddress = _promoCodeOwnerAddress;
       promoCodes[_code].masterOwnerAddress = _masterOwnerAddress;
       promoCodes[_code].baseOwnerPercentageOverride = _baseOwnerPercentageOverride;
       promoCodes[_code].masterOwnerPercentageOverride = _masterOwnerPercentageOverride;
       ownerPromoCodes[_promoCodeOwnerAddress].push(_code);
       ownerPromoCodes[_masterOwnerAddress].push(_code);
    }
    // view function for ops
    function getAllPromoCodeInfo(uint256 fromIdx, uint256 toIdx) external view returns (PromoCode[] memory) {
        if (toIdx > allPromoCodes.length) {
            toIdx = allPromoCodes.length;
        }
        require(fromIdx < toIdx, "Invalid range");
        PromoCode[] memory promoCodeInfos = new PromoCode[](toIdx - fromIdx);
        for (uint i = fromIdx; i < toIdx; i++) {
            promoCodeInfos[i - fromIdx] = promoCodes[allPromoCodes[i]];
        }
        return promoCodeInfos;
    }

    function getPromoCodeLength() external view returns (uint256) {
        return allPromoCodes.length;
    }

    function getAllPromoCodes(uint256 fromIdx, uint256 toIdx) external view returns (string[] memory) {
        if (toIdx > allPromoCodes.length) {
            toIdx = allPromoCodes.length;
        }
        require(fromIdx < toIdx, "Invalid range");
        string[] memory promoCodeList = new string[](toIdx - fromIdx);
        for (uint i = fromIdx; i < toIdx; i++) {
            promoCodeList[i] = allPromoCodes[i];
        }
        return promoCodeList;
    }

    function getOwnerPromoCodes(address owner) external view returns (string[] memory) {
        uint256 length = ownerPromoCodes[owner].length;
        string[] memory promoCodeList = new string[](length);
        for (uint i = 0; i < length; i++) {
            promoCodeList[i] = ownerPromoCodes[owner][i];
        }
        return promoCodeList;
    }


    function getAllTierIds() external view returns (string[] memory) {
        return tierIds;
    }

    // util function
    function addressToString(address _addr) internal pure returns (string memory) {
        return Strings.toHexString(uint256(uint160(_addr)), 20);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.9;

import '@openzeppelin/contracts/access/Ownable.sol';
import '@openzeppelin/contracts/security/ReentrancyGuard.sol';

abstract contract IFWhitelistable is Ownable, ReentrancyGuard {
    // optional whitelist setter (settable by owner)
    address public whitelistSetter;

    // whitelist merkle root; if not set, then sale is open to everyone that has allocation
    bytes32 public whitelistRootHash;

    event SetWhitelistSetter(address indexed whitelistSetter);
    event SetWhitelist(bytes32 indexed whitelistRootHash);

    constructor() {
        whitelistSetter = _msgSender();
    }


    // Throws if called by any account other than the whitelist setter.
    modifier onlyWhitelistSetterOrOwner() {
        require(
            _msgSender() == whitelistSetter || _msgSender() == owner(),
            'caller not whitelist setter or owner'
        );
        _;
    }

    // Function for owner to set an optional, separate whitelist setter
    function setWhitelistSetter(address _whitelistSetter) public onlyOwner {
        whitelistSetter = _whitelistSetter;

        emit SetWhitelistSetter(_whitelistSetter);
    }

    // Function for owner or whitelist setter to set a whitelist; if not set, then everyone allowed
    function setWhitelist(bytes32 _whitelistRootHash)
        public
        onlyWhitelistSetterOrOwner
    {
        whitelistRootHash = _whitelistRootHash;

        emit SetWhitelist(_whitelistRootHash);
    }

    // purchase function when there is a whitelist
    function whitelistedPurchase(uint256 paymentAmount, bytes32[] calldata merkleProof) virtual public {}

    function withdrawGiveaway(bytes32[] calldata merkleProof) virtual public nonReentrant {}
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.9;

interface IIFRetrievableStakeWeight {
    function getTotalStakeWeight(uint24 trackId, uint80 timestamp)
        external
        view
        returns (uint192);

    function getUserStakeWeight(
        uint24 trackId,
        address user,
        uint80 timestamp
    ) external view returns (uint192);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.17;

import '../TieredSaleStructs.sol';

// Define the interface for IFTieredSaleHelper
interface IIFTieredSaleHelper {
    // Structs cannot be defined in interfaces, so keep them in the contract.

    // Check the tier whitelist using a Merkle proof
    function checkTierWhitelist(
        address user,
        bytes32[] calldata merkleProof,
        uint256 allocation,
        bytes32 whitelistRootHash
    ) external pure returns (bool);

    // Convert an address to a string representation
    function addressToString(address _addr)
        external
        pure
        returns (string memory);

    // Function to hash a message and recover the signer
    function getSigner(
        address sender,
        string memory tierId,
        uint256 allocation,
        bytes memory signature
    ) external pure returns (address);

    // View functions for promo codes and purchased amounts
    function getAllPromoCodes(
        string[] memory allPromoCodes,
        uint256 fromIdx,
        uint256 toIdx
    ) external view returns (string[] memory);

    function validatePromoCodeSetting(
        string memory code,
        uint8 discountPercentage,
        address promoCodeOwnerAddress,
        address masterOwnerAddress,
        uint8 baseOwnerPercentageOverride,
        uint8 masterOwnerPercentageOverride,
        uint8 max_base_owner_percentage,
        uint8 max_master_owner_percentage
    ) external pure;

    function isWalletPromoCode(string memory _promoCode)
        external
        pure
        returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}