The Society Collector Token

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        } else if (error == RecoverError.InvalidSignatureV) {
            revert("ECDSA: invalid signature 'v' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        // Check the signature length
        // - case 65: r,s,v signature (standard)
        // - case 64: r,vs signature (cf https://eips.ethereum.org/EIPS/eip-2098) _Available since v4.1._
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else if (signature.length == 64) {
            bytes32 r;
            bytes32 vs;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            assembly {
                r := mload(add(signature, 0x20))
                vs := mload(add(signature, 0x40))
            }
            return tryRecover(hash, r, vs);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address, RecoverError) {
        bytes32 s;
        uint8 v;
        assembly {
            s := and(vs, 0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff)
            v := add(shr(255, vs), 27)
        }
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }
        if (v != 27 && v != 28) {
            return (address(0), RecoverError.InvalidSignatureV);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", hash));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x01", domainSeparator, structHash));
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Interface for the NFT Royalty Standard
 */
interface IERC2981 is IERC165 {
    /**
     * @dev Called with the sale price to determine how much royalty is owed and to whom.
     * @param tokenId - the NFT asset queried for royalty information
     * @param salePrice - the sale price of the NFT asset specified by `tokenId`
     * @return receiver - address of who should be sent the royalty payment
     * @return royaltyAmount - the royalty payment amount for `salePrice`
     */
    function royaltyInfo(uint256 tokenId, uint256 salePrice)
        external
        view
        returns (address receiver, uint256 royaltyAmount);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.9;

//   ____  _  _  ____    ____   __    ___  __  ____  ____  _  _
//  (_  _)/ )( \(  __)  / ___) /  \  / __)(  )(  __)(_  _)( \/ )
//    )(  ) __ ( ) _)   \___ \(  O )( (__  )(  ) _)   )(   )  /
//   (__) \_)(_/(____)  (____/ \__/  \___)(__)(____) (__) (__/
//

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@openzeppelin/contracts/interfaces/IERC721Receiver.sol";
import "@openzeppelin/contracts/interfaces/IERC2981.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

// Society membership is captured in this contract.
//
// It is an NFT (ERC721) with a few custom enhancements:
//
//  1. Captcha Scheme
//      We use a captcha scheme to prevent bots from minting.
//        #isProbablyHuman() - matches a captcha signature signed elsewhere
//
//  2. Money-back Warranty
//      We promise your money back if we don't get enough members:
//               #withdraw()  - locks the money unless there are >=2000 members
//             #refundFull(), - these return your money during refunding
//          #refundKeepArt()    and they're enabled automatically after time has elapsed
//
//      (see "Refund Warranty Process" below for more details)
//
//  3. Minting Limits
//      A single wallet may only mint 2 memberships.
//
//  4. Founding Team
//      During contract construction, we mint 7 memberships,
//      one for each member of the founding team and the first artist.
//
//  5. Member Migration
//      This contract is an improved edition of an earlier membership contract.
//      Early token holders can migrate into this and receive an additional token
//      for their continued loyalty.
//
//  6. Gold/Standard Tokens
//      The first 2,000 memberships will get a Gold token, these are
//      identified by having an ID number 1-2000.
//
//  7. Limited Sales Window
//      After the Feb. 18 sales deadline one of two things will happen:
//        - if there are <2,000 members, then refunds are enabled and the society winds down.
//        - if there are 2,000+ members, then membership is capped to the number already sold.
//
//  Refund Warranty Process
//
//  If 2,000+ memberships are sold by Feb 18 there are no refunds.
//  But if less than 2,000 are sold by Feb 18, then the refund
//  implementation operates within three phases:
//
//   Phase 1: Jan 18 - Feb 18
//     After contract creation, until the sales deadline or >2,000 sold,
//     all minting fees remain locked in the contract.
//       - The Society's #withdraw() is disabled
//       - Member's #refund...() are also disabled
//
//   Phase 2: Feb 18 - Mar 18
//     After the sales deadline (if <2,000 sold), until the refund deadline,
//     Members may claim a #refund...() for the sale price.
//       - The Society's #withdraw() is still disabled
//       - Member's #refund...() are now enabled
//
//   Phase 3: after Mar 18
//     After the refund deadline, Members can no longer claim a #refund...()
//     and The Society can #withdraw() any unrefunded fees.
//       - The Society's #withdraw() is enabled
//       - Member's #refund...() are disabled

contract SocietyMember is
    ERC721,
    IERC2981,
    IERC721Receiver,
    Ownable,
    ReentrancyGuard
{
    using ECDSA for bytes32;

    // This indicates what mode this contract is operating in.
    // See #updateMode() for implementation
    enum Mode {
        // Happy path:
        SellingPreThreshold, // before sales deadline < 2,000 sold
        SellingPostThreshold, // > 2,000 sold, < 5,000 sold
        SoldOut, // 5,000 sold (or 2,000+ sold after sales deadline)
        // Sad path:
        Refunding, // < 2,000 sold, after sales deadline before refund deadline
        ClosingAfterRefundPeriod // < 2,000 sold, after refund deadline
    }

    // This is the sale price of each membership.
    uint256 public constant SALE_PRICE = 0.15 ether;
    // This is the price of individual pieces of art.
    // NOTE: we only use this if people opt for partial refund.
    uint256 public constant ART_PRICE = 0.1 ether;

    // A single wallet may only mint 2 memberships.
    uint256 public constant MINTS_PER_WALLET = 2;

    // There can be only 5,000 members (2,000 gold).
    // However many memberships have been sold at the sales deadline,
    // that number becomes the new maximum total member count.
    uint256 public MAXIMUM_TOTAL_MEMBER_COUNT;
    uint256 public immutable MAXIMUM_GOLD_MEMBER_COUNT;

    // When members rollover a token from the original membership contract
    // they will receive 3 memberships. They receive 2 memberships immediately
    // and then receive a 3rd when the sales threshold is reached.
    // For each membership token, members also receives a piece of artwork.
    // This records where to send the token post-threshold.
    mapping(uint16 => address) private pendingTransfers;
    // Emitted when `tokenId` token is minted and pending transfer to `to`.
    event PendingTransfer(address indexed to, uint256 indexed tokenId);
    // This records the migrated token so the old refund can be claimed.
    mapping(uint16 => uint16) private pendingRefundTokens;
    // The old member contract is used to verify migration.
    IOldMember private oldMemberK;

    // There need to be 2,000 members to proceed.
    // NOTE: permanently fixed upon contract creation
    uint256 public immutable ENOUGH_MEMBERS_TO_PROCEED;

    // Sales must exceed 2,000 members for the Society to proceed.
    // If we fail to get 2,000 members then the first #refund() request
    // after this time will start refunding.
    //   See note re "Refund Warrant Process" for more details.
    // NOTE: permanently fixed upon contract creation
    uint256 public immutable SALES_DEADLINE; // timestamp in seconds

    // If we fail to get 2,000 members then Members have until
    // this time to claim their #refund()
    //   See note re "Refund Warrant Process" for more details.
    // NOTE: permanently fixed upon contract creation
    uint256 public immutable REFUND_DEADLINE; // timestamp in seconds

    // During contract construction, we mint 7 tokens,
    // one for each member of the founding team and the first artist.
    // NOTE: permanently fixed upon contract creation
    uint256 private immutable FOUNDING_TEAM_COUNT;

    // This indicates the current mode (selling, refunding etc)
    Mode public mode;

    // We generate the next token ID by incrementing these counters.
    // Gold tokens have an ID <= 2,000.
    uint16 private goldIds; // 1 - 2000
    uint16 private standardIds; // 2001 - 5000

    // This tracks mint counts to help limit mints per wallet.
    mapping(address => uint8) private mintCountsByAddress;

    // This tracks gold token count per owner.
    mapping(address => uint16) private goldBalances;

    // Minting membership includes an item from the initial art collection.
    IInitialArtSale private artSale;

    // This contains the base URI (e.g. "https://example.com/tokens/")
    // that is used to produce a URI for the metadata about
    // each token (e.g. "https://example.com/tokens/1234")
    string private baseURI;

    // For exchanges that support ERC2981, this sets our royalty rate.
    // NOTE: whereas "percent" is /100, this uses "per mille" which is /1000
    uint256 private royaltyPerMille;

    // To combat bots, minting requests include a captcha signed elsewhere.
    // To verify the captcha, we compare its signature with this signer.
    address private captchaSigner;

    // To enable gas-free listings on OpenSea we integrate with the proxy registry.
    address private openSeaProxyRegistry;
    // The Society can disable gas-free listings in case OpenSea is compromised.
    bool private isOpenSeaProxyEnabled = true;

    struct Config {
        address[] foundingTeam;
        uint256 maximumTotalMemberCount;
        uint256 maximumGoldMemberCount;
        uint256 enoughMembersToProceed;
        uint256 salesDeadline;
        uint256 refundDeadline;
        uint256 royaltyPerMille;
        address captchaSigner;
        address openSeaProxyRegistry;
        IOldMember oldMemberK;
    }

    constructor(Config memory config) ERC721("Collector", "COLLECTOR") {
        require(
            config.enoughMembersToProceed <= config.maximumTotalMemberCount
        );
        require(
            config.maximumGoldMemberCount <= config.maximumTotalMemberCount
        );
        require(config.salesDeadline <= config.refundDeadline);

        MAXIMUM_TOTAL_MEMBER_COUNT = config.maximumTotalMemberCount;
        MAXIMUM_GOLD_MEMBER_COUNT = config.maximumGoldMemberCount;
        ENOUGH_MEMBERS_TO_PROCEED = config.enoughMembersToProceed;
        SALES_DEADLINE = config.salesDeadline;
        REFUND_DEADLINE = config.refundDeadline;
        royaltyPerMille = config.royaltyPerMille;
        captchaSigner = config.captchaSigner;
        openSeaProxyRegistry = config.openSeaProxyRegistry;
        oldMemberK = config.oldMemberK;
        mode = Mode.SellingPreThreshold;

        // Grant the founding team the first 7 tokens.
        FOUNDING_TEAM_COUNT = config.foundingTeam.length;
        for (uint256 i = 0; i < config.foundingTeam.length; i++) {
            _mint(config.foundingTeam[i], generateTokenId());
            // NOTE: the accompanying art is minted later when we #setInitialArtSale().
        }
    }

    //
    // Public Read Methods
    //

    // See how many memberships have been minted by the specified wallet.
    // NOTE: this is not the same as ownership
    function getMintCountByAddress(address minter_)
        external
        view
        returns (uint8)
    {
        return mintCountsByAddress[minter_];
    }

    // How many gold tokens have been issued.
    function goldSupply() external view returns (uint256) {
        return goldIds;
    }

    // Returns the number of gold tokens held by `owner`.
    function goldBalanceOf(address owner) external view returns (uint256) {
        return goldBalances[owner];
    }

    //
    // Public Write Methods
    //

    // This mints membership tokens to the sender.
    // Each token also includes a mint of artwork from the current collection.
    // It requires a `captcha` which is used to verify that
    // the sender is probably human and came here via our web flow.
    function mint(bytes memory captcha, uint8 numberOfTokens)
        external
        payable
        nonReentrant
    {
        require(numberOfTokens > 0, "missing number of tokens to mint");
        updateMode();
        require(
            mode == Mode.SellingPreThreshold ||
                mode == Mode.SellingPostThreshold,
            "minting is not available"
        );
        require(
            memberCount() + numberOfTokens <= MAXIMUM_TOTAL_MEMBER_COUNT,
            "not enough memberships remaining"
        );
        require(
            msg.value == SALE_PRICE * numberOfTokens,
            "incorrect ETH payment amount"
        );
        require(isProbablyHuman(captcha, msg.sender), "you seem like a robot");
        uint8 mintCount = mintCountsByAddress[msg.sender];
        require(
            mintCount + numberOfTokens <= MINTS_PER_WALLET,
            "you can only mint two memberships per wallet"
        );

        mintCountsByAddress[msg.sender] = mintCount + numberOfTokens;

        for (uint256 i = 0; i < numberOfTokens; i++) {
            mintWithArt(msg.sender, generateTokenId());
        }
    }

    // This mints 3 memberships for the user when they migrate the old token.
    // The first 2 memberships are transferred immediately along with 2 art pieces.
    // The 3rd token is marked as pending until reaching the sales threshold.
    function migrateMint(uint256[] memory oldTokenIds) external nonReentrant {
        updateMode();
        require(
            mode == Mode.SellingPreThreshold ||
                mode == Mode.SellingPostThreshold,
            "minting is not available"
        );
        require(
            memberCount() + 3 * oldTokenIds.length <=
                MAXIMUM_TOTAL_MEMBER_COUNT,
            "not enough memberships remaining"
        );
        require(oldTokenIds.length < 4, "migrating too many in a single call");
        for (uint256 i = 0; i < oldTokenIds.length; i++) {
            uint256 oldTokenId = oldTokenIds[i];
            require(
                oldTokenId > FOUNDING_TEAM_COUNT,
                "founding team tokens cannot migrate"
            );

            // The first 2 tokens transfer immediately.
            oldMemberK.transferFrom(msg.sender, address(this), oldTokenId);
            mintFromOldWithArt(oldTokenId, msg.sender, generateTokenId());
            mintFromOldWithArt(oldTokenId, msg.sender, generateTokenId());

            // And we mint the 3rd token and record where it should eventually go.
            // It is transferred upon reaching the sales threshold. See #claimPending()
            uint256 pendingTokenId = generateTokenId();
            _mint(address(this), pendingTokenId);
            pendingTransfers[uint16(pendingTokenId)] = msg.sender;
            emit PendingTransfer(msg.sender, pendingTokenId);
        }
    }

    // After reaching the sales threshold, this transfers the
    // pending 3rd token for migrated members.
    function claimPending(uint256[] memory tokenIds) external nonReentrant {
        updateMode();
        require(
            mode == Mode.SellingPostThreshold || mode == Mode.SoldOut,
            "token remains pending until post-threshold"
        );
        require(tokenIds.length < 8, "claiming too many in a single call");
        for (uint256 i = 0; i < tokenIds.length; i++) {
            uint256 tokenId = tokenIds[i];
            address to = pendingTransfers[uint16(tokenId)];
            require(to != address(0), "token is not pending transfer");
            pendingTransfers[uint16(tokenId)] = address(0);
            _transfer(address(this), to, tokenId);
            artSale.mintTo(to);
        }
    }

    //
    // Refund Options
    // If we fail to get >2,000 members members can call these to receive their ETH back.
    // During a refund, the member can decide what to do with the artwork they received during mint:
    //
    //     refundFull:  a member returns both their membership and the artwork they received.
    //                  The member receives a full refund (.15E).
    //
    //  refundKeepArt:  a member returns their membership but keeps the artwork.
    //                  The member receives the full price minus the art price (.15E - .1E = .05E)
    //

    // This lets a member return both their membership and the artwork they received.
    // The member receives a full refund (.15E).
    // NOTE: to receive the full refund, the member does NOT retain the artwork.
    // NOTE: after the sales deadline this is enabled automatically.
    function refundFull(uint256 memberTokenId, uint256 artTokenId)
        external
        nonReentrant
    {
        require(
            ownerOf(memberTokenId) == msg.sender,
            "only the owner may claim a refund"
        );
        require(
            memberTokenId > FOUNDING_TEAM_COUNT,
            "founding team tokens do not get a refund"
        );
        updateMode();
        require(mode == Mode.Refunding, "refunding is not available");

        claimAnyOldRefunds(memberTokenId);
        artSale.transferFrom(msg.sender, address(this), artTokenId);
        _burn(memberTokenId);
        payable(msg.sender).transfer(SALE_PRICE);
    }

    // This lets a member returns their membership but keeps the artwork.
    // The member receives the full price minus the art price (.15E - .1E = .05E)
    // NOTE: the amount refunded is reduced by the price of the artwork.
    // NOTE: after the sales deadline this is enabled automatically.
    function refundKeepArt(uint256 memberTokenId) external nonReentrant {
        require(
            ownerOf(memberTokenId) == msg.sender,
            "only the owner may claim a refund"
        );
        require(
            memberTokenId > FOUNDING_TEAM_COUNT,
            "founding team tokens do not get a refund"
        );
        updateMode();
        require(mode == Mode.Refunding, "refunding is not available");

        claimAnyOldRefunds(memberTokenId);
        _burn(memberTokenId);
        payable(msg.sender).transfer(SALE_PRICE - ART_PRICE);
    }

    //
    // Admin Methods
    //

    // This allows the Society to withdraw funds from the treasury.
    // NOTE: this is locked until there are at least 2,000 members.
    function withdraw() external onlyOwner {
        updateMode();
        require(
            mode == Mode.SellingPostThreshold ||
                mode == Mode.SoldOut ||
                mode == Mode.ClosingAfterRefundPeriod,
            "locked until there are enough members (or after refund period)"
        );
        uint256 balance = address(this).balance;
        payable(msg.sender).transfer(balance);
    }

    // This allows the Society to withdraw any received ERC20 tokens.
    // NOTE: This method exists to avoid the sad scenario where someone
    //       accidentally sends tokens to this address and the tokens get stuck.
    function withdrawERC20Tokens(IERC20 token) external onlyOwner {
        uint256 balance = token.balanceOf(address(this));
        token.transfer(msg.sender, balance);
    }

    // This allows the Society to withdraw any received ERC721 tokens.
    // NOTE: This method locks to secure old memberships used for refunds.
    // NOTE: This method also exists to avoid the sad scenario where someone
    //       accidentally sends tokens to this address and the tokens get stuck.
    function withdrawERC721Token(IERC721 token, uint256 tokenId)
        external
        onlyOwner
    {
        updateMode();
        require(
            mode == Mode.SellingPostThreshold ||
                mode == Mode.SoldOut ||
                mode == Mode.ClosingAfterRefundPeriod,
            "locked until there are enough members (or after refund period)"
        );
        token.transferFrom(address(this), msg.sender, tokenId);
    }

    // The society can update the baseURI for metadata.
    //  e.g. if there is a hosting change
    function setBaseURI(string memory uri) external onlyOwner {
        baseURI = uri;
    }

    // The society can update the ERC2981 royalty rate.
    // NOTE: whereas "percent" is /100, this uses "per mille" which is /1000
    function setRoyalty(uint256 _royaltyPerMille) external onlyOwner {
        royaltyPerMille = _royaltyPerMille;
    }

    // The society can set the initial art sale.
    function setInitialArtSale(IInitialArtSale _artSale) external onlyOwner {
        require(
            address(artSale) == address(0),
            "initial art sale already specified"
        );
        artSale = _artSale;
        // The art to accompany the founding team's memberships (#1..#7) can now be minted.
        for (uint256 i = 0; i < FOUNDING_TEAM_COUNT; i++) {
            artSale.mintTo(ownerOf(i + 1));
        }
    }

    // The society can update the signer of the captcha used to secure #mint().
    function setCaptchaSigner(address _captchaSigner) external onlyOwner {
        captchaSigner = _captchaSigner;
    }

    // The society can disable gas-less listings for security in case OpenSea is compromised.
    function setOpenSeaProxyEnabled(bool isEnabled) external onlyOwner {
        isOpenSeaProxyEnabled = isEnabled;
    }

    //
    // Interface Override Methods
    //

    // The membership contract can receive ETH deposits.
    receive() external payable {}

    // The membership contract can receive ERC721 tokens.
    // See IERC721Receiver
    function onERC721Received(
        address,
        address,
        uint256,
        bytes calldata
    ) public virtual override returns (bytes4) {
        return this.onERC721Received.selector;
    }

    // This hooks into the ERC721 implementation
    // it is used by `tokenURI(..)` to produce the full thing.
    function _baseURI() internal view override returns (string memory) {
        return baseURI;
    }

    ///
    /// IERC2981 Implementation
    ///

    /**
     * @dev See {IERC2981-royaltyInfo}.
     * This exposes the ERC2981 royalty rate.
     */
    function royaltyInfo(uint256 tokenId, uint256 salePrice)
        external
        view
        returns (address receiver, uint256 royaltyAmount)
    {
        require(_exists(tokenId), "not a valid token");
        return (owner(), (salePrice * royaltyPerMille) / 1000);
    }

    ///
    /// IERC721Enumerable Implementation (partial)
    ///   NOTE: to reduce gas costs, we don't implement tokenOfOwnerByIndex()
    ///

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     * Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256) {
        return memberCount();
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     * Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 _index) external view returns (uint256) {
        if (_index >= goldIds) {
            _index = MAXIMUM_GOLD_MEMBER_COUNT + (goldIds - _index);
        }
        require(_exists(_index + 1), "bad token index");
        return _index + 1;
    }

    // This hooks into transfers to track gold balances.
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual override {
        if (tokenId > MAXIMUM_GOLD_MEMBER_COUNT) {
            // We only do the extra bookkeeping
            // when a gold token is being transferred.
            return;
        }
        if (from != address(0)) {
            goldBalances[from] -= 1;
        }
        if (to != address(0)) {
            goldBalances[to] += 1;
        }
    }

    // This hooks into approvals to allow gas-free listings on OpenSea.
    function isApprovedForAll(address owner, address operator)
        public
        view
        override
        returns (bool)
    {
        if (isOpenSeaProxyEnabled) {
            ProxyRegistry registry = ProxyRegistry(openSeaProxyRegistry);
            if (address(registry.proxies(owner)) == operator) {
                return true;
            }
        }

        return super.isApprovedForAll(owner, operator);
    }

    ///
    /// IERC165 Implementation
    ///

    /**
     * @dev See {IERC165-supportsInterface}.
     * This implements ERC165 which announces our other supported interfaces:
     *   - ERC2981 (royalty info)
     */
    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(IERC165, ERC721)
        returns (bool)
    {
        if (interfaceId == type(IERC2981).interfaceId) {
            return true;
        }
        // NOTE: we don't include IERC721Enumerable
        //       because ours is only a partial implementation.
        return super.supportsInterface(interfaceId);
    }

    //
    // Private Helper Methods
    //

    // This tries to prevent robots from minting a membership.
    // The `captcha` contains a signature (generated via web captcha flow)
    // that was made using the Society's private key.
    //
    // This method checks the signature to see:
    //  - if it was signed by the Society's key and
    //  - if it was for the current msg.sender
    function isProbablyHuman(bytes memory captcha, address sender)
        private
        view
        returns (bool)
    {
        // First we recreate the same message that was originally signed.
        // This is equivalent to how we created it elsewhere:
        //      message = ethers.utils.solidityKeccak256(
        //                  ["string", "address"],
        //                  ["member", sender]);
        bytes32 message = keccak256(abi.encodePacked("member", sender));

        // Now we can see who actually signed it
        address signer = message.toEthSignedMessageHash().recover(captcha);

        // And finally check if the signer was us!
        return signer == captchaSigner;
    }

    // This updates the current mode based on the member count and the time.
    // The contract calls this before any use of the current mode.
    // See "Refund Warranty Process" above for more details.
    function updateMode() private {
        if (mode == Mode.SoldOut) {
            // After selling out, the mode cannot change.
            return;
        }
        uint256 count = memberCount();

        // After the sales deadline, the total supply is fixed to the number sold.
        if (
            block.timestamp >= SALES_DEADLINE &&
            count >= ENOUGH_MEMBERS_TO_PROCEED
        ) {
            MAXIMUM_TOTAL_MEMBER_COUNT = count;
        }

        // Update the mode based on the sales count and time.
        if (count >= MAXIMUM_TOTAL_MEMBER_COUNT) {
            mode = Mode.SoldOut;
        } else if (count >= ENOUGH_MEMBERS_TO_PROCEED) {
            mode = Mode.SellingPostThreshold;
        } else {
            // count < enoughMembersToProceed
            // When there are not enough members to proceed
            // then the mode depends on the time.
            if (block.timestamp < SALES_DEADLINE) {
                // Before sales deadline
                mode = Mode.SellingPreThreshold;
            } else if (block.timestamp < REFUND_DEADLINE) {
                // After sales deadline, before refund deadline
                mode = Mode.Refunding;
            } else {
                // block.timestamp >= refundDeadline
                // After the refund deadline
                mode = Mode.ClosingAfterRefundPeriod;
            }
        }
    }

    // Create the next token ID to be used.
    // This is complicated because we shuffle between two ID ranges:
    //       1-2000 -> gold
    //    2001-5000 -> standard
    // So if there are gold remaining then we use the gold IDs.
    // Otherwise we use the standard IDs.
    function generateTokenId() private returns (uint256) {
        if (goldIds < MAXIMUM_GOLD_MEMBER_COUNT) {
            goldIds += 1;
            return goldIds;
        }
        standardIds += 1;
        return standardIds + MAXIMUM_GOLD_MEMBER_COUNT;
    }

    // Compute the total member count.
    function memberCount() private view returns (uint256) {
        return goldIds + standardIds;
    }

    // This claims any old pending refund to cover the refund of this `memberTokenId`.
    function claimAnyOldRefunds(uint256 memberTokenId) private {
        uint16 oldMemberTokenId = pendingRefundTokens[uint16(memberTokenId)];
        if (oldMemberTokenId != 0) {
            try oldMemberK.refund(oldMemberTokenId) {} catch (bytes memory) {}
        }
    }

    // This actually mints `memberTokenId` to `to` along with a piece of artwork.
    function mintWithArt(address to, uint256 memberTokenId) private {
        _safeMint(to, memberTokenId);
        artSale.mintTo(to);
    }

    // This actually mints `memberTokenId` to `to` along with a piece of artwork.
    // It also associates the minted `memberTokenId` with a pending refund for `oldMemberTokenId`
    function mintFromOldWithArt(
        uint256 oldMemberTokenId,
        address to,
        uint256 memberTokenId
    ) private {
        pendingRefundTokens[uint16(memberTokenId)] = uint16(oldMemberTokenId);
        mintWithArt(to, memberTokenId);
    }
}

// This is the interface to the old membership contract.
interface IOldMember is IERC721 {
    // This allows the membership contract to claim the refund for migrated tokens.
    function refund(uint256 tokenId) external;
}

// This is the interface to the ongoing art sale.
interface IInitialArtSale is IERC721 {
    // This allows the membership contract to mint artwork to a new member.
    function mintTo(address to) external payable;
}

// These types define our interface to the OpenSea proxy registry.
// We use these to support gas-free listings.
contract OwnableDelegateProxy {

}

contract ProxyRegistry {
    mapping(address => OwnableDelegateProxy) public proxies;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

{
  "compilationTarget": {
    "contracts/SocietyMember.sol": "SocietyMember"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 10000
  },
  "remappings": []
}