// File: src/libraries/SafeMath.sol

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
  /**
   * @dev Returns the addition of two unsigned integers, reverting on
   * overflow.
   *
   * Counterpart to Solidity's `+` operator.
   *
   * Requirements:
   * - Addition cannot overflow.
   */
  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    require(c >= a, 'SafeMath: addition overflow');

    return c;
  }

  /**
   * @dev Returns the subtraction of two unsigned integers, reverting on
   * overflow (when the result is negative).
   *
   * Counterpart to Solidity's `-` operator.
   *
   * Requirements:
   * - Subtraction cannot overflow.
   */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    return sub(a, b, 'SafeMath: subtraction overflow');
  }

  /**
   * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
   * overflow (when the result is negative).
   *
   * Counterpart to Solidity's `-` operator.
   *
   * Requirements:
   * - Subtraction cannot overflow.
   */
  function sub(
    uint256 a,
    uint256 b,
    string memory errorMessage
  ) internal pure returns (uint256) {
    require(b <= a, errorMessage);
    uint256 c = a - b;

    return c;
  }

  /**
   * @dev Returns the multiplication of two unsigned integers, reverting on
   * overflow.
   *
   * Counterpart to Solidity's `*` operator.
   *
   * Requirements:
   * - Multiplication cannot overflow.
   */
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
    // benefit is lost if 'b' is also tested.
    // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
    if (a == 0) {
      return 0;
    }

    uint256 c = a * b;
    require(c / a == b, 'SafeMath: multiplication overflow');

    return c;
  }

  /**
   * @dev Returns the integer division of two unsigned integers. Reverts on
   * division by zero. The result is rounded towards zero.
   *
   * Counterpart to Solidity's `/` operator. Note: this function uses a
   * `revert` opcode (which leaves remaining gas untouched) while Solidity
   * uses an invalid opcode to revert (consuming all remaining gas).
   *
   * Requirements:
   * - The divisor cannot be zero.
   */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    return div(a, b, 'SafeMath: division by zero');
  }

  /**
   * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
   * division by zero. The result is rounded towards zero.
   *
   * Counterpart to Solidity's `/` operator. Note: this function uses a
   * `revert` opcode (which leaves remaining gas untouched) while Solidity
   * uses an invalid opcode to revert (consuming all remaining gas).
   *
   * Requirements:
   * - The divisor cannot be zero.
   */
  function div(
    uint256 a,
    uint256 b,
    string memory errorMessage
  ) internal pure returns (uint256) {
    // Solidity only automatically asserts when dividing by 0
    require(b > 0, errorMessage);
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold

    return c;
  }

  /**
   * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
   * Reverts when dividing by zero.
   *
   * Counterpart to Solidity's `%` operator. This function uses a `revert`
   * opcode (which leaves remaining gas untouched) while Solidity uses an
   * invalid opcode to revert (consuming all remaining gas).
   *
   * Requirements:
   * - The divisor cannot be zero.
   */
  function mod(uint256 a, uint256 b) internal pure returns (uint256) {
    return mod(a, b, 'SafeMath: modulo by zero');
  }

  /**
   * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
   * Reverts with custom message when dividing by zero.
   *
   * Counterpart to Solidity's `%` operator. This function uses a `revert`
   * opcode (which leaves remaining gas untouched) while Solidity uses an
   * invalid opcode to revert (consuming all remaining gas).
   *
   * Requirements:
   * - The divisor cannot be zero.
   */
  function mod(
    uint256 a,
    uint256 b,
    string memory errorMessage
  ) internal pure returns (uint256) {
    require(b != 0, errorMessage);
    return a % b;
  }
}

// File: src/Context.sol


// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.7.6;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: src/Ownable.sol



pragma solidity ^0.7.6;

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// File: src/interfaces/IERC20.sol



pragma solidity >=0.7.6;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: src/libraries/Address.sol



pragma solidity >=0.7.6;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// File: src/SafeERC20.sol



pragma solidity >=0.7.6;




/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// File: src/interfaces/IMintableBurnableERC20.sol

pragma solidity >=0.7.6;

interface IMintableBurnableERC20 {
    function burn(uint256 _amount) external;
    function mint(address _to, uint256 _amount) external;
}

// File: src/Booster.sol

pragma solidity >=0.7.6;






