PEPESTUDIO NFT

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Modern, minimalist, and gas efficient ERC-721 implementation.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC721.sol)
abstract contract ERC721 {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event Transfer(address indexed from, address indexed to, uint256 indexed id);

    event Approval(address indexed owner, address indexed spender, uint256 indexed id);

    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /*//////////////////////////////////////////////////////////////
                         METADATA STORAGE/LOGIC
    //////////////////////////////////////////////////////////////*/

    string public name;

    string public symbol;

    function tokenURI(uint256 id) public view virtual returns (string memory);

    /*//////////////////////////////////////////////////////////////
                      ERC721 BALANCE/OWNER STORAGE
    //////////////////////////////////////////////////////////////*/

    mapping(uint256 => address) internal _ownerOf;

    mapping(address => uint256) internal _balanceOf;

    function ownerOf(uint256 id) public view virtual returns (address owner) {
        require((owner = _ownerOf[id]) != address(0), "NOT_MINTED");
    }

    function balanceOf(address owner) public view virtual returns (uint256) {
        require(owner != address(0), "ZERO_ADDRESS");

        return _balanceOf[owner];
    }

    /*//////////////////////////////////////////////////////////////
                         ERC721 APPROVAL STORAGE
    //////////////////////////////////////////////////////////////*/

    mapping(uint256 => address) public getApproved;

    mapping(address => mapping(address => bool)) public isApprovedForAll;

    /*//////////////////////////////////////////////////////////////
                               CONSTRUCTOR
    //////////////////////////////////////////////////////////////*/

    constructor(string memory _name, string memory _symbol) {
        name = _name;
        symbol = _symbol;
    }

    /*//////////////////////////////////////////////////////////////
                              ERC721 LOGIC
    //////////////////////////////////////////////////////////////*/

    function approve(address spender, uint256 id) public virtual {
        address owner = _ownerOf[id];

        require(msg.sender == owner || isApprovedForAll[owner][msg.sender], "NOT_AUTHORIZED");

        getApproved[id] = spender;

        emit Approval(owner, spender, id);
    }

    function setApprovalForAll(address operator, bool approved) public virtual {
        isApprovedForAll[msg.sender][operator] = approved;

        emit ApprovalForAll(msg.sender, operator, approved);
    }

    function transferFrom(
        address from,
        address to,
        uint256 id
    ) public virtual {
        require(from == _ownerOf[id], "WRONG_FROM");

        require(to != address(0), "INVALID_RECIPIENT");

        require(
            msg.sender == from || isApprovedForAll[from][msg.sender] || msg.sender == getApproved[id],
            "NOT_AUTHORIZED"
        );

        // Underflow of the sender's balance is impossible because we check for
        // ownership above and the recipient's balance can't realistically overflow.
        unchecked {
            _balanceOf[from]--;

            _balanceOf[to]++;
        }

        _ownerOf[id] = to;

        delete getApproved[id];

        emit Transfer(from, to, id);
    }

    function safeTransferFrom(
        address from,
        address to,
        uint256 id
    ) public virtual {
        transferFrom(from, to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, from, id, "") ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        bytes calldata data
    ) public virtual {
        transferFrom(from, to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, from, id, data) ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    /*//////////////////////////////////////////////////////////////
                              ERC165 LOGIC
    //////////////////////////////////////////////////////////////*/

    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return
            interfaceId == 0x01ffc9a7 || // ERC165 Interface ID for ERC165
            interfaceId == 0x80ac58cd || // ERC165 Interface ID for ERC721
            interfaceId == 0x5b5e139f; // ERC165 Interface ID for ERC721Metadata
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL MINT/BURN LOGIC
    //////////////////////////////////////////////////////////////*/

    function _mint(address to, uint256 id) internal virtual {
        require(to != address(0), "INVALID_RECIPIENT");

        require(_ownerOf[id] == address(0), "ALREADY_MINTED");

        // Counter overflow is incredibly unrealistic.
        unchecked {
            _balanceOf[to]++;
        }

        _ownerOf[id] = to;

        emit Transfer(address(0), to, id);
    }

    function _burn(uint256 id) internal virtual {
        address owner = _ownerOf[id];

        require(owner != address(0), "NOT_MINTED");

        // Ownership check above ensures no underflow.
        unchecked {
            _balanceOf[owner]--;
        }

        delete _ownerOf[id];

        delete getApproved[id];

        emit Transfer(owner, address(0), id);
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL SAFE MINT LOGIC
    //////////////////////////////////////////////////////////////*/

    function _safeMint(address to, uint256 id) internal virtual {
        _mint(to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, address(0), id, "") ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }

    function _safeMint(
        address to,
        uint256 id,
        bytes memory data
    ) internal virtual {
        _mint(to, id);

        require(
            to.code.length == 0 ||
                ERC721TokenReceiver(to).onERC721Received(msg.sender, address(0), id, data) ==
                ERC721TokenReceiver.onERC721Received.selector,
            "UNSAFE_RECIPIENT"
        );
    }
}

/// @notice A generic interface for a contract which properly accepts ERC721 tokens.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC721.sol)
abstract contract ERC721TokenReceiver {
    function onERC721Received(
        address,
        address,
        uint256,
        bytes calldata
    ) external virtual returns (bytes4) {
        return ERC721TokenReceiver.onERC721Received.selector;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);

    function mint(address _to, uint256 _amount) external returns (bool);

    function burn(uint256 _amount) external returns (bool);
}

pragma solidity ^0.8.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}

pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

import "solmate/tokens/ERC721.sol";
import "solmate/utils/ReentrancyGuard.sol";
import "openzeppelin-contracts/contracts/utils/Strings.sol";

import "./interfaces/IUniswapV2Pair.sol";
import "./interfaces/IUniswapV2Router.sol";
import "./interfaces/IERC20.sol";
import "openzeppelin-contracts/contracts/utils/Address.sol";
import "openzeppelin-contracts/contracts/access/Ownable.sol";

error MintPriceNotPaid();
error NonExistentTokenURI();
error WithdrawTransfer();
error NotEnoughPepe();
error TransferStakedNFT();

contract PepeStudioNFT is ERC721, ReentrancyGuard, Ownable {
    using Strings for uint256;
    string public baseURI;
    IERC20 public immutable pepeToken;
    IERC20 public immutable pepeStudioToken;
    IUniswapV2Pair public immutable uniswapV2Pair;
    uint256 public currentTokenId;
    uint256 public BASE_MINT_PRICE = 10_000_000 ether;
    address public dev;
    
    // referral reward pool
    mapping(address => uint256) public referralRewards;
    mapping(address => uint256) public nextWithdrawTime;

    // emission rate
    uint256 public constant EMISSION_RATE = 200_000 ether; // 200,000 PEPESTUDIO per block
    uint256 public totalStakedNFTs;

    // burn address
    address public constant BURN_ADDRESS = 0x000000000000000000000000000000000000dEaD;

    // Each pepe studio nft has a rarity level
    enum RarityLevel {
        COMMON,
        RARE,
        EPIC,
        LEGENDARY
    }
    struct NFTMetadata {
        uint256 stakedAt;
        uint256 hashRate;
        RarityLevel rarityLevel;
        bool isStaked;
    }
    mapping(uint256 => NFTMetadata) public metadata;

    // Info of each user.
    struct UserInfo {
        uint256 hashRate; // How many hash rate the user has provided.
        uint256 rewardDebt; // Reward debt. See explanation below.
        uint256[] stakedNFTs;
        //
        // We do some fancy math here. Basically, any point in time, the amount of PEPESTUDIO
        // entitled to a user but is pending to be distributed is:
        //
        //   pending reward = (user.amount * pool.accPepestudioPerShare) - user.rewardDebt
        //
        // Whenever a user stake or unstake NFT to a pool. Here's what happens:
        //   1. The pool's `accPepestudioPerShare` (and `lastRewardBlock`) gets updated.
        //   2. User receives the pending reward sent to his/her address.
        //   3. User's `amount` gets updated.
        //   4. User's `rewardDebt` gets updated.
    }

    // Info of each pool.
    struct PoolInfo {
        uint256 currentHashRate; // Current hash rate in this pool
        uint256 minimumHashRate; // Minimum hash rate required to stake
        uint256 maximumHashRate; // Maximum hash rate allowed to stake
        uint256 stakeTime; // Minimum time required to stake
        uint256 allocPoint; // How many allocation points assigned to this pool. PEPESTUDIO to distribute per block.
        uint256 lastRewardBlock; // Last block number that PEPESTUDIO distribution occurs.
        uint256 accPepeStudioPerShare; // Accumulated PEPESTUDIO per share, times 1e12. See below.
    }

    // Info of each pool.
    PoolInfo[] public poolInfo;
    // Info of each user that stakes Pepe Studio NFT.
    mapping(uint256 => mapping(address => UserInfo)) public userInfo;

    // Total allocation points. Must be the sum of all allocation points in all pools.
    uint256 public totalAllocPoint = 0;
    // The block number when PEPESTUDIO mining starts.
    uint256 public startStakingBlock;
    // The block number when PEPESTUDIO NFT minting starts.
    uint256 public startMintBlock;

    event ReferralRegistered(address indexed referrer, address indexed referee, uint256 tokenId);
    event WithdrawReferralReward(address indexed referrer, uint256 amount);
    event Stake(uint256 indexed tokenId);
    event Unstake(uint256 indexed tokenId, uint256 stakedAtTimestamp, uint256 removedFromStakeAtTimestamp);
    event EmergencyUnstake(address indexed user, uint256 indexed pid, uint256[] nfts);

    /**
        * @dev Throws if called by any contract.
     */
    modifier notContract() {
        require(!Address.isContract(msg.sender), "contract not allowed");
        require(msg.sender == tx.origin, "proxy contract not allowed");
        _;
    }

    /**
        * @dev Modifier to make a function callable only when the minting has started.
     */
    modifier startMint() {
        require(block.number >= startMintBlock, "minting has not started yet");
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the staking has started.
     */
    modifier startStake() {
        require(block.number >= startStakingBlock, "staking has not started yet");
        _;
    }

    /**
        * @dev Constructor of the contract.
     */
    constructor(
        string memory _name,
        string memory _symbol,
        string memory _baseURI,
        address _pepeToken,
        address _pepeStudioToken,
        address _uniswapV2Factory,
        uint256 _startStakingBlock,
        uint256 _startMintBlock
    ) ERC721(_name, _symbol) Ownable() {
        dev = msg.sender;
        baseURI = _baseURI;
        pepeToken = IERC20(_pepeToken);
        pepeStudioToken = IERC20(_pepeStudioToken);
        IUniswapV2Factory uniswapV2Factory = IUniswapV2Factory(_uniswapV2Factory);
        // Create a uniswap pair for PEPESTUDIO/PEPE token
        uniswapV2Pair = IUniswapV2Pair(uniswapV2Factory.createPair(_pepeStudioToken, _pepeToken));

        // Set the start staking block
        startStakingBlock = _startStakingBlock;
        // Set the start mint block
        startMintBlock = _startMintBlock;

        // Create a staking pool for common NFT, with 3x allocation point and stake time is 7 days
        poolInfo.push(
            PoolInfo({
                currentHashRate: 0,
                minimumHashRate: 0,
                maximumHashRate: 0,
                stakeTime: 0,
                allocPoint: 0,
                lastRewardBlock: _startStakingBlock,
                accPepeStudioPerShare: 0
            })
        );
        poolInfo.push(
            PoolInfo({
                currentHashRate: 0,
                minimumHashRate: 0,
                maximumHashRate: 100000,
                stakeTime: 9 days,
                allocPoint: 300,
                lastRewardBlock: _startStakingBlock,
                accPepeStudioPerShare: 0
            })
        );
        poolInfo.push(
            PoolInfo({
                currentHashRate: 0,
                minimumHashRate: 100000,
                maximumHashRate: 200000,
                stakeTime: 10 days,
                allocPoint: 200,
                lastRewardBlock: _startStakingBlock,
                accPepeStudioPerShare: 0
            })
        );
        poolInfo.push(
            PoolInfo({
                currentHashRate: 0,
                minimumHashRate: 0,
                maximumHashRate: 200000,
                stakeTime: 7 days,
                allocPoint: 500,
                lastRewardBlock: _startStakingBlock,
                accPepeStudioPerShare: 0
            })
        );

        totalAllocPoint = 1000;
    }

    // Function to calculate NFT minting price
    function calculateMintingPrice(uint256 _tokenId) internal view returns (uint256) {
        // for every 1000 token minted, increase 3% of the minting price
        return BASE_MINT_PRICE * (100 + (_tokenId / 1000) * 3) / 100;
    }

    function getMintingPrice() public view returns (uint256) {
        return calculateMintingPrice(currentTokenId + 1);
    }

    // change dev address
    function changeDev(address _dev) public {
        require(msg.sender == dev, "Only dev can change dev address");
        dev = _dev;
    }


    function randomInRange(uint256 min, uint256 max, uint256 nonce) internal view returns (uint256) {
        return
            uint256(
                keccak256(
                    abi.encodePacked(block.timestamp, block.prevrandao, msg.sender, nonce)
                )
            ) % (max - min) + min;
    }

    function mintUsingPEPE(address recipient, uint256 quantity, address referrer) public startMint notContract {
        // calculate and update new minting price
        uint256 mintingPrice = calculateMintingPrice(currentTokenId + 1);
        if(mintingPrice > BASE_MINT_PRICE) {
            BASE_MINT_PRICE = mintingPrice;
        }

        // Send the pepe token, to save gas, we will not calculate the minting price increase in case of multiple minting
        pepeToken.transferFrom(msg.sender, address(this), mintingPrice * quantity);

        // reward to referrer
        if (referrer != address(0) && referrer != msg.sender) {
            uint256 referrerReward = mintingPrice * quantity / 20; // 5%
            referralRewards[referrer] += referrerReward;
        }

        for(uint256 i = 0; i < quantity; i++) {
            uint256 newTokenId = ++currentTokenId;
            // calculate the rarity level using randomness, 68.75% is common, 19.25% is rare, 10,25% is epic, 1,75% is legendary
            uint256 randomNumber = randomInRange(0, 10000, newTokenId);
            uint256 hashRate;
            RarityLevel rarityLevel;
            if (randomNumber < 6875) {
                rarityLevel = RarityLevel.COMMON;
                hashRate = randomInRange(10000, 100000, block.number * (i + 1));
            } else if (randomNumber < 8700) {
                rarityLevel = RarityLevel.RARE;
                hashRate = randomInRange(20000, 100000, block.number * (i + 1));
            } else if (randomNumber < 9800) {
                rarityLevel = RarityLevel.EPIC;
                hashRate = randomInRange(30000, 100000, block.number * (i + 1));
            } else {
                rarityLevel = RarityLevel.LEGENDARY;
                hashRate = randomInRange(1, 200000, block.number * (i + 1));
            }
            metadata[newTokenId] = NFTMetadata({
                rarityLevel: rarityLevel,
                hashRate: hashRate,
                stakedAt: 0,
                isStaked: false
            });
            _safeMint(recipient, newTokenId);
            emit ReferralRegistered(referrer, recipient, newTokenId);
        }
    }

    function mintUsingPEPEStudio(address recipient, uint256 quantity) public startMint notContract {
        // calculate and update new minting price
        uint256 mintingPrice = calculateMintingPrice(currentTokenId + 1);
        if(mintingPrice > BASE_MINT_PRICE) {
            BASE_MINT_PRICE = mintingPrice;
        }

        // Send the pepe token
        pepeStudioToken.transferFrom(msg.sender, address(this), mintingPrice * quantity);

        // burn the pepe studio token
        pepeStudioToken.burn(mintingPrice * quantity);

        for(uint256 i = 0; i < quantity; i++) {
            uint256 newTokenId = ++currentTokenId;
            // calculate the rarity level using randomness, 68.75% is common, 19.25% is rare, 10,25% is epic, 1,75% is legendary
            uint256 randomNumber = randomInRange(0, 10000, newTokenId);
            RarityLevel rarityLevel;
            uint256 hashRate;
            if (randomNumber < 5875) {
                rarityLevel = RarityLevel.COMMON;
                hashRate = randomInRange(10000, 100000, block.number * (i + 1));
            } else if (randomNumber < 8300) {
                rarityLevel = RarityLevel.RARE;
                hashRate = randomInRange(20000, 100000, block.number * (i + 1));
            } else if (randomNumber < 9625) {
                rarityLevel = RarityLevel.EPIC;
                hashRate = randomInRange(30000, 100000, block.number * (i + 1));
            } else {
                rarityLevel = RarityLevel.LEGENDARY;
                hashRate = randomInRange(1, 200000, block.number * (i + 1));
            }
            metadata[newTokenId] = NFTMetadata({
                rarityLevel: rarityLevel,
                hashRate: hashRate,
                stakedAt: 0,
                isStaked: false
            });
            _safeMint(recipient, newTokenId);
        }
    }

    function addLiquidity() public nonReentrant notContract returns (bool) {
        // send 2% of pepe to dev
        pepeToken.transfer(dev, pepeToken.balanceOf(address(this)) * 2 / 100);

        // reward to caller of this function 0.3% of the pepe balance
        pepeToken.transfer(msg.sender, pepeToken.balanceOf(address(this)) * 3 / 1000);

        uint256 amountB = pepeToken.balanceOf(address(this));
        uint256 amountA;

        if(uniswapV2Pair.totalSupply() == 0) {
            amountA = amountB;
        } else {
            // Calculate the amount of PEPESTUDIO token needed to add for the current liquidity
            amountA = (amountB * pepeStudioToken.balanceOf(address(uniswapV2Pair))) /
                pepeToken.balanceOf(address(uniswapV2Pair));
        }
        
        // Transfer the PEPESTUDIO token from the contract to the pair
        pepeStudioToken.mint(address(uniswapV2Pair), amountA);
        pepeToken.transfer(address(uniswapV2Pair), amountB);

        // Mint the LP token
        uniswapV2Pair.mint(address(this));

        // send the LP token to address dead
        uniswapV2Pair.transfer(BURN_ADDRESS, uniswapV2Pair.balanceOf(address(this)));

        return true;
    }


    // Function to claim referral rewards
    function claimReferralRewards() public nonReentrant returns (bool) {
        require(nextWithdrawTime[msg.sender] < block.timestamp, "You can only claim once every 3 days");
        uint256 amount = referralRewards[msg.sender];
        require(amount > 0, "No referral rewards to claim");
        if(amount > pepeToken.balanceOf(address(this))) {
            revert NotEnoughPepe();
        }
        referralRewards[msg.sender] = 0;
        pepeToken.transfer(msg.sender, amount);
        // lock for 3 days before next claim
        nextWithdrawTime[msg.sender] = block.timestamp + 3 days;
        return true;
    }

    function transferFrom(address from, address to, uint256 tokenId) public virtual override {
        if(metadata[tokenId].isStaked) {
            revert TransferStakedNFT();
        }
        super.transferFrom(from, to, tokenId);
    }

    function tokenURI(uint256 tokenId)
        public
        view
        virtual
        override
        returns (string memory)
    {
        if (ownerOf(tokenId) == address(0)) {
            revert NonExistentTokenURI();
        }
        return
            bytes(baseURI).length > 0
                ? string(abi.encodePacked(baseURI, tokenId.toString()))
                : "";
    }

    function poolLength() external view returns (uint256) {
        return poolInfo.length;
    }

    // Return reward multiplier over the given _from to _to block.
    function getMultiplier(uint256 _from, uint256 _to) public pure returns (uint256) {
        return (_to - _from);
    }

    // View function to see pending PEPESTUDIO on frontend.
    function pendingPepeStudio(uint256 _pid, address _user) external view returns (uint256) {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][_user];
        uint256 accPepeStudioPerShare = pool.accPepeStudioPerShare;
        uint256 totalHashRate = pool.currentHashRate;
        if (block.number > pool.lastRewardBlock && totalHashRate != 0) {
            uint256 multiplier = getMultiplier(pool.lastRewardBlock, block.number);
            uint256 pepeStudioReward = multiplier * EMISSION_RATE * pool.allocPoint / totalAllocPoint;
            accPepeStudioPerShare = accPepeStudioPerShare + (pepeStudioReward * 1e12 / totalHashRate);
        }
        return (user.hashRate * accPepeStudioPerShare / 1e12) - user.rewardDebt;
    }

    // Update reward variables for all pools. Be careful of gas spending!
    function massUpdatePools() public {
        uint256 length = poolInfo.length;
        for (uint256 pid = 0; pid < length; ++pid) {
            updatePool(pid);
        }
    }

    // Update reward variables of the given pool to be up-to-date.
    function updatePool(uint256 _pid) public {
        PoolInfo storage pool = poolInfo[_pid];
        if (block.number <= pool.lastRewardBlock) {
            return;
        }
        uint256 totalHashRate = pool.currentHashRate;
        if (totalHashRate == 0) {
            pool.lastRewardBlock = block.number;
            return;
        }

        // Calculate the reward to distribute
        uint256 multiplier = getMultiplier(pool.lastRewardBlock, block.number);
        uint256 pepeStudioReward = multiplier * EMISSION_RATE * pool.allocPoint / totalAllocPoint;
        // Send the reward to the dev address
        pepeStudioToken.mint(dev, pepeStudioReward / 30);
        // Send the reward to the contract
        pepeStudioToken.mint(address(this), pepeStudioReward);
        // Update the pool
        pool.accPepeStudioPerShare = pool.accPepeStudioPerShare + (pepeStudioReward * 1e12 / totalHashRate);
        // Update the last reward block
        pool.lastRewardBlock = block.number;
    }

    // Stake NFT tokens to PepeStudio for PEPESTUDIO allocation.
    function stake(uint256 _pid, uint256[] memory _nfts) public startStake {
        require(_pid != 0, "deposit NFT by staking");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        // Update the pool
        updatePool(_pid);
        if (user.hashRate > 0) {
            // Calculate the pending reward
            uint256 pending = (user.hashRate * pool.accPepeStudioPerShare / 1e12) - user.rewardDebt;
            if (pending > 0) {
                // Send the pending reward to the user
                safePepeStudioTransfer(msg.sender, pending);
            }
        }
        for (uint256 i = 0; i < _nfts.length; i++) {
            // Check ownership of the NFT
            require(ownerOf(_nfts[i]) == msg.sender, "You are not the owner of this token");
            // Check if the NFT is already staked
            require(!metadata[_nfts[i]].isStaked, "This token is already staked");
            // Check for minimum and maximum hash rate
            require(metadata[_nfts[i]].hashRate >= pool.minimumHashRate, "hash rate is too low");
            require(metadata[_nfts[i]].hashRate <= pool.maximumHashRate, "hash rate is too high");

            // Recalculate the hash rate
            pool.currentHashRate += metadata[_nfts[i]].hashRate;
            user.hashRate += metadata[_nfts[i]].hashRate;

            // Add the NFT to the user's staked NFTs
            user.stakedNFTs.push(_nfts[i]);

            // Set the metadata of the nft
            metadata[_nfts[i]].isStaked = true;

            emit Stake(_nfts[i]);
        }
        // Update the user's reward debt
        user.rewardDebt = user.hashRate * pool.accPepeStudioPerShare / 1e12;
    }

    // Withdraw NFT tokens from PepeStudio.
    function unstake(uint256 _pid, uint256[] memory _nfts) public {
        require(_pid != 0, "withdraw NFT by unstaking");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];
        require(user.hashRate > 0, "no hash rate");
        require(user.stakedNFTs.length >= _nfts.length, "not enough nfts");
        updatePool(_pid);
        uint256 pending = (user.hashRate * pool.accPepeStudioPerShare / 1e12) - user.rewardDebt;
        if (pending > 0) {
            safePepeStudioTransfer(msg.sender, pending);
        }
        for (uint256 i = 0; i < _nfts.length; i++) {
            require(ownerOf(_nfts[i]) == msg.sender, "You are not the owner of this token");
            require(metadata[_nfts[i]].isStaked, "This token is not staked");
            require(metadata[_nfts[i]].stakedAt + pool.stakeTime < block.timestamp, "You cannot withdraw this token yet");
            pool.currentHashRate -= metadata[_nfts[i]].hashRate;
            user.hashRate -= metadata[_nfts[i]].hashRate;
            metadata[_nfts[i]].isStaked = false;
            for (uint256 j = 0; j < user.stakedNFTs.length; j++) {
                if (user.stakedNFTs[j] == _nfts[i]) {
                    user.stakedNFTs[j] = user.stakedNFTs[user.stakedNFTs.length - 1];
                    user.stakedNFTs.pop();
                    break;
                }
            }
            emit Unstake(_nfts[i], metadata[_nfts[i]].stakedAt, block.timestamp);
        }
        user.rewardDebt = user.hashRate * pool.accPepeStudioPerShare / 1e12;
    }

    // emergency unstake without caring about rewards. EMERGENCY ONLY.
    function emergencyUnstake(uint256 _pid, uint256[] memory _nfts) public {
        require(_pid != 0, "emergency withdraw NFT by unstaking");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];
        require(user.hashRate > 0, "no hash rate");
        require(user.stakedNFTs.length >= _nfts.length, "not enough nfts");
        for (uint256 i = 0; i < _nfts.length; i++) {
            require(ownerOf(_nfts[i]) == msg.sender, "You are not the owner of this token");
            require(metadata[_nfts[i]].isStaked, "This token is not staked");
            pool.currentHashRate -= metadata[_nfts[i]].hashRate;
            user.hashRate -= metadata[_nfts[i]].hashRate;
            metadata[_nfts[i]].isStaked = false;
            for (uint256 j = 0; j < user.stakedNFTs.length; j++) {
                if (user.stakedNFTs[j] == _nfts[i]) {
                    user.stakedNFTs[j] = user.stakedNFTs[user.stakedNFTs.length - 1];
                    user.stakedNFTs.pop();
                    break;
                }
            }
        }
        user.rewardDebt = user.hashRate * pool.accPepeStudioPerShare / 1e12;
        emit EmergencyUnstake(msg.sender, _pid, _nfts);
    }

    function safePepeStudioTransfer(address _to, uint256 _amount) internal {
        uint256 pepeStudioBal = pepeStudioToken.balanceOf(address(this));
        if (_amount > pepeStudioBal) {
            pepeStudioToken.transfer(_to, pepeStudioBal);
        } else {
            pepeStudioToken.transfer(_to, _amount);
        }
    }

    function burnNFT(uint256 _tokenId) public {
        require(ownerOf(_tokenId) == msg.sender, "You are not the owner of this token");
        require(!metadata[_tokenId].isStaked, "This token is staked");
        // return 50% of the price they minted the nft to the user, calculate the price at minting time
        pepeToken.transfer(msg.sender, calculateMintingPrice(_tokenId) / 2);
        _burn(_tokenId);
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Gas optimized reentrancy protection for smart contracts.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/ReentrancyGuard.sol)
/// @author Modified from OpenZeppelin (https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/security/ReentrancyGuard.sol)
abstract contract ReentrancyGuard {
    uint256 private locked = 1;

    modifier nonReentrant() virtual {
        require(locked == 1, "REENTRANCY");

        locked = 2;

        _;

        locked = 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

{
  "compilationTarget": {
    "src/PepeStudioNFT.sol": "PepeStudioNFT"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":openzeppelin/=lib/openzeppelin-contracts/contracts/",
    ":solmate/=lib/solmate/src/"
  ]
}