ESM

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

import "./IERC20.sol";

/**
 * @title ERC20Detailed token
 * @dev The decimals are only for visualization purposes.
 * All the operations are done using the smallest and indivisible token unit,
 * just as on Ethereum all the operations are done in wei.
 */
abstract contract ERC20Detailed is IERC20 {
  string private _name;
  string private _symbol;
  uint8 private _decimals;
  
  constructor(string memory name, string memory symbol, uint8 decimals) 
    public
  {
     _name = name;
     _symbol = symbol;
     _decimals = decimals;
  }

  /**
   * @return the name of the token.
   */
  function name() public view returns(string memory) {
    return _name;
  }

  /**
   * @return the symbol of the token.
   */
  function symbol() public view returns(string memory) {
    return _symbol;
  }

  /**
   * @return the number of decimals of the token.
   */
  function decimals() public view returns(uint8) {
    return _decimals;
  }
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

import "./SafeMath.sol";
import "./Pausable.sol";
import "./Lockable.sol";
import "./ERC20Detailed.sol";


/**
 * ESMToken
 * v1.0
 */
contract ESMToken is ERC20Detailed, Lockable, Pausable {
    using SafeMath for uint256;

    // All config
    string private constant TOKEN_NAME = "ESM";
    string private constant TOKEN_SYMBOL = "ESM";
    uint8  private constant  TOKEN_DECIMALS = 6;
    uint256 private constant TOKEN_INIT_SUPPLY = 100000000 * (10**(uint256(TOKEN_DECIMALS)));

    // Total supply
    uint256 private _totalSupply;
    mapping(address => uint256) _balances;

    /// events
    event Mint(address indexed to, uint256 amount);
    event Burn(address indexed burner, uint256 value);

    // This is denominated in Fragments, because the gons-fragments conversion might change before
    // it's fully paid.
    mapping (address => mapping (address => uint256)) private _allowedFragments;

    constructor()
        ERC20Detailed(TOKEN_NAME, TOKEN_SYMBOL, TOKEN_DECIMALS)
        public
    {
        _totalSupply = TOKEN_INIT_SUPPLY;
        _balances[msg.sender] = TOKEN_INIT_SUPPLY;

        emit Transfer(address(0x0), msg.sender, TOKEN_INIT_SUPPLY);
    }

    /// mint token
    function mint(address to, uint256 value)
        public
        onlyOwner
        returns (bool)
    {
        require(to != address(0), "EFIToken: [mint] to illegal");
        _totalSupply = _totalSupply.add(value);
        _balances[to] = _balances[to].add(value);
        emit Mint(to, value);
        emit Transfer(address(0), to, value);
        return true;
    }

    /// burn token
    function burn(uint256 value)
        public
        returns (bool)
    {
        address burner = msg.sender;
        _balances[burner] = _balances[burner].sub(value);
        _totalSupply = _totalSupply.sub(value);
        emit Burn(burner, value);
        return true;
    }

    /// move tokens
    function _move(address from, address to, uint256 value)
        private
    {
        require(value <= _balances[from], "EFIToken: [_move] balance not enough");
        require(to != address(0), "EFIToken: [_move] to[address] is illegal");

        _balances[from] = _balances[from].sub(value);
        _balances[to] = _balances[to].add(value);
    }

    /// transfer token
    function transfer(address to, uint256 value)
        public
        override
        whenNotPaused
        returns (bool)
    {
        require(notLock(msg.sender));
        require(notLock(to));
        _move(msg.sender, to, value);
        emit Transfer(msg.sender, to, value);
        return true;
    }

    /// transferFrom token
    function transferFrom(address from, address to, uint256 value)
        public
        override
        whenNotPaused
        returns (bool)
    {
        require(notLock(msg.sender));
        require(notLock(from));
        require(notLock(to));
        // sub value
        _allowedFragments[from][msg.sender] = _allowedFragments[from][msg.sender].sub(value);
        _move(from, to, value);
        
        emit Transfer(from, to, value);
        return true;
    }

    /**
     * @return The total number of fragments.
     */
    function totalSupply()
        public
        override
        view
        returns (uint256)
    {
        return _totalSupply;
    }

    /**
     * @param who The address to query.
     * @return The balance of the specified address.
     */
    function balanceOf(address who)
        public
        override
        view
        returns (uint256)
    {
        return _balances[who];
    }

    /**
     * @return approve value
     */
    function allowance(address owner, address spender)
        external
        override
        view
        returns (uint256)
    {
        return _allowedFragments[owner][spender];
    }

    /**
     * @dev Approve the passed address to spend the specified amount of tokens on behalf of
     * msg.sender. This method is included for ERC20 compatibility.
     * increaseAllowance and decreaseAllowance should be used instead.
     * Changing an allowance with this method brings the risk that someone may transfer both
     * the old and the new allowance - if they are both greater than zero - if a transfer
     * transaction is mined before the later approve() call is mined.
     *
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     */
    function approve(address spender, uint256 value)
        public
        override
        returns (bool)
    {
        _allowedFragments[msg.sender][spender] = value;
        emit Approval(msg.sender, spender, value);
        return true;
    }

    /**
     * @dev Increase the amount of tokens that an owner has allowed to a spender.
     * This method should be used instead of approve() to avoid the double approval vulnerability
     * described above.
     * @param spender The address which will spend the funds.
     * @param addedValue The amount of tokens to increase the allowance by.
     */
    function increaseAllowance(address spender, uint256 addedValue)
        public
        returns (bool)
    {
        _allowedFragments[msg.sender][spender] = _allowedFragments[msg.sender][spender].add(addedValue);
        emit Approval(msg.sender, spender, _allowedFragments[msg.sender][spender]);
        return true;
    }

    /**
     * @dev Decrease the amount of tokens that an owner has allowed to a spender.
     *
     * @param spender The address which will spend the funds.
     * @param subtractedValue The amount of tokens to decrease the allowance by.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue)
        public
        returns (bool)
    {
        uint256 oldValue = _allowedFragments[msg.sender][spender];
        if (subtractedValue >= oldValue) {
            _allowedFragments[msg.sender][spender] = 0;
        } else {
            _allowedFragments[msg.sender][spender] = oldValue.sub(subtractedValue);
        }
        emit Approval(msg.sender, spender, _allowedFragments[msg.sender][spender]);
        return true;
    }
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
interface IERC20 {
  function totalSupply() external view returns (uint256);

  function balanceOf(address who) external view returns (uint256);

  function allowance(address owner, address spender)
    external view returns (uint256);

  function transfer(address to, uint256 value) external returns (bool);

  function approve(address spender, uint256 value)
    external returns (bool);

  function transferFrom(address from, address to, uint256 value)
    external returns (bool);

  event Transfer(
    address indexed from,
    address indexed to,
    uint256 value
  );

  event Approval(
    address indexed owner,
    address indexed spender,
    uint256 value
  );
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

import "./Ownable.sol";

contract Lockable is Ownable {

    // blockList
    mapping (address => uint) private _blockList;
    

    /**
     * @param who address
     */
    function notLock(address who)
        public
        view
        returns (bool)
    {
        return _blockList[who] == 0;
    }

    /**
     * @param whos addresses
     */
    function setBlockList(address[] calldata whos)
        external
        onlyOwner
    {
        for (uint i = 0; i < whos.length; i++) {
            _blockList[whos[i]] = 1;
        }
    }

    /**
     * @param whos addresses
     */
    function unsetBlockList(address[] calldata whos)
        external
        onlyOwner
    {
        for (uint i = 0; i < whos.length; i++) {
            _blockList[whos[i]] = 0;
        }
    }
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
  address public owner;

  event OwnershipRenounced(address indexed previousOwner);
  event OwnershipTransferred(
    address indexed previousOwner,
    address indexed newOwner
  );


  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  constructor() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner, "Ownable: [onlyOwner]");
    _;
  }

  /**
   * @dev Allows the current owner to relinquish control of the contract.
   * @notice Renouncing to ownership will leave the contract without an owner.
   * It will not be possible to call the functions with the `onlyOwner`
   * modifier anymore.
   */
  function renounceOwnership() public onlyOwner {
    emit OwnershipRenounced(owner);
    owner = address(0);
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param _newOwner The address to transfer ownership to.
   */
  function transferOwnership(address _newOwner) public onlyOwner {
    require(_newOwner != address(0), "Ownable: [transferOwnership] _newOwner illegal");
    emit OwnershipTransferred(owner, _newOwner);
    owner = _newOwner;
  }
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

import "./Ownable.sol";

/**
 * @title Pausable
 * @dev Base contract which allows children to implement an emergency stop mechanism.
 */
contract Pausable is Ownable {
  event Pause();
  event Unpause();

  bool public paused = false;


  /**
   * @dev Modifier to make a function callable only when the contract is not paused.
   */
  modifier whenNotPaused() {
    require(!paused, "Pausable: not paused");
    _;
  }

  /**
   * @dev Modifier to make a function callable only when the contract is paused.
   */
  modifier whenPaused() {
    require(paused, "Pausable: paused");
    _;
  }

  /**
   * @dev called by the owner to pause, triggers stopped state
   */
  function pause()
    public 
    onlyOwner 
    whenNotPaused 
  {
    paused = true;
    emit Pause();
  }

  /**
   * @dev called by the owner to unpause, returns to normal state
   */
  function unpause() 
    public 
    onlyOwner 
    whenPaused
  {
    paused = false;
    emit Unpause();
  }
}

// SPDX-License-Identifier: GPL-2.0-only
pragma solidity ^0.6.4;

/**
 * @title SafeMath
 * @dev Math operations with safety checks that revert on error
 */
library SafeMath {

  /**
  * @dev Multiplies two numbers, reverts on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
    // benefit is lost if 'b' is also tested.
    // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
    if (a == 0) {
      return 0;
    }

    uint256 c = a * b;
    require(c / a == b);

    return c;
  }

  /**
  * @dev Integer division of two numbers truncating the quotient, reverts on division by zero.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b > 0); // Solidity only automatically asserts when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold

    return c;
  }

  /**
  * @dev Subtracts two numbers, reverts on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b <= a);
    uint256 c = a - b;

    return c;
  }

  /**
  * @dev Adds two numbers, reverts on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    require(c >= a);

    return c;
  }

  /**
  * @dev Divides two numbers and returns the remainder (unsigned integer modulo),
  * reverts when dividing by zero.
  */
  function mod(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b != 0);
    return a % b;
  }
}

{
  "compilationTarget": {
    "browser/ESMToken.sol": "ESMToken"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}