// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastValue;
                // Update the index for the moved value
                set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: Unlicense
// Version 0.0.1

pragma solidity ^0.8.17;

import "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "./IEve.sol";
import "./utils.sol";

contract GenesisStoneEveStaking is AccessControl {
    // Using
    using EnumerableSet for EnumerableSet.UintSet;

    // Struct
    struct StakedNFTInfo {
        address stakedBy; // Address of the staker. Once set, never changes. If never staked, the value is zero address.
        uint64 stakedTime; // Staked time. 0 if not currently staked
        bool minted; // whether the nft has been used to min an Eve
    }

    struct StakerInfo {
        EnumerableSet.UintSet stakedNFTs; // The CURRENTLY staked tokenIds
        EnumerableSet.UintSet mintedNFTs; // minted tokenIds
        bool fiveStonesMinted; // whether the staker has minted the five stones reward
        bool tenStonesMinted; // whether the staker has minted the ten stones reward
    }

    // Events
    event EveMinted(uint256 indexed tokenId, uint8 indexed mintType); // mintType defined in constants

    // Constants
    uint8 public constant MINT_TYPE_NORMAL = 0;
    uint8 public constant MINT_TYPE_MYTHIC = 1;
    uint8 public constant MINT_TYPE_FIVE = 2;
    uint8 public constant MINT_TYPE_TEN = 3;
    uint16 public constant MAX_GENESISSTONE_NFTS = 1000;
    IERC721 public immutable GENESIS_STONE_CONTRACT;
    IEve public immutable EVE_CONTRACT;

    // Public variables
    uint256 public stakingPeriod;

    // Private variables
    mapping(uint256 => StakedNFTInfo) private _stakedNFTInfos; // tokenId => StakedNFTInfo
    mapping(address => StakerInfo) private _stakerInfos; // staker => StakerInfo

    /// @notice Initializes a new instance of the GenesisStoneStaking contract.
    /// @dev Grants the DEFAULT_ADMIN_ROLE to the defaultAdmin_ address
    /// @param defaultAdmin_ The address to be granted the DEFAULT_ADMIN_ROLE.
    /// @param genesisStoneContract_ The address of the deployed GenesisStone contract.
    /// @param eveContract_ The address of the deployed Eve contract.
    /// @param stakingPeriod_ The staking period in seconds.
    constructor(
        address defaultAdmin_,
        address genesisStoneContract_,
        address eveContract_,
        uint256 stakingPeriod_
    ) {
        if (defaultAdmin_ == address(0)) {
            revert Utils.AdminIsZeroAddress();
        }
        _grantRole(DEFAULT_ADMIN_ROLE, defaultAdmin_);

        if (!Utils.contractExists(genesisStoneContract_)) {
            revert Utils.ContractDoesNotExist();
        }
        GENESIS_STONE_CONTRACT = IERC721(genesisStoneContract_);

        if (!Utils.contractExists(eveContract_)) {
            revert Utils.ContractDoesNotExist();
        }
        EVE_CONTRACT = IEve(eveContract_);

        if (stakingPeriod_ == 0) {
            revert Utils.StakingPeriodIsZero();
        }
        stakingPeriod = stakingPeriod_;
    }

    /// @notice Stakes multiple GenesisStone NFTs
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds that will be staked
    function stake(uint256[] calldata tokenIds_) external {
        for (uint256 i = 0; i < tokenIds_.length; ) {
            uint256 tokenId = tokenIds_[i];

            if (_stakedNFTInfos[tokenId].stakedBy != address(0)) {
                revert Utils.TokenAlreadyStaked();
            }

            if (GENESIS_STONE_CONTRACT.ownerOf(tokenId) != msg.sender) {
                revert Utils.NotTheOwnerOfTheToken();
            }

            _stakedNFTInfos[tokenId].stakedBy = msg.sender;
            _stakedNFTInfos[tokenId].stakedTime = uint64(block.timestamp);
            _stakerInfos[msg.sender].stakedNFTs.add(tokenId);
            GENESIS_STONE_CONTRACT.transferFrom(
                msg.sender,
                address(this),
                tokenId
            );

            unchecked {
                ++i;
            }
        }
    }

    /// @notice Sets the staking period
    /// @param stakingPeriod_ The new staking period
    function setStakingPeriod(
        uint256 stakingPeriod_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        stakingPeriod = stakingPeriod_;
    }

    /// @notice Checks if the given GenesisStone NFTs are already staked
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds
    /// @return An array of bool values indicating the staking status of each tokenId
    function isAlreadyStaked(
        uint256[] calldata tokenIds_
    ) external view returns (bool[] memory) {
        bool[] memory results = new bool[](tokenIds_.length);

        for (uint256 i = 0; i < tokenIds_.length; ) {
            results[i] = _stakedNFTInfos[tokenIds_[i]].stakedBy != address(0);

            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @notice Returns the staker of the given GenesisStone NFTs
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds
    /// @return An array of addresses, where each address is the staker of the corresponding tokenId
    function stakerOf(
        uint256[] calldata tokenIds_
    ) external view returns (address[] memory) {
        address[] memory results = new address[](tokenIds_.length);

        for (uint256 i = 0; i < tokenIds_.length; ) {
            results[i] = _stakedNFTInfos[tokenIds_[i]].stakedBy;
            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @notice Returns the staked GenesisStone NFTs of the given user
    /// @param user_ The address of the user
    /// @return An array of GenesisStone NFT tokenIds staked by the user
    function stakedNFTOf(
        address user_
    ) external view returns (uint256[] memory) {
        EnumerableSet.UintSet storage stakedTokens = _stakerInfos[user_]
            .stakedNFTs;
        uint256 stakedCount = stakedTokens.length();

        uint256[] memory results = new uint256[](stakedCount);
        for (uint256 i = 0; i < stakedCount; ) {
            results[i] = stakedTokens.at(i);
            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @notice Returns all staked GenesisStone NFTs.
    /// This function should only be called off-chain. An on-chain call to this function will be extremely expensive.
    /// @return An array of staked GenesisStone NFT tokenIds
    function getAllStakedNFTs() external view returns (uint256[] memory) {
        // Figure out how many NFTs are currently staked and create the results array
        uint256[] memory results = new uint256[](
            GENESIS_STONE_CONTRACT.balanceOf(address(this))
        );

        // Scan through all the NFT ids of GenesisStone
        uint256 count = 0;
        for (uint256 i = 0; i < MAX_GENESISSTONE_NFTS; ) {
            unchecked {
                if (_stakedNFTInfos[i].stakedTime != 0) {
                    results[count++] = i;
                }
                ++i;
            }
        }
        return results;
    }

    /// @dev Checks if staking is complete for each tokenId in the provided array.
    /// @param tokenIds_ An array of tokenIds for which the staking completion status will be checked.
    /// @return results An array of bool values indicating staking completion status for each corresponding tokenId.
    /// Each value in the results array is 'true' if staking is complete for the tokenId, and 'false' otherwise.
    function isStakingComplete(
        uint256[] calldata tokenIds_
    ) external view returns (bool[] memory) {
        bool[] memory results = new bool[](tokenIds_.length);

        for (uint256 i = 0; i < tokenIds_.length; ) {
            results[i] = _stakingComplete(tokenIds_[i]);
            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @dev Checks if staking is complete for the given tokenId.
    /// @param tokenId_ The tokenId for which the staking completion status will be checked.
    /// @return True if staking is complete for the tokenId
    function _stakingComplete(uint256 tokenId_) private view returns (bool) {
        unchecked {
            return
                _stakedNFTInfos[tokenId_].stakedTime != 0 &&
                block.timestamp >=
                _stakedNFTInfos[tokenId_].stakedTime + stakingPeriod;
        }
    }

    /// @notice Returns the staking timestamps of the given GenesisStone NFTs
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds
    /// @return results An array of timestamps, where each timestamp corresponds to the staking time of the tokenId
    function stakedNFTTime(
        uint256[] calldata tokenIds_
    ) external view returns (uint64[] memory) {
        uint64[] memory results = new uint64[](tokenIds_.length);

        for (uint256 i = 0; i < tokenIds_.length; ) {
            results[i] = _stakedNFTInfos[tokenIds_[i]].stakedTime;
            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @dev Returns the number of currently staked GenesisStone NFTs
    /// @return result The number of currently staked GenesisStone NFTs
    function _completedStakes(
        address user_
    ) private view returns (uint256 result) {
        EnumerableSet.UintSet storage stakedTokens = _stakerInfos[user_]
            .stakedNFTs;
        uint256 stakedCount = stakedTokens.length();
        for (uint256 i = 0; i < stakedCount; ) {
            uint256 tokenId = stakedTokens.at(i);
            unchecked {
                if (_stakingComplete(tokenId)) {
                    ++result;
                }
                ++i;
            }
        }
        return result;
    }

    /// @notice Returns the number of currently completed stakes for a user
    /// @param user_ The address of the user
    /// @return result The number of completed stakes for the user
    function completedStakes(address user_) external view returns (uint256) {
        return _completedStakes(user_);
    }

    /// @dev Checks if the given tokenId is a mythic GenesisStone NFT
    /// @param tokenId_ The tokenId of the GenesisStone NFT
    function _isMythicStone(uint256 tokenId_) private pure returns (bool) {
        return tokenId_ < 9 || tokenId_ == 999;
    }

    /// @dev Checks if the given tokenId has been used to mint a Eve
    /// @param tokenId_ The tokenId of the GenesisStone NFT
    function _isMinted(uint256 tokenId_) internal view returns (bool) {
        return _stakedNFTInfos[tokenId_].minted;
    }

    /// @notice Checks if the given tokenIds have been used for Eve minting
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds
    /// @return results An array of bool values indicating whether each tokenId has been used for Eve minting
    function hasBeenUsedForMinting(
        uint256[] calldata tokenIds_
    ) external view returns (bool[] memory) {
        bool[] memory usedForMinting = new bool[](tokenIds_.length);

        for (uint256 i = 0; i < tokenIds_.length; ) {
            usedForMinting[i] = _isMinted(tokenIds_[i]);
            unchecked {
                ++i;
            }
        }

        return usedForMinting;
    }

    /// @notice Returns the minted Eve NFTs for the given user
    /// @param user_ The address of the user
    /// @return results An array of Eve NFT tokenIds
    function getMintedNFTs(
        address user_
    ) external view returns (uint256[] memory) {
        EnumerableSet.UintSet storage mintedTokens = _stakerInfos[user_]
            .mintedNFTs;
        uint256 mintedCount = mintedTokens.length();

        uint256[] memory results = new uint256[](mintedCount);
        for (uint256 i = 0; i < mintedCount; ) {
            results[i] = mintedTokens.at(i);
            unchecked {
                ++i;
            }
        }

        return results;
    }

    /// @notice Returns the number of normal Eve NFTs that can be minted for the given user
    /// @param user_ The address of the user
    /// @return result The number of normal Eve NFTs that can be minted for the user
    function numOfNormalEveMintable(
        address user_
    ) external view returns (uint256 result) {
        EnumerableSet.UintSet storage stakedTokens = _stakerInfos[user_]
            .stakedNFTs;
        uint256 stakedCount = stakedTokens.length();
        for (uint256 i = 0; i < stakedCount; ) {
            uint256 tokenId = stakedTokens.at(i);
            unchecked {
                if (
                    !_isMythicStone(tokenId) &&
                    _stakingComplete(tokenId) &&
                    !_isMinted(tokenId)
                ) {
                    ++result;
                }
                ++i;
            }
        }

        return result;
    }

    /// @notice Returns the number of mythic Eve NFTs that can be minted for the given user
    /// @param user_ The address of the user
    /// @return result The number of mythic Eve NFTs that can be minted for the user
    function numOfMythicEveMintable(
        address user_
    ) external view returns (uint256 result) {
        EnumerableSet.UintSet storage stakedTokens = _stakerInfos[user_]
            .stakedNFTs;
        uint256 stakedCount = stakedTokens.length();
        for (uint256 i = 0; i < stakedCount; ) {
            uint256 tokenId = stakedTokens.at(i);
            unchecked {
                if (
                    _isMythicStone(tokenId) &&
                    _stakingComplete(tokenId) &&
                    !_isMinted(tokenId)
                ) {
                    ++result;
                }

                ++i;
            }
        }

        return result;
    }

    /// @notice Mints a number of Eve NFTs for the caller
    /// @param tokenIds_ An array of GenesisStone NFT tokenIds
    function mintEve(uint256[] calldata tokenIds_) external {
        for (uint256 i = 0; i < tokenIds_.length; ) {
            if (_stakedNFTInfos[tokenIds_[i]].stakedBy != msg.sender) {
                revert Utils.NotTheOwnerOfTheToken();
            }

            if (_isMinted(tokenIds_[i])) {
                revert Utils.AlreadyMinted();
            }

            if (!_stakingComplete(tokenIds_[i])) {
                revert Utils.StakingNotCompleted();
            }

            bool isMythic = _isMythicStone(tokenIds_[i]);

            // Transfer the staked NFT back to the user
            _stakedNFTInfos[tokenIds_[i]].stakedTime = 0;
            _stakerInfos[msg.sender].stakedNFTs.remove(tokenIds_[i]);
            GENESIS_STONE_CONTRACT.transferFrom(
                address(this),
                msg.sender,
                tokenIds_[i]
            );

            // Mint the NFT
            _stakedNFTInfos[tokenIds_[i]].minted = true;
            uint256[] memory tokenIds = isMythic
                ? EVE_CONTRACT.mintMythic(msg.sender, 1)
                : EVE_CONTRACT.mintNormal(msg.sender, 1);

            // Emit event for the minted Eve tokenId
            _stakerInfos[msg.sender].mintedNFTs.add(tokenIds[0]);
            emit EveMinted(
                tokenIds[0],
                isMythic ? MINT_TYPE_MYTHIC : MINT_TYPE_NORMAL
            );

            unchecked {
                ++i;
            }
        }
    }

    /// @notice Returns if the user can mint a normal Eve using five staked Genesis Stones
    /// @param user_ The address of the user
    /// @return True if the user can mint a normal Eve using five staked Genesis Stones
    function fiveStonesMintable(address user_) external view returns (bool) {
        return
            !_stakerInfos[user_].fiveStonesMinted &&
            _completedStakes(user_) > 4;
    }

    /// @notice Checks whether the specified user has minted Eve with five stones.
    /// @param user_ The address of the user to check.
    /// @return A boolean value indicating whether the user has minted Eve with five stones.
    function hasMintedEveWithFiveStones(
        address user_
    ) external view returns (bool) {
        return _stakerInfos[user_].fiveStonesMinted;
    }

    /// @notice Mint a normal Eve using five staked Genesis Stones
    function mintEveWithFiveStones() external {
        if (_stakerInfos[msg.sender].fiveStonesMinted) {
            revert Utils.AlreadyMinted();
        }

        if (_completedStakes(msg.sender) < 5) {
            revert Utils.NotEnoughStakedGenesisStones();
        }

        // Mint the NFT
        _stakerInfos[msg.sender].fiveStonesMinted = true;
        uint256[] memory tokenIds = EVE_CONTRACT.mintNormal(msg.sender, 1);

        // Record and Emit events for each of the tokenIds
        _stakerInfos[msg.sender].mintedNFTs.add(tokenIds[0]);
        emit EveMinted(tokenIds[0], MINT_TYPE_FIVE);
    }

    /// @notice Returns if the user can mint a mythic Eve using ten staked Genesis Stones
    /// @param user_ The address of the user
    /// @return True if the user can mint a mythic Eve using ten staked Genesis Stones
    function tenStonesMintable(address user_) external view returns (bool) {
        return
            !_stakerInfos[user_].tenStonesMinted && _completedStakes(user_) > 9;
    }

    /// @notice Checks whether the specified user has minted Eve with ten stones.
    /// @param user_ The address of the user to check.
    /// @return A boolean value indicating whether the user has minted Eve with ten stones.
    function hasMintedEveWithTenStones(
        address user_
    ) external view returns (bool) {
        return _stakerInfos[user_].tenStonesMinted;
    }

    /// @notice Mint a mythic Eve using ten staked Genesis Stones
    function mintEveWithTenStones() external {
        if (_stakerInfos[msg.sender].tenStonesMinted) {
            revert Utils.AlreadyMinted();
        }

        if (_completedStakes(msg.sender) < 10) {
            revert Utils.NotEnoughStakedGenesisStones();
        }

        // Mint the NFT
        _stakerInfos[msg.sender].tenStonesMinted = true;
        uint256[] memory tokenIds = EVE_CONTRACT.mintMythic(msg.sender, 1);

        // Record and Emit events for each of the tokenIds
        _stakerInfos[msg.sender].mintedNFTs.add(tokenIds[0]);
        emit EveMinted(tokenIds[0], MINT_TYPE_TEN);
    }

    /// @dev Performs an emergency transfer of the specified token to the specified address.
    /// Only the account with the DEFAULT_ADMIN_ROLE can invoke this function.
    /// @param tokenId_ The ID of the token to be transferred.
    /// @param to_ The address to which the token will be transferred.
    function emergencyTransfer(
        uint256 tokenId_,
        address to_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        if (_stakedNFTInfos[tokenId_].stakedTime != 0) {
            revert Utils.TokenIsStaked();
        }

        GENESIS_STONE_CONTRACT.transferFrom(address(this), to_, tokenId_);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: Unlicense
// Version 0.0.1

pragma solidity ^0.8.17;

interface IEve {
    function mintNormal(
        address to_,
        uint256 quantity_
    ) external returns (uint256[] memory);

    function mintMythic(
        address to_,
        uint256 quantity_
    ) external returns (uint256[] memory);

    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    function exists(uint256 tokenId) external view returns (bool);

    function nextTokenId() external view returns (uint256);

    function nextMythicTokenId() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator
    ) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1);

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator,
        Rounding rounding
    ) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10**64) {
                value /= 10**64;
                result += 64;
            }
            if (value >= 10**32) {
                value /= 10**32;
                result += 32;
            }
            if (value >= 10**16) {
                value /= 10**16;
                result += 16;
            }
            if (value >= 10**8) {
                value /= 10**8;
                result += 8;
            }
            if (value >= 10**4) {
                value /= 10**4;
                result += 4;
            }
            if (value >= 10**2) {
                value /= 10**2;
                result += 2;
            }
            if (value >= 10**1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}

// SPDX-License-Identifier: Unlicense
// Version 0.0.1

pragma solidity ^0.8.17;

/**
 * @dev Collection of utility functions
 */
library Utils {
    /**
     * Default admin is zero address
     */
    error AdminIsZeroAddress();

    /**
     * Default owner is zero address
     */
    error OwnerIsZeroAddress();

    /**
     * Royalty is zero
     */
    error RoyaltyIsZero();

    /**
     * The signature is invalid
     */
    error InvalidSignature();

    /**
     * The number of NFTs exceeds the limit
     */
    error NFTQuantityExceedsLimit();

    /**
     * Transfer ownership to zero address
     */
    error TransferOwnershipToZeroAddress();

    /**
     * Unmatched Array lengths
     */
    error UnmatchedArrayLengths();

    /**
     * Contract does not exist at the address
     */
    error ContractDoesNotExist();

    /**
     * Staking Period Is Zero
     */
    error StakingPeriodIsZero();

    /**
     * Quantity Is Zero
     */
    error QuantityIsZero();

    /**
     * Allowed Quantity Is Zero
     */
    error AllowedQuantityIsZero();

    /**
     * Input quantity exceeds allowed quantity
     */
    error ExceedsAllowedQuantity();

    /**
     * The person is not whitelisted
     */
    error NotWhitelisted();

    /**
     * Token Already Staked
     */
    error TokenAlreadyStaked();

    /**
     * Not The Owner Of The Token
     */
    error NotTheOwnerOfTheToken();

    /**
     * Not enough staked Genesis Stones
     */
    error NotEnoughStakedGenesisStones();

    /**
     * Already Minted with the method
     */
    error AlreadyMinted();

    /**
     * Not Staked
     */
    error NotStaked();

    /**
     * Staking Not Completed
     */
    error StakingNotCompleted();

    /**
     * Invalid addrses
     */
    error InvalidAddress();

    /**
     * Token Is Staked
     */
    error TokenIsStaked();

    /**
     * Not A Mythic Stone
     */
    error NotAMythicStone();

    /**
     * Not A Normal Stone
     */
    error NotANormalStone();

    /**
     * Incorrect NFT Id 
     */
    error IncorrectNFTId();

    /**
     * Incorrect Data
     */
    error IncorrectData();

    function contractExists(address addr) internal view returns (bool) {
        uint size;
        assembly {
            size := extcodesize(addr)
        }
        return (size > 0);
    }
}

{
  "compilationTarget": {
    "contracts/GenesisStoneEveStaking.sol": "GenesisStoneEveStaking"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 800
  },
  "remappings": []
}