// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

contract PKNVesting is Ownable {

    uint256 private constant ONE_MONTH = 30 days;
    uint256 public immutable START_TIME;
    uint256 public immutable DURATION_MONTHS;
    uint256 public totalAllocations;

    IERC20 public PKN;

    struct Allocation {
        uint256 amount;
        uint256 amountClaimed;
        uint256 monthsClaimed;
    }

    mapping (address => Allocation) public PKNAllocations;

    constructor(address _PKN, uint256 _startTime, uint256 _numOfMonths) {
        PKN = IERC20(_PKN);
        START_TIME = _startTime;
        DURATION_MONTHS = _numOfMonths;
    }

    function getVestedAmount(address _recipient) public view returns(uint256 monthsVested, uint256 amountVested) {
        Allocation storage PKNAllocation = PKNAllocations[_recipient];

        require(PKNAllocation.amountClaimed < PKNAllocation.amount, "Allocation fully claimed");

        if (_currentTime() < START_TIME) {
            return (0, 0);
        }

        uint256 elapsedMonths = 1 + (_currentTime() - START_TIME) / ONE_MONTH;

        if(elapsedMonths >= DURATION_MONTHS) {
            uint256 remainingAllocation = PKNAllocation.amount - PKNAllocation.amountClaimed;
            return (DURATION_MONTHS, remainingAllocation);
        }

        monthsVested = elapsedMonths - PKNAllocation.monthsClaimed;
        amountVested = monthsVested * (PKNAllocation.amount / DURATION_MONTHS);
    }

    function getAllocationDetails(address _recipient) external view returns(Allocation memory) {
        return PKNAllocations[_recipient];
    }

    function addAllocation(address[] calldata _recipients, uint256[] calldata _amounts) external onlyOwner {
        require(_recipients.length == _amounts.length, "Invalid input lengths");
        uint256 totalAmount = 0;
        for (uint256 i = 0; i < _recipients.length; i++) {
            totalAmount += _amounts[i];
            _addAllocation(_recipients[i], _amounts[i]);
        }
        totalAllocations += _recipients.length;
        require(_receivePKN(msg.sender, totalAmount) == totalAmount, "Recieved less PKN than transferred");
    }

    function releaseVestedTokens() external {
        _releaseVestedTokens(msg.sender);
    }

    function batchReleaseVestedTokens(address[] calldata _recipients) external {
        for (uint256 i = 0; i < _recipients.length; i++) {
            _releaseVestedTokens(_recipients[i]);
        }
    }

    // DOES NOT transfer PKN to the contract. Needs to be handled by the caller.
    function _addAllocation(address _recipient, uint256 _amount) internal {
        require(PKNAllocations[_recipient].amount == 0, "Allocation already exists");
        require(_amount >= DURATION_MONTHS, "Amount too low");

        Allocation memory allocation = Allocation({
            amount: _amount,
            amountClaimed: 0,
            monthsClaimed: 0
        });
        PKNAllocations[_recipient] = allocation;
    }

    function _releaseVestedTokens(address _recipient) internal {
        (uint256 monthsVested, uint256 amountVested) = getVestedAmount(_recipient);
        require(amountVested > 0, "Vested amount is 0");

        Allocation storage PKNAllocation = PKNAllocations[_recipient];
        PKNAllocation.monthsClaimed = PKNAllocation.monthsClaimed + monthsVested;
        PKNAllocation.amountClaimed = PKNAllocation.amountClaimed + amountVested;

        PKN.transfer(_recipient, amountVested);
    }

    function _receivePKN(address from, uint256 amount) internal returns(uint256) {
        uint256 balanceBefore = PKN.balanceOf(address(this));
        PKN.transferFrom(from, address(this), amount);
        uint256 balanceAfter = PKN.balanceOf(address(this));
        return balanceAfter - balanceBefore;
    }

    function _currentTime() internal view returns(uint256) {
        return block.timestamp;
    }
}

{
  "compilationTarget": {
    "vesting.sol": "PKNVesting"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}