EDUM

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol


// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;


/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol


// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;




/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

// File: contracts/EDUM.sol


pragma solidity ^0.8.0;



contract EDUM is ERC20, Ownable {
    // Initial totalSupply
    uint256 private constant TOTAL_SUPPLY = 2000000000;

    /**
     * @dev transferWithLocked function can only be called by a controller 
     */
    modifier onlyController {
        require(isController[_msgSender()]);
        _;
    }

    /**
     * @dev Lockup event 
     * @param addr 수신 주소 
     * @param amount Lockup 수량
     * @param timestamp Release 시간
     *        isListed == true  -> 절대 시간
     *        isListed == false -> listingDate 상대 시간   간 
     * @param isListed transferPreTimelock(상장 전), transferTimelock(상장 후) 구분
     */   
    event Locked(address indexed addr, uint256 amount, uint timestamp, bool isListed);
    
    /**
     * @dev Lising event 
     * @param timestamp Listing Date
     */   
    event Listing(uint timestamp);

    /**
     * @dev Specify the lockup quantity and release time. 
     * @dev Lockup Lockup quantity 
     * @dev releaseTime Release time
     */
    struct TokenLockInfo {
        uint256 amount;                 // locked amount
        uint256 releaseTime;            // unix timestamp
    }

    /**
     * @dev Account 별 Lockup 정보 저장 
     * @dev minReleaeTime lockInfo 리스트 중 가장 작은 releaseTime 값.
     *      transferPreTimelock 함수 호출 시에는 0 으로 세팅 됨. (_refactoringPreTimelock 세팅 됨) 
     *      transferTimeLock 호출 시에는 값이 세팅 됨
     * @dev lockInfo TokenLockInfo 배열
     */
    struct TokenLockState {
        uint256 minReleaseTime;
        TokenLockInfo[] lockInfo;     // Multiple token locks can exist
    }

    // mapping for TokenLockState 
    mapping(address => TokenLockState) public lockStates;

    // Mapping from controllers to controller status.
    mapping(address => bool) internal isController;

    // Array of controllers.
    address[] internal controllers;  

    // 상장 일 
    uint256 listingDate = 0;

    /**
     * @dev Initialize EDUM.
     *      총 발행량은 20억개 (추가 상장 불가)
     */
    constructor() ERC20('EDUM', 'EDUM') {
        _mint(_msgSender(), TOTAL_SUPPLY*10**decimals());
    }

    /**
     * @dev 상장일 설정. 한번만 불릴 수 있음 
     *      transferPreTimelock 의 ReleaseTime 이 확정 됨
     * @param _listingDate 상장일
     */
    function setListingDate(uint _listingDate) external onlyOwner {
        require(listingDate == 0, "listingDate already set");

        // listingDate = block.timestamp;
        if (_listingDate == 0) {
            listingDate = block.timestamp;
        } else {
            listingDate = _listingDate;
        }

        emit Listing(listingDate);
    }

    /**
     * @dev Get listingDate 
     * @return listingDate Date of listing
     */
    function getListingDate() public view returns(uint256) {
        return listingDate;
    }

    /**
     * @dev Set list of controllers.
     * @param controllerList List of controller addresses.
     */
    function setControllers(address[] memory controllerList) public onlyOwner {
        uint ii;
        for (ii = 0; ii < controllers.length; ii++) {
            isController[controllers[ii]] = false;
        }
        for (ii = 0; ii < controllerList.length; ii++) {
            isController[controllerList[ii]] = true;
        }
        controllers = controllerList;
    }    

    /**
     * @dev Get list of controllers.
     * @return List of address of all the controllers.
     */
    function getControllers() public view returns(address[] memory) {
        return controllers;
    }    

    /**
     * @dev don't send eth directly to token contract 
     */
    receive() external payable {
        revert("Don't accept ETH");
    }

   /**
    * @dev transferPreTimelock 으로 추가 된 Lockup ReleaseTime 정보를 세팅.
    *      _beforeTransfer / transferTimelock 에서 호출. 
    * @param _addr address.
    */
    function _refactoringPreTimelock(address _addr) internal {
        uint length = lockStates[_addr].lockInfo.length;
        // transferPreTimelock 호출이 된 상태 && 상장 후 첫번째 호출 시에만 진행 됨. 
        if ((length > 0) &&                                 // 처리할 내용이 있는가
            (lockStates[_addr].minReleaseTime == 0) &&      // transferPreTimelock 인가 & 이미 처리가 되었는가  
            (listingDate > 0))                              // 상장된 상태인가
        {
            uint releaseTime;
            for (uint ii = 0; ii < length; /* unchecked inc */) {
                releaseTime = lockStates[_addr].lockInfo[ii].releaseTime + listingDate; 
                lockStates[_addr].lockInfo[ii].releaseTime = releaseTime; 
                if (lockStates[_addr].minReleaseTime == 0 || lockStates[_addr].minReleaseTime > releaseTime) {
                   lockStates[_addr].minReleaseTime = releaseTime; 
                }
                unchecked {
                    ii++;
                }
            }
        }
    }

   /**
    * @dev Release 된 Lock 정보를 삭제 
    * @param _addr address.
    */
    function _releaseLockInfo(address _addr) internal {
        uint256 lockCount = 0;
        uint256 lockLength;

        // 상장이 되지 않은 상태에서는 Release 될 Lock 정보는 없음. 
        if (listingDate==0) return;

        // transferPreTimelock 정보 refactoring 
        _refactoringPreTimelock(_addr);

        // 현재 시점에서 Release 할 Lock 정보는 없음.
        if (lockStates[_addr].minReleaseTime > block.timestamp) return;

        lockStates[_addr].minReleaseTime = 0;
        lockLength = lockStates[_addr].lockInfo.length; 
        for (uint256 ii = 0; ii < lockLength; /* unchecked inc */) {
            // 아직 Release 시간이 되지 않은 상태 이면 남겨둔다.
            if (lockStates[_addr].lockInfo[ii].releaseTime > block.timestamp) {   
                // Update minReleaseTime
                if ((lockStates[_addr].minReleaseTime == 0) || 
                    (lockStates[_addr].minReleaseTime > lockStates[_addr].lockInfo[ii].releaseTime)) 
                {
                    lockStates[_addr].minReleaseTime = lockStates[_addr].lockInfo[ii].releaseTime;
                }
                lockStates[_addr].lockInfo[lockCount] = lockStates[_addr].lockInfo[ii];
                unchecked {
                    lockCount++;
                }
            }
            unchecked {
                ii++;
            }
        }

        if (lockCount == 0) {
            // 모든 Lock 정보가 삭제되었을 경우 
            delete lockStates[_addr];
        } else {
            // 삭제된 Lock 정보 수 만큰 Pop 
            uint256 removeCount = lockStates[_addr].lockInfo.length - lockCount;            
            for (uint256 ii = 0; ii < removeCount; /* unchecked inc */) {
                lockStates[_addr].lockInfo.pop();
                unchecked {
                    ii++;
                }
            }
        }
    }

  /**
   * @dev Get the amount of locked tokens 
   * @param _addr address.
   * @return totalLocked Amount of locked tokens.
   */
    function getLockedBalance(address _addr) public view returns (uint256) {
        uint256 totalLocked = 0;
        uint256 lockLength;
        uint256 releaseTime;

        lockLength = lockStates[_addr].lockInfo.length; 
        for (uint256 ii = 0; ii < lockLength; /* unchecked inc */) {
            if (listingDate == 0) {
                // 아직 상장이 되지 않은 상태이면 무조건 Lock 상태
                totalLocked += lockStates[_addr].lockInfo[ii].amount;
            } else {
                releaseTime = lockStates[_addr].lockInfo[ii].releaseTime;
                // 상장 후 _refactoringPreTimelock 이 호출되지 않았을 경우 listingDate 기준으로 ReleaseTime 계산
                if (lockStates[_addr].minReleaseTime == 0) {
                    releaseTime += listingDate;
                }

                if (releaseTime > block.timestamp) {
                    totalLocked += lockStates[_addr].lockInfo[ii].amount;
                }
            }
            unchecked {
                ii++;
            }
        }

        return totalLocked;
    }

   /**
    * @dev Hook that is called before any transfer of tokens. 
    * @param from The address to transfer from.
    * @param to The address to transfer to.
    * @param amount The amount to be transferred.
    */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal override {
        super._beforeTokenTransfer(from, to, amount);

        // Release 되어야 할 Lock 정보 삭제
        _releaseLockInfo(from);

        if (from != address(0)) {       // Skip when mint
            uint256 locked = getLockedBalance(from);
            uint256 accountBalance = balanceOf(from);
            require(accountBalance - locked >= amount, "Transfer amount exeeds balance or some amounts are locked.");
        }
    }

   /**
    * @dev 토큰 Lock 전송. 상장 후 호출 가능. 
    * @param _addr The address to transfer to.
    * @param _amount The amount to be transferred.
    * @param _releaseTime The timestamp to unlock token.
    * @return The result of transferTimelock
    */
    function transferTimelock(address _addr, uint256[] memory _amount, uint256[] memory _releaseTime)
        external
        onlyController
        returns(bool)
    {
        require(listingDate > 0, "Token is not listed");
        return _transferTimelock(_addr, _amount, _releaseTime);
    }

   /**
    * @dev 토큰 Lock 전송. 상장 전 호출 가능. 
    * @param _addr The address to transfer to.
    * @param _amount The amount to be transferred.
    * @param _releaseTime The timestamp to unlock token.
    * @return The result of transferPreTimelock
    */
    function transferPreTimelock(address _addr, uint256[] memory _amount, uint256[] memory _releaseTime)
        external
        onlyController
        returns(bool)
    {
        require(listingDate == 0, "Token is listed");
        return _transferTimelock(_addr, _amount, _releaseTime);
    }

   /**
    * @dev 토큰 Lock 전송
    * @param _addr The address to transfer to.
    * @param _amount The amount to be transferred.
    * @param _releaseTime The timestamp to unlock token.
    * @return The result of transferTimelock
    */
    function _transferTimelock(address _addr, uint256[] memory _amount, uint256[] memory _releaseTime) 
        internal
        onlyController 
        returns (bool)
    {
        require(_amount.length == _releaseTime.length, "amount and releaeTime must have save length");

        uint ii;
        uint256 totalAmount = 0;
        uint256 amountLength = 0;

        // transferPreTimelock 정보가 있을 경우 Release 정보 업데이트
        _refactoringPreTimelock(_addr);

        amountLength = _amount.length; 
        for (ii = 0; ii < amountLength; /* unchecked inc */) {
            totalAmount += _amount[ii]; 

            // Add lockInfo
            lockStates[_addr].lockInfo.push(TokenLockInfo(_amount[ii], _releaseTime[ii]));

            // If token is listed, update minReleaseTime
            if (listingDate > 0) {
                if ((lockStates[_addr].minReleaseTime == 0) || (lockStates[_addr].minReleaseTime > _releaseTime[ii])) {
                    lockStates[_addr].minReleaseTime = _releaseTime[ii];
                }
            }
            emit Locked(_addr, _amount[ii], _releaseTime[ii], listingDate>0);

            unchecked {
                ii++;
            }
        }

        transfer(_addr, totalAmount);

        return true;
    }

   /**
    * @dev 계정별 TokenLockState 정보 리턴 
    * @param _addr address
    * @return The TokenLockState of _addr
    */
    function getTokenlockStates(address _addr) external view returns(TokenLockState memory) {
        return lockStates[_addr];
    }

   /**
    * @dev Multiple transfer function (onlyOwner)
    * @param _to address list 
    * @param _amount amount list 
    */
    function multiTransfer(address[] memory _to, uint256[] memory _amount) external onlyOwner {
        uint transferCount = _to.length;

        require(_to.length == _amount.length, "to and amount must have save length");

        for (uint ii = 0; ii < transferCount; ) {
            transfer(_to[ii], _amount[ii]);
            unchecked {
                ii++;
            }
        }
    }

   /**
    * @dev Destroy amount of tokens from account 
    * @dev Reduce totalSupply 
    * @dev A locked amount of token cannot be burned. 
    * @param _amount Amount to burn 
    */
    function burn(uint256 _amount) external {
        _burn(_msgSender(), _amount);
    }

    /*
    /////////////////////////////////
    // for test
    /////////////////////////////////
    function getLockedCount(address _account) public view returns (uint) {
        return lockStates[_account].lockInfo.length;
    }

    event Dummy(uint value);
    function dummy() public {
        emit Dummy(0);
    }
    */
}

{
  "compilationTarget": {
    "EDUM.sol": "EDUM"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}