CardioCoin

pragma solidity >= 0.5.0;

import "./Ownable.sol";
import "./SafeMath.sol";
import "./ERC20.sol";

contract CardioCoin is ERC20, Ownable {
    using SafeMath for uint256;

    uint public constant UNLOCK_PERIOD = 30 days;
    uint public constant UNLOCK_TIME = 1572566400;    // 11월 1일 0시

    string public constant name = "CardioCoin";
    string public constant symbol = "CRDC";

    uint8 public constant decimals = 18;

    uint256 internal totalSupply_ = 12000000000 * (10 ** uint256(decimals));

    struct balance {
        uint256 available;
        uint256 lockedUp;
    }

    struct lockUp {
        uint256 amount;
        uint unlockTimestamp;
        uint unlockCount;
    }

    struct locker {
        bool isLocker;
        string role;
        uint lockUpPeriod;
        uint unlockCount;
        bool useFixedTime;
    }

    mapping(address => balance) internal _balances;
    mapping(address => lockUp[]) internal _lockUps;
    mapping(address => locker) internal _lockerList;

    event Burn(address indexed burner, uint256 value);
    event AddToLocker(address indexed owner, string role, uint lockUpPeriod, uint unlockCount);
    event TokenLocked(address indexed owner, uint256 amount);
    event TokenUnlocked(address indexed owner, uint256 amount);

    constructor() public Ownable() {
        balance memory b;

        b.available = totalSupply_;
        _balances[msg.sender] = b;
        emit Transfer(address(0), msg.sender, totalSupply_);
    }

    //Getter Functions
    function lockerInfo(address _operator)public view returns(bool isLocker, string memory role, uint lockUpPeriod, uint unlockCount) {
        locker memory l = _lockerList[_operator];
        isLocker = l.isLocker;
        role = l.role;
        lockUpPeriod = l.lockUpPeriod;
        unlockCount = l.unlockCount;
    }

    function balanceInfo(address user) view public returns(uint256 available, uint256 lockedUp) {
        balance memory b = _balances[user];
        available = b.available;
        lockedUp = b.lockedUp;
    }

    function lockUpInfo(address user, uint256 index) view public returns (uint256 amount, uint256 unlockTimestamp, uint256 unlockCount) {
        lockUp memory l = _lockUps[user][index];
        amount = l.amount;
        unlockTimestamp = l.unlockTimestamp;
        unlockCount = l.unlockCount;
    }

    function lockUpLength(address user) view public returns (uint256) {
        lockUp[] memory l = _lockUps[user];
        return l.length;
    }

    // ERC20 Custom
    function totalSupply() public view returns (uint256) {
        return totalSupply_;
    }

    function _transfer(address from, address to, uint256 value) internal {
        locker storage l = _lockerList[from];

        this.unlockAll(from);
        require(value <= _balances[from].available);
        require(to != address(0));
        _balances[from].available = _balances[from].available.sub(value);
        if (l.isLocker) {
            if (l.useFixedTime) {
                if (UNLOCK_TIME <= now) {
                    uint elapsedPeriod = (now - UNLOCK_TIME) / UNLOCK_PERIOD + 1;

                    if (elapsedPeriod < l.unlockCount) {
                        uint unlockedAmount = (value / l.unlockCount).mul(elapsedPeriod);

                        _balances[to].available = _balances[to].available.add(unlockedAmount);
                        addLockedUpTokens(to, value.sub(unlockedAmount), UNLOCK_TIME + UNLOCK_PERIOD * elapsedPeriod - now, l.unlockCount - elapsedPeriod);
                    } else {
                        l.isLocker = false;
                        _balances[to].available = _balances[to].available.add(value);
                    }
                } else {
                    addLockedUpTokens(to, value, UNLOCK_TIME - now, l.unlockCount);
                }
            } else {
                addLockedUpTokens(to, value, l.lockUpPeriod, l.unlockCount);
            }
        } else {
            _balances[to].available = _balances[to].available.add(value);
        }
        emit Transfer(from, to, value);
    }

    function balanceOf(address _owner) public view returns (uint256) {
        return _balances[_owner].available.add(_balances[_owner].lockedUp);
    }

    // Burnable
    function burn(uint256 _value) public {
        _burn(msg.sender, _value);
    }

    function _burn(address _who, uint256 _value) internal {
        require(_value <= _balances[_who].available);

        _balances[_who].available = _balances[_who].available.sub(_value);
        totalSupply_ = totalSupply_.sub(_value);
        emit Burn(_who, _value);
        emit Transfer(_who, address(0), _value);
    }

    // Lockup
    function addAddressToLockerList(address _operator, string memory role, uint lockUpPeriod, uint unlockCount, bool useFixedTime)
    public
    onlyOwner {
        locker memory lockerData = _lockerList[_operator];

        require(!lockerData.isLocker);
        require(unlockCount > 0);
        lockerData.isLocker = true;
        lockerData.role = role;
        lockerData.lockUpPeriod = lockUpPeriod;
        lockerData.unlockCount = unlockCount;
        lockerData.useFixedTime = useFixedTime;
        _lockerList[_operator] = lockerData;
        emit AddToLocker(_operator, role, lockUpPeriod, unlockCount);
    }

    function lockedUpBalanceOf(address _owner) public view returns (uint256) {
        lockUp[] memory lockups = _lockUps[_owner];
        balance memory b = _balances[_owner];
        uint256 lockedUpBalance = b.lockedUp;

        for (uint i = 0; i < lockups.length; i++) {
            lockUp memory l = lockups[i];

            uint count = calculateUnlockCount(l.unlockTimestamp, l.unlockCount);
            uint256 unlockedAmount = l.amount.mul(count).div(l.unlockCount);
            lockedUpBalance = lockedUpBalance.sub(unlockedAmount);
        }

        return lockedUpBalance;
    }

    function addLockedUpTokens(address _owner, uint256 amount, uint lockUpPeriod, uint unlockCount)
    internal {
        lockUp[] storage lockups = _lockUps[_owner];
        lockups.length += 1;
        lockUp storage l = lockups[lockups.length - 1];
        l.amount = amount;
        l.unlockTimestamp = now.add(lockUpPeriod);
        l.unlockCount = unlockCount;

        balance storage b = _balances[_owner];
        b.lockedUp = b.lockedUp.add(amount);
        emit TokenLocked(_owner, amount);
    }

    function unlockAll(address _owner) external returns (bool success) {
        balance storage b = _balances[_owner];
        lockUp[] storage lockupList = _lockUps[_owner];
        uint256 unlocked = 0;
        for (uint i = 0; i < lockupList.length; i++){
            uint256 unlocked_i = _unlock(_owner,i);
            unlocked = unlocked.add(unlocked_i);
            //when fullyUnlocked
            if(lockupList[i].unlockCount == 0) {
                //remove
                lockUp storage temp = lockupList[lockupList.length.sub(1)];
                lockupList[i] = temp;
                lockupList.length--;
                i--;
            }
        }
        //add unlocked to available
        b.available = b.available.add(unlocked);
        //sub unlocked from lockedUp
        b.lockedUp = b.lockedUp.sub(unlocked);

        success = true;

        emit TokenUnlocked(_owner, unlocked);
    }

    function _unlock(address _owner, uint256 index) internal returns(uint256 unlocked) {
        lockUp storage l = _lockUps[_owner][index];

        uint count = calculateUnlockCount(l.unlockTimestamp, l.unlockCount);
        if( count == 0 ){
            return 0;
        }
        // if fully unlocked, unlocked amount will match l.amount
        unlocked = l.amount.mul(count).div(l.unlockCount);

        l.unlockTimestamp = l.unlockTimestamp.add(UNLOCK_PERIOD * count);
        l.amount = l.amount.sub(unlocked);
        l.unlockCount = l.unlockCount.sub(count);
    }


    function calculateUnlockCount(uint timestamp, uint unlockCount) view internal returns (uint) {
        if (now < timestamp) {
            return 0;
        }
        uint256 timeCount = (now.sub(timestamp)).div(UNLOCK_PERIOD).add(1);
        if (timeCount > unlockCount){
            return unlockCount;
        }
        else {
            return timeCount;
        }
    }
}

