// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../interfaces/IERC20.sol";
import "../Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
        uint256 oldAllowance = token.allowance(address(this), spender);
        require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
        uint256 newAllowance = oldAllowance - value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }
}

/**
 * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
 * on the return value: the return value is optional (but if data is returned, it must not be false).
 * @param token The token targeted by the call.
 * @param data The call data (encoded using abi.encode or one of its variants).
 */
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.

bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {// Return data is optional
// solhint-disable-next-line max-line-length
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.0;

contract StakingLocks {
    enum LockType { NULL, HOURS1, DAYS30, DAYS180, DAYS365, DAYS730}

    LockType[5] lockTypes = [LockType.HOURS1, LockType.DAYS30, LockType.DAYS180, LockType.DAYS365, LockType.DAYS730];

    struct LockData {
        uint32 period;
        uint8 multiplicator; // 11 factor is equal 1.1
    }

    mapping(LockType => LockData) public locks; // All our locks

    function _initLocks() internal {
        locks[LockType.HOURS1] = LockData(1 hours, 10);
        locks[LockType.DAYS30] = LockData(30 days, 12);
        locks[LockType.DAYS180] = LockData(180 days, 13);
        locks[LockType.DAYS365] = LockData(365 days, 15);
        locks[LockType.DAYS730] = LockData(730 days, 20);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "./access/Ownable.sol";
import "./interfaces/IERC20.sol";
import "./utils/token/SafeERC20.sol";
import "./StakingLocks.sol";

contract TimeWarpPool is Ownable, StakingLocks {
    event Deposit(LockType _lockType, uint256 _amount, uint256 _amountStacked);
    event Withdraw(uint256 _amount, uint256 _amountWithdraw);
    event Harvest(LockType _lockType, uint256 _amount, uint32 _lastRewardIndex);
    event Compound(LockType _lockType, uint256 _amount, uint32 _lastRewardIndex);
    event RewardPay(uint256 _amount, uint256 _accumulatedFee);

    using SafeERC20 for IERC20;
    IERC20 public erc20Deposit;
    IERC20 public erc20Reward;
    bool private initialized;
    bool private unlockAll;
    uint256 public accumulatedFee;
    uint256 public depositFeePercent = 0;
    uint256 public depositFeePrecision = 1000;
    uint256 public withdrawFeePercent = 0;
    uint256 public withdrawFeePrecision = 1000;
    uint8 public constant MAX_LOOPS = 100;
    uint256 public precision = 10000000000;
    uint32 public lastReward;

    struct Reward {
        uint256 amount;
        uint256 totalStacked;
    }

    // -------------- New --------------
    mapping(address => LockType) public userLock;
    mapping(address => uint256) public userStacked;
    mapping(address => uint256) public expirationDeposit;
    mapping(address => uint32) public userLastReward;
    mapping(LockType => uint256) public totalStacked;
    mapping(LockType => mapping(uint32 => Reward)) public rewards;

    function init(address _erc20Deposit, address _erc20Reward) external onlyOwner {
        require(!initialized, "Initialized");
        erc20Deposit = IERC20(_erc20Deposit);
        erc20Reward = IERC20(_erc20Reward);
        _initLocks();
        initialized = true;
    }

    function setUnlockAll(bool _flag) external onlyOwner {
        unlockAll = _flag;
    }

    function setPrecision(uint256 _precision) external onlyOwner {
        precision = _precision;
    }

    function setDepositFee(uint256 _feePercent, uint256 _feePrecision) external onlyOwner {
        depositFeePercent = _feePercent;
        depositFeePrecision = _feePrecision;
    }

    function setWithdrawFee(uint256 _feePercent, uint256 _feePrecision) external onlyOwner {
        withdrawFeePercent = _feePercent;
        withdrawFeePrecision = _feePrecision;
    }

    function deposit(LockType _lockType, uint256 _amount, bool _comp) external {
        require(_amount > 0, "The amount of the deposit must not be zero");
        require(erc20Deposit.allowance(_msgSender(), address(this)) >= _amount, "Not enough allowance");
        LockType lastLock = userLock[_msgSender()];
        require(lastLock == LockType.NULL || _lockType >= lastLock, "You cannot decrease the time of locking");
        uint256 amountStacked;
        if (address(erc20Deposit) == address(erc20Reward)) {
            uint256 part = depositFeePercent * _amount / depositFeePrecision;
            amountStacked = _amount - part;
            accumulatedFee = accumulatedFee + part;
        } else {
            amountStacked = _amount;
        }

        erc20Deposit.safeTransferFrom(_msgSender(), address(this), _amount);
        if (_lockType >= lastLock) {
            (uint256 amountReward, uint32 lastRewardIndex) = getReward(_msgSender(), 0);
            require(lastRewardIndex == lastReward, "We cannot get reward in one transaction");
            if (amountReward > 0) {
                if (_comp && address(erc20Deposit) == address(erc20Reward)) {
                    _compound(lastLock, amountReward, lastRewardIndex);
                } else {
                    _harvest(lastLock, amountReward, lastRewardIndex);
                }
            }
        }
        userLock[_msgSender()] = _lockType;
        if (lastLock == LockType.NULL || _lockType == lastLock) {
            // If we deposit to current stacking period, or make first deposit
            userStacked[_msgSender()] = userStacked[_msgSender()] + amountStacked;
            totalStacked[_lockType] = totalStacked[_lockType] + amountStacked;
        } else if (_lockType > lastLock) {
            // If we increase stacking period
            totalStacked[lastLock] = totalStacked[lastLock] - userStacked[_msgSender()];
            userStacked[_msgSender()] = userStacked[_msgSender()] + amountStacked;
            totalStacked[_lockType] = totalStacked[_lockType] + userStacked[_msgSender()];
        }
        userLastReward[_msgSender()] = lastReward;
        if (lastLock == LockType.NULL || _lockType > lastLock) {
            // If we have first deposit, or increase lock time
            expirationDeposit[_msgSender()] = block.timestamp + locks[_lockType].period;
        }
        emit Deposit(_lockType, _amount, amountStacked);
    }

    function withdraw(uint256 amount) external {
        require(userStacked[_msgSender()] >= amount, "Withdrawal amount is more than balance");
        require(userLock[_msgSender()] != LockType.NULL, "You do not have locked tokens");
        require(
            block.timestamp > expirationDeposit[_msgSender()] || unlockAll,
            "Expiration time of the deposit is not over"
        );
        (uint256 amountReward, uint32 lastRewardIndex) = getReward(_msgSender(), 0);
        require(lastRewardIndex == lastReward, "We cannot get reward in one transaction");
        if (amountReward > 0) {
            _harvest(userLock[_msgSender()], amountReward, lastRewardIndex);
        }
        uint256 amountWithdraw;
        if (address(erc20Deposit) == address(erc20Reward)) {
            uint256 part = withdrawFeePercent * amount / withdrawFeePrecision;
            amountWithdraw = amount - part;
            accumulatedFee = accumulatedFee + part;
        } else {
            amountWithdraw = amount;
        }
        totalStacked[userLock[_msgSender()]] = totalStacked[userLock[_msgSender()]] - amount;
        userStacked[_msgSender()] = userStacked[_msgSender()] - amount;
        if (userStacked[_msgSender()] == 0) {
            userLock[_msgSender()] = LockType.NULL;
        }
        erc20Deposit.safeTransfer(_msgSender(), amountWithdraw);
        emit Withdraw(amount, amountWithdraw);
    }

    function reward(uint256 amount) external onlyOwner {
        require(amount > 0, "The amount of the reward must not be zero");
        require(erc20Reward.allowance(_msgSender(), address(this)) >= amount, "Not enough allowance");
        erc20Reward.safeTransferFrom(_msgSender(), address(this), amount);
        uint256 _stakedWithMultipliers = stakedWithMultipliers();
        uint256 amountWithAccumFee = address(erc20Deposit) == address(erc20Reward) ? amount + accumulatedFee : amount;
        uint256 distributed;
        uint32 _lastReward = lastReward + 1;
        for (uint8 i = 0; i < lockTypes.length; i++) {
            if (i == lockTypes.length - 1) {
                uint256 remainder = amountWithAccumFee - distributed;
                rewards[lockTypes[i]][_lastReward] = Reward(
                    remainder,
                    totalStacked[lockTypes[i]]
                );
                break;
            }
            uint256 staked = stakedWithMultiplier(lockTypes[i]);
            uint256 amountPart = staked * precision * amountWithAccumFee / _stakedWithMultipliers / precision;
            rewards[lockTypes[i]][_lastReward] = Reward(
                amountPart,
                totalStacked[lockTypes[i]]
            );
            distributed += amountPart;
        }
        lastReward = _lastReward;
        emit RewardPay(amount, accumulatedFee);
        accumulatedFee = 0;
    }

    function compound() public {
        require(userLock[_msgSender()] != LockType.NULL, "You do not have locked tokens");
        require(address(erc20Deposit) == address(erc20Reward), "Method not available");
        require(userLastReward[_msgSender()] != lastReward, "You have no accumulated reward");
        (uint256 amountReward, uint32 lastRewardIndex) = getReward(_msgSender(), 0);
        _compound(userLock[_msgSender()], amountReward, lastRewardIndex);
    }

    function harvest() public {
        require(userLock[_msgSender()] != LockType.NULL, "You do not have locked tokens");
        require(userLastReward[_msgSender()] != lastReward, "You have no accumulated reward");
        (uint256 amountReward, uint32 lastRewardIndex) = getReward(_msgSender(), 0);
        _harvest(userLock[_msgSender()], amountReward, lastRewardIndex);
    }

    function _compound(LockType _userLock, uint256 _amountReward, uint32 lastRewardIndex) internal {
        userStacked[_msgSender()] = userStacked[_msgSender()] + _amountReward;
        totalStacked[_userLock] = totalStacked[_userLock] + _amountReward;
        userLastReward[_msgSender()] = lastRewardIndex;
        emit Compound(_userLock, _amountReward, lastRewardIndex);
    }

    function _harvest(LockType _userLock, uint256 _amountReward, uint32 lastRewardIndex) internal {
        userLastReward[_msgSender()] = lastRewardIndex;
        erc20Reward.safeTransfer(_msgSender(), _amountReward);
        emit Harvest(_userLock, _amountReward, lastRewardIndex);
    }

    function stakedWithMultipliers() public view returns (uint256) {
        uint256 reserves;
        for (uint8 i = 0; i < lockTypes.length; i++) {
            reserves = reserves + stakedWithMultiplier(lockTypes[i]);
        }
        return reserves;
    }

    function totalStakedInPools() public view returns (uint256) {
        uint256 reserves;
        for (uint8 i = 0; i < lockTypes.length; i++) {
            reserves = reserves + totalStacked[lockTypes[i]];
        }
        return reserves;
    }

    function stakedWithMultiplier(LockType _lockType) public view returns (uint256) {
        return totalStacked[_lockType] * locks[_lockType].multiplicator / 10;
    }

    function getReward(address _user, uint32 _lastRewardIndex) public view returns (uint256 amount, uint32 lastRewardIndex) {
        uint256 _amount;
        if (userLock[_user] == LockType.NULL) {
            return (0, lastReward);
        }
        uint32 rewardIterator = _lastRewardIndex != 0 ? _lastRewardIndex : userLastReward[_user];
        uint32 maxRewardIterator = lastReward - rewardIterator > MAX_LOOPS
        ? rewardIterator + MAX_LOOPS
        : lastReward;
        while (rewardIterator < maxRewardIterator) {
            rewardIterator++;
            Reward memory reward = rewards[userLock[_user]][rewardIterator];
            _amount = _amount + (userStacked[_user] * precision * reward.amount / reward.totalStacked  / precision);
        }
        lastRewardIndex = rewardIterator;
        amount = _amount;
    }
}

{
  "compilationTarget": {
    "contracts/TimeWarpPool.sol": "TimeWarpPool"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}