// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

import "./IERC20Metadata.sol";
import "./Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) internal _balances;

    mapping(address => mapping(address => uint256)) internal _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() external view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() external view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() external view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() external view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) external view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) external virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) external virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) external virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) external virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

import "./IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;

import "./ERC20.sol";
///////////////////////////////////////////////
// QANX STARTS HERE, OPENZEPPELIN CODE ABOVE //
///////////////////////////////////////////////

contract QANX is ERC20 {

    /// @notice Represents a lock which might be applied on an address
    /// @dev Lock logic is described in the _applyLock() method
    struct Lock {
        uint256 tokenAmount;    /// How many tokens are locked
        uint256 unlockPerSec;   /// How many tokens are unlockable each sec from hl -> sl
        uint64 hardLockUntil;   /// Until when no locked tokens can be accessed
        uint64 softLockUntil;   /// Until when locked tokens can be gradually released
        uint64 lastUnlock;      /// Last gradual unlock time (softlock period)
        uint64 allowedHops;     /// How many transfers left with same lock params
    }

    /// @notice Cheque signer address
    /// @dev This is compared against a recovered secp256k1 signature
    address private chequeSigner;

    /// @notice This maps used cheques so they can not be encashed twice
    /// @dev Ensures that every unique cheque paramset can be encashed once
    mapping (bytes32 => bool) private chequesEncashed;

    /// @notice This maps lock params to certain addresses which received locked tokens
    /// @dev Lookup table for locks assigned to specific addresses
    mapping (address => Lock) private _locks;    

    /// @notice Emitted when a lock is applied on an account
    /// @dev The first param is indexed which makes it easy to listen to locks applied to a specific account
    event LockApplied(address indexed account, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops);

    /// @notice Emitted when a lock is removed from an account
    /// @dev The account param is indexed which makes it easy to listen to locks getting removed from a specific account
    event LockRemoved(address indexed account);

    /// @notice Emitted when a lock amount is decreased on an account
    /// @dev The first param is indexed which makes it easy to listen to locked amount getting decreased on a specific account
    event LockDecreased(address indexed account, uint256 amount);

    /// @notice Emitted when a the permitted cheque signer address is changed
    /// @dev This will be new address the ecrecover result is compared against
    event ChequeSignerUpdated(address signer);

    /// @notice Initialize an erc20 token based on the openzeppelin version
    /// @dev Sets the initial cheque signer to the deployer address and mints total supply to the contract itself
    constructor() ERC20("QANX Token", "QANX") {

        // Assign deployer as cheque signer initially
        chequeSigner = msg.sender;

        // Initially mint total supply to contract itself
        _mint(address(this), 3_333_333_000 * 1e18);
    }

    /// @notice Refuse any kind of payment to the contract
    /// @dev This is the implicit default behavior, it just exists for verbosity
    receive() external payable {
        revert();
    }

    /// @notice Refuse any kind of payment to the contract
    /// @dev This is the implicit default behavior, it just exists for verbosity
    fallback() external payable {
        revert();
    }

    /// @notice Ability to update cheque signer
    /// @dev Make sure to externally double check the new cheque signer address!
    /// @param _newChequeSigner The address which new cheque signatures will be compared against from now
    function setChequeSigner(address _newChequeSigner) external {
        require(msg.sender == chequeSigner && _newChequeSigner != address(0), "Invalid cheque signer");
        chequeSigner = _newChequeSigner;
        emit ChequeSignerUpdated(chequeSigner);
    }

    /// @notice Method to encash a received cheque
    /// @dev Ability to encash offline signed cheques using on-chain signature verification.
    /// Please note that cheques are expected to be one cheque per address, so using CID as
    /// a nonce is intentional and works as designed.
    /// @param beneficiary The address which will receive the tokens
    /// @param amount The amount of tokens the beneficiary will receive
    /// @param hardLockUntil The UNIX timestamp until which the tokens are not transferable
    /// @param softLockUntil The UNIX timestamp until which the tokens are gradually unlockable
    /// @param allowedHops How many times the locked tokens can be transferred further
    /// @param signature The secp256k1 signature of CID as per EIP-2098 (r + _vs)
    function encashCheque(address beneficiary, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops, bytes32[2] calldata signature) external {

        // Calculate cheque id
        bytes32 cid = keccak256(abi.encode(block.chainid, address(this), beneficiary, amount, hardLockUntil, softLockUntil, allowedHops));

        // Verify cheque signature
        require(verifyChequeSignature(cid, signature), "Cheque signature is invalid!");

        // Make sure this cheque was not encashed before
        require(!chequesEncashed[cid], "This cheque was encashed already!");

        // Mark cheque as encashed
        chequesEncashed[cid] = true;
        
        // If any lock related params were defined as non-zero
        if (hardLockUntil > 0) {

            // Encash through a locked transfer
            _transferLocked(address(this), beneficiary, amount, hardLockUntil, softLockUntil, allowedHops);
            return;
        }

        // Otherwise encash using a normal transfer
        _transfer(address(this), beneficiary, amount);
    }

    /// @notice Transfer function with lock parameters
    /// @dev Wraps the _transferLocked internal method
    /// @param recipient The address whose locked balance will be credited
    /// @param amount The amount which will be credited to the recipient address
    /// @param hardLockUntil The UNIX timestamp until which the tokens are not transferable
    /// @param softLockUntil The UNIX timestamp until which the tokens are gradually unlockable
    /// @param allowedHops How many times the locked tokens can be transferred further
    /// @return Success
    function transferLocked(address recipient, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops) external returns (bool) {
        _transferLocked(_msgSender(), recipient, amount, hardLockUntil, softLockUntil, allowedHops);
        return true;
    }

    /// @notice Transferfrom function with lock parameters
    /// @dev Wraps the _transferLocked internal method
    /// @param sender The address whose balance will be debited
    /// @param recipient The address whose locked balance will be credited
    /// @param amount The amount which will be credited to the recipient address
    /// @param hardLockUntil The UNIX timestamp until which the tokens are not transferable
    /// @param softLockUntil The UNIX timestamp until which the tokens are gradually unlockable
    /// @param allowedHops How many times the locked tokens can be transferred further
    /// @return Success
    function transferFromLocked(address sender, address recipient, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops) external returns (bool) {

        // Query current allowance of spender
        uint256 currentAllowance = _allowances[sender][_msgSender()];

        // If the allowance is not unlimited
        if (currentAllowance != type(uint256).max) {

            // Ensure sufficient allowance and decrease it by current amount
            require(currentAllowance >= amount, "ERC20: transfer amount exceeds allowance");
            unchecked {
                _approve(sender, _msgSender(), currentAllowance - amount);
            }
        }

        // Perform locked transfer
        _transferLocked(sender, recipient, amount, hardLockUntil, softLockUntil, allowedHops);
        return true;
    }

    /// @notice Unlocks all unlockable tokens of a particular account
    /// @dev Calculates the unlockable amount based on the private _locks mapping
    /// @param account The address whose tokens should be unlocked
    /// @return Success
    function unlock(address account) external returns (bool) {

        // Lookup lock
        Lock storage lock = _locks[account];

        // Calculate unlockable balance
        uint256 unlockable = unlockableBalanceOf(account);

        // Only addresses owning locked tokens and bypassed hardlock time are unlockable
        require(unlockable > 0 && lock.tokenAmount > 0, "No unlockable tokens!");

        // Set last unlock time, deduct from locked balance & credit to regular balance
        lock.lastUnlock = uint64(block.timestamp);
        lock.tokenAmount = lock.tokenAmount - unlockable;
        _balances[account] += unlockable;

        // If no more locked tokens left, remove lock object from address
        if(lock.tokenAmount == 0){
            delete _locks[account];
            emit LockRemoved(account);
        }

        // Unlock successful
        emit LockDecreased(account, unlockable);
        return true;
    }

    /// @notice Returns the locked token balance of a particular account
    /// @dev Reads the private _locks mapping to return data
    /// @param account The address whose locked balance should be read
    /// @return The number of locked tokens owned by the account
    function lockedBalanceOf(address account) external view returns (uint256) {
        return _locks[account].tokenAmount;
    }

    /// @notice Returns the unlocked token balance of a particular account
    /// @dev Reads the internal _balances mapping to return data
    /// @param account The address whose unlocked balance should be read
    /// @return The number of unlocked tokens owned by the account
    function unlockedBalanceOf(address account) external view returns (uint256) {
        return _balances[account];
    }

    /// @notice Returns lock information of a given address
    /// @dev Reads a whole entry of the private _locks mapping to return data
    /// @param account The address whose lock object should be read
    /// @return The lock object of the particular account
    function lockOf(address account) external view returns (Lock memory) {
        return _locks[account];
    }

    /// @notice Return the balance of unlocked and locked tokens combined
    /// @dev This overrides the OZ version for combined output
    /// @param account The address whose total balance is looked up
    /// @return The combined (unlocked + locked) balance of the particular account
    function balanceOf(address account) external view override returns (uint256) {
        return _balances[account] + _locks[account].tokenAmount;
    }

    /// @notice Calculates the number of unlockable tokens of a particular account
    /// @dev Dynamically calculates unlockable balance based on current block timestamp
    /// @param account The address whose unlockable balance is calculated
    /// @return The amount of tokens which can be unlocked at the current block timestamp
    function unlockableBalanceOf(address account) public view returns (uint256) {

        // Lookup lock
        Lock memory lock = _locks[account];

        // If the hardlock has not passed yet, there are no unlockable tokens
        if(block.timestamp < lock.hardLockUntil) {
            return 0;
        }

        // If the softlock period passed, all currently tokens are unlockable
        if(block.timestamp > lock.softLockUntil) {
            return lock.tokenAmount;
        }

        // Otherwise the proportional amount is unlockable
        uint256 unlockable = (block.timestamp - lock.lastUnlock) * lock.unlockPerSec;
        return lock.tokenAmount < unlockable ? lock.tokenAmount : unlockable;
    }

    /// @dev Abstract method to execute locked transfers
    /// @param sender The address whose balance will be debited
    /// @param recipient The address whose locked balance will be credited
    /// @param amount The amount which will be credited to the recipient address
    /// @param hardLockUntil The UNIX timestamp until which the tokens are not transferable
    /// @param softLockUntil The UNIX timestamp until which the tokens are gradually unlockable
    /// @param allowedHops How many times the locked tokens can be transferred further
    /// @return Success
    function _transferLocked(address sender, address recipient, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops) internal returns (bool) {

        // Perform zero address validation
        require(recipient != address(0), "ERC20: transfer to the zero address");

        // Lookup sender balance
        uint256 sBalance = _balances[sender];

        // Lookup lock of sender and recipient
        Lock storage rLock = _locks[recipient];
        Lock storage sLock = _locks[sender];

        // Only a single set of lock parameters allowed per recipient
        if (rLock.tokenAmount > 0){
            require(
                hardLockUntil == rLock.hardLockUntil &&
                softLockUntil == rLock.softLockUntil &&
                allowedHops == rLock.allowedHops
            , "Only one lock params per address allowed!");
        }

        // Sender must have enough tokens (unlocked + locked balance combined)
        require(sBalance + sLock.tokenAmount >= amount, "Transfer amount exceeds balance");

        // If sender has enough unlocked balance, then lock params can be chosen
        if(sBalance >= amount){

            // Deduct sender balance
            unchecked {
                _balances[sender] = sBalance - amount;
            }

            // Apply lock
            return _applyLock(sender, recipient, amount, hardLockUntil, softLockUntil, allowedHops);
        }

        // Otherwise require that the chosen lock params are same / stricter (allowedhops) than the sender's
        require(
            hardLockUntil >= sLock.hardLockUntil && 
            softLockUntil >= sLock.softLockUntil && 
            allowedHops < sLock.allowedHops
            , "Only same / stricter lock params allowed!"
        );

        // If sender has enough locked balance
        if(sLock.tokenAmount >= amount){

            // Decrease locked balance of sender
            unchecked {
                sLock.tokenAmount = sLock.tokenAmount - amount;
            }

            // Apply lock
            return _applyLock(sender, recipient, amount, hardLockUntil, softLockUntil, allowedHops);
        }

        // If no conditions were met so far, deduct from the unlocked balance
        unchecked {
            _balances[sender] = sBalance - (amount - sLock.tokenAmount);
        }

        // Then spend locked balance of sender first
        sLock.tokenAmount = 0;

        // Apply lock
        return _applyLock(sender, recipient, amount, hardLockUntil, softLockUntil, allowedHops);
    }

    /// @notice Applies lock to recipient with specified params and emits a transfer event
    /// @param sender The address whose balance will be debited
    /// @param recipient The address whose locked balance will be credited
    /// @param amount The amount which will be credited to the recipient address
    /// @param hardLockUntil The UNIX timestamp until which the tokens are not transferable
    /// @param softLockUntil The UNIX timestamp until which the tokens are gradually unlockable
    /// @param allowedHops How many times the locked tokens can be transferred further
    /// @return Success
    function _applyLock(address sender, address recipient, uint256 amount, uint64 hardLockUntil, uint64 softLockUntil, uint64 allowedHops) private returns (bool) {

        // Make sure that softlock is not before hardlock
        require(softLockUntil >= hardLockUntil, "SoftLock must be >= HardLock!");

        // Make sure that hardlock is in the future
        require(hardLockUntil >= block.timestamp, "HardLock must be in the future!");

        // Make sure that the amount is increased if a lock already exists
        uint256 totalAmount;
        uint256 lockSeconds;
        uint256 unlockPerSec;
        unchecked {
            totalAmount = _locks[recipient].tokenAmount + amount;
            lockSeconds = softLockUntil - hardLockUntil;
            unlockPerSec = lockSeconds > 0 ? totalAmount / lockSeconds : 0;
        }

        // Apply lock, emit transfer event
        _locks[recipient] = Lock({
            tokenAmount: totalAmount,
            unlockPerSec: unlockPerSec,
            hardLockUntil: hardLockUntil,
            softLockUntil: softLockUntil,
            lastUnlock: hardLockUntil,
            allowedHops: allowedHops
        });
        emit LockApplied(recipient, totalAmount, hardLockUntil, softLockUntil, allowedHops);
        emit Transfer(sender, recipient, amount);
        return true;
    }

    /// @notice Method to verify cheque signature
    /// @dev This verifies a compact secp256k1 signature as per EIP-2098
    /// @param cid The Cheque ID which is calculated deterministically based on cheque params
    /// @param signature The EIP-2098 signature which was created offline by the permitted chequeSigner
    /// @return Whether the recovered signer address matches the permitted chequeSigner
    function verifyChequeSignature(bytes32 cid, bytes32[2] memory signature) private view returns (bool) {

        // Determine s and v from vs (signature[1])
        bytes32 s = signature[1] & bytes32(0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);
        uint8 v = uint8((uint256(signature[1]) >> 255) + 27);

        // Ensure valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return false;
        }

        // Recover & verify signer identity related to amount
        return ecrecover(cid, v, signature[0], s) == chequeSigner;
    }
}

{
  "compilationTarget": {
    "QANX.sol": "QANX"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}