// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;

import "openzeppelin-solidity/contracts/token/ERC721/ERC721.sol";
import "./ERC721Ref.sol";

/**
 * @title BlockArt
 * BlockArt - a contract for my non-fungible BlockArts.
 */
contract BlockArt is ERC721Ref {
    constructor(string memory contractURI) ERC721("BlockArt", "EBA") {
        _setContractURI(contractURI);
    }

    function setContractURI(string memory uri) external onlyOwner {
        _setContractURI(uri);
    }

    /// @dev owner of contract can change token URIs, allowing for later hydrating the metadata for an already owned token
    function setTokenURI(uint256 id, string memory uri) external onlyOwner {
        _setTokenURI(id, uri);
    }

    function burnToken(uint256 id) external onlyOwner {
        _burn(id);
    }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;
pragma experimental ABIEncoderV2;

import "openzeppelin-solidity/contracts/access/Ownable.sol";
import "openzeppelin-solidity/contracts/math/SafeMath.sol";

import "./BArt.sol";
import "./BStyle.sol";

contract BlockArtFactory is Ownable {
    using Strings for string;
    using SafeMath for uint256;

    event StyleAdded(uint256 indexed styleId);
    event StyleRemoved(uint256 indexed styleId);
    event StyleFeeCollected(
        address indexed to,
        uint256 styleId,
        uint256 amount
    );

    event Transfer(
        address indexed from,
        address indexed to,
        uint256 indexed tokenId
    );

    event ReMint(address indexed to, uint256 indexed tokenId);
    event Burn(address indexed to, uint256 indexed tokenId);

    address public artsAddr; // art nft
    address public stylesAddr; // style nft
    uint256 public priceFloor; // minimum price for art nft mint
    uint256 public priceCeil; // max price for dutch auction for art nft mint
    uint256 public stylePrice; // fixed price for style nft mint
    uint256 public remintFee; // Cost of mutating a BlockArt metadata
    uint256 public burnFee; // Cost of burning a BlockArt
    uint256 public dutchLength; // length of dutch price decrease;
    uint256 public coinsBalance = 0; // fees collected for treasury

    mapping(uint256 => uint256) scfb; // style collectable fee balance
    mapping(uint256 => uint256) psfb; // price set for block
    mapping(uint256 => bool) asl; // allowed styles list

    struct Bp {
        uint256 bNumber;
        uint256 value;
    }

    constructor(address _artsAddr, address _stylesAddr) {
        artsAddr = _artsAddr;
        stylesAddr = _stylesAddr;
        priceFloor = 0.01 ether;
        priceCeil = 0.09 ether;
        stylePrice = 0.01 ether;
        remintFee = 0.01 ether;
        burnFee = 0.01 ether;
        dutchLength = 1028; // blocks
    }

    /// @dev check in the style allow list
    modifier onlyStyleListed(uint256 styleId) {
        require(isStyleListed(styleId), "Style not listed");
        _;
    }

    /// @dev check if sender owns token
    modifier onlyStyleOwner(uint256 styleId) {
        BlockStyle _style = BlockStyle(stylesAddr);
        require(msg.sender == _style.ownerOf(styleId), "Sender not Owner");
        _;
    }

    /// @dev check if sender owns token
    modifier onlyArtOwner(uint256 artId) {
        BlockArt _art = BlockArt(artsAddr);
        require(msg.sender == _art.ownerOf(artId), "Sender not Owner");
        _;
    }

    /// @dev Mint BlockArt NFTs, splits fees from value,
    /// @dev gives style highest between minimum/multiplier diff, and rest goes to treasury
    /// @param to The token receiver
    /// @param blockNumber The blocknumber associated
    /// @param styleId The style used
    /// @param metadata The tokenURI pointing to the metadata
    function mintArt(
        address to,
        uint256 blockNumber,
        uint256 styleId,
        string memory metadata
    ) external payable {
        uint256 price = calcArtPrice(blockNumber, styleId);
        uint256 canMint = canMintWithStyle(styleId);
        require(msg.value >= price, "Value too low");
        require(canMint > 0, "Cannot mint style");

        BlockArt _blockArt = BlockArt(artsAddr);
        _blockArt.mint(to, blockNumber, styleId, msg.value, metadata);

        psfb[blockNumber] = msg.value;

        BlockStyle _style = BlockStyle(stylesAddr);
        uint256 sfm = _style.getStyleFeeMul(styleId); // style fee multiplier
        uint256 msf = _style.getStyleFeeMin(styleId); // minimum style fee
        uint256 sf = msg.value.sub(msg.value.div(sfm).mul(100)); // style fee

        if (msf > sf) sf = msf; // whichever is higher
        scfb[styleId] = scfb[styleId].add(sf);
        coinsBalance = coinsBalance.add(msg.value.sub(sf));
    }

    /// @dev owner of BlockArts can change their token metadata URI for a fee
    function burnArt(uint256 tokenId) external payable onlyArtOwner(tokenId) {
        require(msg.value >= burnFee, "Value too low");
        BlockArt _ba = BlockArt(artsAddr);
        uint256 bav = _ba.tokenToValue(tokenId);
        uint256 bab = _ba.tokenToBlock(tokenId);
        uint256 _psfb = psfb[bab].sub(bav);
        psfb[bab] = _psfb;

        _ba.burnToken(tokenId);
        coinsBalance = coinsBalance.add(msg.value);

        emit Burn(msg.sender, tokenId);
    }

    /// @dev owner of BlockArts can change their token metadata URI for a fee
    function remint(uint256 tokenId, string memory metadata)
        external
        payable
        onlyArtOwner(tokenId)
    {
        require(msg.value >= remintFee, "Value too low");
        BlockArt _blockArt = BlockArt(artsAddr);
        _blockArt.setTokenURI(tokenId, metadata);
        coinsBalance = coinsBalance.add(msg.value);
        emit ReMint(msg.sender, tokenId);
    }

    /// @dev Calculate the cost of minting a BlockArt NFT for a given block and style
    /// @dev Starts with the price floor
    /// @dev Checks for existing price for block, or does dutch auction
    /// @dev Applies style fee multiplier or minimum fee, whichever is highest
    /// @param blockNumber Block number selected
    /// @param styleId BlockStyle ID selected
    function calcArtPrice(uint256 blockNumber, uint256 styleId)
        public
        view
        returns (uint256)
    {
        BlockStyle _style = BlockStyle(stylesAddr);
        uint256 msf = _style.getStyleFeeMin(styleId);

        uint256 price = priceFloor;

        // check if there's a price set for this block
        uint256 _psfb = psfb[blockNumber];

        if (_psfb > 0) {
            // price floor for block set
            price = price.add(_psfb);
        } else {
            // go dutch
            if (blockNumber >= block.number) {
                price = price.add(priceCeil);
            } else if (blockNumber.add(dutchLength) >= block.number) {
                // only if blocknumber in dutch range from current block
                uint256 blockDiff = block.number - blockNumber;
                uint256 priceDiff =
                    priceCeil.sub((blockDiff.mul(priceCeil.div(dutchLength))));

                price = price.add(priceDiff);
            }
        }

        uint256 sfa =
            price.mul(_style.getStyleFeeMul(styleId)).div(100).sub(price); //style fee amount

        if (sfa >= msf) {
            // style fee amount vs. minimum style fee
            return price.add(sfa);
        } else {
            return price.add(msf);
        }
    }

    /// @dev Mint BlockStyle NFTs, anyone can mint a BlockStyle NFT for a fee set by owner of contract
    /// @param to The token receiver
    /// @param cap Initial supply cap
    /// @param feeMul Initial Fee Multiplier
    /// @param feeMin Initial Minimum Fee
    /// @param canvas The token canvas URI
    function mintStyle(
        address to,
        uint256 cap,
        uint256 feeMul,
        uint256 feeMin,
        string memory canvas
    ) external payable {
        require(msg.value >= stylePrice, "Value too low");

        BlockStyle _blockStyle = BlockStyle(stylesAddr);
        _blockStyle.mint(to, cap, feeMul, feeMin, canvas);

        coinsBalance = coinsBalance.add(msg.value);
    }

    /// @dev Checks if is possible to mint with selected Style
    function canMintWithStyle(uint256 styleId)
        public
        view
        onlyStyleListed(styleId)
        returns (uint256)
    {
        BlockStyle _style = BlockStyle(stylesAddr);
        BlockArt _art = BlockArt(artsAddr);

        // style supply cap
        uint256 ssc = _style.getStyleSupplyCap(styleId);

        // style current supply
        uint256 scs = _art.styleArtSupply(styleId);

        // supply available to be minted
        uint256 diff = ssc - scs;

        if (diff < 0) return 0;

        return 1;
    }

    /// @notice Withdrawals

    /// @dev BlockStyle owner collects style fees
    function collectStyleFees(uint256 styleId)
        external
        onlyStyleOwner(styleId)
    {
        uint256 _amount = scfb[styleId];

        scfb[styleId] = 0;
        payable(msg.sender).transfer(_amount);
        emit StyleFeeCollected(msg.sender, styleId, _amount);
    }

    /// @dev Contract Owner collects treasury fees
    function collectCoins() external onlyOwner {
        uint256 _amount = coinsBalance;

        coinsBalance = 0;
        payable(msg.sender).transfer(_amount);
    }

    /// @dev Contract Owner collects balance
    function collectBalance() external onlyOwner {
        uint256 _amount = address(this).balance;
        payable(msg.sender).transfer(_amount);
    }

    /// @notice Getters

    function getStyleBalance(uint256 styleId) external view returns (uint256) {
        return scfb[styleId];
    }

    function getCoinsBalance() external view returns (uint256) {
        return coinsBalance;
    }

    function getPriceCeil() external view returns (uint256) {
        return priceCeil;
    }

    function getPriceFloor() external view returns (uint256) {
        return priceFloor;
    }

    function getDutchLength() external view returns (uint256) {
        return dutchLength;
    }

    function getPsfb(uint256 blockNumber) public view returns (uint256) {
        return psfb[blockNumber];
    }

    /// @notice Internal Constants Management

    function setPsfb(uint256 blockNumber, uint256 value) public onlyOwner {
        psfb[blockNumber] = value;
    }

    function setFloor(uint256 value) external onlyOwner {
        priceFloor = value;
    }

    function setCeil(uint256 value) external onlyOwner {
        priceCeil = value;
    }

    function setStylePrice(uint256 value) external onlyOwner {
        stylePrice = value;
    }

    function setDutchLength(uint256 value) external onlyOwner {
        dutchLength = value;
    }

    function setRemintFee(uint256 value) external onlyOwner {
        remintFee = value;
    }

    function setStyleBaseURI(string memory uri) external onlyOwner {
        BlockStyle _style = BlockStyle(stylesAddr);
        _style.setBase(uri);
    }

    function setArtContractURI(string memory uri) external onlyOwner {
        BlockArt _art = BlockArt(artsAddr);
        _art.setContractURI(uri);
    }

    /// @notice Allowed Styles List Management

    function addStyle(uint256 styleId) public onlyOwner {
        asl[styleId] = true;
        emit StyleAdded(styleId);
    }

    function removeStyle(uint256 styleId) external onlyOwner {
        asl[styleId] = false;
        emit StyleRemoved(styleId);
    }

    function isStyleListed(uint256 styleId) public view returns (bool) {
        return asl[styleId];
    }

    function setPsfbs(Bp[] calldata psfba) external onlyOwner {
        for (uint256 i = 0; i < psfba.length; i++) {
            setPsfb(psfba[i].bNumber, psfba[i].value);
        }
    }

    function setAsl(uint256[] calldata asls) external onlyOwner {
        for (uint256 i = 0; i < asls.length; i++) {
            addStyle(asls[i]);
        }
    }

    /// @dev transfers ownership of blockart and blockstyle token contracts owned by factory
    function transferTokensOwnership(address to) external onlyOwner {
        BlockStyle _style = BlockStyle(stylesAddr);
        BlockArt _art = BlockArt(artsAddr);
        _style.transferOwnership(to);
        _art.transferOwnership(to);
    }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;
pragma experimental ABIEncoderV2;

import "openzeppelin-solidity/contracts/access/Ownable.sol";
import "openzeppelin-solidity/contracts/math/SafeMath.sol";

import "./BArt.sol";
import "./BStyle.sol";
import "./BFactory.sol";

contract BlockArtFactoryV2 is Ownable {
    using Strings for string;
    using SafeMath for uint256;

    event StyleAdded(uint256 indexed styleId);
    event StyleRemoved(uint256 indexed styleId);
    event StyleFeeCollected(
        address indexed to,
        uint256 styleId,
        uint256 amount
    );

    event Transfer(
        address indexed from,
        address indexed to,
        uint256 indexed tokenId
    );

    event ReMint(address indexed to, uint256 indexed tokenId);
    event Burn(address indexed to, uint256 indexed tokenId);

    address public artsAddr; // art nft
    address public stylesAddr; // style nft
    address public oldFactoryAddr; // style nft
    uint256 public priceFloor; // minimum price for art nft mint
    uint256 public priceCeil; // max price for dutch auction for art nft mint
    uint256 public stylePrice; // fixed price for style nft mint
    uint256 public remintFee; // Cost of mutating a BlockArt metadata
    uint256 public burnFee; // Cost of burning a BlockArt
    uint256 public dutchLength; // length of dutch price decrease;
    uint256 public coinsBalance = 0; // fees collected for treasury

    mapping(uint256 => uint256) scfb; // style collectable fee balance
    mapping(uint256 => bool) asl; // allowed styles list

    struct Bp {
        uint256 bNumber;
        uint256 value;
    }

    constructor(
        address _artsAddr,
        address _stylesAddr,
        address _oldFactoryAddr
    ) {
        artsAddr = _artsAddr;
        stylesAddr = _stylesAddr;
        oldFactoryAddr = _oldFactoryAddr;
        priceFloor = 0.01 ether;
        priceCeil = 0.09 ether;
        stylePrice = 0.01 ether;
        remintFee = 0.01 ether;
        burnFee = 0.01 ether;
        dutchLength = 1028; // blocks
    }

    /// @dev check in the style allow list
    modifier onlyStyleListed(uint256 styleId) {
        require(isStyleListed(styleId), "Style not listed");
        _;
    }

    /// @dev check if sender owns token
    modifier onlyStyleOwner(uint256 styleId) {
        BlockStyle _style = BlockStyle(stylesAddr);
        require(msg.sender == _style.ownerOf(styleId), "Sender not Owner");
        _;
    }

    /// @dev check if sender owns token
    modifier onlyArtOwner(uint256 artId) {
        BlockArt _art = BlockArt(artsAddr);
        require(msg.sender == _art.ownerOf(artId), "Sender not Owner");
        _;
    }

    /// @dev Mint BlockArt NFTs, splits fees from value,
    /// @dev gives style highest between minimum/multiplier diff, and rest goes to treasury
    /// @param to The token receiver
    /// @param blockNumber The blocknumber associated
    /// @param styleId The style used
    /// @param metadata The tokenURI pointing to the metadata
    function mintArt(
        address to,
        uint256 blockNumber,
        uint256 styleId,
        string memory metadata
    ) external payable {
        uint256 price = calcArtPrice(blockNumber, styleId);
        bool canMint = canMintWithStyle(styleId);
        require(msg.value >= price, "Value too low");
        require(canMint, "Cannot mint style");

        BlockArt _blockArt = BlockArt(artsAddr);
        _blockArt.mint(to, blockNumber, styleId, msg.value, metadata);

        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.setPsfb(blockNumber, msg.value);

        BlockStyle _style = BlockStyle(stylesAddr);
        uint256 sfm = _style.getStyleFeeMul(styleId); // style fee multiplier
        uint256 msf = _style.getStyleFeeMin(styleId); // minimum style fee
        uint256 sf = msg.value.sub(msg.value.div(sfm).mul(100)); // style fee

        if (msf > sf) sf = msf; // whichever is higher
        scfb[styleId] = scfb[styleId].add(sf);
        coinsBalance = coinsBalance.add(msg.value.sub(sf));
    }

    /// @dev owner of BlockArts can change their token metadata URI for a fee
    function burnArt(uint256 tokenId) external payable onlyArtOwner(tokenId) {
        require(msg.value >= burnFee, "Value too low");
        BlockArt _ba = BlockArt(artsAddr);
        uint256 bav = _ba.tokenToValue(tokenId);
        uint256 bab = _ba.tokenToBlock(tokenId);
        uint256 _psfb = getPsfb(bab);
        _psfb = _psfb.sub(bav);

        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.setPsfb(bab, _psfb);

        _ba.burnToken(tokenId);
        coinsBalance = coinsBalance.add(msg.value);

        emit Burn(msg.sender, tokenId);
    }

    /// @dev owner of BlockArts can change their token metadata URI for a fee
    function remint(uint256 tokenId, string memory metadata)
        external
        payable
        onlyArtOwner(tokenId)
    {
        require(msg.value >= remintFee, "Value too low");
        BlockArt _blockArt = BlockArt(artsAddr);
        _blockArt.setTokenURI(tokenId, metadata);
        coinsBalance = coinsBalance.add(msg.value);
        emit ReMint(msg.sender, tokenId);
    }

    /// @dev Calculate the cost of minting a BlockArt NFT for a given block and style
    /// @dev Starts with the price floor
    /// @dev Checks for existing price for block, or does dutch auction
    /// @dev Applies style fee multiplier or minimum fee, whichever is highest
    /// @param blockNumber Block number selected
    /// @param styleId BlockStyle ID selected
    function calcArtPrice(uint256 blockNumber, uint256 styleId)
        public
        view
        returns (uint256)
    {
        BlockStyle _style = BlockStyle(stylesAddr);
        uint256 msf = _style.getStyleFeeMin(styleId);

        uint256 price = priceFloor;

        // check if there's a price set for this block
        uint256 _psfb = getPsfb(blockNumber);

        if (_psfb > 0) {
            // price floor for block set
            price = price.add(_psfb);
        } else {
            // go dutch
            if (blockNumber >= block.number) {
                price = price.add(priceCeil);
            } else if (blockNumber.add(dutchLength) >= block.number) {
                // only if blocknumber in dutch range from current block
                uint256 blockDiff = block.number - blockNumber;
                uint256 priceDiff = priceCeil.sub(
                    (blockDiff.mul(priceCeil.div(dutchLength)))
                );

                price = price.add(priceDiff);
            }
        }

        uint256 sfa = price.mul(_style.getStyleFeeMul(styleId)).div(100).sub(
            price
        ); //style fee amount

        if (sfa >= msf) {
            // style fee amount vs. minimum style fee
            return price.add(sfa);
        } else {
            return price.add(msf);
        }
    }

    /// @dev Mint BlockStyle NFTs, anyone can mint a BlockStyle NFT for a fee set by owner of contract
    /// @param to The token receiver
    /// @param cap Initial supply cap
    /// @param feeMul Initial Fee Multiplier
    /// @param feeMin Initial Minimum Fee
    /// @param canvas The token canvas URI
    function mintStyle(
        address to,
        uint256 cap,
        uint256 feeMul,
        uint256 feeMin,
        string memory canvas
    ) external payable {
        require(msg.value >= stylePrice, "Value too low");

        BlockStyle _blockStyle = BlockStyle(stylesAddr);
        _blockStyle.mint(to, cap, feeMul, feeMin, canvas);

        coinsBalance = coinsBalance.add(msg.value);
    }

    /// @dev Checks if is possible to mint with selected Style
    function canMintWithStyle(uint256 styleId)
        public
        view
        onlyStyleListed(styleId)
        returns (bool)
    {
        BlockStyle _style = BlockStyle(stylesAddr);
        BlockArt _art = BlockArt(artsAddr);

        // style supply cap
        uint256 ssc = _style.getStyleSupplyCap(styleId);

        // style current supply
        uint256 scs = _art.styleArtSupply(styleId);

        return scs < ssc;
    }

    /// @notice Withdrawals

    /// @dev BlockStyle owner collects style fees
    function collectStyleFees(uint256 styleId)
        external
        onlyStyleOwner(styleId)
    {
        uint256 _amount = scfb[styleId];

        scfb[styleId] = 0;
        payable(msg.sender).transfer(_amount);
        emit StyleFeeCollected(msg.sender, styleId, _amount);
    }

    /// @dev Contract Owner collects treasury fees
    function collectCoins() external onlyOwner {
        uint256 _amount = coinsBalance;

        coinsBalance = 0;
        payable(msg.sender).transfer(_amount);
    }

    /// @dev Contract Owner collects balance
    function collectBalance() external onlyOwner {
        uint256 _amount = address(this).balance;
        payable(msg.sender).transfer(_amount);
    }

    /// @notice Getters

    function getStyleBalance(uint256 styleId) external view returns (uint256) {
        return scfb[styleId];
    }

    function getCoinsBalance() external view returns (uint256) {
        return coinsBalance;
    }

    function getPriceCeil() external view returns (uint256) {
        return priceCeil;
    }

    function getPriceFloor() external view returns (uint256) {
        return priceFloor;
    }

    function getDutchLength() external view returns (uint256) {
        return dutchLength;
    }

    function getPsfb(uint256 blockNumber) public view returns (uint256) {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        return _oldFa.getPsfb(blockNumber);
    }

    /// @notice Internal Constants Management

    function setPsfb(uint256 blockNumber, uint256 value) public onlyOwner {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.setPsfb(blockNumber, value);
    }

    function setFloor(uint256 value) external onlyOwner {
        priceFloor = value;
    }

    function setCeil(uint256 value) external onlyOwner {
        priceCeil = value;
    }

    function setStylePrice(uint256 value) external onlyOwner {
        stylePrice = value;
    }

    function setDutchLength(uint256 value) external onlyOwner {
        dutchLength = value;
    }

    function setRemintFee(uint256 value) external onlyOwner {
        remintFee = value;
    }

    function setStyleBaseURI(string memory uri) external onlyOwner {
        BlockStyle _style = BlockStyle(stylesAddr);
        _style.setBase(uri);
    }

    function setArtContractURI(string memory uri) external onlyOwner {
        BlockArt _art = BlockArt(artsAddr);
        _art.setContractURI(uri);
    }

    /// @notice Allowed Styles List Management

    function addStyle(uint256 styleId) public onlyOwner {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.addStyle(styleId);
        emit StyleAdded(styleId);
    }

    function removeStyle(uint256 styleId) external onlyOwner {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.removeStyle(styleId);
        emit StyleRemoved(styleId);
    }

    function isStyleListed(uint256 styleId) public view returns (bool) {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        return _oldFa.isStyleListed(styleId);
    }

    function setPsfbs(Bp[] calldata psfba) external onlyOwner {
        for (uint256 i = 0; i < psfba.length; i++) {
            setPsfb(psfba[i].bNumber, psfba[i].value);
        }
    }

    function setAsl(uint256[] calldata asls) external onlyOwner {
        for (uint256 i = 0; i < asls.length; i++) {
            addStyle(asls[i]);
        }
    }

    function setOldFa(address _oldfa) external onlyOwner {
        oldFactoryAddr = _oldfa;
    }

    /// @dev transfers ownership of blockart and blockstyle token contracts owned by factory
    function transferTokensOwnership(address to) external onlyOwner {
        BlockStyle _style = BlockStyle(stylesAddr);
        BlockArt _art = BlockArt(artsAddr);
        _style.transferOwnership(to);
        _art.transferOwnership(to);
    }

    /// @dev transfers ownership of blockart and blockstyle token contracts owned by factory
    function transferOldFaOwnership(address to) external onlyOwner {
        BlockArtFactory _oldFa = BlockArtFactory(oldFactoryAddr);
        _oldFa.transferOwnership(to);
    }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;

import "./ERC721Style.sol";

// import "hardhat/console.sol";

contract BlockStyle is ERC721Style {
    constructor(string memory baseURI, string memory contractURI)
        ERC721("BlockStyle", "EBS")
    {
        _setBaseURI(baseURI);
        _setContractURI(contractURI);
    }

    function setContractURI(string memory uri) external onlyOwner {
        _setContractURI(uri);
    }

    /// @dev BlockStyle token metadata URIs are meant to use base + id concatenation
    function setBase(string memory uri) external onlyOwner {
        _setBaseURI(uri);
    }

    /// @dev BlockStyle tokens have a canvas URI which can be changed by owner
    function setCanvas(uint256 id, string memory canvas) external {
        require(
            _isApprovedOrOwner(_msgSender(), id),
            "Operator is not approved"
        );
        _setCanvasURI(id, canvas);
    }

    /// @dev Opt in specifying token metadata URI
    function setToken(uint256 id, string memory uri) external {
        require(
            _isApprovedOrOwner(_msgSender(), id),
            "Operator is not approved"
        );
        _setTokenURI(id, uri);
    }

    /// @notice BlockArt minting with BlockStyle, supply and fee management
    function setStyleSupplyCap(uint256 _id, uint256 _cap) external {
        require(
            _isApprovedOrOwner(_msgSender(), _id),
            "Operator is not approved"
        );
        _setStyleSupplyCap(_id, _cap);
    }

    function setStyleFeeMul(uint256 _id, uint256 _value) external {
        require(
            _isApprovedOrOwner(_msgSender(), _id),
            "Operator is not approved"
        );

        require(_value >= 100, "Value too low");

        _setStyleFeeMul(_id, _value);
    }

    function setStyleFeeMin(uint256 _id, uint256 _value) external {
        require(
            _isApprovedOrOwner(_msgSender(), _id),
            "Operator is not approved"
        );
        _setStyleFeeMin(_id, _value);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "../math/SafeMath.sol";

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented or decremented by one. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 * Since it is not possible to overflow a 256 bit integer with increments of one, `increment` can skip the {SafeMath}
 * overflow check, thereby saving gas. This does assume however correct usage, in that the underlying `_value` is never
 * directly accessed.
 */
library Counters {
    using SafeMath for uint256;

    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        // The {SafeMath} overflow check can be skipped here, see the comment at the top
        counter._value += 1;
    }

    function decrement(Counter storage counter) internal {
        counter._value = counter._value.sub(1);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts may inherit from this and call {_registerInterface} to declare
 * their support of an interface.
 */
abstract contract ERC165 is IERC165 {
    /*
     * bytes4(keccak256('supportsInterface(bytes4)')) == 0x01ffc9a7
     */
    bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;

    /**
     * @dev Mapping of interface ids to whether or not it's supported.
     */
    mapping(bytes4 => bool) private _supportedInterfaces;

    constructor () internal {
        // Derived contracts need only register support for their own interfaces,
        // we register support for ERC165 itself here
        _registerInterface(_INTERFACE_ID_ERC165);
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     *
     * Time complexity O(1), guaranteed to always use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) public view override returns (bool) {
        return _supportedInterfaces[interfaceId];
    }

    /**
     * @dev Registers the contract as an implementer of the interface defined by
     * `interfaceId`. Support of the actual ERC165 interface is automatic and
     * registering its interface id is not required.
     *
     * See {IERC165-supportsInterface}.
     *
     * Requirements:
     *
     * - `interfaceId` cannot be the ERC165 invalid interface (`0xffffffff`).
     */
    function _registerInterface(bytes4 interfaceId) internal virtual {
        require(interfaceId != 0xffffffff, "ERC165: invalid interface id");
        _supportedInterfaces[interfaceId] = true;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "../../GSN/Context.sol";
import "./IERC721.sol";
import "./IERC721Metadata.sol";
import "./IERC721Enumerable.sol";
import "./IERC721Receiver.sol";
import "../../introspection/ERC165.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";
import "../../utils/EnumerableSet.sol";
import "../../utils/EnumerableMap.sol";
import "../../utils/Strings.sol";

/**
 * @title ERC721 Non-Fungible Token Standard basic implementation
 * @dev see https://eips.ethereum.org/EIPS/eip-721
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata, IERC721Enumerable {
    using SafeMath for uint256;
    using Address for address;
    using EnumerableSet for EnumerableSet.UintSet;
    using EnumerableMap for EnumerableMap.UintToAddressMap;
    using Strings for uint256;

    // Equals to `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`
    // which can be also obtained as `IERC721Receiver(0).onERC721Received.selector`
    bytes4 private constant _ERC721_RECEIVED = 0x150b7a02;

    // Mapping from holder address to their (enumerable) set of owned tokens
    mapping (address => EnumerableSet.UintSet) private _holderTokens;

    // Enumerable mapping from token ids to their owners
    EnumerableMap.UintToAddressMap private _tokenOwners;

    // Mapping from token ID to approved address
    mapping (uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping (address => mapping (address => bool)) private _operatorApprovals;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Optional mapping for token URIs
    mapping (uint256 => string) private _tokenURIs;

    // Base URI
    string private _baseURI;

    /*
     *     bytes4(keccak256('balanceOf(address)')) == 0x70a08231
     *     bytes4(keccak256('ownerOf(uint256)')) == 0x6352211e
     *     bytes4(keccak256('approve(address,uint256)')) == 0x095ea7b3
     *     bytes4(keccak256('getApproved(uint256)')) == 0x081812fc
     *     bytes4(keccak256('setApprovalForAll(address,bool)')) == 0xa22cb465
     *     bytes4(keccak256('isApprovedForAll(address,address)')) == 0xe985e9c5
     *     bytes4(keccak256('transferFrom(address,address,uint256)')) == 0x23b872dd
     *     bytes4(keccak256('safeTransferFrom(address,address,uint256)')) == 0x42842e0e
     *     bytes4(keccak256('safeTransferFrom(address,address,uint256,bytes)')) == 0xb88d4fde
     *
     *     => 0x70a08231 ^ 0x6352211e ^ 0x095ea7b3 ^ 0x081812fc ^
     *        0xa22cb465 ^ 0xe985e9c5 ^ 0x23b872dd ^ 0x42842e0e ^ 0xb88d4fde == 0x80ac58cd
     */
    bytes4 private constant _INTERFACE_ID_ERC721 = 0x80ac58cd;

    /*
     *     bytes4(keccak256('name()')) == 0x06fdde03
     *     bytes4(keccak256('symbol()')) == 0x95d89b41
     *     bytes4(keccak256('tokenURI(uint256)')) == 0xc87b56dd
     *
     *     => 0x06fdde03 ^ 0x95d89b41 ^ 0xc87b56dd == 0x5b5e139f
     */
    bytes4 private constant _INTERFACE_ID_ERC721_METADATA = 0x5b5e139f;

    /*
     *     bytes4(keccak256('totalSupply()')) == 0x18160ddd
     *     bytes4(keccak256('tokenOfOwnerByIndex(address,uint256)')) == 0x2f745c59
     *     bytes4(keccak256('tokenByIndex(uint256)')) == 0x4f6ccce7
     *
     *     => 0x18160ddd ^ 0x2f745c59 ^ 0x4f6ccce7 == 0x780e9d63
     */
    bytes4 private constant _INTERFACE_ID_ERC721_ENUMERABLE = 0x780e9d63;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor (string memory name_, string memory symbol_) public {
        _name = name_;
        _symbol = symbol_;

        // register the supported interfaces to conform to ERC721 via ERC165
        _registerInterface(_INTERFACE_ID_ERC721);
        _registerInterface(_INTERFACE_ID_ERC721_METADATA);
        _registerInterface(_INTERFACE_ID_ERC721_ENUMERABLE);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");

        return _holderTokens[owner].length();
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view override returns (address) {
        return _tokenOwners.get(tokenId, "ERC721: owner query for nonexistent token");
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory _tokenURI = _tokenURIs[tokenId];

        // If there is no base URI, return the token URI.
        if (bytes(_baseURI).length == 0) {
            return _tokenURI;
        }
        // If both are set, concatenate the baseURI and tokenURI (via abi.encodePacked).
        if (bytes(_tokenURI).length > 0) {
            return string(abi.encodePacked(_baseURI, _tokenURI));
        }
        // If there is a baseURI but no tokenURI, concatenate the tokenID to the baseURI.
        return string(abi.encodePacked(_baseURI, tokenId.toString()));
    }

    /**
    * @dev Returns the base URI set via {_setBaseURI}. This will be
    * automatically added as a prefix in {tokenURI} to each token's URI, or
    * to the token ID if no specific URI is set for that token ID.
    */
    function baseURI() public view returns (string memory) {
        return _baseURI;
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view override returns (uint256) {
        return _holderTokens[owner].at(index);
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view override returns (uint256) {
        // _tokenOwners are indexed by tokenIds, so .length() returns the number of tokenIds
        return _tokenOwners.length();
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view override returns (uint256) {
        (uint256 tokenId, ) = _tokenOwners.at(index);
        return tokenId;
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(_msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(address from, address to, uint256 tokenId) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory _data) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(address from, address to, uint256 tokenId, bytes memory _data) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view returns (bool) {
        return _tokenOwners.contains(tokenId);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     d*
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(address to, uint256 tokenId, bytes memory _data) internal virtual {
        _mint(to, tokenId);
        require(_checkOnERC721Received(address(0), to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _holderTokens[to].add(tokenId);

        _tokenOwners.set(tokenId, to);

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        // Clear metadata (if any)
        if (bytes(_tokenURIs[tokenId]).length != 0) {
            delete _tokenURIs[tokenId];
        }

        _holderTokens[owner].remove(tokenId);

        _tokenOwners.remove(tokenId);

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(address from, address to, uint256 tokenId) internal virtual {
        require(ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _holderTokens[from].remove(tokenId);
        _holderTokens[to].add(tokenId);

        _tokenOwners.set(tokenId, to);

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Sets `_tokenURI` as the tokenURI of `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _setTokenURI(uint256 tokenId, string memory _tokenURI) internal virtual {
        require(_exists(tokenId), "ERC721Metadata: URI set of nonexistent token");
        _tokenURIs[tokenId] = _tokenURI;
    }

    /**
     * @dev Internal function to set the base URI for all token IDs. It is
     * automatically added as a prefix to the value returned in {tokenURI},
     * or to the token ID if {tokenURI} is empty.
     */
    function _setBaseURI(string memory baseURI_) internal virtual {
        _baseURI = baseURI_;
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory _data)
        private returns (bool)
    {
        if (!to.isContract()) {
            return true;
        }
        bytes memory returndata = to.functionCall(abi.encodeWithSelector(
            IERC721Receiver(to).onERC721Received.selector,
            _msgSender(),
            from,
            tokenId,
            _data
        ), "ERC721: transfer to non ERC721Receiver implementer");
        bytes4 retval = abi.decode(returndata, (bytes4));
        return (retval == _ERC721_RECEIVED);
    }

    function _approve(address to, uint256 tokenId) private {
        _tokenApprovals[tokenId] = to;
        emit Approval(ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 tokenId) internal virtual { }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;

import "openzeppelin-solidity/contracts/math/SafeMath.sol";
import "openzeppelin-solidity/contracts/token/ERC721/ERC721.sol";
import "openzeppelin-solidity/contracts/access/Ownable.sol";
import "openzeppelin-solidity/contracts/utils/Counters.sol";

abstract contract ERC721Ref is ERC721, Ownable {
    using SafeMath for uint256;
    using Counters for Counters.Counter;
    Counters.Counter private _ids; // token IDs

    mapping(uint256 => uint256) private _bas; // block art supply
    mapping(uint256 => uint256) private _sas; // style art supply
    mapping(uint256 => uint256) private _ats; // art to style
    mapping(uint256 => uint256) private _atb; // art to block
    mapping(uint256 => uint256) private _atv; // art to value
    string _contractURI;

    /// @dev Only owner can mint, stores information about the block and style used
    /// @param to The token receiver
    /// @param blockNumber The blocknumber associated
    /// @param styleId The style used
    /// @param value The cost paid
    /// @param metadata The tokenURI pointing to the metadata
    function mint(
        address to,
        uint256 blockNumber,
        uint256 styleId,
        uint256 value,
        string memory metadata
    ) external onlyOwner returns (uint256) {
        _ids.increment();
        uint256 newId = _ids.current();

        _bas[blockNumber] = _bas[blockNumber].add(1);
        _sas[styleId] = _sas[styleId].add(1);
        _ats[newId] = styleId;
        _atb[newId] = blockNumber;
        _atv[newId] = value;

        _safeMint(to, newId);
        _setTokenURI(newId, metadata);

        return newId;
    }

    /// @notice Getters

    function blockArtSupply(uint256 blockNumber)
        external
        view
        returns (uint256)
    {
        return _bas[blockNumber];
    }

    function styleArtSupply(uint256 styleId) public view returns (uint256) {
        return _sas[styleId];
    }

    function tokenToStyle(uint256 id) public view returns (uint256) {
        require(_exists(id), "Unknown query for unknown token");
        return _ats[id];
    }

    function tokenToBlock(uint256 id) public view returns (uint256) {
        require(_exists(id), "Unknown query for unknown token");
        return _atb[id];
    }

    function tokenToValue(uint256 id) public view returns (uint256) {
        require(_exists(id), "Unknown query for unknown token");
        return _atv[id];
    }

    /// @notice Contract metadata URI management

    function _setContractURI(string memory uri) internal onlyOwner {
        _contractURI = uri;
    }

    function contractURI() external view returns (string memory) {
        return _contractURI;
    }
}

// SPDX-License-Identifier: AGPL-3.0-or-later

// Copyright (C) 2020 adrianleb

// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <https://www.gnu.org/licenses/>.

pragma solidity ^0.7.3;

import "openzeppelin-solidity/contracts/access/Ownable.sol";
import "openzeppelin-solidity/contracts/token/ERC721/ERC721.sol";
import "openzeppelin-solidity/contracts/utils/Counters.sol";

abstract contract ERC721Style is Ownable, ERC721 {
    using Counters for Counters.Counter;
    Counters.Counter private _ids; // for tracking token IDs

    mapping(uint256 => string) private _scu; // style canvas uris
    mapping(uint256 => uint256) private _ssc; // style suply cap
    mapping(uint256 => address) private _stc; // style to creator
    mapping(uint256 => uint256) private _sfmu; // style fee multiplier
    mapping(uint256 => uint256) private _sfmi; // style fee minimum
    string _contractURI;

    /// @dev Mint BlockStyle NFTs, called by contract owner
    /// @param to The token receiver
    /// @param cap Initial supply cap
    /// @param feeMul Initial Fee Multiplier
    /// @param feeMin Initial Minimum Fee
    /// @param canvas The token canvas URI
    function mint(
        address to,
        uint256 cap,
        uint256 feeMul,
        uint256 feeMin,
        string memory canvas
    ) external onlyOwner {
        _ids.increment();
        uint256 newId = _ids.current();

        _safeMint(to, newId);
        _setCreator(newId, to);
        _setStyleSupplyCap(newId, cap);
        _setStyleFeeMul(newId, feeMul);
        _setStyleFeeMin(newId, feeMin);
        _setCanvasURI(newId, canvas);
    }

    /// @notice Setters
    function _setStyleSupplyCap(uint256 id, uint256 cap) internal virtual {
        require(_exists(id), "");
        _ssc[id] = cap;
    }

    function _setCreator(uint256 id, address who) internal virtual {
        require(_exists(id), "");
        _stc[id] = who;
    }

    function _setStyleFeeMul(uint256 id, uint256 amount) internal virtual {
        require(_exists(id), "");
        _sfmu[id] = amount;
    }

    function _setStyleFeeMin(uint256 id, uint256 amount) internal virtual {
        require(_exists(id), "");
        _sfmi[id] = amount;
    }

    /// @notice Getters

    function getStyleSupplyCap(uint256 id)
        public
        view
        virtual
        returns (uint256)
    {
        require(_exists(id), "");
        return _ssc[id];
    }

    function getCreator(uint256 id) public view virtual returns (address) {
        require(_exists(id), "");
        return _stc[id];
    }

    function getStyleFeeMul(uint256 id) public view virtual returns (uint256) {
        require(_exists(id), "");
        return _sfmu[id];
    }

    function getStyleFeeMin(uint256 id) public view virtual returns (uint256) {
        require(_exists(id), "");
        return _sfmi[id];
    }

    /// @notice Canvas URI management, by token owner

    function _setCanvasURI(uint256 id, string memory uri) internal virtual {
        require(_exists(id), "ID not found");
        _scu[id] = uri;
    }

    function canvasURI(uint256 tokenId) external view returns (string memory) {
        require(_exists(tokenId), "ID Not Found");
        return _scu[tokenId];
    }

    /// @notice Contract metadata URI management, only by owner

    function _setContractURI(string memory uri) internal virtual onlyOwner {
        _contractURI = uri;
    }

    function contractURI() external view returns (string memory) {
        return _contractURI;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Library for managing an enumerable variant of Solidity's
 * https://solidity.readthedocs.io/en/latest/types.html#mapping-types[`mapping`]
 * type.
 *
 * Maps have the following properties:
 *
 * - Entries are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Entries are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableMap for EnumerableMap.UintToAddressMap;
 *
 *     // Declare a set state variable
 *     EnumerableMap.UintToAddressMap private myMap;
 * }
 * ```
 *
 * As of v3.0.0, only maps of type `uint256 -> address` (`UintToAddressMap`) are
 * supported.
 */
library EnumerableMap {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Map type with
    // bytes32 keys and values.
    // The Map implementation uses private functions, and user-facing
    // implementations (such as Uint256ToAddressMap) are just wrappers around
    // the underlying Map.
    // This means that we can only create new EnumerableMaps for types that fit
    // in bytes32.

    struct MapEntry {
        bytes32 _key;
        bytes32 _value;
    }

    struct Map {
        // Storage of map keys and values
        MapEntry[] _entries;

        // Position of the entry defined by a key in the `entries` array, plus 1
        // because index 0 means a key is not in the map.
        mapping (bytes32 => uint256) _indexes;
    }

    /**
     * @dev Adds a key-value pair to a map, or updates the value for an existing
     * key. O(1).
     *
     * Returns true if the key was added to the map, that is if it was not
     * already present.
     */
    function _set(Map storage map, bytes32 key, bytes32 value) private returns (bool) {
        // We read and store the key's index to prevent multiple reads from the same storage slot
        uint256 keyIndex = map._indexes[key];

        if (keyIndex == 0) { // Equivalent to !contains(map, key)
            map._entries.push(MapEntry({ _key: key, _value: value }));
            // The entry is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            map._indexes[key] = map._entries.length;
            return true;
        } else {
            map._entries[keyIndex - 1]._value = value;
            return false;
        }
    }

    /**
     * @dev Removes a key-value pair from a map. O(1).
     *
     * Returns true if the key was removed from the map, that is if it was present.
     */
    function _remove(Map storage map, bytes32 key) private returns (bool) {
        // We read and store the key's index to prevent multiple reads from the same storage slot
        uint256 keyIndex = map._indexes[key];

        if (keyIndex != 0) { // Equivalent to contains(map, key)
            // To delete a key-value pair from the _entries array in O(1), we swap the entry to delete with the last one
            // in the array, and then remove the last entry (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = keyIndex - 1;
            uint256 lastIndex = map._entries.length - 1;

            // When the entry to delete is the last one, the swap operation is unnecessary. However, since this occurs
            // so rarely, we still do the swap anyway to avoid the gas cost of adding an 'if' statement.

            MapEntry storage lastEntry = map._entries[lastIndex];

            // Move the last entry to the index where the entry to delete is
            map._entries[toDeleteIndex] = lastEntry;
            // Update the index for the moved entry
            map._indexes[lastEntry._key] = toDeleteIndex + 1; // All indexes are 1-based

            // Delete the slot where the moved entry was stored
            map._entries.pop();

            // Delete the index for the deleted slot
            delete map._indexes[key];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the key is in the map. O(1).
     */
    function _contains(Map storage map, bytes32 key) private view returns (bool) {
        return map._indexes[key] != 0;
    }

    /**
     * @dev Returns the number of key-value pairs in the map. O(1).
     */
    function _length(Map storage map) private view returns (uint256) {
        return map._entries.length;
    }

   /**
    * @dev Returns the key-value pair stored at position `index` in the map. O(1).
    *
    * Note that there are no guarantees on the ordering of entries inside the
    * array, and it may change when more entries are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function _at(Map storage map, uint256 index) private view returns (bytes32, bytes32) {
        require(map._entries.length > index, "EnumerableMap: index out of bounds");

        MapEntry storage entry = map._entries[index];
        return (entry._key, entry._value);
    }

    /**
     * @dev Returns the value associated with `key`.  O(1).
     *
     * Requirements:
     *
     * - `key` must be in the map.
     */
    function _get(Map storage map, bytes32 key) private view returns (bytes32) {
        return _get(map, key, "EnumerableMap: nonexistent key");
    }

    /**
     * @dev Same as {_get}, with a custom error message when `key` is not in the map.
     */
    function _get(Map storage map, bytes32 key, string memory errorMessage) private view returns (bytes32) {
        uint256 keyIndex = map._indexes[key];
        require(keyIndex != 0, errorMessage); // Equivalent to contains(map, key)
        return map._entries[keyIndex - 1]._value; // All indexes are 1-based
    }

    // UintToAddressMap

    struct UintToAddressMap {
        Map _inner;
    }

    /**
     * @dev Adds a key-value pair to a map, or updates the value for an existing
     * key. O(1).
     *
     * Returns true if the key was added to the map, that is if it was not
     * already present.
     */
    function set(UintToAddressMap storage map, uint256 key, address value) internal returns (bool) {
        return _set(map._inner, bytes32(key), bytes32(uint256(value)));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the key was removed from the map, that is if it was present.
     */
    function remove(UintToAddressMap storage map, uint256 key) internal returns (bool) {
        return _remove(map._inner, bytes32(key));
    }

    /**
     * @dev Returns true if the key is in the map. O(1).
     */
    function contains(UintToAddressMap storage map, uint256 key) internal view returns (bool) {
        return _contains(map._inner, bytes32(key));
    }

    /**
     * @dev Returns the number of elements in the map. O(1).
     */
    function length(UintToAddressMap storage map) internal view returns (uint256) {
        return _length(map._inner);
    }

   /**
    * @dev Returns the element stored at position `index` in the set. O(1).
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(UintToAddressMap storage map, uint256 index) internal view returns (uint256, address) {
        (bytes32 key, bytes32 value) = _at(map._inner, index);
        return (uint256(key), address(uint256(value)));
    }

    /**
     * @dev Returns the value associated with `key`.  O(1).
     *
     * Requirements:
     *
     * - `key` must be in the map.
     */
    function get(UintToAddressMap storage map, uint256 key) internal view returns (address) {
        return address(uint256(_get(map._inner, bytes32(key))));
    }

    /**
     * @dev Same as {get}, with a custom error message when `key` is not in the map.
     */
    function get(UintToAddressMap storage map, uint256 key, string memory errorMessage) internal view returns (address) {
        return address(uint256(_get(map._inner, bytes32(key), errorMessage)));
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;

        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping (bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) { // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            // When the value to delete is the last one, the swap operation is unnecessary. However, since this occurs
            // so rarely, we still do the swap anyway to avoid the gas cost of adding an 'if' statement.

            bytes32 lastvalue = set._values[lastIndex];

            // Move the last value to the index where the value to delete is
            set._values[toDeleteIndex] = lastvalue;
            // Update the index for the moved value
            set._indexes[lastvalue] = toDeleteIndex + 1; // All indexes are 1-based

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        require(set._values.length > index, "EnumerableSet: index out of bounds");
        return set._values[index];
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint256(_at(set._inner, index)));
    }


    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

import "../../introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
      * @dev Safely transfers `tokenId` token from `from` to `to`.
      *
      * Requirements:
      *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
      * - `tokenId` token must exist and be owned by `from`.
      * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
      * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
      *
      * Emits a {Transfer} event.
      */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

import "./IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {

    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256 tokenId);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

import "./IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {

    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(address operator, address from, uint256 tokenId, bytes calldata data) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "../GSN/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    /**
     * @dev Converts a `uint256` to its ASCII `string` representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        uint256 index = digits - 1;
        temp = value;
        while (temp != 0) {
            buffer[index--] = byte(uint8(48 + temp % 10));
            temp /= 10;
        }
        return string(buffer);
    }
}

{
  "compilationTarget": {
    "contracts/BFactoryV2.sol": "BlockArtFactoryV2"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 1000
  },
  "remappings": []
}