contract Booster is Ownable {
    using SafeMath for uint256;
    using SafeERC20 for IERC20;
    address public immutable msig;
    // Start time of epoch 0
    uint256 public startTime;
    // In seconds
    uint256 public epochLength;
    address public bstETH;
    bool public stopped;
    uint256 public finalEpoch;
    uint256 public lastCalculated;
    bool public calculationComplete;
    address public blast;
    uint256 public totalAirdrop;

    // Epoch to user to loan amounts
    mapping(uint256 => mapping(address => uint256)) public loans;
    // Epoch to total lent
    mapping(uint256 => uint256) public totalLentPerEpoch;
    // Epoch to user to borrows
    mapping(uint256 => mapping(address => uint256)) public borrows;
    // Epoch to total borrowed
    mapping(uint256 => uint256) public totalBorrowedPerEpoch;
    // Epoch to collected (to msig)
    mapping(uint256 => bool) public epochToCollected;
    /* Epoch to contributions toward airdrop
    * Uses the following formula:
    * totalLentPerEpoch[_epoch] * (finalEpoch - _epoch)
    * This gives us a representation of an epoch's contribution
    * To get proportional contribution toward the airdrop, we divide by sumContributions
    */
    mapping(uint256 => uint256) public epochToContributions;
    uint256 public sumContributions;

    constructor(address _msig, uint256 _epochLength, address _bstETH) {
        msig = _msig;
        epochLength = _epochLength;
        bstETH = _bstETH;
    }

    event Loan(address indexed user, uint256 indexed timeStamp, uint256 indexed epoch, uint256 amount);
    event Borrow(address indexed user, uint256 indexed timeStamp, uint256 indexed epoch, uint256 amount);
    event Claim(address indexed user, uint256 indexed timeStamp, uint256 indexed epoch, uint256 amount);
    event Refund(address indexed user, uint256 indexed timeStamp, uint256 indexed epoch, uint256 amount);
    event RedeemPrincipal(address indexed user, uint256 indexed timeStamp, uint256 amount);
    event RedeemAirdrop(address indexed user, uint256 indexed timeStamp, uint256 indexed epoch, uint256 correspondingEthPaid, uint256 airdropAmount);

    receive() external payable {}

    fallback() external payable {}

    // If for some reason ERC20 tokens are sent to the contract, allow withdrawal
    function emergencyWithdraw(address _token, address _to, uint256 _amount) external onlyOwner {
        IERC20(_token).safeTransfer(_to, _amount);
    }

    // Emergency ETH withdraw - only msig wallet can run
    function emergencyWithdrawETH(uint256 _amount) external {
        require(msg.sender == msig, "Not msig");
        (bool sent, ) = msig.call{value: _amount}("");
        require(sent, "Failed to send Ether");
    }

    // Withdraw to msig wallet for Blast farming
    function withdrawToMsig(uint256 _epoch) external onlyOwner {
        require(getCurrentEpoch() > _epoch, "Epoch has not passed");
        require(!epochToCollected[_epoch], "Already collected for epoch");
        epochToCollected[_epoch] = true;
        if (totalLentPerEpoch[_epoch] == 0 || totalBorrowedPerEpoch[_epoch] == 0) {
            return;
        }
        // Send ETH to msig
        (bool sent, ) = msig.call{value: totalLentPerEpoch[_epoch]}("");
        require(sent, "Failed to send Ether");
    }

    function lend(address _lender) external payable {
        require(!stopped, "Stopped");
        require(msg.value > 0, "No ETH sent");
        require(startTime != 0, "Not started");
        uint256 currentEpoch = getCurrentEpoch();
        loans[currentEpoch][_lender] = loans[currentEpoch][_lender].add(msg.value);
        totalLentPerEpoch[currentEpoch] = totalLentPerEpoch[currentEpoch].add(msg.value);
        // Mint receipt token
        IMintableBurnableERC20(bstETH).mint(_lender, msg.value);

        // Emit lend event
        emit Loan(_lender, block.timestamp, currentEpoch, msg.value);
    }

    function claim(uint256 _epoch) external {
        // If borrowed / lent is 0, users should be collecting their refund
        require(totalLentPerEpoch[_epoch] != 0 && totalBorrowedPerEpoch[_epoch] != 0, "Nothing to claim");
        require(getCurrentEpoch() > _epoch, "Epoch has not passed");
        require(loans[_epoch][msg.sender] > 0, "Nothing lent during epoch");
        uint256 lentAmount = loans[_epoch][msg.sender];
        loans[_epoch][msg.sender] = 0;
        uint256 amountToSend = totalBorrowedPerEpoch[_epoch].mul(lentAmount).div(totalLentPerEpoch[_epoch]);
        (bool sent, ) = msg.sender.call{value: amountToSend}("");
        require(sent, "Failed to send Ether");

        // Emit claim event
        emit Claim(msg.sender, block.timestamp, _epoch, amountToSend);
    }

    function borrow(address _borrower) external payable {
        require(!stopped, "Stopped");
        require(msg.value > 0, "No ETH sent");
        require(startTime != 0, "Not started");
        uint256 currentEpoch = getCurrentEpoch();
        borrows[currentEpoch][_borrower] = borrows[currentEpoch][_borrower].add(msg.value);
        totalBorrowedPerEpoch[currentEpoch] = totalBorrowedPerEpoch[currentEpoch].add(msg.value);

        // Emit borrow event
        emit Borrow(_borrower, block.timestamp, currentEpoch, msg.value);
    }

    // Function to get refunded if total lent / borrowed was 0 in an epoch
    function refund(uint256 _epoch) external {
        require(totalLentPerEpoch[_epoch] == 0 || totalBorrowedPerEpoch[_epoch] == 0, "Nothing to refund this epoch");
        require(getCurrentEpoch() > _epoch, "Epoch has not passed");
        uint256 ethToRefund = 0;
        if (totalLentPerEpoch[_epoch] == 0) {
            uint256 userBorrows = borrows[_epoch][msg.sender];
            if (userBorrows > 0) {
                borrows[_epoch][msg.sender] = 0;
                ethToRefund = ethToRefund.add(userBorrows);
            }
        }
        if (totalBorrowedPerEpoch[_epoch] == 0) {
            uint256 userLoans = loans[_epoch][msg.sender];
            if (userLoans > 0) {
                // Burn receipt token
                IERC20(bstETH).safeTransferFrom(msg.sender, address(this), userLoans);
                IMintableBurnableERC20(bstETH).burn(userLoans);
                loans[_epoch][msg.sender] = 0;
                ethToRefund = ethToRefund.add(userLoans);
            }
        }
        require(ethToRefund > 0, "Nothing to refund");
        // Refund ETH to user
        (bool sent, ) = msg.sender.call{value: ethToRefund}("");
        require(sent, "Failed to send Ether");

        // Emit refund event
        emit Refund(msg.sender, block.timestamp, _epoch, ethToRefund);
    }

    function redeemPrincipalETH(uint256 _amount) external {
        require(stopped, "Still ongoing");
        // Burn receipt token
        IERC20(bstETH).safeTransferFrom(msg.sender, address(this), _amount);
        IMintableBurnableERC20(bstETH).burn(_amount);
        // Redeem ETH to user
        (bool sent, ) = msg.sender.call{value: _amount}("");
        require(sent, "Failed to send Ether");

        // Emit redeem principal event
        emit RedeemPrincipal(msg.sender, block.timestamp, _amount);
    }

    function redeemBlastAirdrop(uint256 _epoch) external {
        require(stopped, "Still ongoing");
        require(calculationComplete, "Calculation ongoing");
        require(blast != address(0), "No blast address");
        require(_epoch <= finalEpoch, "Invalid epoch");
        require(totalBorrowedPerEpoch[_epoch] != 0 && totalLentPerEpoch[_epoch] != 0, "Empty epoch");

        uint256 borrowedDuringEpoch = borrows[_epoch][msg.sender];
        borrows[_epoch][msg.sender] = 0;
        uint256 blastOwedForEpoch = epochToContributions[_epoch].mul(borrowedDuringEpoch).mul(totalAirdrop).div(sumContributions).div(totalBorrowedPerEpoch[_epoch]);
        IERC20(blast).transfer(msg.sender, blastOwedForEpoch);

        // Emit redeem airdrop event
        emit RedeemAirdrop(msg.sender, block.timestamp, _epoch, borrowedDuringEpoch, blastOwedForEpoch);
    }

    function start() external onlyOwner {
        require(startTime == 0, "Already started");
        startTime = block.timestamp;
    }

    function stop() external onlyOwner {
        require(!stopped, "Already stopped");
        stopped = true;
        finalEpoch = getCurrentEpoch();
    }

    // In case we have too many epochs and loop becomes too long, we allow slicing over multiple transactions
    function calculateEpochContributions(uint256 _startEpoch, uint256 _endEpoch) external onlyOwner {
        require(stopped, "Still ongoing");
        require(_endEpoch > _startEpoch, "Invalid range");
        require(_startEpoch == 0 || (lastCalculated != 0 && _startEpoch == lastCalculated + 1), "Invalid calc");
        require(_endEpoch <= finalEpoch, "Out of range");
        require(!calculationComplete, "Already complete");

        for (uint256 i = _startEpoch; i < _endEpoch; i++) {
            if (totalLentPerEpoch[i] != 0 && totalBorrowedPerEpoch[i] != 0) {
                epochToContributions[i] = totalLentPerEpoch[i].mul(finalEpoch.sub(i));
                sumContributions = sumContributions.add(epochToContributions[i]);
            }
        }

        lastCalculated = _endEpoch;
        if (_endEpoch == finalEpoch) {
            calculationComplete = true;
        }
    }

    function modifyParams(uint256 _startTime, uint256 _epochLength, address _bstETH) external onlyOwner {
        startTime = _startTime;
        epochLength = _epochLength;
        bstETH = _bstETH;
    }

    function setAirdrop(address _blast, uint256 _totalAirdrop) external onlyOwner {
        blast = _blast;
        totalAirdrop = _totalAirdrop;
    }

    function getCurrentEpoch() public view returns (uint256) {
        return block.timestamp.sub(startTime).div(epochLength);
    }

    function getEpoch(uint256 _timestamp) public view returns (uint256) {
        return _timestamp.sub(startTime).div(epochLength);
    }
}

{
  "compilationTarget": {
    "Booster.sol": "Booster"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}