pragma solidity ^0.5.0;

import "./IERC20.sol";
import "./SafeMath.sol";

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20.md
 * Originally based on code by FirstBlood:
 * https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 *
 * This implementation emits additional Approval events, allowing applications to reconstruct the allowance status for
 * all accounts just by listening to said events. Note that this isn't required by the specification, and other
 * compliant implementations may not do it.
 */
contract ERC20 is IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowed;

    uint256 private _totalSupply;

    /**
    * @dev Total number of tokens in existence
    */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
    * @dev Gets the balance of the specified address.
    * @param owner The address to query the balance of.
    * @return An uint256 representing the amount owned by the passed address.
    */
    function balanceOf(address owner) public view returns (uint256) {
        return _balances[owner];
    }

    /**
     * @dev Function to check the amount of tokens that an owner allowed to a spender.
     * @param owner address The address which owns the funds.
     * @param spender address The address which will spend the funds.
     * @return A uint256 specifying the amount of tokens still available for the spender.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowed[owner][spender];
    }

    /**
    * @dev Transfer token for a specified address
    * @param to The address to transfer to.
    * @param value The amount to be transferred.
    */
    function transfer(address to, uint256 value) public returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    /**
     * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
     * Beware that changing an allowance with this method brings the risk that someone may use both the old
     * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
     * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     */
    function approve(address spender, uint256 value) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = value;
        emit Approval(msg.sender, spender, value);
        return true;
    }

    /**
     * @dev Transfer tokens from one address to another.
     * Note that while this function emits an Approval event, this is not required as per the specification,
     * and other compliant implementations may not emit the event.
     * @param from address The address which you want to send tokens from
     * @param to address The address which you want to transfer to
     * @param value uint256 the amount of tokens to be transferred
     */
    function transferFrom(address from, address to, uint256 value) public returns (bool) {
        _allowed[from][msg.sender] = _allowed[from][msg.sender].sub(value);
        _transfer(from, to, value);
        emit Approval(from, msg.sender, _allowed[from][msg.sender]);
        return true;
    }

    /**
     * @dev Increase the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To increment
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param addedValue The amount of tokens to increase the allowance by.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = _allowed[msg.sender][spender].add(addedValue);
        emit Approval(msg.sender, spender, _allowed[msg.sender][spender]);
        return true;
    }

    /**
     * @dev Decrease the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To decrement
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param subtractedValue The amount of tokens to decrease the allowance by.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = _allowed[msg.sender][spender].sub(subtractedValue);
        emit Approval(msg.sender, spender, _allowed[msg.sender][spender]);
        return true;
    }

    /**
    * @dev Transfer token for a specified addresses
    * @param from The address to transfer from.
    * @param to The address to transfer to.
    * @param value The amount to be transferred.
    */
    function _transfer(address from, address to, uint256 value) internal {
        require(to != address(0));

        _balances[from] = _balances[from].sub(value);
        _balances[to] = _balances[to].add(value);
        emit Transfer(from, to, value);
    }

    /**
     * @dev Internal function that mints an amount of the token and assigns it to
     * an account. This encapsulates the modification of balances such that the
     * proper events are emitted.
     * @param account The account that will receive the created tokens.
     * @param value The amount that will be created.
     */
    function _mint(address account, uint256 value) internal {
        require(account != address(0));

        _totalSupply = _totalSupply.add(value);
        _balances[account] = _balances[account].add(value);
        emit Transfer(address(0), account, value);
    }

    /**
     * @dev Internal function that burns an amount of the token of a given
     * account.
     * @param account The account whose tokens will be burnt.
     * @param value The amount that will be burnt.
     */
    function _burn(address account, uint256 value) internal {
        require(account != address(0));

        _totalSupply = _totalSupply.sub(value);
        _balances[account] = _balances[account].sub(value);
        emit Transfer(account, address(0), value);
    }

    /**
     * @dev Internal function that burns an amount of the token of a given
     * account, deducting from the sender's allowance for said account. Uses the
     * internal burn function.
     * Emits an Approval event (reflecting the reduced allowance).
     * @param account The account whose tokens will be burnt.
     * @param value The amount that will be burnt.
     */
    function _burnFrom(address account, uint256 value) internal {
        _allowed[account][msg.sender] = _allowed[account][msg.sender].sub(value);
        _burn(account, value);
        emit Approval(account, msg.sender, _allowed[account][msg.sender]);
    }
}

