// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

interface IVault {
    function totalDepositedAsset() external view returns (uint256);
    function depositedAsset(address user) external view returns (uint256);
    function getBorrowedOf(address user) external view returns (uint256);
    function getPoolTotalCirculation() external view returns (uint256);
    function getAsset() external view returns (address);
    function burn(address onBehalfOf, uint256 amount) external;
    function collateralAsset() external view returns (address);
    function getAssetToUnderlyingRate() external view returns (uint256);
    function isDepegged() external view returns (bool);
    function getMarketRate() external view returns (uint256);
    function getAssetPrice() external view returns (uint256);
    function calculateRedemption(address provider, uint256 nusdAmount) external view returns (uint256 providerFee, uint256 protocolFee, uint256 nusdToProtocol, uint256 nusdToRepay, uint256 nusdToConvert, uint256 collateralReceived);
    function getRedeemableAmount(address provider) external view returns (uint256);
    function getCollateralRatio(address user) external view returns (uint256);
    function getOriginationFee(uint256 amount) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/Address.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!Address.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

interface IsnUSD {
  // Events //
  /// @notice Event emitted when the rewards are received
  event RewardsReceived(uint256 indexed amount, uint256 newVestingnUSDAmount);
  /// @notice Event emitted when the balance from an FULL_RESTRICTED_STAKER_ROLE user are redistributed
  event LockedAmountRedistributed(address indexed from, address indexed to, uint256 amount);

  // Errors //
  /// @notice Error emitted shares or assets equal zero.
  error InvalidAmount();
  /// @notice Error emitted when owner attempts to rescue USDe tokens.
  error InvalidToken();
  /// @notice Error emitted when slippage is exceeded on a deposit or withdrawal
  error SlippageExceeded();
  /// @notice Error emitted when a small non-zero share amount remains, which risks donations attack
  error MinSharesViolation();
  /// @notice Error emitted when owner is not allowed to perform an operation
  error OperationNotAllowed();
  /// @notice Error emitted when there is still unvested amount
  error StillVesting();
  /// @notice Error emitted when owner or blacklist manager attempts to blacklist owner
  //error CantBlacklistOwner();
  /// @notice Error emitted when the zero address is given
  error InvalidZeroAddress();

  function transferInRewards(uint256 amount) external;

  function rescueTokens(address token, uint256 amount, address to) external;

