// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol";

interface ITokenBurn {
    function burnFrom(address account, uint256 value) external;
}

/**
 * @title DAOStaking
 * @dev A contract for staking tokens with DAO features.
 */
contract DAOStaking is Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    event Staked(address indexed user, uint256 amount);
    event Claimed(address indexed user, uint256 amount);
    event Withdrawn(address indexed user, uint256 penalty);
    event UnStake(
        address indexed user,
        uint256 reward,
        uint256 amount,
        uint256 penalty
    );
    event AddReward(address indexed user, uint256 amount);
    event RegularWallet(
        address indexed owner,
        uint256 burnAmount,
        uint256 votingPower
    );
    event RemainingClaim(address indexed owner, uint256 amount);
    event IncreasePool(address indexed owner, uint256 amount);

    address public immutable token;


    uint256 constant private RW_BURN_AMOUNT = 10_000 * TOKEN_DECIMAL; // Regular Wallet burn amount
    uint256 internal _rwTotalBurnAmount;

    uint256 internal constant TOKEN_DECIMAL = 1e18;
    uint256 internal constant PRO_WOTING = 200;
    uint256 internal constant REG_WOTING = 1;

    uint256 internal immutable LAUNCH_TIME;
    uint256 internal immutable LOCK_PERIOD; // 2 years 
    uint256 internal constant STAKE_AMOUNT = 2_000_000 * TOKEN_DECIMAL;
    uint256 internal constant PENALTY = 20; // 20% penalty for early withdrawal
    uint256 internal constant DAILY_REWARD = 500_000 * TOKEN_DECIMAL;
    uint256 internal immutable REWARD_PERIOD;

    uint256 internal _poolSize;
    uint256 internal _totalStaked;
    uint256 internal _totalClaimedReward;


    uint256 internal _lastUpdateDay; 

    struct Stake {
        uint256 startTime;
        uint256 lastClaimTime;
        uint256 totalClaim;
        uint256 epochDay;
        bool isActive;
    }
    
    mapping(address => Stake) internal stakes;
    mapping(uint256 => uint256) internal daysUser;

    mapping(address => bool) internal _votingProWallet; // PRO Wallet
    mapping(address => bool) internal _votingRegWallet; // Regular Wallet

    /**
     * @notice Constructor to initialize the DAOStaking contract.
     * @param initialOwner The address of the initial owner.
     * @param tokenAddress The address of the token contract.
     * @param pool The initial size of the reward pool.
     * @param launchTime The timestamp of when staking starts.
     * @param lockPeriod The duration for which staked tokens are locked.
     * @param rewardPeriod The duration of each reward period.
     */
    constructor(
        address initialOwner,
        address tokenAddress,
        uint256 pool,
        uint256 launchTime,
        uint256 lockPeriod,
        uint256 rewardPeriod
    ) Ownable(initialOwner) {
        require(
            initialOwner != address(0),
            "STAKE:PRO:Owner's address cannot be zero."
        );
        require(
            tokenAddress != address(0),
            "STAKE:PRO:Token address cannot be zero."
        );
        require(
            launchTime > block.timestamp,
            "STAKE:PRO:Launch time must be greater than present time."
        );

        token = tokenAddress;
        // Token will be sent in to contract amount of poolsize when its deployed.
        _poolSize = pool;
        LAUNCH_TIME = launchTime;
        LOCK_PERIOD = lockPeriod;
        REWARD_PERIOD = rewardPeriod;
    }

    /**
     * @notice Allows a user to stake tokens into the DAO.
     */
    function stake() external nonReentrant {
        address account = _msgSender();
        require(
            IERC20(token).allowance(account, address(this)) >= STAKE_AMOUNT,
            "STAKE:PRO:Insufficient allowance."
        );
        _stake(account);
    }

    /**
     * @notice Allows a user to stake tokens using permit signature.
     * @param account The owner of the tokens. 
     * @param amount The amount of tokens to stake.
     * @param deadline The deadline for the permit signature.
     * @param v The `v` component of the permit signature.
     * @param r The `r` component of the permit signature.
     * @param s The `s` component of the permit signature.
     */
    function stakeWithPermit(
        address account,
        uint256 amount,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external {
        require(
            amount == STAKE_AMOUNT,
            "STAKE:PRO:Exactly 2 milion token must be staked."
        );
        IERC20Permit(token).permit(
            account,
            address(this),
            amount,
            deadline,
            v,
            r,
            s
        );
        _stake(account); 
    }
    /**
     * @dev Internal function for staking tokens.
     * @param account Address of the account to stake tokens.
     */
    function _stake(address account) private {
        // Ensure staking time has started
        uint256 currentTime = block.timestamp;
        require(
            currentTime >= LAUNCH_TIME,
            "STAKE:PRO:Staking time has not started yet."
        );

        // Ensure staking period is still active
        uint256 currentDay = _currentDay();
        require(
            currentDay < _totalPeriod(),
            "STAKE:PRO:All tokens have been distributed."
        );

        // Ensure user has sufficient balance to stake
        require(
            IERC20(token).balanceOf(account) >= STAKE_AMOUNT,
            "STAKE:PRO:Insufficient balance."
        );

        Stake storage user = stakes[account];
        // Ensure user is not already staked
        require(!user.isActive, "STAKE:PRO:Already staked.");

        // Transfer tokens from user to contract
        IERC20(token).safeTransferFrom(account, address(this), STAKE_AMOUNT);

        // Update user stake information
        user.startTime = currentTime;
        user.lastClaimTime = 0;
        user.epochDay = currentDay + 1;
        user.isActive = true;

        // Update global variables
        _votingProWallet[account] = true;
        _totalStaked += STAKE_AMOUNT;
        _update(currentDay + 1);

        emit Staked(account, STAKE_AMOUNT);
    }

    /**
     * @notice Allows a user to claim their rewards.
     */
    function claim() external nonReentrant {
        address account = _msgSender();
        Stake storage user = stakes[account];
        require(user.isActive, "STAKE:PRO:You have none staked tokens.");
        uint256 currentDay = _currentDay();
        _update(currentDay);
        uint256 reward = _calculateReward(user.epochDay, currentDay);
        require(reward > 0, "STAKE:PRO:No reward have been earned yet.");

        user.lastClaimTime = block.timestamp;
        user.totalClaim += reward;
        user.epochDay = currentDay;
        _totalClaimedReward += reward;

        IERC20(token).safeTransfer(account, reward);

        _poolSize -= reward;

        emit Claimed(account, reward);
    }

    /**
     * @notice Unstakes tokens for the sender.
     */
    function unStake() external nonReentrant {
        address account = _msgSender();
        Stake storage user = stakes[account];

        // Ensure user has an active stake
        require(user.isActive, "STAKE:PRO:No active stake");

        uint256 currentTime = block.timestamp;
        uint256 currentDay = _currentDay();

        // Ensure user cannot unstake before their period is up
        require(
            currentDay >= user.epochDay,
            "STAKE:PRO:You cannot exit before period is up."
        );

        uint256 penaltyAmount;
        if (currentTime < user.startTime + LOCK_PERIOD) {
            penaltyAmount = PENALTY * (STAKE_AMOUNT / 100);
            _poolSize += penaltyAmount;
            emit Withdrawn(account, penaltyAmount);
        }

        uint256 returnAmount = STAKE_AMOUNT - penaltyAmount;

        // Give user any remaining claim rights
        uint256 reward = _calculateReward(user.epochDay, currentDay);
        if (reward > 0) {
            user.totalClaim += reward;
            returnAmount += reward;
            _totalClaimedReward += reward;
            _poolSize -= reward;
        }

        // Update global variables
        _totalStaked -= STAKE_AMOUNT;

        user.lastClaimTime = currentTime;
        user.epochDay = currentDay;
        user.isActive = false;

        _votingProWallet[account] = false;

        // Transfer remaining amount to user
        IERC20(token).safeTransfer(account, returnAmount);

        _update(currentDay + 1);

        emit UnStake(account, reward, returnAmount, penaltyAmount);
    }

    /**
     * @notice In order to lengthen stake contracts time, may increase the staking reward pool.
     * @param amount Stake amount can increase.
     */
    function increasePool(uint256 amount) external nonReentrant {
        IERC20(token).safeTransferFrom(_msgSender(), address(this), amount);
        _poolSize += amount;
        emit IncreasePool(_msgSender(), amount);
    }

    /**
     * @notice Owner can send to account rest amount token after contracts end.
     * @param account Transfer token to account
     */
    function remainingClaim(address account) external onlyOwner nonReentrant {
        require(_currentDay() >= _totalPeriod(), "STAKE:PRO:Distribution is still continue.");
        require(_totalStaked / STAKE_AMOUNT == 0, "STAKE:PRO:There is still pro wallet account at the contract.");
        require(account != address(this), "STAKE:PRO:You cannot send token to staking contract.");
        IERC20(token).safeTransfer(account, _poolSize);
        _poolSize = 0; 
        emit RemainingClaim(account, _poolSize);
    }

    // ------------------------------------------------------------
    // ===================== INTERNAL FUNCTIONS
    // ------------------------------------------------------------
    /**
     * @dev Updates the stake contract for the given day if necessary.
     * @param day The day to update the contract for.
     */
    function _update(uint256 day) internal {
        if (_lastUpdateDay <= day) {
            daysUser[day] = _totalStaked / STAKE_AMOUNT;
            _lastUpdateDay = day;
        }
    }
    /**
     * @dev Calculates the total reward to be distributed between two epoch days.
     * @param epochDay The starting epoch day.
     * @param claimDay The ending epoch day.
     * @return The total reward for the given period.
     */
    function _calculateReward(
        uint256 epochDay,
        uint256 claimDay
    ) internal view returns (uint256) {
        uint256 totalReward;
        uint256 lastUsers;
        for (uint256 i = epochDay; i < claimDay; i++) {
            uint256 dayUser = daysUser[i];
            if (dayUser != 0) {
                lastUsers = dayUser;
            }
            if(lastUsers > 0){
                totalReward += DAILY_REWARD / lastUsers; 
            }
        }
        return totalReward;
    }
    /**
     * @dev Calculates the timestamp for the next reward distribution. 
     * @param epochDay The epoch day to calculate the next reward for.
     * @return The timestamp for the next reward distribution.
     */
    function _nextRewardTime(uint256 epochDay) internal view returns (uint256) {
        uint256 daysPassed = (block.timestamp - LAUNCH_TIME) / REWARD_PERIOD;
        if (_currentDay() >= epochDay) {
            daysPassed += 1;
        } else {
            daysPassed += 2;
        }
        return LAUNCH_TIME + (daysPassed * REWARD_PERIOD);
    }
    /**
     * @dev Retrieves the current epoch day.
     * @return The current epoch day.
     */
    function _currentDay() internal view returns (uint256) {
        uint256 currentTime = block.timestamp;
        if (LAUNCH_TIME > currentTime) {
            return 0;
        }
        if (currentTime >= _endTime()) {
            return _totalPeriod(); 
        }
        return (currentTime - LAUNCH_TIME) / REWARD_PERIOD;
    }
    /**
     * @dev Calculates the total period of the stake contract.
     * @return The total period of the stake contract.
     */
    function _totalPeriod() internal view returns (uint256) { 
        return ((_poolSize + _totalClaimedReward) / DAILY_REWARD) + 1;
    }
    /**
     * @dev Calculates the end timestamp of the stake contract.
     * @return The end timestamp of the stake contract.
     */
    function _endTime() internal view returns (uint256) { 
        return LAUNCH_TIME + (_totalPeriod() * REWARD_PERIOD);
    }

    // ------------------------------------------------------------
    // ===================== PUBLIC FUNCTIONS
    // ------------------------------------------------------------

    /**
     * @notice Retrieves the voting power associated with an account.
     * @param account Address of the account to check.
     * @return The voting power of the account.
     */
    function votingPower(address account) public view returns (uint256) {
        return
            _votingProWallet[account]
                ? PRO_WOTING
                : _votingRegWallet[account]
                    ? REG_WOTING
                    : 0;
    }

    /**
     * @notice Checks if an account is a regular wallet.
     * @param account Address of the account to check.
     * @return A boolean indicating whether the account is a regular wallet.
     */
    function isRegularWallet(address account) public view returns (bool) {
        return _votingRegWallet[account];
    }

    /**
     * @notice Retrieves information about the stake account.
     * @param account Address of the stake account.
     * @return startTime The timestamp when the stake started.
     * @return lastClaimTime The timestamp of the last claim.
     * @return totalClaim Total claimed rewards.
     * @return unlockAmount Amount of rewards available for claiming.
     * @return nextUnlockTime Timestamp of the next reward unlock.
     * @return nextUnlockAmount Amount of rewards to unlock next.
     * @return epochDay The current day of the stake epoch.
     * @return endTime The timestamp when the stake ends.
     * @return power Voting power associated with the account.
     * @return isActive Whether the stake account is active.
     */
    function accountInfo(
        address account
    )
        public
        view
        returns (
            uint256 startTime,
            uint256 lastClaimTime,
            uint256 totalClaim,
            uint256 unlockAmount,
            uint256 nextUnlockTime,
            uint256 nextUnlockAmount,
            uint256 epochDay,
            uint256 endTime,
            uint256 power,
            bool isActive
        )
    {
        Stake memory user = stakes[account];

        startTime = user.startTime;
        lastClaimTime = user.lastClaimTime;
        totalClaim = user.totalClaim;
        epochDay = user.epochDay;
        isActive = user.isActive;

        power = votingPower(account);

        if (user.isActive) {
            unlockAmount = _calculateReward(user.epochDay, _currentDay());
            nextUnlockTime = _nextRewardTime(user.epochDay);
            nextUnlockAmount = DAILY_REWARD / (_totalStaked / STAKE_AMOUNT);
            endTime = user.startTime + LOCK_PERIOD; 
        }
    }


    /**
     * @notice Retrieves general information about the staking contract.
     * @return launchTime Timestamp of the staking contract launch.
     * @return rewardPeriod Duration of each reward period.
     * @return lastUpdateDay Last day the contract was updated.
     * @return currentDay The current day of the staking contract
     * @return poolSize Total size of the staking pool.
     * @return dailyReward The daily reward rate
     * @return totalStaked Total amount of tokens staked.
     * @return totalClaimedReward Total amount of claimed rewards.
     * @return userCount Number of users who have staked.
     * @return rwTotalBurnAmount Total amount burned from regular wallets.
     */
     function info() public view returns(
        uint256 launchTime,
        uint256 rewardPeriod,
        uint256 lastUpdateDay,
        uint256 currentDay,
        uint256 poolSize,
        uint256 dailyReward,
        uint256 totalStaked,
        uint256 totalClaimedReward,
        uint256 userCount,
        uint256 rwTotalBurnAmount
    ){
        return (
            LAUNCH_TIME,
            REWARD_PERIOD, 
            _lastUpdateDay, 
            _currentDay(), 
            _poolSize, 
            DAILY_REWARD,
            _totalStaked, 
            _totalClaimedReward, 
            _totalStaked / STAKE_AMOUNT, 
            _rwTotalBurnAmount
        );
    }

    /**
     * @notice Retrieves the number of users on a specific day.
     * @param day The day for which to retrieve the user count.
     * @return The number of users on the specified day.
     */
    function getDayUser(uint256 day) public view returns(uint256) {

        uint256 currentDay = day;
        while (true) {
            if (daysUser[currentDay] != 0) {
                return daysUser[currentDay];
            }
            if (currentDay == 0) {
                break;
            }
            currentDay--;
        }
        return 0;
    }

    /**
     * @notice Burns tokens from the sender's account and adds voting power.
     */
    function burnRW() public {
        _addVotingPower(_msgSender());
    }

    /**
     * @notice Burns tokens with permit and adds voting power.
     * @param account Address of the account to burn tokens from.
     * @param amount Amount of tokens to burn.
     * @param deadline Expiry timestamp for the permit.
     * @param v Component of the signature.
     * @param r Component of the signature.
     * @param s Component of the signature.
     */
    function burnRWWithPermit(
        address account,
        uint256 amount,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) public {
        require(
            amount == RW_BURN_AMOUNT,
            "STAKE:REGULAR:Exactly 10 thousands token must be staked"
        );
        IERC20Permit(address(token)).permit(
            account,
            address(this),
            amount,
            deadline,
            v,
            r,
            s
        );
        _addVotingPower(account);
    }

    /**
     * @dev Adds voting power to an account and emits an event.
     * @param account Address of the account to add voting power to.
     */
    function _addVotingPower(address account) internal {
        require(!_votingRegWallet[account], "STAKE:REGULAR:This address is already a regular wallet.");
        ITokenBurn(token).burnFrom(account, RW_BURN_AMOUNT);
        _votingRegWallet[account] = true;
        emit RegularWallet(account, RW_BURN_AMOUNT, REG_WOTING);
        _rwTotalBurnAmount += RW_BURN_AMOUNT;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/DAOStaking.sol": "DAOStaking"
  },
  "debug": {
    "revertStrings": "debug"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}