// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

import {ReentrancyGuard} from "@openzeppelin/utils/ReentrancyGuard.sol";
import {Ownable} from "@openzeppelin/access/Ownable.sol";
import {Pausable} from "@openzeppelin/utils/Pausable.sol";
import {IERC721} from "@openzeppelin/token/ERC721/IERC721.sol";
import {IBBitsCheckIn} from "./interfaces/IBBitsCheckIn.sol";
import {IBBitsRaffle} from "./interfaces/IBBitsRaffle.sol";

/// @title  Based Bits Raffle
/// @notice This contract allows users to participate in raffles to win NFTs from the Based Bits collection.
/// @dev    The contract operates on a loop, cycling through the PendingRaffle and InRaffle stages continuously.
///         The Owner retains admin rights over pausability, the antiBotFee, and the duration of raffle entry 
///         periods.
contract BBitsRaffle is IBBitsRaffle, Ownable, ReentrancyGuard, Pausable {

    /// @notice Based Bits NFT collection.
    IERC721 public immutable collection;

    /// @notice Based Bits checkin contract.
    IBBitsCheckIn public immutable checkIn;

    /// @notice The current raffle status of this contract.
    ///         PendingRaffle:     Raffle not started (just deployed/just settled and contract without BBs).
    ///         InRaffle:          Accepting entries.
    RaffleStatus public status;

    /// @notice The total number of raffles held by this contract.
    uint256 public count;

    /// @notice Length of time that a raffle lasts.
    uint256 public duration;

    /// @notice A fee that must be paid on some functions to discourage botting or abuse.
    // TODO: Change to paid fee
    uint256 public antiBotFee;

    /// @notice A mapping from raffle ids to raffle info.
//    TODO: Change to raffle
    mapping(uint256 => Raffle) public idToRaffle;

    /// @notice A mapping to track addresses that have entered any given raffle.
    /// @dev    raffleId => address => entered
    mapping(uint256 => mapping(address => bool)) public hasEnteredRaffle;

    /// @notice An array of token ids and corresponding sponsors that are held by the contract.
    SponsoredPrize[] public prizes;

    constructor(address _owner, IERC721 _collection, IBBitsCheckIn _checkIn) Ownable(_owner) {
        status = RaffleStatus.PendingRaffle;
        collection = _collection;
        checkIn = _checkIn;
        duration = 1 days;
        antiBotFee = 0.0001 ether;
        count = 1;
    }

    receive() external payable {}

    /// DEPOSIT ///

    /// @notice This function allows anyone to deposit Based Bits NFTs to be raffled.
    /// @param  _tokenIds An array of token IDs to deposit.
    /// @dev    The user must approve this contract to move the NFTs prior to calling this function.
    ///         Can deposit under any contract status.
    function depositBasedBits(uint256[] calldata _tokenIds) external nonReentrant whenNotPaused {
        uint256 length = _tokenIds.length;
        if (length == 0) revert DepositZero();
        uint256 tokenId;
        SponsoredPrize memory newSponsoredPrize;
        for (uint256 i; i < length; ++i) {
            tokenId = _tokenIds[i];
            collection.transferFrom(msg.sender, address(this), tokenId);
            newSponsoredPrize = SponsoredPrize({
                tokenId: tokenId,
                sponsor: msg.sender
            });
            prizes.push(newSponsoredPrize);
            emit BasedBitsDeposited(msg.sender, tokenId);
        }
    }

    /// START RAFFLE ///

    /// @notice This function allows any user to initiate the next raffle. 
    /// @dev    Must be in PendingRaffle status. 
    ///         There must be collection NFTs to raffle.
    function startNextRaffle() external nonReentrant whenNotPaused {
        if (status != RaffleStatus.PendingRaffle) revert WrongStatus();
        uint256 prizesLength = prizes.length;
        if (prizesLength == 0) revert NoBasedBitsToRaffle();
        _startNextRaffle();
    }

    function _startNextRaffle() internal {
        address[] memory newEntries;
        Raffle memory newRaffle = Raffle({
            startedAt: block.timestamp,
            settledAt: 0,
            entries: newEntries,
            winner: address(0),
            sponsoredPrize: prizes[0]
        });
        idToRaffle[count++] = newRaffle;
        status = RaffleStatus.InRaffle;
        emit NewRaffleStarted(getCurrentRaffleId());
    }

    /// ENTRIES ///

    /// @notice This function allows eligible users to enter into the current raffle for free.
    /// @dev    Must be in InRaffle status.
    ///         Must be eligible for free entry.
    function newFreeEntry() external nonReentrant whenNotPaused {
        if (!isEligibleForFreeEntry(msg.sender)) revert NotEligibleForFreeEntry();
        _newEntry();
    }

    /// @notice This function allows anyone to enter into the current raffle.
    /// @dev    Must be in InRaffle status. 
    ///         Must pay the antiBotFee.
    function newPaidEntry() external payable nonReentrant whenNotPaused {
        if (msg.value != antiBotFee) revert MustPayAntiBotFee();
        _newEntry();
    }

    function _newEntry() internal {
        if (status != RaffleStatus.InRaffle) revert WrongStatus();
        uint256 currentRaffleId = getCurrentRaffleId();
        Raffle storage currentRaffle = idToRaffle[currentRaffleId];
        if (block.timestamp - currentRaffle.startedAt > duration) revert RaffleExpired();
        if (hasEnteredRaffle[currentRaffleId][msg.sender]) revert AlreadyEnteredRaffle();
        hasEnteredRaffle[currentRaffleId][msg.sender] = true;
        currentRaffle.entries.push(msg.sender);
        emit RaffleEntered(currentRaffleId, msg.sender);
    }

    /// SETTLEMENT ///

    /// @notice This function allows anyone to settle the current raffle. Either a winner is chosen or the raffle
    ///         is reset. If there are additional raffle prizes a new raffle is initiated automatically.
    /// @dev    Must be in InRaffle status, with the raffle entry period having expired.
    function settleRaffle() external nonReentrant whenNotPaused {
        if (status != RaffleStatus.InRaffle) revert WrongStatus();
        uint256 currentRaffleId = getCurrentRaffleId();
        Raffle storage currentRaffle = idToRaffle[currentRaffleId];
        if (block.timestamp - currentRaffle.startedAt < duration) revert RaffleOnGoing();
        uint256 entriesLength = currentRaffle.entries.length;
        uint256 prizesLength = prizes.length;
        if (entriesLength == 0 || prizesLength == 0) {
            currentRaffle.settledAt = block.timestamp;
            emit RaffleSettled(currentRaffleId, address(0), 0);
        } else {
            prizes[0] = prizes[--prizesLength];
            prizes.pop();
            uint256 pseudoRandom = uint256(keccak256(abi.encodePacked(msg.sender, blockhash(block.number - 1))));
            address winner = currentRaffle.entries[pseudoRandom % entriesLength];
            address sponsor = currentRaffle.sponsoredPrize.sponsor;
            uint256 tokenId = currentRaffle.sponsoredPrize.tokenId;
            currentRaffle.settledAt = block.timestamp;
            currentRaffle.winner = winner;
            collection.transferFrom(address(this), winner, tokenId);
            sponsor.call{value: address(this).balance}("");
            emit RaffleSettled(currentRaffleId, winner, tokenId);
        }
        status = RaffleStatus.PendingRaffle;
        if (prizesLength > 0) _startNextRaffle();
    }

    /// VIEW ///

    /// @notice A view function that returns the current raffle Id.
    /// @dev    There is no raffle zero.
    function getCurrentRaffleId() public view returns (uint256) {
        return count - 1;
    }

    /// @notice A view function that returns the total number of entries for any given raffle.
    function getRaffleEntryNumber(uint256 _raffleId) public view returns (uint256) {
        return idToRaffle[_raffleId].entries.length;
    }

    /// @notice A view function that returns the entry address for any raffle given raffle and entry position.
    function getRaffleEntryByIndex(uint256 _raffleId, uint256 _index) public view returns (address) {
        if (_index >= getRaffleEntryNumber(_raffleId)) revert IndexOutOfBounds();
        return idToRaffle[_raffleId].entries[_index];
    }

    /// @notice A view function that returns whether any given user is eligible for free entry into the current 
    ///         raffle.
    function isEligibleForFreeEntry(address _user) public view returns (bool) {
        (uint256 lastCheckIn,,) = checkIn.checkIns(_user);
        if (block.timestamp - lastCheckIn > 2 days) return false;
        return true;
    }

    /// OWNER ///

    function setPaused(bool _setPaused) external onlyOwner {
        _setPaused ? _pause() : _unpause();
    }

    function setAntiBotFee(uint256 _newFee) external onlyOwner {
        antiBotFee = _newFee;
    }

    function setDuration(uint256 _newDuration) external onlyOwner {
        duration = _newDuration;
    }

    /// @notice This function allows the Owner to return up to 20 deposited NFTs at a time.
    /// @dev    Contract must be paused. 
    function returnDeposits() external onlyOwner nonReentrant whenPaused {
        uint256 length = (prizes.length > 20) ? 20 : prizes.length;
        if (length == 0) revert DepositZero();
        SponsoredPrize memory prize;
        for (uint256 i; i < length; i++) {
            prize = prizes[prizes.length - 1];
            collection.transferFrom(address(this), prize.sponsor, prize.tokenId);
            prizes.pop();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IBBitsCheckIn {
    function checkIns(address user) external view returns (uint256 lastCheckIn, uint16 streak, uint16 count);

    function banned(address user) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IBBitsRaffle {
    enum RaffleStatus {
        PendingRaffle,
        InRaffle
    }

    struct Raffle {
        uint256 startedAt;
        uint256 settledAt;
        address[] entries;
        address winner;
        SponsoredPrize sponsoredPrize;
    }

    struct SponsoredPrize {
        uint256 tokenId;
        address sponsor;
    }

    error DepositZero();
    error WrongStatus();
    error NoBasedBitsToRaffle();
    error NotEligibleForFreeEntry();
    error RaffleExpired();
    error RaffleOnGoing();
    error AlreadyEnteredRaffle();
    error MustPayAntiBotFee();
    error TransferFailed();
    error IndexOutOfBounds();

    event BasedBitsDeposited(address _sponsor, uint256 _tokenId);
    event NewRaffleStarted(uint256 _raffleId);
    event RaffleEntered(uint256 _raffleId, address _user);
    event RaffleSettled(uint256 _raffleId, address _winner, uint256 _tokenId);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "src/BBitsRaffle.sol": "BBitsRaffle"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 420000
  },
  "remappings": [
    ":@openzeppelin/=lib/openzeppelin-contracts/contracts/",
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":ds-test/=lib/openzeppelin-contracts/lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/"
  ]
}