// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

interface Burnable {
    function burn(uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

interface IController {
    function set_pair(address pair) external;
    function set_ready(bool _ready) external;
    function notify() external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

import "./safe-math.sol";
import "./context.sol";

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: contracts/utils/Address.sol


/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return _functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        return _functionCallWithValue(target, data, value, errorMessage);
    }

    function _functionCallWithValue(address target, bytes memory data, uint256 weiValue, string memory errorMessage) private returns (bytes memory) {
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: weiValue }(data);
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// File: contracts/token/ERC20/ERC20.sol

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;
    using Address for address;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol) public {
        _name = name;
        _symbol = symbol;
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }
}

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

import "./context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

import "./interfaces/burnable.sol";
import "./interfaces/uniswap-v2.sol";
import "./interfaces/controller.sol";
import "./interfaces/token-timelock.sol";

import "./libs/ownable.sol";
import "./libs/erc20.sol";
import "./libs/safe-math.sol";

contract YvsPresale is Ownable {
    using SafeMath for uint256;
    using SafeERC20 for IERC20;

    // the token being sold
    IERC20 public token;

    // the addresses where collected funds are sent
    address payable public team;
    address payable public marketing;
    address payable public listing;

    // controller contract
    address public controller;

    // treasury contract
    address payable public treasury = 0xe04af79053639D2c4C1c3827F72e52459eE0E88e;

    // timelock contract
    address public timelock;

    // presale duration
    uint256 public start;
    uint256 public duration = 5 days;
    uint256 public grace = 12 days;

    // token max cap
    uint256 public cap = 100000000000000000000000; // 100.000 $yvs

    // presale threshold to close
    uint256 public threshold = 90; // 90 % of token cap

    // total to be distributed
    uint256 public total;

    // total wei deposited
    uint256 public deposited;

    // total number of depositors
    uint256 public depositors;

    // limits for investment
    uint256 public min = 1000000000000000000; // 1 eth
    uint256 public max = 50000000000000000000; // 50 eth

    // token exchange rate for base amount (1 eth = 45 $yvs)
    uint256 public rate = 45000000000000000000;

    // referral bonus
    uint256 public referralRate = 10;
    uint256 public referralRateReferrer = 5;
    uint256 public referralRateDepositor = 5;
    uint256 public referralRateBase = 1000;

    // public contact information
    string public contact;

    // is the presale finalized
    bool public finalized = false;

    // is the distribution finished
    bool public completed = false;

    // is the presale cancelled
    bool public cancelled = false;

    // is the presale closed
    bool public closed = false;

    struct ReferralBonus {
        uint256 count;
        uint256 amount;
    }

    // mappings for deposited, claimable
    mapping(address => uint256) public deposits;
    mapping(address => uint256) public balances;
    mapping(address => ReferralBonus) public bonus;

    // mappings for referrals
    mapping(bytes12 => address) public referrals;
    mapping(address => bool) public registered;

    UniswapRouterV2 internal uniswap = UniswapRouterV2(0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D);
    UniswapV2Factory internal factory = UniswapV2Factory(0x5C69bEe701ef814a2B6a3EDD4B1652CB9cc5aA6f);

    address internal weth = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;

    /**
    * event for presale enter logging
    * @param account who will receive the tokens
    * @param value weis entered into presale
    * @param amount amount of tokens to be distributed
    */ 
    event PresaleEntered(address indexed account, uint256 value, uint256 amount);

    /**
    * event for referral earned from user
    * @param beneficiary that receives the referral bonus
    * @param amount amount of bonus tokens from daily
    */ 
    event DailyBonusEarned(address indexed beneficiary, uint256 amount);

    /**
    * event for referral earned from user
    * @param beneficiary that receives the referral bonus
    * @param account that entered presale with referral code
    * @param amount amount of bonus tokens from referral
    */ 
    event ReferrerEarned(address indexed beneficiary, address indexed account, uint256 amount);

    /**
    * event for referral earned from user
    * @param account that entered presale with referral code
    * @param amount amount of bonus tokens from referral
    */ 
    event DepositorEarned(address indexed account, uint256 amount);

    /**
    * event for claim of tokens
    * @param recipient that received the tokens
    * @param amount amount of tokens received
    */ 
    event Claimed(address indexed recipient, uint256 amount);

    /**
    * event for refund of wei
    * @param recipient that received the wei
    * @param amount amount of wei received
    */ 
    event Refunded(address indexed recipient, uint256 amount);

    /**
    * event for setting a referral
    * @param account the account that set the referral code
    * @param code referral string from 8 characters
    */ 
    event ReferralSet(address indexed account, bytes12 code);

    /**
    * event for signaling liquidity creation & lock
    * @param amount amount of lp tokens created
    * @param timelock address of timelock contract
    */
    event LiquidityAddedAndLocked(uint256 amount, address timelock);

    /**
    * event for signaling salvaged non-token assets
    * @param token salvaged token address
    * @param amount amount of tokens salvaged
    */
    event Salvaged(address token, uint256 amount);

    /**
    * event for signaling dist collection of wei
    * @param recipient address that received the wei
    * @param amount amount of wei collected
    */
    event DustCollected(address recipient, uint256 amount);

    /**
    * event for signaling destruction of leftover tokens
    * @param amount amount of tokens burned
    */
    event Destroyed(uint256 amount);

    /**
    * event for signaling presale completion
    */
    event Completed();

    // CONSTRUCTOR

    constructor(
        address _token,
        address _timelock,
        uint256 _start,
        string memory _contact
    ) public {
        require(_start >= block.timestamp);
        
        token = IERC20(_token);
        timelock = _timelock;
        start = _start;
        contact = _contact;

        team = 0x0dB32cD2805c541375DFa609D4866D132A4687A6;
        marketing = 0x685Da6c75698611ac875d8a485d6eFB18A88921D;
        listing = 0xBF2Ba575C25F36Ea507726656a7fdB4374974Aa2;
    }

    // fallback function to enter presale
    receive () external payable {
        // will probably fail unless gas limit is set high
        enter(msg.value);
    }

    /**
    * Low level presale enter function
    * @param _amount the wei amount
    */
    function enter(uint256 _amount) public payable active {
        require(msg.value == _amount);
        require(msg.sender != address(0));
        require(valid(msg.sender, _amount));

        uint256 amount;
        uint256 acquired;

        // calculate base tokens
        amount = _amount.mul(rate).div(1e18);
        require(distributable(amount), "not enough tokens for distribution");

        // calculate daily bonus
        uint256 dailyBonus;
        if (block.timestamp <= start.add(1 days)) {
            dailyBonus = amount.mul(125).div(1000); // 12.5 % for first day
        }
        else if (block.timestamp <= start.add(2 days)) {
            dailyBonus = amount.mul(75).div(1000); // 7.5 % for second day
        }
        else if (block.timestamp <= start.add(3 days)) {
            dailyBonus = amount.mul(50).div(1000); // 5.0 % for third day
        }
        else if (block.timestamp <= start.add(4 days)) {
            dailyBonus = amount.mul(25).div(1000); // 2.5 % for fourth day
        }
        
        if (dailyBonus > 0) {
            if (distributable(amount.add(dailyBonus))) {
                acquired = acquired.add(dailyBonus);
                emit DailyBonusEarned(msg.sender, dailyBonus);
            }
        }

        // store in dictionary
        uint256 distribution = amount.add(acquired);
        deposits[msg.sender] = deposits[msg.sender].add(_amount);
        balances[msg.sender] = balances[msg.sender].add(distribution);
        emit PresaleEntered(msg.sender, amount, distribution);

        deposited = deposited.add(_amount);
        depositors = depositors.add(1);
        total = total.add(distribution);
    }

    /**
    * Low level presale enter function
    * @param _amount the wei amount
    * @param _code referral code
    */
    function enter(uint256 _amount, bytes12 _code) public payable active {
        require(msg.value == _amount);
        require(msg.sender != address(0));
        require(valid(msg.sender, _amount));
        require(referrals[_code] != address(0), "referral code is invalid");
        require(referrals[_code] != msg.sender, "can not use your own referral code");

        uint256 acquired;
        uint256 amount;

        // calculate base tokens
        amount = _amount.mul(rate).div(1e18);
        require(distributable(amount), "not enough tokens for distribution");

        // calculate daily bonus
        uint256 dailyBonus;
        if (block.timestamp <= start.add(1 days)) {
            dailyBonus = amount.mul(125).div(1000); // 12.5 % for first day
        }
        else if (block.timestamp <= start.add(2 days)) {
            dailyBonus = amount.mul(75).div(1000); // 7.5 % for second day
        }
        else if (block.timestamp <= start.add(3 days)) {
            dailyBonus = amount.mul(50).div(1000); // 5.0 % for third day
        }
        else if (block.timestamp <= start.add(4 days)) {
            dailyBonus = amount.mul(25).div(1000); // 2.5 % for fourth day
        }
        
        if (dailyBonus > 0) {
            if (distributable(amount.add(dailyBonus))) {
                acquired = acquired.add(dailyBonus);
                emit DailyBonusEarned(msg.sender, dailyBonus);
            }
        }

        // calculate bonus for referral
        uint256 referralBonus = amount.mul(referralRate).div(referralRateBase); 
        if (referralBonus > 0) {
            if (distributable(amount.add(acquired).add(referralBonus))) {
                address referrer = referrals[_code];
                uint256 referrerBonus = amount.mul(referralRateReferrer).div(referralRateBase); 
                uint256 depositorBonus = amount.mul(referralRateDepositor).div(referralRateBase); 
                balances[referrer] = balances[referrer].add(referrerBonus);
                bonus[referrer].count = bonus[referrer].count.add(1);
                bonus[referrer].amount = bonus[referrer].amount.add(referrerBonus);
                acquired = acquired.add(depositorBonus);
                total = total.add(referrerBonus);
                emit ReferrerEarned(referrer, msg.sender, referrerBonus);
                emit DepositorEarned(msg.sender, depositorBonus);
            }
        }

        // store in dictionary
        uint256 distribution = amount.add(acquired);
        deposits[msg.sender] = deposits[msg.sender].add(_amount);
        balances[msg.sender] = balances[msg.sender].add(distribution);
        emit PresaleEntered(msg.sender, amount, distribution);

        deposited = deposited.add(_amount);
        depositors = depositors.add(1);
        total = total.add(distribution);
    }

    /**
    * Refund collected eth from user if presale is cancelled
    */
    function refund() external {
        require(cancelled, "presale is not cancelled");
        require(deposits[msg.sender] > 0, "you have not deposited anything");

        // return collected ether
        msg.sender.transfer(deposits[msg.sender]);
        emit Refunded(msg.sender, deposits[msg.sender]);
        deposited = deposited.sub(deposits[msg.sender]);
        total = total.sub(balances[msg.sender]);
        deposits[msg.sender] = 0;
        balances[msg.sender] = 0;
    }

    /**
    * Claim tokens after presale is distributed
    */
    function claim() external distributed {
        require(balances[msg.sender]> 0, "you can not claim any tokens");

        // send claimable token to user
        token.safeTransfer(msg.sender, balances[msg.sender]);
        emit Claimed(msg.sender, balances[msg.sender]);
        balances[msg.sender] = 0;
    }

    /**
    * Set a referral code for an address
    * @param code referral code
    */
    function referral(bytes12 code) external {
        require(referrals[code] == address(0), "referral code already set");
        require(!registered[msg.sender], "you have already set a referral code");

        referrals[code] = address(msg.sender);
        registered[msg.sender] = true;
        emit ReferralSet(msg.sender, code);
    }

    /**
    * Distribute wei, create liquidity pair and start rewards after presale end
    */
    function distribute() external {
        require(concluded(), "presale is not concluded");
        require(address(this).balance >= deposited, "!balance >= deposited");
        
        if (deposited > 0) {
            // calculate distribution amounts
            uint256 _liquidity = deposited.mul(30).div(100); // 30 % to liquidity
            uint256 _team = deposited.mul(20).div(100); // 20 % to team
            uint256 _marketing = deposited.mul(30).div(100); // 30 % to marketing
            uint256 _listing = deposited
                .sub(_liquidity)
                .sub(_team)
                .sub(_marketing); // 20 % to exchange listings

            // calculate token uniswap liquidity amount
            uint256 _uniswap = _liquidity.mul(rate).div(1e18);

            // create uniswap pair
            token.safeApprove(address(uniswap), _uniswap);
            ( , , uint256 added) = uniswap.addLiquidityETH{value: _liquidity}(address(token), _uniswap, 0, 0, address(timelock), block.timestamp + 5 minutes);
            emit LiquidityAddedAndLocked(added, timelock);

            // get uniswap pair address
            address pair = factory.getPair(address(token), weth);

            // set token in timelock contract
            ITokenTimelock(timelock).set_token(pair);

            // set uniswap pair address in controller
            IController(controller).set_pair(pair);

            // set controller to ready
            IController(controller).set_ready(true);

            // start distribution
            IController(controller).notify();

            // transfer wei to addresses
            team.transfer(_team);
            marketing.transfer(_marketing);
            listing.transfer(_listing);
        }

        // signal distribution complete
        completed = true;
        emit Completed();
    }

    /**
    * Salvage unrelated tokens to presale
    * @param _token address of token to salvage
    */
    function salvage(address _token) external distributed onlyOwner {
        require(_token != address(token), "can not salvage token");

        uint256 balance = IERC20(_token).balanceOf(address(this));
        if (balance > 0) {
            IERC20(_token).safeTransfer(treasury, balance);
            emit Salvaged(_token, balance);
        }
    }

    /**
    * Collect wei left as dust on contract after grace period
    */
    function collect_dust() external distributed onlyOwner {
        require(!cancelled);
        require(block.timestamp >= start.add(grace), "grace period not over");

        uint256 balance = address(this).balance;
        if (balance > 0) {
            treasury.transfer(balance);
            emit DustCollected(treasury, balance);
        }
    }

    /**
    * Destroy (burn) leftover tokens from presale
    */
    function destroy() external distributed onlyOwner {
        require(!cancelled);
        require(block.timestamp >= start.add(grace), "grace period not over");

        uint256 balance = token.balanceOf(address(this));
        if (balance > 0) {
            Burnable(address(token)).burn(balance);
            emit Destroyed(balance);
        }
    }

    // *** RESTRICTED ***

    /**
    * Set controller contract for the presale
    * @param _controller address of controller contract
    */
    function set_controller(address _controller) external onlyOwner {
        require(controller == address(0), "!controller");
        controller = _controller;
    }

    /**
    * Update contact information on the contract
    * @param _contact text to set as contact information
    */
    function update(string memory _contact) external onlyOwner {
        contact = _contact;
    }

    /**
    * Cancel presale, stop accepting wei and enable refunds
    */
    function cancel() external onlyOwner {
        cancelled = true;
    }

    /**
    * Close presale if threshold is reached
    */
    function close() external onlyOwner {
        require(reached(), "threshold is not reached");

        closed = true;
    }

    // *** VIEWS **** //


    /**
    * Returns claimable amount for address
    */
    function claimable() external view returns (uint256 amount) {
        if (!cancelled) {
            amount = balances[msg.sender];
        }
    }

    /**
    * Check if wei amount is within limits
    */
    function valid(address account, uint256 amount) internal view returns (bool) {
        bool above = deposits[account].add(amount) >= min;
        bool below = deposits[account].add(amount) <= max;

        return (above && below);
    }

    /**
    * Check if token amount can be distributed
    */
    function distributable(uint256 amount) internal view returns (bool) {
        bool below = total.add(amount) <= cap;

        return (below);
    }

    /**
    * Check if presale if concluded
    */
    function concluded() internal view returns (bool) {
        if (closed) {
            return true;
        }

        if (block.timestamp > start.add(duration) && !cancelled) {
            return true;
        }

        return false;
    }

    /**
    * Check if threshold is reached
    */
    function reached() internal view returns (bool) {
        bool above = total.mul(100).div(cap) >= threshold;

        return (above);
    }

    // *** MODIFIERS **** //

    modifier distributed {
        require(
            completed,
            "tokens were not distributed yet"
        );

        _;
    }

    modifier active {
        require(
            block.timestamp >= start,
            "presale has not started yet"
        );

        require(
            block.timestamp <= start.add(duration),
            "presale has concluded"
        );

        require(
            !cancelled,
            "presale was cancelled"
        );

        require(
            !closed,
            "presale was closed"
        );

        _;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

interface ITokenTimelock {
    function set_token(address token_) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.6.12;

interface UniswapRouterV2 {
    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint256 amountADesired,
        uint256 amountBDesired,
        uint256 amountAMin,
        uint256 amountBMin,
        address to,
        uint256 deadline
    )
        external
        returns (
            uint256 amountA,
            uint256 amountB,
            uint256 liquidity
        );

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    )
        external
        payable
        returns (
            uint256 amountToken,
            uint256 amountETH,
            uint256 liquidity
        );

    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint256 liquidity,
        uint256 amountAMin,
        uint256 amountBMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountA, uint256 amountB);

    function getAmountsOut(uint256 amountIn, address[] calldata path)
        external
        view
        returns (uint256[] memory amounts);

    function getAmountsIn(uint256 amountOut, address[] calldata path)
        external
        view
        returns (uint256[] memory amounts);

    function swapETHForExactTokens(
        uint256 amountOut,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable returns (uint256[] memory amounts);

    function swapExactETHForTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable returns (uint256[] memory amounts);
}

interface IUniswapV2Pair {
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
    event Transfer(address indexed from, address indexed to, uint256 value);

    function name() external pure returns (string memory);

    function symbol() external pure returns (string memory);

    function decimals() external pure returns (uint8);

    function totalSupply() external view returns (uint256);

    function balanceOf(address owner) external view returns (uint256);

    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    function approve(address spender, uint256 value) external returns (bool);

    function transfer(address to, uint256 value) external returns (bool);

    function transferFrom(
        address from,
        address to,
        uint256 value
    ) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);

    function PERMIT_TYPEHASH() external pure returns (bytes32);

    function nonces(address owner) external view returns (uint256);

    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    event Mint(address indexed sender, uint256 amount0, uint256 amount1);
    event Burn(
        address indexed sender,
        uint256 amount0,
        uint256 amount1,
        address indexed to
    );
    event Swap(
        address indexed sender,
        uint256 amount0In,
        uint256 amount1In,
        uint256 amount0Out,
        uint256 amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint256);

    function factory() external view returns (address);

    function token0() external view returns (address);

    function token1() external view returns (address);

    function getReserves()
        external
        view
        returns (
            uint112 reserve0,
            uint112 reserve1,
            uint32 blockTimestampLast
        );

    function price0CumulativeLast() external view returns (uint256);

    function price1CumulativeLast() external view returns (uint256);

    function kLast() external view returns (uint256);

    function mint(address to) external returns (uint256 liquidity);

    function burn(address to)
        external
        returns (uint256 amount0, uint256 amount1);

    function swap(
        uint256 amount0Out,
        uint256 amount1Out,
        address to,
        bytes calldata data
    ) external;

    function skim(address to) external;

    function sync() external;
}

interface UniswapV2Factory {
    event PairCreated(
        address indexed token0,
        address indexed token1,
        address pair,
        uint256
    );

    function getPair(address tokenA, address tokenB)
        external
        view
        returns (address pair);

    function allPairs(uint256) external view returns (address pair);

    function allPairsLength() external view returns (uint256);

    function feeTo() external view returns (address);

    function feeToSetter() external view returns (address);

    function createPair(address tokenA, address tokenB)
        external
        returns (address pair);
}

{
  "compilationTarget": {
    "localhost/presale.sol": "YvsPresale"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}