// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/Pausable.sol";

interface IMAG is IERC20 {
    function mint(address to, uint256 amount) external;
}

contract MAGTieredStaking is ReentrancyGuard, Ownable, Pausable {
    // State variables
    IMAG public immutable magToken;

    uint256 public constant PERCENTAGE_DENOMINATOR = 10000; // For handling APY percentages (100% = 10000)
    uint256 public totalStaked;

    // Staking tier configuration
    struct StakingTier {
        uint256 lockPeriod; // in days
        uint256 apy; // in basis points (15% = 1500)
    }

    StakingTier[] public stakingTiers;

    // Staking information per user
    struct StakeInfo {
        uint256 amount;
        uint256 stakingStartTime;
        uint256 lockEndTime;
        uint256 apy; // APY for this stake in basis points
        uint256 lastRewardClaimTime;
        bool initialized;
    }

    // User stakes mapping
    mapping(address => StakeInfo) public stakes;

    // Events
    event Staked(
        address indexed user,
        uint256 amount,
        uint256 lockPeriod,
        uint256 apy
    );
    event Unstaked(address indexed user, uint256 amount, uint256 rewards);
    event RewardsClaimed(address indexed user, uint256 amount);
    event StakingTierAdded(uint256 lockPeriod, uint256 apy);
    event StakingTierUpdated(uint256 lockPeriod, uint256 apy);

    constructor(address _magToken, address _owner) Ownable(_owner) Pausable() {
        require(_magToken != address(0), "Invalid token address");
        magToken = IMAG(_magToken);

        // Initialize staking tiers
        stakingTiers.push(StakingTier(30, 1500)); // 15% APY
        stakingTiers.push(StakingTier(60, 2250)); // 22.5% APY
        stakingTiers.push(StakingTier(90, 3000)); // 30% APY
    }

    // View functions
    function getStakingTiers() external view returns (StakingTier[] memory) {
        return stakingTiers;
    }

    function getAPYForLockPeriod(
        uint256 lockPeriod
    ) public view returns (uint256) {
        for (uint256 i = 0; i < stakingTiers.length; i++) {
            if (stakingTiers[i].lockPeriod == lockPeriod) {
                return stakingTiers[i].apy;
            }
        }
        revert("Invalid lock period");
    }

    function calculateRewards(address user) public view returns (uint256) {
        StakeInfo storage stakeInfo = stakes[user];
        if (!stakeInfo.initialized || stakeInfo.amount == 0) return 0;

        uint256 timeElapsed = block.timestamp - stakeInfo.lastRewardClaimTime;

        // Calculate rewards: (amount * APY * timeElapsed) / (365 days * PERCENTAGE_DENOMINATOR)
        return
            (stakeInfo.amount * stakeInfo.apy * timeElapsed) /
            (365 days * PERCENTAGE_DENOMINATOR);
    }

    // Core functions
    function stake(
        uint256 amount,
        uint256 lockPeriodInDays
    ) external nonReentrant whenNotPaused {
        require(amount > 0, "Cannot stake 0 tokens");
        require(
            !stakes[msg.sender].initialized || stakes[msg.sender].amount == 0,
            "Existing stake found"
        );

        // Get APY for lock period
        uint256 apy = getAPYForLockPeriod(lockPeriodInDays);

        // Calculate lock end time
        uint256 lockEndTime = block.timestamp + (lockPeriodInDays * 1 days);

        // Transfer tokens from user
        require(
            magToken.transferFrom(msg.sender, address(this), amount),
            "Transfer failed"
        );

        // Update stake info
        stakes[msg.sender] = StakeInfo({
            amount: amount,
            stakingStartTime: block.timestamp,
            lockEndTime: lockEndTime,
            apy: apy,
            lastRewardClaimTime: block.timestamp,
            initialized: true
        });

        totalStaked += amount;
        emit Staked(msg.sender, amount, lockPeriodInDays, apy);
    }

    function unstake() external nonReentrant {
        StakeInfo storage stakeInfo = stakes[msg.sender];
        require(
            stakeInfo.initialized && stakeInfo.amount > 0,
            "No stake found"
        );
        require(
            block.timestamp >= stakeInfo.lockEndTime,
            "Stake is still locked"
        );

        uint256 amount = stakeInfo.amount;
        uint256 rewards = calculateRewards(msg.sender);

        // Reset stake info
        delete stakes[msg.sender];
        totalStaked -= amount;

        // Transfer tokens and rewards
        require(magToken.transfer(msg.sender, amount), "Transfer failed");
        if (rewards > 0) {
            require(
                magToken.transfer(msg.sender, rewards),
                "Rewards transfer failed"
            );
        }

        emit Unstaked(msg.sender, amount, rewards);
    }

    function claimRewards() external nonReentrant whenNotPaused {
        StakeInfo storage stakeInfo = stakes[msg.sender];
        require(
            stakeInfo.initialized && stakeInfo.amount > 0,
            "No stake found"
        );

        uint256 rewards = calculateRewards(msg.sender);
        require(rewards > 0, "No rewards to claim");

        // Update last claim time
        stakeInfo.lastRewardClaimTime = block.timestamp;

        // Transfer rewards
        require(
            magToken.transfer(msg.sender, rewards),
            "Rewards transfer failed"
        );

        emit RewardsClaimed(msg.sender, rewards);
    }

    // Emergency functions
    function emergencyWithdraw() external nonReentrant {
        StakeInfo storage stakeInfo = stakes[msg.sender];
        require(
            stakeInfo.initialized && stakeInfo.amount > 0,
            "No stake found"
        );

        uint256 amount = stakeInfo.amount;

        // Reset stake info
        delete stakes[msg.sender];
        totalStaked -= amount;

        // Only return principal, no rewards
        require(magToken.transfer(msg.sender, amount), "Transfer failed");

        emit Unstaked(msg.sender, amount, 0);
    }

    // Admin functions
    function addStakingTier(
        uint256 lockPeriod,
        uint256 apy
    ) external onlyOwner {
        require(lockPeriod > 0, "Invalid lock period");
        require(apy > 0 && apy <= 3000, "Invalid APY"); // Max 30% APY

        for (uint256 i = 0; i < stakingTiers.length; i++) {
            require(
                stakingTiers[i].lockPeriod != lockPeriod,
                "Lock period already exists"
            );
        }

        stakingTiers.push(StakingTier(lockPeriod, apy));
        emit StakingTierAdded(lockPeriod, apy);
    }

    function updateStakingTier(uint256 index, uint256 apy) external onlyOwner {
        require(index < stakingTiers.length, "Invalid tier index");
        require(apy > 0 && apy <= 3000, "Invalid APY"); // Max 30% APY

        stakingTiers[index].apy = apy;
        emit StakingTierUpdated(stakingTiers[index].lockPeriod, apy);
    }

    function pause() external onlyOwner {
        _pause();
    }

    function unpause() external onlyOwner {
        _unpause();
    }

    // In case tokens get stuck
    function recoverERC20(
        address tokenAddress,
        uint256 tokenAmount
    ) external onlyOwner {
        require(
            tokenAddress != address(magToken),
            "Cannot recover staking token"
        );
        IERC20(tokenAddress).transfer(owner(), tokenAmount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

{
  "compilationTarget": {
    "MagTieredStaking.sol": "MAGTieredStaking"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}