Yidocy

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;


/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/interfaces/draft-IERC6093.sol


// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;





/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// File: @openzeppelin/contracts/access/IAccessControl.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// File: @openzeppelin/contracts/utils/introspection/IERC165.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/utils/introspection/ERC165.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;


/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// File: @openzeppelin/contracts/access/AccessControl.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;




/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// File: IRewardPool.sol



pragma solidity ^0.8.0;

interface IRewardPool {
    function notifyReward(uint256 amount) external;
    function getUserStakingBalance(address account) external view returns(uint256);
    function deposit(address staker, uint256 amount) external;
}

// File: YidocyToken.sol



pragma solidity ^0.8.0;




contract YidocyToken is ERC20, AccessControl {
    uint256 internal immutable _supplyCap;
    IRewardPool internal _rewardPool;

    struct VestingSchedule {
        uint256 validFromDate;
        uint256 amount;
    }
    struct LockupInfo {
        uint256 lockupAmount;
        uint256 code; // 1: Team, 2: Advisor, 3: Private Sale
        address rewardPoolAddress;
        VestingSchedule[] vestingSchedules;
    }
    address[] internal _userLockupAddresses;
    mapping(address => LockupInfo) internal _userLockups;

    address[] internal _adminRoleMembers;

    struct AdminRoleRequest {
        address newAdmin;
        address revokeAdmin;
        uint256 action; // 1: add, 2: revoke, 3: transfer
        uint256 status; // 0: requested, 1: executed, 2: rejected
        address requestedAdmin;
        address approvedAdmin;
        address rejectedAdmin;
    }
    mapping(uint256 => AdminRoleRequest) internal _adminRoleRequests;
    uint256 internal _adminRoleRequestCount;

    event AdminRoleTransferred(address indexed currentAdmin, address indexed newAdmin, uint256 requestId);
    event AdminRoleAdded(address indexed performedAdmin, address indexed newAdmin, uint256 requestId);
    event AdminRoleRevoked(address indexed performedAdmin, address indexed revokedAdmin, uint256 requestId);
    event AdminRoleRequested(address indexed requesteAdmin, uint256 action, uint256 requestId);
    event AdminRoleRejected(address indexed rejectedAdmin, uint256 action, uint256 requestId);

    modifier onlyAdmin() {
        require(_isAdmin(msg.sender), "YidocyToken : Restricted to admins.");
        _;
    }

    constructor(address[] memory multiAdminRoles, uint256 supplyCap) ERC20("Yidocy", "YIDO") {
        require(multiAdminRoles.length > 1, "YidocyToken : Number of multiAdminRoles must be over 1");
        for (uint256 i = 0; i < multiAdminRoles.length; i++) {
            require(multiAdminRoles[i] != address(0), "YidocyToken : multiAdminRole address could not be zero");
            require(multiAdminRoles[i] != msg.sender, "YidocyToken : Except contructor, number of multiAdminRoles must be over 1");
        }
        _grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
        _adminRoleMembers.push(msg.sender);
        for (uint256 i = 0; i < multiAdminRoles.length; i++) {
            _adminRoleMembers.push(multiAdminRoles[i]);
            _grantRole(DEFAULT_ADMIN_ROLE, multiAdminRoles[i]);
        }
        _supplyCap = supplyCap;
        _mint(msg.sender, _supplyCap);    
    }

    function decimals() public view virtual override returns (uint8) {
        return 8;
    }

    function getLockupUsers() external view returns(address[] memory) {
        return _userLockupAddresses;
    }

    function getUserLockup(address account) external view returns(
        uint256 lockupAmount,
        uint256 code,
        uint256[] memory vestingValidFromDateList,
        uint256[] memory vestingAmountList
    ) {
        lockupAmount = 0;
        LockupInfo memory userLockup = _userLockups[account];
        if (userLockup.lockupAmount > 0) {
            lockupAmount = userLockup.lockupAmount;
            code = userLockup.code;
            vestingValidFromDateList = new uint256[](userLockup.vestingSchedules.length);
            vestingAmountList = new uint256[](userLockup.vestingSchedules.length);
            for (uint256 i = 0; i < userLockup.vestingSchedules.length; i++) {
                vestingValidFromDateList[i] = userLockup.vestingSchedules[i].validFromDate;
                vestingAmountList[i] = userLockup.vestingSchedules[i].amount;
            }
        }
    }

    function transferableAmount(address sender, address recipient) internal view returns (uint256){
        uint256 senderBalanceOf = balanceOf(sender);
        LockupInfo memory userLockup = _userLockups[sender];
        if (userLockup.lockupAmount == 0 || userLockup.rewardPoolAddress == recipient) {
            return senderBalanceOf;
        }
        uint256 senderStakingBalanceOf = IRewardPool(userLockup.rewardPoolAddress).getUserStakingBalance(sender);
        uint256 amount = senderBalanceOf + senderStakingBalanceOf;
        uint256 nowTimestamp = uint256(block.timestamp);
        uint256 vestingScheduleLength = userLockup.vestingSchedules.length;
        for (uint256 i = 0; i < vestingScheduleLength; i++) {
            if (userLockup.vestingSchedules[i].validFromDate > nowTimestamp) {
                if (amount < userLockup.vestingSchedules[i].amount) {
                    return 0;
                }
                amount -= userLockup.vestingSchedules[i].amount;
            }
        }
        if (amount >= senderBalanceOf) {
            return senderBalanceOf;
        }
        return amount;
    }

    function stakeToken(uint256 amount) external {
        transfer(address(_rewardPool), amount);
        _rewardPool.deposit(msg.sender, amount);
    }

    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        require(transferableAmount(_msgSender(), recipient)  >= amount, "YidocyToken : Cannot transfer more than transferable amount");
        return super.transfer(recipient, amount);
    }

    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        require(transferableAmount(sender, recipient)  >= amount, "YidocyToken : Cannot transfer from more than transferable amount");
        return super.transferFrom(sender, recipient, amount);
    }

    function mint() external pure {
        revert("YidocyToken : mint is not supported for this TOKEN!!");
    }
    function setRewardPool(address rewardPool) external onlyAdmin {
        require(address(_rewardPool) == address(0), "YidocyToken : setRewardPool must called once at the deploy time");
        require(rewardPool != address(0), "YidocyToken : RewardPool address is required");
        _rewardPool = IRewardPool(rewardPool);
    }

    function burn() external pure {
        revert("YidocyToken : burn is not supported for this TOKEN!!");
    }

    function setUserLockup(
        address rewardPoolAddress,
        address account,
        uint256 lockupAmount,
        uint8 code, // 1: Team, 2: Advisor, 3: Private Sale
        uint256[] memory vestingValidFromDateList,
        uint256[] memory vestingAmountList
    ) external onlyAdmin {
        if (lockupAmount == 0) {
            delete _userLockups[account];
            uint256 addressLength = _userLockupAddresses.length;
            for (uint256 i = 0; i < addressLength; i++) {
                if (_userLockupAddresses[i] == account) {
                    delete _userLockupAddresses[i];
                    _userLockupAddresses[i] = _userLockupAddresses[addressLength-1];
                    _userLockupAddresses.pop();
                    break;
                }
            }
            return;
        }
        require(vestingValidFromDateList.length == vestingAmountList.length, "YidocyToken : Lockup date list and amount list must be the same length!");
        uint256 vestingTotalAmount = 0;
        for (uint256 i = 0; i < vestingValidFromDateList.length; i++) {
            vestingTotalAmount += vestingAmountList[i];
        }
        require(vestingTotalAmount <= lockupAmount, "YidocyToken : Lockup vesting total amount must be less or equal to the lockup amount!");

        _userLockups[account].lockupAmount = lockupAmount;
        _userLockups[account].code = code;
        _userLockups[account].rewardPoolAddress = rewardPoolAddress;
        delete _userLockups[account].vestingSchedules;
        for (uint256 i = 0; i < vestingValidFromDateList.length; i++) {
            _userLockups[account].vestingSchedules.push(VestingSchedule(vestingValidFromDateList[i], vestingAmountList[i]));
        }
        bool addressFound = false;
        uint256 userLockupAddressLength = _userLockupAddresses.length;
        for (uint256 i = 0; i < userLockupAddressLength; i++) {
            if (_userLockupAddresses[i] == account) {
                addressFound = true;
                break;
            }
        }
        if (!addressFound) {
            _userLockupAddresses.push(account);
        }
    }

    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
    }
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
    } 
    function renounceRole(bytes32 role, address callerConfirmation) public virtual override {
    }

    function _isAdmin(address account) internal view returns (bool) {
        return hasRole(DEFAULT_ADMIN_ROLE, account);
    }
    function isAdmin(address account) external view returns (bool) {
        return hasRole(DEFAULT_ADMIN_ROLE, account);
    }
    function _adminRoleMembersCount() internal view returns (uint256) {
        uint256 count = 0;
        for (uint256 i = 0; i < _adminRoleMembers.length; i++) {
            if (_adminRoleMembers[i] != address(0)) {
                count++;
            }
        }
        return count;
    }
    function adminRoleMembersCount() external view returns (uint256) {
        return _adminRoleMembersCount();
    }
    function getAdminRoleMembers() external view returns (address[] memory adminRoleMembers) {
        adminRoleMembers = new address[](_adminRoleMembersCount());
        uint256 index = 0;
        for (uint256 i = 0; i < _adminRoleMembers.length; i++) {
            if (_adminRoleMembers[i] != address(0)) {
                adminRoleMembers[index++] = _adminRoleMembers[i];
            }
        }
    }
    function getAdminRoleRequestCount() external view returns(uint256) {
        return _adminRoleRequestCount;
    }
    
    function getAdminRoleRequest(uint256 requestId) external view returns (
        address newAdmin,
        address revokeAdmin,
        uint256 action,
        uint256 status,
        address requestedAdmin,
        address approvedAdmin,
        address rejectedAdmin       
    ) {
        require(requestId < _adminRoleRequestCount, "YidocyToken : requestId does not exist");
        newAdmin = _adminRoleRequests[requestId].newAdmin;
        revokeAdmin = _adminRoleRequests[requestId].revokeAdmin;
        action = _adminRoleRequests[requestId].action;
        status = _adminRoleRequests[requestId].status;
        requestedAdmin = _adminRoleRequests[requestId].requestedAdmin;
        approvedAdmin = _adminRoleRequests[requestId].approvedAdmin;
        rejectedAdmin = _adminRoleRequests[requestId].newAdmin;
    }
    function requestTransferAdminRole(address newAdmin) external onlyAdmin returns(uint256) {
        require(newAdmin != address(0), "YidocyToken : Cannot transfer admin role to zero address");
        require(newAdmin != msg.sender, "YidocyToken : Cannot transfer admin role to the same address");
        require(_adminRoleRequestCount == 0 || _adminRoleRequests[_adminRoleRequestCount-1].status > 0, "YidocyToken : Previous AdminRole Request is pending");
        uint256 requestId = _adminRoleRequestCount;
        _adminRoleRequestCount += 1;
        _adminRoleRequests[requestId] = AdminRoleRequest({
            newAdmin: newAdmin,
            revokeAdmin: msg.sender,
            action: 3,
            status: 0,
            requestedAdmin: msg.sender,
            approvedAdmin: address(0),
            rejectedAdmin: address(0)
        });
        emit AdminRoleRequested(msg.sender, 3, requestId);
        return requestId;
    }
    function requestAddAdminRole(address newAdmin) external onlyAdmin returns(uint256) {
        require(newAdmin != address(0), "YidocyToken : Cannot add admin role for zero address");
        require(newAdmin != msg.sender, "YidocyToken : Cannot add admin role for the same address");
        require(_adminRoleRequestCount == 0 || _adminRoleRequests[_adminRoleRequestCount-1].status > 0, "YidocyToken : Previous AdminRole Request is pending");
        uint256 requestId = _adminRoleRequestCount;
        _adminRoleRequestCount += 1;
        _adminRoleRequests[requestId] = AdminRoleRequest({
            newAdmin: newAdmin,
            revokeAdmin: address(0),
            action: 1,
            status: 0,
            requestedAdmin: msg.sender,
            approvedAdmin: address(0),
            rejectedAdmin: address(0)
        });
        emit AdminRoleRequested(msg.sender, 1, requestId);
        return requestId;
    }
    function requestRevokeAdminRole(address revokeAdmin) external onlyAdmin returns(uint256) {
        require(revokeAdmin != address(0), "YidocyToken : Cannot add admin role for zero address");
        require(_adminRoleRequestCount == 0 || _adminRoleRequests[_adminRoleRequestCount-1].status > 0, "YidocyToken : Previous AdminRole Request is pending");
        uint256 requestId = _adminRoleRequestCount;
        _adminRoleRequestCount += 1;
        _adminRoleRequests[requestId] = AdminRoleRequest({
            newAdmin: address(0),
            revokeAdmin: revokeAdmin,
            action: 2,
            status: 0,
            requestedAdmin: msg.sender,
            approvedAdmin: address(0),
            rejectedAdmin: address(0)
        });
        emit AdminRoleRequested(msg.sender, 2, requestId);
        return requestId;
    }

    function executeRequestAdminRole(bool approval) external onlyAdmin returns(uint256) {
        require(_adminRoleRequestCount > 0, "YidocyToken : There is no excutable AdminRoleRequest");
        uint256 requestId = _adminRoleRequestCount-1;
        require(_adminRoleRequestCount > 0 && _adminRoleRequests[requestId].status == 0, "YidocyToken : No AdminRole Request is requested");
        require(msg.sender != _adminRoleRequests[requestId].requestedAdmin, "YidocyToken : Execute Request must be the other amdinRoler");
        if (approval) {
            _adminRoleRequests[requestId].status = 1;
            _adminRoleRequests[requestId].approvedAdmin = msg.sender;
            _adminRoleRequests[requestId].rejectedAdmin = address(0);
            if (_adminRoleRequests[requestId].action == 1) { // add new AdminRole
                _grantRole(DEFAULT_ADMIN_ROLE, _adminRoleRequests[requestId].newAdmin);
                _adminRoleMembers.push(_adminRoleRequests[requestId].newAdmin);
                emit AdminRoleAdded(msg.sender, _adminRoleRequests[requestId].newAdmin, requestId);
            } else if (_adminRoleRequests[requestId].action == 2) { // revoke AdminRole
                _revokeRole(DEFAULT_ADMIN_ROLE, _adminRoleRequests[requestId].revokeAdmin);
                for (uint256 i = 0; i < _adminRoleMembers.length; i++) {
                    if (_adminRoleMembers[i] == _adminRoleRequests[requestId].revokeAdmin) {
                        _adminRoleMembers[i] = address(0);
                        break;
                    }
                }        
                emit AdminRoleRevoked(msg.sender, _adminRoleRequests[requestId].revokeAdmin, requestId);
            } else if (_adminRoleRequests[requestId].action == 3) { // transfer AdminRole
                _grantRole(DEFAULT_ADMIN_ROLE, _adminRoleRequests[requestId].newAdmin);
                _revokeRole(DEFAULT_ADMIN_ROLE, _adminRoleRequests[requestId].revokeAdmin);
                for (uint256 i = 0; i < _adminRoleMembers.length; i++) {
                    if (_adminRoleMembers[i] == _adminRoleRequests[requestId].revokeAdmin) {
                        _adminRoleMembers[i] = _adminRoleRequests[requestId].newAdmin;
                        break;
                    }
                }
                emit AdminRoleTransferred(msg.sender, _adminRoleRequests[requestId].newAdmin, requestId);
            }
        } else {
            _adminRoleRequests[requestId].status = 2;
            _adminRoleRequests[requestId].approvedAdmin = address(0);
            _adminRoleRequests[requestId].rejectedAdmin = msg.sender;
            emit AdminRoleRejected(msg.sender, _adminRoleRequests[requestId].action, requestId);
        }
        return requestId;
    }
}

{
  "compilationTarget": {
    "YidocyToken.sol": "YidocyToken"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}