// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: Unlicensed
pragma solidity ^0.8.20;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";
import { ReentrancyGuard } from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

interface IWETH {
    function deposit() external payable;
    function transfer(address to, uint value) external returns (bool);
    function withdraw(uint) external;
}

interface IUniswapV2Factory {
    function createPair(address tokenA, address tokenB) external returns (address pair);
    function getPair(address tokenA, address tokenB) external view returns (address pair);
}

interface IUniswapV2Pair {
    function factory() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function mint(address to) external returns (uint liquidity);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
}

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);
}

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
}

/**
 * @dev Interface of the tax structure contract.
 */
interface ITaxStructure {
    function routerAddress() external view returns (address);

    // these taxes will be taken as eth
    function nativeTaxBuyAmount(address) external view returns (uint256);
    function nativeTaxSellAmount(address) external view returns (uint256);

    // this tax will be taken as tokens
    function tokenTaxBuyAmount(address) external view returns (uint256);
    function tokenTaxSellAmount(address) external view returns (uint256);
}

interface OwnableContract {
    function owner() external view returns (address);
}

interface ICharityRegistry {
    function isApprovedDonationRecipient(address) external view returns (bool);
}

contract Pawswap is ReentrancyGuard, Ownable {
    using SafeERC20 for IERC20;
    
    struct TaxStruct {
        address addr;
        IERC20 token;
        uint256 nativeTax;
        uint256 tokenTax;
        uint256 customTax;
        address router;
    }

    mapping(address => bool) public excludedTokens; // tokens that are not allowed to list
    mapping(address => bool) public listers; // addresses that can list new tokens
    mapping(address => address) public tokenTaxContracts; // token address => tax structure contract address
    mapping(address => bool) public dexExcludedFromTreasury; // dex router address => true/false

    address public pawSwapRouter;
    address public immutable weth;
    // sets treasury fee to 0.03%
    uint256 public treasuryFee = 3;
    uint256 public constant TAX_DENOMINATOR = 10**4;

    ICharityRegistry public charityRegistry;

    event Buy(
        address indexed buyer,
        address indexed tokenAddress,
        uint256 ethSpent,
        uint256 tokensReceived,
        uint256 customTaxAmount,
        address indexed customTaxAddress
    );

    event Sell(
        address indexed seller,
        address indexed tokenAddress,
        uint256 tokensSold,
        uint256 ethReceived,
        uint256 customTaxAmount,
        address indexed customTaxAddress
    );

    event Donation(
        address indexed donor,
        address indexed tokenAddress,
        uint256 ethDonated,
        address indexed donationRecipient
    );

    modifier ensure(uint deadline) {
        require(deadline >= block.timestamp, "Pawswap: EXPIRED");
        _;
    }

    constructor (address _router, address _weth, address _charityRegistry) Ownable(msg.sender) {
        weth = _weth;
        pawSwapRouter = _router;
        charityRegistry = ICharityRegistry(_charityRegistry);
        dexExcludedFromTreasury[_router] = true;
    }

    function buyOnPawswap (
        address tokenAddress,
        uint customTaxAmount, 
        address customTaxAddress, 
        uint256 minTokensToReceive,
        bool isExactIn
    ) external payable nonReentrant {
        address _taxStructAddr = tokenTaxContracts[tokenAddress];
        require(address(_taxStructAddr) != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(_taxStructAddr, customTaxAmount, _msgSender(), tokenAddress, true);

        // uses getBuyAmountIn if this is an exact out trade because
        // we should take taxes out based on what the actual buy amount is since
        // the user might give us more eth than necessary -- we only want to tax the
        // amount used to purchased, not the excess eth sent in msg.value
        (uint256 _ethToSwap, uint256 _customTaxSent) = processPreSwapBuyTaxes(
          isExactIn ? msg.value : getBuyAmountIn(_msgSender(), tokenAddress, customTaxAmount, minTokensToReceive),
          customTaxAddress,
          _taxStruct,
          _taxStructAddr
        );

        (uint256 tokensFromSwap, uint256 dustEth) = swapEthForTokens(
          _ethToSwap,
          isExactIn ? 0 : addTokenTax(minTokensToReceive, _taxStruct),
          _taxStruct,
          isExactIn
        );

        uint256 purchasedTokens = processPostSwapBuyTaxes(
          _taxStruct.token,
          tokensFromSwap,
          _taxStruct
        );

        // require that we met the minimum set by the user
        require (purchasedTokens >= minTokensToReceive, "Insufficient tokens purchased");
        // send the tokens to the buyer
        _taxStruct.token.safeTransfer(_msgSender(), purchasedTokens);
        // refund dust eth, if any
        if (dustEth > 0) {
            (bool sent, ) = _msgSender().call{value: dustEth}("");
            require(sent, "Failed to refund user dust eth");
        }

        emit Buy(
            _msgSender(),
            tokenAddress,
            isExactIn ? msg.value : msg.value - dustEth, 
            purchasedTokens,
            _customTaxSent,
            customTaxAddress
        );
    }


    function processPreSwapBuyTaxes (
        uint256 ethAmount,
        address customTaxAddress,
        TaxStruct memory taxStructure,
        address taxContract
    ) private returns (uint256 _ethToSwap, uint256 _customTaxSent) {
        _ethToSwap = ethAmount;

        if (!dexExcludedFromTreasury[taxStructure.router]) {
            // take a treasury fee if we are not using the pawswap dex. 300 is 0.3%
            uint256 treasuryEth = ethAmount * treasuryFee / TAX_DENOMINATOR;
            // leave the eth in the contract for the owner to withdraw later
            _ethToSwap -= treasuryEth;
        }

        if (taxStructure.nativeTax != 0) {
            // send native tax to tax contract
            uint256 _nativeTax = ethAmount * taxStructure.nativeTax / TAX_DENOMINATOR;
            _ethToSwap -= _nativeTax;
            (bool sent, ) = taxContract.call{value: _nativeTax}("");
            require(sent, "Failed to send tax eth");
        }
        
        if (taxStructure.customTax != 0) {
            require(charityRegistry.isApprovedDonationRecipient(customTaxAddress), "Charity not approved");
            // send to the custom tax address
            _customTaxSent = ethAmount * taxStructure.customTax / TAX_DENOMINATOR;
            _ethToSwap -= _customTaxSent;
            (bool sent, ) = customTaxAddress.call{value: _customTaxSent}("");
            require(sent, "Failed to donate");
            emit Donation(
                _msgSender(),
                address(taxStructure.token),
                _customTaxSent,
                customTaxAddress
            );
        }

        return (_ethToSwap, _customTaxSent);
    }

    function processPostSwapBuyTaxes(
      IERC20 token,
      uint256 tokensFromSwap,
      TaxStruct memory taxStruct
    ) private returns (uint256 purchasedTokens) {
        purchasedTokens = tokensFromSwap;

        if (taxStruct.tokenTax != 0) {
            // send to the token tax wallet
            uint256 taxTokens = tokensFromSwap * taxStruct.tokenTax / TAX_DENOMINATOR;
            purchasedTokens -= taxTokens;
            token.safeTransfer(taxStruct.addr, taxTokens);
        }

        return purchasedTokens;
    }

    function sellOnPawswap (
        address tokenAddress,
        uint256 tokensSold, 
        uint customTaxAmount, 
        address customTaxAddress, 
        uint minEthToReceive,
        bool isExactIn
    ) external nonReentrant {
        address _taxStructAddr = tokenTaxContracts[tokenAddress];
        require(address(_taxStructAddr) != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(_taxStructAddr, customTaxAmount, _msgSender(), tokenAddress, false);

        _taxStruct.token.safeTransferFrom(_msgSender(), address(this), tokensSold);
        tokensSold = isExactIn ? tokensSold : getSellAmountIn(_msgSender(), tokenAddress, customTaxAmount, minEthToReceive);
        (uint256 tokensToSwap) = processPreSwapSellTaxes(
          tokensSold,
          _taxStruct
        );

        uint256 ethFromSwap = swapTokensForEth(
          tokensToSwap, 
          addEthTax(minEthToReceive, _taxStruct),
          _taxStruct,
          isExactIn
        );

        (uint256 ethToTransfer, uint256 customTaxSent) = processPostSwapSellTaxes(
          ethFromSwap, 
          customTaxAddress,
          _taxStruct
        );

        // require that we met the minimum set by the user
        require(ethToTransfer >= minEthToReceive, "Insufficient ETH out");

        // send the eth to seller
        sendEth(_msgSender(), ethToTransfer);

        emit Sell(
            _msgSender(),
            tokenAddress,
            tokensSold,
            ethToTransfer,
            customTaxSent,
            customTaxAddress
        );
    }

    function sendEth (address _to, uint256 _amount) internal {
        (bool sent, ) = _to.call{value: _amount}("");
        require(sent, "Failed to send eth");
    }

    function processPreSwapSellTaxes(
        uint256 tokensToSwap,
        TaxStruct memory taxStruct
    ) private returns (uint256) {
        if (taxStruct.tokenTax != 0) {
            // send to the token tax wallet
            uint256 taxTokens = tokensToSwap * taxStruct.tokenTax / TAX_DENOMINATOR;
            taxStruct.token.safeTransfer(taxStruct.addr, taxTokens);
            tokensToSwap -= taxTokens;
        }

        return tokensToSwap;
    }

    function processPostSwapSellTaxes(
      uint256 ethFromSwap,
      address customTaxAddress,
      TaxStruct memory taxStructure
    ) private returns (uint256 _ethToTransfer, uint256 _customTaxSent) {
        _ethToTransfer = ethFromSwap;

        if (!dexExcludedFromTreasury[taxStructure.router]) {
            // take a treasury fee if we are not using the pawswap dex
            uint256 treasuryEth = ethFromSwap * treasuryFee / TAX_DENOMINATOR;
            // leave the eth in the contract for the owner to withdraw later
            _ethToTransfer -= treasuryEth;
        }

        if (taxStructure.nativeTax != 0) {
            // send eth percentage to the tax1 wallet
            uint256 _nativeTax = ethFromSwap * taxStructure.nativeTax / TAX_DENOMINATOR;
            _ethToTransfer -= _nativeTax;
            (bool sent, ) = taxStructure.addr.call{value: _nativeTax}("");
            require(sent, "Failed to send tax eth");
        }

        if (taxStructure.customTax != 0) {
            require(charityRegistry.isApprovedDonationRecipient(customTaxAddress), "Charity not approved");
            // send to the custom tax address
            _customTaxSent = ethFromSwap * taxStructure.customTax / TAX_DENOMINATOR;
            _ethToTransfer -= _customTaxSent;
            (bool sent, ) = customTaxAddress.call{value: _customTaxSent}("");
            require(sent, "Failed to donate");
            emit Donation(
                _msgSender(),
                address(taxStructure.token),
                _customTaxSent,
                customTaxAddress
            );
        }

        return (_ethToTransfer, _customTaxSent);
    }

    function addTokenTax (uint256 amount, TaxStruct memory taxStruct) private pure returns (uint256) {
        uint256 percentageTakenPostSwap = taxStruct.tokenTax;
        uint256 minAmount = amount + (amount * percentageTakenPostSwap / TAX_DENOMINATOR);

        return minAmount;
    }

    function addEthTax (uint256 amount, TaxStruct memory taxStruct) private view returns (uint256) {
        uint256 percentageTaken = taxStruct.nativeTax + taxStruct.customTax;

        if (!dexExcludedFromTreasury[taxStruct.router]) {
            uint256 treasuryTax = amount * treasuryFee / TAX_DENOMINATOR;
            percentageTaken += treasuryTax;
        }

        return amount + (amount * percentageTaken / TAX_DENOMINATOR);
    }

    function swapEthForTokens(
      uint256 ethToSwap,
      uint256 minAmountOut,
      TaxStruct memory taxStruct,
      bool isExactIn
    ) private returns (uint256, uint256) {
        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = uniswapV2Router.WETH();
        path[1] = address(taxStruct.token);

        uint256 initialTokenBalance = taxStruct.token.balanceOf(address(this));
        uint256 dustEth;

        if (isExactIn) {
          // if user specified amount of eth to spend, get as many tokens as possible
          swapExactETHForTokensSupportingFeeOnTransferTokens(
              ethToSwap,
              uniswapV2Router.getAmountsOut(ethToSwap, path)[1],
              path,
              uniswapV2Router
          );
        } else {
          (, dustEth) = swapETHForExactTokens(
              ethToSwap,
              minAmountOut,
              path,
              uniswapV2Router
          );
        }

        return (taxStruct.token.balanceOf(address(this)) - initialTokenBalance, dustEth);
    }

    function swapTokensForEth(
      uint256 tokenAmount,
      uint256 minEthToReceive,
      TaxStruct memory taxStruct,
      bool isExactIn
    ) private returns (uint256) {
        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = address(taxStruct.token);
        path[1] = uniswapV2Router.WETH();
        
        taxStruct.token.approve(address(uniswapV2Router), tokenAmount);

        uint256 initialEthBalance = address(this).balance;
        if (isExactIn) {
          swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokenAmount,
            uniswapV2Router.getAmountsOut(tokenAmount, path)[1],
            path,
            uniswapV2Router
          );
        } else {                        
          uint256 dustTokens = swapTokensForExactETH(
            minEthToReceive,
            tokenAmount,
            path,
            address(this),
            uniswapV2Router
          )[1];
          // refund dust tokens, if any
          if (dustTokens > 0) {
            taxStruct.token.safeTransfer(_msgSender(), dustTokens);
          }
        }

        return address(this).balance - initialEthBalance;
    }

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] memory path,
        IUniswapV2Router02 uniswapV2Router
    ) internal {
        require(path[path.length - 1] == weth, "Pawswap: INVALID_PATH");
        address pair = IUniswapV2Factory(uniswapV2Router.factory()).getPair(path[0],path[1]);
        IERC20(path[0]).transfer(pair, amountIn);
        _swapSupportingFeeOnTransferTokens(path, uniswapV2Router);
        uint amountOut = IERC20(weth).balanceOf(address(this));
        require(amountOut >= amountOutMin, "Pawswap: INSUFFICIENT_OUTPUT_AMT");
        IWETH(weth).withdraw(amountOut);
    }


    function swapETHForExactTokens(
        uint amountIn, 
        uint amountOut, 
        address[] memory path,
        IUniswapV2Router02 uniswapV2Router
    )
        private
        returns (uint[] memory amounts, uint dustEth)
    {
        require(path[0] == weth, "Pawswap: INVALID_PATH");
        amounts = uniswapV2Router.getAmountsIn(amountOut, path);
        require(amounts[0] <= amountIn, "Pawswap: EXCESSIVE_INPUT_AMOUNT");
        IWETH(weth).deposit{value: amounts[0]}();
        address pair = IUniswapV2Factory(uniswapV2Router.factory()).getPair(path[0],path[1]);
        assert(IWETH(weth).transfer(pair, amounts[0]));
        _swap(amounts, path, pair);
        // refund dust eth, if any
        if (amountIn > amounts[0]) {
            dustEth = amountIn - amounts[0];
            (bool sent, ) = _msgSender().call{value: dustEth}("");
            require(sent, "Failed to refund user dust eth");
        }
    }

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] memory path,
        IUniswapV2Router02 uniswapV2Router
    ) private {
        require(path[0] == weth, "Pawswap: INVALID_PATH");
        IWETH(weth).deposit{value: amountIn}();
        address pair = IUniswapV2Factory(uniswapV2Router.factory()).getPair(path[0],path[1]);
        assert(IWETH(weth).transfer(pair, amountIn));
        uint balanceBefore = IERC20(path[path.length - 1]).balanceOf(address(this));
        _swapSupportingFeeOnTransferTokens(path, uniswapV2Router);
        require(
            IERC20(path[path.length - 1]).balanceOf(address(this)) - balanceBefore >= amountOutMin,
            "Pawswap: INSUFFICIENT_OUTPUT_AMT"
        );
    }

    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] memory path, address to, IUniswapV2Router02 uniswapV2Router)
        private
        returns (uint[] memory amounts)
    {
        require(path[path.length - 1] == weth, "Pawswap: INVALID_PATH");
        amounts = uniswapV2Router.getAmountsIn(amountOut, path);
        require(amounts[0] <= amountInMax, "Pawswap: EXCESSIVE_INPUT_AMOUNT");
        address pair = IUniswapV2Factory(uniswapV2Router.factory()).getPair(path[0],path[1]);
        IERC20(path[0]).transfer(pair, amounts[0]);
        _swap(amounts, path, pair);
        IWETH(weth).withdraw(amounts[amounts.length - 1]);
        (bool sent, ) = to.call{value: amounts[amounts.length - 1]}("");
        require(sent, "Failed to send eth to seller");
    }

    // **** SWAP ****
    // requires the initial amount to have already been sent to the first pair
    function _swap(uint[] memory amounts, address[] memory path, address _pair) private {
        (address input, address output) = (path[0], path[1]);
        (address token0,) = sortTokens(input, output);
        uint amountOut = amounts[1];
        (uint amount0Out, uint amount1Out) = input == token0 ? (uint(0), amountOut) : (amountOut, uint(0));
        IUniswapV2Pair(_pair).swap(
            amount0Out, amount1Out, address(this), new bytes(0)
        );
    }

    // **** SWAP (supporting fee-on-transfer tokens) ****
    // requires the initial amount to have already been sent to the first pair
    function _swapSupportingFeeOnTransferTokens(address[] memory path, IUniswapV2Router02 uniswapV2Router) private {
        (address input, address output) = (path[0], path[1]);
        (address token0,) = sortTokens(input, output);
        IUniswapV2Pair pair = IUniswapV2Pair(IUniswapV2Factory(uniswapV2Router.factory()).getPair(input, output));
        uint amountInput;
        uint amountOutput;
        { // scope to avoid stack too deep errors
        (uint reserve0, uint reserve1,) = pair.getReserves();
        (uint reserveInput, uint reserveOutput) = input == token0 ? (reserve0, reserve1) : (reserve1, reserve0);
        amountInput = IERC20(input).balanceOf(address(pair)) - reserveInput;
        amountOutput = uniswapV2Router.getAmountOut(amountInput, reserveInput, reserveOutput);
        }
        (uint amount0Out, uint amount1Out) = input == token0 ? (uint(0), amountOutput) : (amountOutput, uint(0));
        pair.swap(amount0Out, amount1Out, address(this), new bytes(0));
    }

    // returns sorted token addresses, used to handle return values from pairs sorted in this order
    function sortTokens(address tokenA, address tokenB) internal pure returns (address token0, address token1) {
        require(tokenA != tokenB, "Pawswap: IDENTICAL_ADDRESSES");
        (token0, token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);
        require(token0 != address(0), "Pawswap: ZERO_ADDRESS");
    }

    function getTaxStruct(
        address _taxStructureAddress,
        uint256 _customTaxAmount,
        address _account, 
        address _token, 
        bool _isBuy
    ) internal view returns (TaxStruct memory) {
        ITaxStructure taxStructureContract = ITaxStructure(_taxStructureAddress);
        if (_isBuy) {
            return TaxStruct(
                _taxStructureAddress,
                IERC20(_token),
                taxStructureContract.nativeTaxBuyAmount(_account),
                taxStructureContract.tokenTaxBuyAmount(_account),
                _customTaxAmount,
                taxStructureContract.routerAddress()
            );
        } else {
            return TaxStruct(
                _taxStructureAddress,
                IERC20(_token),
                taxStructureContract.nativeTaxSellAmount(_account),
                taxStructureContract.tokenTaxSellAmount(_account),
                _customTaxAmount,
                taxStructureContract.routerAddress()
            );
        }
    }

    function getBuyAmountIn (
        address buyer,
        address tokenAddress,
        uint customTaxAmount,
        uint minTokensToReceive
    ) public view returns (uint256 amountIn) {
        require(tokenTaxContracts[tokenAddress] != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(tokenTaxContracts[tokenAddress], customTaxAmount, buyer, tokenAddress, true);

        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(_taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = uniswapV2Router.WETH();
        path[1] = tokenAddress;

        uint256 [] memory amountsIn = uniswapV2Router.getAmountsIn(
            addTokenTax(minTokensToReceive, _taxStruct),
            path
        );

        return addEthTax(amountsIn[0], _taxStruct);
    }

    function getSellAmountIn (
        address seller,
        address tokenAddress,
        uint customTaxAmount,
        uint minEthToReceive
    ) public view returns (uint256) {
        require(tokenTaxContracts[tokenAddress] != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(tokenTaxContracts[tokenAddress], customTaxAmount, seller, tokenAddress, false);

        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(_taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = tokenAddress;
        path[1] = uniswapV2Router.WETH();

        uint256 [] memory amountsIn = uniswapV2Router.getAmountsIn(
            addEthTax(minEthToReceive, _taxStruct),
            path
        );
        return addTokenTax(amountsIn[0], _taxStruct);
    }

    function getMinimumAmountOutBuy (address _tokenAddress, uint256 _ethAmount, uint256 _customTaxAmount, address _buyer, uint256 _slippage) external view returns (uint256 amountOut) {
        address _taxStructAddr = tokenTaxContracts[_tokenAddress];
        require(address(_taxStructAddr) != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(_taxStructAddr, _customTaxAmount, _buyer, _tokenAddress, true);

        if (!dexExcludedFromTreasury[_taxStruct.router]) {
            _ethAmount -= _ethAmount * treasuryFee / TAX_DENOMINATOR;
        }

        if (_taxStruct.nativeTax != 0) {
            _ethAmount -= _ethAmount * _taxStruct.nativeTax / TAX_DENOMINATOR;
        }

        if (_customTaxAmount != 0) {
            _ethAmount -= _ethAmount * _customTaxAmount / TAX_DENOMINATOR;
        }

        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(_taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = uniswapV2Router.WETH();
        path[1] = _tokenAddress;

        amountOut = uniswapV2Router.getAmountsOut(_ethAmount, path)[1];

        if (_taxStruct.tokenTax != 0) {
            amountOut -= amountOut * _taxStruct.tokenTax / TAX_DENOMINATOR;
        }

        return amountOut - (amountOut * _slippage / TAX_DENOMINATOR);
    }

    function getMinimumAmountOutSell (address _tokenAddress, uint256 _tokenAmount, uint256 _customTaxAmount, address _seller, uint256 _slippage) external view returns (uint256 amountOut) {
        address _taxStructAddr = tokenTaxContracts[_tokenAddress];
        require(address(_taxStructAddr) != address(0), "Token not listed");
        TaxStruct memory _taxStruct = getTaxStruct(_taxStructAddr, _customTaxAmount, _seller, _tokenAddress, false);

        if (_taxStruct.tokenTax != 0) {
            _tokenAmount -= _tokenAmount * _taxStruct.tokenTax / TAX_DENOMINATOR;
        }

        IUniswapV2Router02 uniswapV2Router = IUniswapV2Router02(_taxStruct.router);
        address [] memory path = new address[](2);
        path[0] = _tokenAddress;
        path[1] = uniswapV2Router.WETH();

        amountOut = uniswapV2Router.getAmountsOut(_tokenAmount, path)[1];

        if (!dexExcludedFromTreasury[_taxStruct.router]) {
            amountOut -= amountOut * treasuryFee / TAX_DENOMINATOR;
        }

        if (_taxStruct.nativeTax != 0) {
            amountOut -= amountOut * _taxStruct.nativeTax / TAX_DENOMINATOR;
        }

        if (_customTaxAmount != 0) {
            amountOut -= amountOut * _customTaxAmount / TAX_DENOMINATOR;
        }

        return amountOut - (amountOut * _slippage / TAX_DENOMINATOR);
    }

    function setTokenTaxContract (address _tokenAddress, address _taxStructureContractAddress) external {
        require (!excludedTokens[_tokenAddress], "Token is not allowed to list");
        require (tokenTaxContracts[_tokenAddress] != _taxStructureContractAddress, "Structure already set to this");
        // caller must be the pawswap owner, have the listing role, or be the owner of the listed contract
        require (
            listers[_msgSender()] ||
            OwnableContract(_tokenAddress).owner() == _msgSender() ||
            this.owner() == _msgSender(),
            "Permission denied"
        );
        tokenTaxContracts[_tokenAddress] = _taxStructureContractAddress;
    }

    function setListerAccount (address _address, bool isLister) external onlyOwner {
        listers[_address] = isLister;
    }

    function excludeToken (address _tokenAddress, bool isExcluded) external onlyOwner {
        excludedTokens[_tokenAddress] = isExcluded;
    }

    function setCharityRegistry (address _address) external onlyOwner {
        require (address(charityRegistry) != _address, "Registry already set to this");
        charityRegistry = ICharityRegistry(_address);
    }

    function setPawSwapRouter (address _address) external onlyOwner {
        require (pawSwapRouter != _address, "Router already set to this");
        pawSwapRouter = _address;
    }

    function setTreasuryFee (uint256 _fee) external onlyOwner {
        require (treasuryFee != _fee, "Fee already set to this value");
        require (_fee <= 300, "Fee cannot exceed 3%");
        treasuryFee = _fee;
    }

    function toggleDexExcludedFromTreasuryFee (address _dex, bool _excluded) external onlyOwner {
        dexExcludedFromTreasury[_dex] = _excluded;
    }

    function withdrawEthToOwner (uint256 _amount) external onlyOwner {
        (bool sent, ) = (msg.sender).call{value: _amount}("");
        require(sent, "Failed to send eth to owner");
    }

    function withdrawTokenToOwner(IERC20 token, uint256 amount) external onlyOwner {
        uint256 balance = token.balanceOf(address(this));
        require(balance >= amount, "Insufficient token balance");

        token.safeTransfer(msg.sender, amount);
    }

    receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/src/Pawswap.sol": "Pawswap"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 999999
  },
  "remappings": []
}