  function getUnvestedAmount() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT

/**
 * @title Unstable Protocol V2 Configurator Contract
 * @dev The Configurator contract is used to set various control functionalities of the Unstable Protocol.
 * There are two types of governance roles:
 * * OWNER: Higher level privilege, multisig + timelock.
 * * ADMIN: Lower level privilege for emergency pauses and low level configs (e.g. incentives).
 * All setting functions have two levels of calling permissions:
 * * onlyOwner: Only callable by owner.
 * * onlyOwnerOrAdmin: Callable by owner and admin.
 * All ratios, fees and similar decimal parameters should be configured as bps (basis points), i.e. 4 decimals of precision.
 */

pragma solidity 0.8.19;

import "contracts/unstable/interfaces/IsnUSD.sol";
import "contracts/unstable/interfaces/IVault.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

contract UnstableConfigurator is Ownable {
    using SafeERC20 for IERC20;

    struct OriginationFeeConfig {
        uint16 minOriginationFee; // fee at 0% utilization
        uint16 maxOriginationFee; // fee at 100% utilization
    }

    struct RedemptionConfig {
        bool enabled; //whether a vault can redeem
        uint16 baseFee; // base fee for redemption
        uint16 maxMultiplier; // fee for redemption
        uint16 maxCollateralRatio; // collateral ratio for max fee multiplier
        uint16 providerShare; // share of redemption fee that goes to provider
    }

    address[] vaults; //list of all vaults

    mapping(address => bool) public collateralEnabled;        //for fast lookup
    address[] collaterals;                                    //list of all collaterals

    //lst specific config
    mapping(address => address) public zkOracleAddress;       //mapping of lst to zkOracle

    //vault configuration settings: must be set before vault is activated
    mapping(address => bool) public vaultEnabled;             //toggle minting for vault, required to be true to mint
    mapping(address => uint256) public mintVaultMaxSupply;    //max nUSD that can be minted for a vault

    //vault configuration settings: if you want to override defaults
    mapping(address => uint16) vaultBadCollateralRatio;      //minimum 1/ltv where liquidation can occur
    mapping(address => uint16) vaultSafeCollateralRatio;     //minimum 1/ltv required to open a position
    mapping(address => uint16) public borrowApr;             //borrowing APR. Default zero
    mapping(address => uint16) public vaultKeeperRatio;      //liquidation reward. Default in constructor
    mapping(address => uint16) depegThreshold;               //threshold to auto pause minting when market rate diverges
    mapping(address => bool) public useMarketRate;           //toggle using market rate (as opposed to redemption rate). Default false
    mapping(address => OriginationFeeConfig) public vaultOriginationFee; //origination fee config. Default in constructor
    mapping(address => RedemptionConfig) public vaultRedemptionConfig; //redemption config. Default in constructor

    //vault settings that can be changed after vault is activated
    mapping(address => bool) public vaultMintPaused;          //toggle minting for vault, required to be false to mint
    mapping(address => bool) public vaultBurnPaused;          //toggle burning for vault, required to be false to burn

    //multireward stuff
    mapping(address => bool) public rewardManager;          //user that can manage rewards

    //global config
    uint16 public flashloanFee;                           //fee for flashloaning nUSD

    //defaults
    uint16 public immutable defaultSafeCollateralRatio;                //default safe collateral ratio
    uint16 public immutable defaultBadCollateralRatioDistance;         //default amount bad collateral ratio is under the safe collateral ratio
    OriginationFeeConfig public defaultOriginationFee;                 //default origination fee config
    RedemptionConfig public defaultRedemptionConfig;                   //default redemption config
    uint16 public immutable defaultKeeperReward;                       //default liquidation reward
    uint16 public immutable defaultDepegThreshold;                     //default depeg threshold

    address public admin;
    address public treasury;
    IERC20 public nUSD;
    IsnUSD public snUSD; 
    address public etherOracle; //chainlink Oracle

    event AdminChanged(address newAdmin);
    event nUSDSet(address indexed nUSD);
    event snUSDSet(address indexed newAddr);
    event EtherOracleChanged(address newAddr);
    event TreasuryChanged(address newTreasury);

    event ZkOracleSet(address indexed vault, address zkOracle);
    event ZkOracleChanged(address indexed vault, address zkOracle);

    event VaultEnabled(address indexed vault);
    event VaultMintPaused(address indexed vault, bool paused);
    event VaultBurnPaused(address indexed vault, bool paused);
    event DepegThresholdUpdated(address indexed vault, uint16 threshold);
    event UseMarketRateChanged(address indexed vault, bool useMarketRate);

    event MintVaultMaxSupplyChanged(address indexed vault, uint256 maxSupply);
    event BadCollateralRatioChanged(address indexed vault, uint16 newRatio);
    event SafeCollateralRatioChanged(address indexed vault, uint16 newRatio);
    event BorrowAprChanged(address indexed vault, uint16 newApr);
    event KeeperRewardChanged(address indexed vault, uint16 newReward);
    event OriginationFeeChanged(address indexed vault, uint16 minOriginationFee, uint16 maxOriginationFee);
    event RedemptionConfigChanged(address indexed vault, bool enabled, uint16 baseFee, uint16 maxMultiplier, uint16 maxCollateralRatio, uint16 providerShare);

    event FeesDistributed(uint256 amount);
    event FlashloanFeeUpdated(uint16 fee);

    event TokensWithdrawn(address tokenAddress, address to, uint256 amount);
    event RewardManagerSet(address managerAddress);
    event RewardManagerRemoved(address managerAddress);

    constructor(address _etherOracle) {
        flashloanFee = 500; //500 bps = 5%
        defaultSafeCollateralRatio = 150_00; //15000 bps = 150%
        defaultBadCollateralRatioDistance = 15_00; //1500 bps = 15%
        defaultOriginationFee = OriginationFeeConfig(0, 1000); //0% at 0% utilization, 10% at 100% utilization
        defaultKeeperReward = 500; //500 bps = 5% reward
        defaultDepegThreshold = 300; //300 bps = 3% depeg
        defaultRedemptionConfig = RedemptionConfig(true, 100, 3, 200_00, 75_00); //100 bp fee, 3x max multiplier, 200% cr for max multiplier, 75% fee to provider
        etherOracle = _etherOracle; //chainlink oracle
    }

    modifier onlyOwnerOrAdmin {
        require(msg.sender == owner() || msg.sender == admin, "Only owner or admin can call this");
        _;
    }

    /**
     * @notice Sets the admin address. This function can only be executed by the owner.
     * @param _admin The address of the new admin.
     */
    function setAdmin(address _admin) external onlyOwner {
        admin = _admin;
        emit AdminChanged(_admin);
    }

    /**
     * @notice Sets the treasury address. This function can only be executed by the owner.
     * @param _treasury The address of the new treasury.
     */
    function setTreasury(address _treasury) external onlyOwner {
        treasury = _treasury;
        emit TreasuryChanged(_treasury);
    }

    /**
     * @notice Sets the reward manager status for a given address. This function can only be executed by the owner.
     * @param _rewardManager The address to set as a reward manager.
     * @dev The zero address cannot be set as a reward manager. If the address is already a reward manager, this function will have no effect.
     */
    function setRewardManager(address _rewardManager) external onlyOwner {
        require(_rewardManager != address(0), "Reward manager cannot be the zero address");
        if (!rewardManager[_rewardManager]) {
            rewardManager[_rewardManager] = true;
            emit RewardManagerSet(_rewardManager);
        }
    }

    /**
     * @notice Removes the reward manager status for a given address. This function can only be executed by the owner.
     * @param _rewardManager The address to remove as a reward manager.
     * @dev If the address is not currently a reward manager, this function will have no effect.
     */
    function removeRewardManager(address _rewardManager) external onlyOwner {
        if (rewardManager[_rewardManager]) {
            rewardManager[_rewardManager] = false;
            emit RewardManagerRemoved(_rewardManager);
        }
    }

    /**
     * @notice Sets the nUSD address. This function can only be executed once by the owner.
     * @param _nUSD The address of the new nUSD.
     */
    function setnUSD(address _nUSD) external onlyOwner {
        if (address(nUSD) == address(0)) nUSD = IERC20(_nUSD);
        emit nUSDSet(_nUSD);
    }

    /**
     * @notice Sets the snUSD address. This function can only be executed once by the owner.
     * @param _snUSD The address of the new nUSD.
     */
    function setsnUSD(address _snUSD) external onlyOwner {
        if (address(snUSD) == address(0)) snUSD = IsnUSD(_snUSD);
        IERC20(_snUSD).approve(address(nUSD), type(uint256).max);
        emit snUSDSet(_snUSD);
    }
    
    /**
     * @notice Sets the ether oracle address.
     * @param _etherOracle The address of the new ether oracle.
     */
    function updateEtherOracle(address _etherOracle) external onlyOwner {
        etherOracle = _etherOracle;
        emit EtherOracleChanged(_etherOracle);
    }

    /**
     * @notice Sets the zkOracle address for a specific nUSD vault.
     * @param collateral The address of the asset vault.
     * @param zkOracle The address of the zkOracle.
     * @dev This function can only be executed once per vault.
     */
    function setZkOracle(address collateral, address zkOracle) external onlyOwner {
        require(zkOracleAddress[collateral] == address(0), "ZkOracle already set");
        require(zkOracle != address(0), "ZkOracle cannot be zero address");
        zkOracleAddress[collateral] = zkOracle;
        emit ZkOracleSet(collateral, zkOracle);
    }

    /**
     * @notice Updates the zkOracle address for a specific nUSD vault.
     * @param collateral The address of the asset vault.
     * @param zkOracle The address of the zkOracle.
     */
    function updateZkOracle(address collateral, address zkOracle) external onlyOwner {
        require(zkOracle != address(0), "ZkOracle cannot be zero address");
        zkOracleAddress[collateral] = zkOracle;
        emit ZkOracleChanged(collateral, zkOracle);
    }

    /**
     * @notice Controls the activation of a specific nUSD vault.
     * @param vault The address of the asset vault.
     */
    function enableVault(address vault) external onlyOwner {
        require(!vaultEnabled[vault], "Vault already enabled");
        address collateral = IVault(vault).collateralAsset();
        require(zkOracleAddress[collateral] != address(0), "Set zkOracle before activating vault");
        require(IVault(vault).getAssetPrice() > 0, "Price oracle not working");

        vaultEnabled[vault] = true; //enable vaults
        vaults.push(); //add to vaults list

        //if collateral is unique
        if(collateralEnabled[collateral] == false) {
            collaterals.push(collateral); //add to collateral list
            collateralEnabled[collateral] = true; //add to lookup
        }
        emit VaultEnabled(vault);
    }

    /**
     * @notice Enables or disables the minting functionality for a asset vault.
     * @param vault The address of the vault.
     * @param isActive Boolean value indicating whether minting is active or paused.
     */
    function setVaultMintPaused(address vault, bool isActive) external onlyOwnerOrAdmin {
        vaultMintPaused[vault] = isActive;
        emit VaultMintPaused(vault, isActive);
    }

    /**
     * @notice Enables or disables the repayment functionality for a asset vault.
     * @param vault The address of the vault.
     * @param isActive Boolean value indicating whether repayment is active or paused.
     */
    function setVaultBurnPaused(address vault, bool isActive) external onlyOwnerOrAdmin {
        vaultBurnPaused[vault] = isActive;
        emit VaultBurnPaused(vault, isActive);
    }

    function setDepegThreshold(address vault, uint16 threshold) external onlyOwner {
        require(threshold <= 20_00, "Threshold too high");
        depegThreshold[vault] = threshold;
        emit DepegThresholdUpdated(vault, threshold);
    }

    /**
     * @notice Enables or disables the use of market rate for a asset vault.
     * @param vault The address of the vault.
     * @param _useMarketRate Boolean value indicating whether market rate is used.
     */
    function setUseMarketRate(address vault, bool _useMarketRate) external onlyOwner {
        if(_useMarketRate) {
            require(IVault(vault).getMarketRate() > 0, "Invalid market rate");
        }
        useMarketRate[vault] = _useMarketRate;
        emit UseMarketRateChanged(vault, _useMarketRate);
    }

    /**
     * @notice Controls the minting limit of nUSD for an asset vault.
     * @param vault The address of the asset vault.
     * @param maxSupply The maximum amount of nUSD that can be minted for the asset vault.
     */
    function setMintVaultMaxSupply(address vault, uint256 maxSupply) external onlyOwner {
        mintVaultMaxSupply[vault] = maxSupply;
        emit MintVaultMaxSupplyChanged(vault, maxSupply);
    }

    /**
        * @notice Sets the bad collateral ratio for a specific nUSD vault.
        * @param vault The address of the asset vault.
        * @param newRatio The new bad collateral ratio to set.
     */
    function setBadCollateralRatio(address vault, uint16 newRatio) external onlyOwner {
        // should be at least 10% lower than safe collateral ratio
        require(newRatio <= vaultSafeCollateralRatio[vault] - 10_00, "config too high");
        // bad collateral ratio should be between 105% and 200%
        require(newRatio >= 110_00 && newRatio <= 200_00, "config out of range");
        vaultBadCollateralRatio[vault] = newRatio;
        emit BadCollateralRatioChanged(vault, newRatio);
    }

    /**
     * @notice Sets the safe collateral ratio for a specific nUSD vault.
     * @param vault The address of the asset vault.
     * @param newRatio The new safe collateral ratio to set.
     */
    function setSafeCollateralRatio(address vault, uint16 newRatio) external onlyOwner {
        // should be at least 10% higher than bad collateral ratio
        require(newRatio >= vaultBadCollateralRatio[vault] + 10_00, "config too low");
        // safe collateral ratio should be at least 115% (10% higher than 105% minimum bad collateral ratio)
        require(newRatio >= 120_00, "config too low");
        vaultSafeCollateralRatio[vault] = newRatio;
        emit SafeCollateralRatioChanged(vault, newRatio);
    }

    /**
     * @notice Set the borrowing annual percentage rate (APR) for a asset vault.
     * @param vault The address of the vault to set the borrowing APR for.
     * @param newApr The new borrowing APR to set (in bps), limited to a maximum of 1000%.
     */
    function setBorrowApr(address vault, uint16 newApr) external onlyOwner {
        require(newApr <= 1000_00, "Borrow APR cannot exceed 1000%");
        borrowApr[vault] = newApr;
        emit BorrowAprChanged(vault, newApr);
    }

    /**
     * @notice Set the reward ratio for the liquidator after liquidation.
     * @param vault The address of the vault to set the reward ratio for.
     * @param newReward The new reward to set, limited to a maximum of 5% (out of maximum 10% liquidation penalty).
     */
    function setKeeperReward(address vault, uint16 newReward) external onlyOwner {
        require(newReward <= 500, "Max Keeper reward is 5%");
        vaultKeeperRatio[vault] = newReward;
        emit KeeperRewardChanged(vault, newReward);
    }

    /**
     * @notice Sets the redemption fee.
     */
    function setRedemptionFee(address vault, bool enabled, uint16 baseFee, uint16 maxMultiplier, uint16 maxCollateralRatio, uint16 providerShare) external onlyOwner {
        require(baseFee <= 10_00, "Max Redemption Fee is 10%");
        require(maxMultiplier <= 100_000, "Max multiplier is 10x");
        require(maxCollateralRatio >= 150_00 && maxCollateralRatio <= 300_00, "Cr for max multiplier must be 150%-300%");
        require(providerShare >= 50_00 && providerShare <= 100_00, "Provider share must be 50%-100%");
        vaultRedemptionConfig[vault] = RedemptionConfig(enabled, baseFee, maxMultiplier, maxCollateralRatio, providerShare);
        emit RedemptionConfigChanged(vault, enabled, baseFee, maxMultiplier, maxCollateralRatio, providerShare);
    }

    /**
     * @notice Set the origination fee for a asset vault.
     * @param vault The address of the vault to set the origination fee for.
     * @param minOriginationFee The minimum origination fee in percentage.
     * @param maxOriginationFee The maximum origination fee in percentage.
     */
    function setOriginationFee(address vault, uint16 minOriginationFee, uint16 maxOriginationFee) external onlyOwner {
        require(minOriginationFee <= maxOriginationFee, "Min fee cannot exceed max fee");
        require(maxOriginationFee <= 10_00, "Origination fee cannot exceed 10%");
        vaultOriginationFee[vault] = OriginationFeeConfig(minOriginationFee, maxOriginationFee);
        emit OriginationFeeChanged(vault, minOriginationFee, maxOriginationFee);
    }

    /**
     * @notice Update the flashloan fee percentage, only available to the manager of the contract
     * @param fee The fee for nUSD in bps
     */
    function setFlashloanFee(uint16 fee) external onlyOwner {
        require(fee <= 100_00, "Fee cannot exceed 100%");
        emit FlashloanFeeUpdated(fee);
        flashloanFee = fee;
    }

    /**
     * @notice Withdraws tokens from the contract.
     * @param tokenAddress The address of the token to withdraw.
     * @param to The address to send the tokens to.
     * @param amount The amount of tokens to withdraw.
     */
    function withdrawTokens(address tokenAddress, address to, uint256 amount) external onlyOwner {
        require(amount > IERC20(tokenAddress).balanceOf(address(this)), "Amount exceeds balance");
        IERC20(tokenAddress).safeTransfer(to, amount);
        emit TokensWithdrawn(tokenAddress, to, amount);
    }

    /**
     * @notice Transfers 50% of nUSD protocol fees to the snUSD contract, and remainder to the treasury
     */
    function distributeFees() external onlyOwnerOrAdmin {
        uint256 nusdBalance = nUSD.balanceOf(address(this));
        require(nusdBalance > 0, "No fees to distribute");
        uint256 snUsdRewards = nusdBalance / 2;
        snUSD.transferInRewards(snUsdRewards);
        nUSD.transfer(treasury, nusdBalance - snUsdRewards);
        emit FeesDistributed(nusdBalance);
    }

    /**
     * @dev Returns the list of all vaults.
     * @return The list of all vaults.
     */
    function getAllVaults() external view returns (address[] memory) {
        return vaults;
    }

    /**
     * @dev Returns the list of all collaterals.
     * @return The list of all collaterals.
     */
    function getAllCollaterals() external view returns (address[] memory) {
        return collaterals;
    }

    /**
     * @dev Returns the safe collateral ratio for a asset vault (or the default).
     * @param vault The address of the vault to check.
     * @return The safe collateral ratio for the specified vault.
     */
    function getSafeCollateralRatio(address vault) public view returns (uint16) {
        if (vaultSafeCollateralRatio[vault] == 0) return defaultSafeCollateralRatio;
        return vaultSafeCollateralRatio[vault];
    }

    /**
     * @dev Returns the bad collateral ratio for a asset vault (or the default).
     * @param vault The address of the vault to check.
     * @return The bad collateral ratio for the specified vault.
     */
    function getBadCollateralRatio(address vault) public view returns(uint16) {
        if(vaultBadCollateralRatio[vault] == 0) return getSafeCollateralRatio(vault) - defaultBadCollateralRatioDistance;
        return vaultBadCollateralRatio[vault];
    }

    /**
     * @dev Returns the origination fee for an asset vault (or the default if none is configured).
     * @param vault The address of the vault to check.
     */
    function getOriginationFee(address vault) external view returns(uint256 minOriginationFee, uint256 maxOriginationFee) {
        OriginationFeeConfig memory config = vaultOriginationFee[vault];
        if(config.minOriginationFee == 0 && config.maxOriginationFee == 0) return (defaultOriginationFee.minOriginationFee, defaultOriginationFee.maxOriginationFee);
        else return (config.minOriginationFee, config.maxOriginationFee);
    }

    /**
     * @dev Returns the redemption config for an asset vault (or the default if none is configured).
     * @param vault The address of the vault to check.
     */
    function getRedemptionConfig(address vault) public view returns(RedemptionConfig memory) {
        RedemptionConfig memory config = vaultRedemptionConfig[vault];
        if(config.enabled == false && config.providerShare == 0 && config.baseFee == 0 && config.maxCollateralRatio == 0 && config.maxMultiplier == 0) {
            return defaultRedemptionConfig;
        }
        else return config;
    }

    /**
     * @dev Returns the redemption fee for an asset vault.
     * @param vault The address of the vault to check.
     * @param collateralRatio The collateral ratio of the provider whose collateral is being redeemed.
     */
    function getRedemptionFee(address vault, uint256 collateralRatio) external view returns(uint256 providerFee, uint256 protocolFee) {
        require(vaultEnabled[vault], "Vault not enabled");
        require(collateralRatio >= 100_00, "Cannot redeem when collateral ratio is below 100%");
        RedemptionConfig memory config = getRedemptionConfig(vault);
        require(collateralRatio <= config.maxCollateralRatio, "Cannot redeem collateral ratio above max");
        uint16 badCollateralRatio = getBadCollateralRatio(vault);
        uint16 safeCollateralRatio = getSafeCollateralRatio(vault);
        uint16 providerShare = 80_00; //80% of redemption fee goes to provider

        uint256 totalFee;
        //Liquidateable positions don't get any redemption bonus, the baseFee goes to protocol
        if(collateralRatio <= badCollateralRatio) {
            totalFee = config.baseFee;
            providerFee = 0;
            protocolFee = totalFee;
        }
        //Positions between safe and bad collateral ratio get proportional baseFee based on how close to safe
        else if(collateralRatio <= safeCollateralRatio) {
            totalFee = config.baseFee;
            providerFee = totalFee * providerShare * (collateralRatio-badCollateralRatio) / (safeCollateralRatio-badCollateralRatio) / 100_00;
        }
        //Positions above collateralRatioForMaxMultiplier get baseFee * maxMultiplier
        else if(collateralRatio > config.maxCollateralRatio) {
            totalFee = config.baseFee * config.maxMultiplier / 100_00;
            providerFee = totalFee * providerShare / 100_00;
        }
        //Positions above safe collateral ratio and below collateralRatioForMaxMultiplier get linearly proportional multiplier
        else {
            totalFee = config.baseFee * (100_00 + (config.maxMultiplier-100_00) * (collateralRatio-safeCollateralRatio) / (config.maxCollateralRatio -safeCollateralRatio)) / 100_00;
            providerFee = totalFee * providerShare / 100_00;
        }
        protocolFee = totalFee - providerFee;
    }

    /**
     * @dev Returns the depeg threshold for a asset vault (or the default).
     * @param vault The address of the vault to check.
     * @return The depeg threshold for the specified vault.
     */
    function getDepegThreshold(address vault) external view returns(uint256) {
        if(depegThreshold[vault] == 0) return defaultDepegThreshold;
        return depegThreshold[vault];
    }

    /**
     * @dev Returns the keeper ratio for a asset vault (or the default).
     * @param vault The address of the vault to check.
     * @return The keeper ratio for the specified vault.
     */
    function getKeeperReward(address vault) external view returns(uint256) {
        if(vaultKeeperRatio[vault] == 0) return defaultKeeperReward;
        return vaultKeeperRatio[vault];
    }

    /**
     * @dev Returns whether a user is reward manager
     * @param user The address of the user to check.
     * @notice The owner is always a reward manager.
     * @return boolean indicating whether the user is a reward manager.
     */
    function isRewardManager(address user) external view returns(bool) {
        return rewardManager[user] || user == owner();
    }
}

{
  "compilationTarget": {
    "contracts/unstable/configuration/UnstableConfigurator.sol": "UnstableConfigurator"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 9999
  },
  "remappings": [
    ":@chainlink/=node_modules/@chainlink/",
    ":@ensdomains/=node_modules/@ensdomains/",
    ":@eth-optimism/=node_modules/@eth-optimism/",
    ":@ethereum-waffle/=node_modules/@ethereum-waffle/",
    ":@layerzerolabs/=node_modules/@layerzerolabs/",
    ":@openzeppelin-3/=node_modules/@openzeppelin-3/",
    ":@openzeppelin/=node_modules/@openzeppelin/",
    ":@redstone-finance/=node_modules/@redstone-finance/",
    ":@uniswap/=node_modules/@uniswap/",
    ":erc721a/=node_modules/erc721a/",
    ":eth-gas-reporter/=node_modules/eth-gas-reporter/",
    ":forge-std/=lib/forge-std/src/",
    ":hardhat-deploy/=node_modules/hardhat-deploy/",
    ":hardhat/=node_modules/hardhat/"
  ]
}