xxxxxa

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Address.sol)

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Counters.sol)

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits a {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.11;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/Counters.sol";

/* 
NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNNNNNmmmmmNNNNNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNmmddmNNNmddmmNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNmhhdNNNNmdddmNNNNmhhmNNNNNNNNNNNNNNN
NNNNNNNNNNmhs+///+syhdmNNNmmhyo/:::/shmNNNNNNNNNNN
NNNNNNNNNNy:::::/:://+shdho/:-------..oNNNNNNNNNNN
NNNNNNNNNNs::::::::::::::.............+NNNNNNNNNNN
NNNNNNNNNNs:::::::::::::-.....--......+NNNNNNNNNNN
NNNNNNNNNNs:::::://:///:--------......+NNNNNNNNNNN
NNNNNNNNNNs::::+///:////:::------:....+NNNNNNNNNNN
NNNNNNNNNNs::::mdyo/////:::-::+ydm:...+NNNNNNNNNNN
NNNNNNNNNNs::::NNNNhdyo+:/+ydhNNNN:...+NNNNNNNNNNN
NNNNNNNNNNs::::mNNNdNNNmymNNNdNNNm:...+NNNNNNNNNNN
NNNNNNNNNNs:::/mmmmhNNNNdNNNNhmmmm:...+NNNNNNNNNNN
NNNNNNNNNNd+//:NNNNhmmmmdNmmmhNNNN:.-/yNNNNNNNNNNN
NNNNNNNNNNNNmdymmNNdNNNNhmNNNdNNNmyhmNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNmmhmNNNdNNNNhmmmNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNNNNmmmhmmmmNNNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN
NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN
*/

/// @title ERC-721 token for Meta Mint Software License.
/// @author @ItsCuzzo

contract MetaMint is Ownable, ERC721 {

    using Strings for uint;
    using Counters for Counters.Counter;

    string private _tokenURI;
    string private _contractURI;
    Counters.Counter private _tokenIdCounter;

    uint public maxSupply = 300;
    uint public tokenPrice = 1.25 ether;
    uint public renewalPrice = 0.3 ether;
    uint public maxTokensPerTx = 3;
    uint public gracePeriod = 3 days;

    mapping(uint => uint) public expiryTime;
    mapping(uint => bool) public isBanned;

    struct DutchAuction {
        uint32 startTime;
        uint72 startingPrice;
        uint16 stepDuration;
        uint72 reservePrice;
        uint64 decrementAmount;
    }

    enum SaleStates {
        PAUSED,
        FCFS_MINT,
        DUTCH_AUCTION
    }

    DutchAuction public auction;
    SaleStates public saleState;

    event Minted(address indexed _from, uint _amount);
    event Renewed(address indexed _from, uint _tokenId);
    event RenewedBatch(address indexed _from, uint[] _tokenIds);
    event Banned(address indexed _from, uint _tokenId);
    event Unbanned(address indexed _from, uint _tokenId);

    constructor(
        string memory tokenURI_,
        string memory contractURI_
    ) ERC721("Meta Mint", "MMAIO") {
        _tokenURI = tokenURI_;
        _contractURI = contractURI_;
    }

    /// @notice Function used to mint a token during the `DUTCH_AUCTION` sale.
    function auctionMint() external payable {
        require(tx.origin == msg.sender, "Caller should not be a contract.");
        require(SaleStates.DUTCH_AUCTION == saleState, "Auction not active.");
        require(auction.startTime <= block.timestamp, "Auction has not started.");
        
        uint tokenIndex = _tokenIdCounter.current() + 1;

        require(maxSupply >= tokenIndex, "Minted tokens would exceed supply.");
        require(msg.value >= getAuctionPrice(), "Incorrect Ether amount.");

        _tokenIdCounter.increment();
        _safeMint(msg.sender, tokenIndex);
        expiryTime[tokenIndex] = block.timestamp + 30 days;

        emit Minted(msg.sender, 1);
    }

    /// @notice Function used to mint tokens during the `FCFS_MINT` sale.
    /// @param numTokens The desired number of tokens to mint.
    function mint(uint numTokens) external payable {
        require(tx.origin == msg.sender, "Caller should not be a contract.");
        require(saleState == SaleStates.FCFS_MINT, "FCFS minting is not active.");
        require(tokenPrice * numTokens == msg.value, "Incorrect Ether amount.");
        require(maxSupply >= _tokenIdCounter.current() + numTokens, "Minted tokens would exceed supply.");
        require(maxTokensPerTx >= numTokens, "Token tx limit exceeded.");

        for (uint i=0; i<numTokens; i++) {
            _tokenIdCounter.increment();

            uint tokenIndex = _tokenIdCounter.current();
            _safeMint(msg.sender, tokenIndex);

            expiryTime[tokenIndex] = block.timestamp + 30 days;
        }

        emit Minted(msg.sender, numTokens);
    }

    /// @notice Function that is used to extend/renew a tokens expiry date
    /// in increments of 30 days.
    /// @param tokenId The token ID to extend/renew.
    function renewToken(uint tokenId) public payable {
        require(_exists(tokenId), "Token does not exist.");
        require(ownerOf(tokenId) == msg.sender, "Caller does not own token.");
        require(!isBanned[tokenId], "Token is banned.");
        require(msg.value == renewalPrice, "Incorrect Ether amount.");

        uint _currentexpiryTime = expiryTime[tokenId];

        if (block.timestamp > _currentexpiryTime) {
            expiryTime[tokenId] = block.timestamp + 30 days;
        } else {
            expiryTime[tokenId] += 30 days;
        }

        emit Renewed(msg.sender, tokenId);
    }

    /// @notice Function that is used to extend/renew multiple tokens expiry date
    /// in increments of 30 days.
    /// @param tokenIds The token IDs to extend/renew.
    function batchRenewToken(uint[] calldata tokenIds) public payable {
        require(tokenIds.length >= 2, "Invalid array length.");
        require(renewalPrice * tokenIds.length == msg.value, "Incorrect Ether amount.");

        for (uint i=0; i<tokenIds.length; i++) {
            require(_exists(tokenIds[i]), "Token does not exist.");
            require(ownerOf(tokenIds[i]) == msg.sender, "Caller does not own token.");
            require(!isBanned[tokenIds[i]], "Token is banned.");

            uint _currentexpiryTime = expiryTime[tokenIds[i]];
            
            if (block.timestamp > _currentexpiryTime) {
                expiryTime[tokenIds[i]] = block.timestamp + 30 days;
            } else {
                expiryTime[tokenIds[i]] += 30 days;
            }
        }

        emit RenewedBatch(msg.sender, tokenIds);
    }

    /// @notice Function that is used to mint a token free of charge, only
    /// callable by the owner.
    function ownerMint(address receiver) public onlyOwner {
        uint tokenIndex = _tokenIdCounter.current() + 1;

        require(maxSupply >= tokenIndex, "Minted tokens would exceed supply.");

        _tokenIdCounter.increment();
        _safeMint(receiver, tokenIndex);

        expiryTime[tokenIndex] = block.timestamp + 30 days;

        emit Minted(msg.sender, 1);
    }

    /// @notice Function that is used to extend/renew a tokens expiry date
    /// in increments of 30 days free of charge, only callable by the owner.
    /// @param tokenId The token ID to extend/renew.
    function ownerRenewToken(uint tokenId) public onlyOwner {
        require(_exists(tokenId), "Token does not exist.");

        uint _currentexpiryTime = expiryTime[tokenId];

        if (block.timestamp > _currentexpiryTime) {
            expiryTime[tokenId] = block.timestamp + 30 days;
        } else {
            expiryTime[tokenId] += 30 days;
        }

        emit Renewed(msg.sender, tokenId);
    }

    /// @notice Function that is used to extend/renew multiple tokens expiry date
    /// in increments of 30 days free of charge, only callable by the owner.
    /// @param tokenIds The token IDs to extend/renew.
    function ownerBatchRenewToken(uint[] calldata tokenIds) public onlyOwner {
        require(tokenIds.length >= 2, "Invalid array length.");

        for (uint i=0; i<tokenIds.length; i++) {
            require(_exists(tokenIds[i]), "Token does not exist.");

            uint _currentexpiryTime = expiryTime[tokenIds[i]];
            
            if (block.timestamp > _currentexpiryTime) {
                expiryTime[tokenIds[i]] = block.timestamp + 30 days;
            } else {
                expiryTime[tokenIds[i]] += 30 days;
            }
        }

        emit RenewedBatch(msg.sender, tokenIds);
    }

    /// @notice Function used to get the current price of a token during the
    /// dutch auction.
    /// @dev This function should be polled externally to determine how much
    /// Ether a participant should send.
    /// @return Returns a uint indicating the current price of the token in
    /// wei.
    function getAuctionPrice() public view returns (uint72) {
        if (saleState != SaleStates.DUTCH_AUCTION || auction.startTime >= block.timestamp) {
            return auction.startingPrice;
        }

        uint72 decrements = (uint72(block.timestamp) - auction.startTime) / auction.stepDuration;
        if (decrements * auction.decrementAmount >= auction.startingPrice) {
            return auction.reservePrice;
        }

        if (auction.startingPrice - decrements * auction.decrementAmount < auction.reservePrice) {
            return auction.reservePrice;
        }

        return auction.startingPrice - decrements * auction.decrementAmount;
    }

    /// @notice Function used to define the dutch auction settings.
    /// @param _startTime Starting time for the auction in seconds.
    /// @param _startingPrice Starting price for the auction in wei.
    /// @param _stepDuration Time between each price decrease, in seconds.
    /// @param _reservePrice Reserve price for the auction in wei.
    /// @param _decrementAmount Amount that price decreases every step, in wei.
    /// @dev Reasoning for doing one function for all updates is that once the
    /// auction is configured once, it shouldn't need changing until afterwards.
    function setAuctionBulk(
        uint32 _startTime, uint72 _startingPrice, uint16 _stepDuration, uint72 _reservePrice, uint64 _decrementAmount
    ) external onlyOwner {
        require(_startTime > block.timestamp, "Invalid start time.");
        require(_startingPrice > _reservePrice, "Initial price must exceed reserve.");

        auction.startTime = _startTime;
        auction.startingPrice = _startingPrice;
        auction.stepDuration = _stepDuration;
        auction.reservePrice = _reservePrice;
        auction.decrementAmount = _decrementAmount;
    }

    /// @notice Function used to set the dutch auction start time.
    /// @param _startTime A UNIX epoch, in seconds, of the intended start time.
    /// @dev Pssst, https://www.epochconverter.com/
    function setAuctionStartTime(uint32 _startTime) external onlyOwner {
        require(_startTime > block.timestamp, "Invalid start time.");
        auction.startTime = _startTime;
    }

    /// @notice Function used to set the starting price of the dutch auction.
    /// @param _startingPrice uint value in wei representing the starting price.
    function setAuctionStartingPrice(uint72 _startingPrice) external onlyOwner {
        require(auction.startingPrice != _startingPrice, "Price has not changed.");
        auction.startingPrice = _startingPrice;
    }

    /// @notice Function used to set the step time during the dutch auction.
    /// @param _stepDuration uint value is seconds representing how frequently the
    /// price will drop. E.g. Input of 120 is equivalent to 2 minutes.
    function setAuctionStepDuration(uint16 _stepDuration) external onlyOwner {
        require(auction.stepDuration != _stepDuration, "Duration has not changed.");
        auction.stepDuration = _stepDuration;
    }

    /// @notice Function used to set the dutch auction reserve price.
    /// @param _reservePrice Represents the reserve price in units of wei.
    function setAuctionReservePrice(uint72 _reservePrice) external onlyOwner {
        require(auction.reservePrice != _reservePrice, "Price has not changed.");
        auction.reservePrice = _reservePrice;
    }

    /// @notice Function used to set the dutch auction decrement amount.
    /// @param _decrementAmount uint value representing how much the price
    /// will drop each step. E.g. 25000000000000000 is 0.025 Ether.
    function setAuctionDecrementAmount(uint64 _decrementAmount) external onlyOwner {
        require(auction.decrementAmount != _decrementAmount, "Decrement has not changed.");
        auction.decrementAmount = _decrementAmount;
    }

    /// @notice Function that is used to update the `renewalPrice` variable,
    /// only callable by the owner.
    /// @param newRenewalPrice The new renewal price in units of wei. E.g.
    /// 500000000000000000 is 0.50 Ether.
    function updateRenewalPrice(uint newRenewalPrice) external onlyOwner {
        require(renewalPrice != newRenewalPrice, "Price has not changed.");
        renewalPrice = newRenewalPrice;
    }

    /// @notice Function that is used to update the `tokenPrice` variable,
    /// only callable by the owner.
    /// @param newTokenPrice The new initial token price in units of wei. E.g.
    /// 2000000000000000000 is 2 Ether.
    function updateTokenPrice(uint newTokenPrice) external onlyOwner {
        require(tokenPrice != newTokenPrice, "Price has not changed.");
        tokenPrice = newTokenPrice;
    }

    /// @notice Function that is used to update the `maxTokensPerTx` variable,
    /// only callable by the owner.
    /// @param newMaxTokensPerTx The new maximum amount of tokens a user can
    /// mint in a single tx.
    function updateMaxTokensPerTx(uint newMaxTokensPerTx) external onlyOwner {
        require(maxTokensPerTx != newMaxTokensPerTx, "Max tokens has not changed.");
        maxTokensPerTx = newMaxTokensPerTx;
    }

    /// @notice Function that is used to update the `GRACE_PERIOD` variable,
    /// only callable by the owner.
    /// @param newGracePeriod The new grace period in units of seconds in wei. 
    /// E.g. 2592000 is 30 days.
    /// @dev Grace period should be atleast 1 day, uint value of 86400.
    function updateGracePeriod(uint newGracePeriod) external onlyOwner {
        require(gracePeriod != newGracePeriod, "Duration has not changed.");
        require(newGracePeriod % 1 days == 0, "Must provide 1 day increments.");
        gracePeriod = newGracePeriod;
    }

    /// @notice Function used to set a new `saleState` value.
    /// @param newSaleState The newly desired sale state.
    /// @dev 0 = PAUSED, 1 = FCFS_MINT, 2 = DUTCH_AUCTION.
    function setSaleState(uint newSaleState) external onlyOwner {
        require(uint(SaleStates.DUTCH_AUCTION) >= newSaleState, "Invalid sale state.");
        saleState = SaleStates(newSaleState);
    }

    /// @notice Function that is used to authenticate a user.
    /// @param tokenId The desired token owned by a user.
    /// @return Returns a bool value determining if authentication was
    /// was successful. `true` is successful, `false` if otherwise.
    function authenticateUser(uint tokenId) public view returns (bool) {
        require(_exists(tokenId), "Token does not exist.");
        require(!isBanned[tokenId], "Token is banned.");
        require(expiryTime[tokenId] + gracePeriod > block.timestamp, "Token has expired. Please renew!");

        return msg.sender == ownerOf(tokenId) ? true : false;
    }

    /// @notice Function used to increment the `maxSupply` value.
    /// @param numTokens The amount of tokens to add to `maxSupply`.
    function addTokens(uint numTokens) external onlyOwner {
        maxSupply += numTokens;
    }
    
    /// @notice Function used to decrement the `maxSupply` value.
    /// @param numTokens The amount of tokens to remove from `maxSupply`.
    function removeTokens(uint numTokens) external onlyOwner {
        require(maxSupply - numTokens >= _tokenIdCounter.current(), "Supply cannot fall below minted tokens.");
        maxSupply -= numTokens;
    }

    /// @notice Function used to ban a token, only callable by the owner.
    /// @param tokenId The token ID to ban.
    function banToken(uint tokenId) external onlyOwner {
        require(!isBanned[tokenId], "Token already banned.");
        expiryTime[tokenId] = block.timestamp;
        isBanned[tokenId] = true;

        emit Banned(msg.sender, tokenId);
    }

    /// @notice Function used to unban a token, only callable by the owner.
    /// @param tokenId The token ID to unban.
    function unbanToken(uint tokenId) external onlyOwner {
        require(isBanned[tokenId], "Token is not banned.");
        isBanned[tokenId] = false;

        emit Unbanned(msg.sender, tokenId);
    }

    /// @notice Function that is used to get the current `_contractURI` value.
    /// @return Returns a string value of `_contractURI`.
    function contractURI() public view returns (string memory) {
        return _contractURI;
    }

    /// @notice Function that is used to update the `_contractURI` value, only
    /// callable by the owner.
    /// @param contractURI_ A string value to replace the current 'contractURI_'.
    function setContractURI(string calldata contractURI_) external onlyOwner {
        _contractURI = contractURI_;
    }

    /// @notice Function that is used to get the `_tokenURI` for `tokenId`.
    /// @param tokenId The `tokenId` to get the `_tokenURI` for.
    /// @return Returns a string representing the `_tokenURI` for `tokenId`.
    function tokenURI(uint tokenId) public view override returns (string memory) {
        require(_exists(tokenId), "Token does not exist.");
        return string(abi.encodePacked(_tokenURI, tokenId.toString()));
    }

    /// @notice Function that is used to update the `_tokenURI` value, only 
    /// callable by the owner.
    /// @param tokenURI_ A string value to replace the current `_tokenURI` value.
    function setTokenURI(string calldata tokenURI_) external onlyOwner {
        _tokenURI = tokenURI_;
    }

    /// @notice Function used to get the total number of minted tokens.
    function totalSupply() public view returns (uint) {
        return _tokenIdCounter.current();
    }

    /// @notice Function that is used to withdraw the total balance of the
    /// contract, only callable by the owner.
    function withdrawBalance() public onlyOwner {
		payable(msg.sender).transfer(address(this).balance);
	}

    /// @notice Function used to get the tokens owned by a provided address.
    /// @param _address The specified address to perform a lookup for.
    /// @dev DO NOT CALL THIS FUNCTION ON-CHAIN.
    function getTokensOwnedByAddress(address _address) external view returns (uint[] memory) {
        uint tokenBalance = balanceOf(_address);

        if (tokenBalance == 0) {
            return new uint[](0);
        }

        uint[] memory tokensOwned = new uint[](tokenBalance);
        uint resultIndex = 0;

        for (uint i=1; i<=_tokenIdCounter.current(); i++) {
            if (ownerOf(i) == _address) {
                tokensOwned[resultIndex] = i;
                resultIndex++;
            }
        }

        return tokensOwned;
    }

    /// @notice Function used to get the tokens currently within the grace period.
    /// @dev DO NOT CALL THIS FUNCTION ON-CHAIN.
    function getTokensInGracePeriod() external view returns (uint[] memory) {
        uint tokenSupply = _tokenIdCounter.current();
        uint numTokens = 0;

        for (uint i=1; i<=tokenSupply; i++) {
            if (block.timestamp > expiryTime[i] && expiryTime[i] + gracePeriod > block.timestamp) {
                if (!isBanned[i]) {
                    numTokens++;
                }
            }
        }

        uint[] memory graceTokens = new uint[](numTokens);
        uint index = 0;

        for (uint i=1; i<=tokenSupply; i++) {
            if (block.timestamp > expiryTime[i] && expiryTime[i] + gracePeriod > block.timestamp) {
                if (!isBanned[i]) {
                    graceTokens[index] = i;
                    index++;
                }
            }
        }

        return graceTokens;
    }

    /// @notice Function that is used to safely transfer a token from one owner to another.
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "Transfer caller is not owner nor approved.");
        if (owner() != msg.sender) {
            require(!isBanned[tokenId], "Token is banned.");
            require(expiryTime[tokenId] > block.timestamp, "Token has expired.");
        }
        _safeTransfer(from, to, tokenId, _data);
    }

    /// @notice Function that is used to transfer a token from one owner to another.
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "Transfer caller is not owner nor approved.");
        if (owner() != msg.sender) {
            require(!isBanned[tokenId], "Token is banned.");
            require(expiryTime[tokenId] > block.timestamp, "Token has expired.");
        }
        _transfer(from, to, tokenId);
    }

}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

{
  "compilationTarget": {
    "contracts/MetaMint.sol": "MetaMint"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}