pragma solidity ^0.5.0;

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
interface IERC20 {
    function transfer(address to, uint256 value) external returns (bool);

    function approve(address spender, uint256 value) external returns (bool);

    function transferFrom(address from, address to, uint256 value) external returns (bool);

    function totalSupply() external view returns (uint256);

    function balanceOf(address who) external view returns (uint256);

    function allowance(address owner, address spender) external view returns (uint256);

    event Transfer(address indexed from, address indexed to, uint256 value);

    event Approval(address indexed owner, address indexed spender, uint256 value);
}

pragma solidity ^0.5.0;

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev The Ownable constructor sets the original `owner` of the contract to the sender
     * account.
     */
    constructor () internal {
        _owner = msg.sender;
        emit OwnershipTransferred(address(0), _owner);
    }

    /**
     * @return the address of the owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(isOwner());
        _;
    }

    /**
     * @return true if `msg.sender` is the owner of the contract.
     */
    function isOwner() public view returns (bool) {
        return msg.sender == _owner;
    }

    /**
     * @dev Allows the current owner to relinquish control of the contract.
     * @notice Renouncing to ownership will leave the contract without an owner.
     * It will not be possible to call the functions with the `onlyOwner`
     * modifier anymore.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Allows the current owner to transfer control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function _transferOwnership(address newOwner) internal {
        require(newOwner != address(0));
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

pragma solidity ^0.5.0;

/**
 * @title SafeMath
 * @dev Unsigned math operations with safety checks that revert on error
 */
library SafeMath {
    /**
    * @dev Multiplies two unsigned integers, reverts on overflow.
    */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b);

        return c;
    }

    /**
    * @dev Integer division of two unsigned integers truncating the quotient, reverts on division by zero.
    */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
    * @dev Subtracts two unsigned integers, reverts on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a);
        uint256 c = a - b;

        return c;
    }

    /**
    * @dev Adds two unsigned integers, reverts on overflow.
    */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a);

        return c;
    }

    /**
    * @dev Divides two unsigned integers and returns the remainder (unsigned integer modulo),
    * reverts when dividing by zero.
    */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b != 0);
        return a % b;
    }
}

{
  "compilationTarget": {
    "CardioCoin.sol": "CardioCoin"
  },
  "evmVersion": "petersburg",
  "libraries": {},
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}