Anchor Neural World Token

pragma solidity ^0.5.0;

import "./Context.sol";
import "./TokenRecover.sol";
import "./ERC20.sol";
import "./ERC20Detailed.sol";
import "./ERC20Burnable.sol";
import "./ERC20Pausable.sol";
import "./ERC20VotingMintable.sol";

contract ANWToken is Context, TokenRecover, ERC20, ERC20Detailed, ERC20Burnable, ERC20VotingMintable, ERC20Pausable{
    
    string private _issuingCountry = "Hongkong";
    string private _issuingCompany = "Huimin World Holdings Limited";
    uint256 private _initialSupply = 1000000000;
    
    constructor () public ERC20Detailed
    ( "Anchor Neural World Token", "ANW", 18 ) 
    { _mint(_msgSender(), _initialSupply * (10 ** uint256(decimals()))); }
    
    function issuingCountry() public view returns ( string memory ){
        return _issuingCountry;
    }
    
    function issuingCompany() public view returns ( string memory ){
        return _issuingCompany;
    }

    function initialSupply() public view returns ( uint256 ){
        return _initialSupply;
    }
    
}

pragma solidity ^0.5.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
contract Context {
    // Empty internal constructor, to prevent people from mistakenly deploying
    // an instance of this contract, which should be used via inheritance.
    constructor () internal { }
    // solhint-disable-previous-line no-empty-blocks

    function _msgSender() internal view returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

pragma solidity ^0.5.0;

import "./Context.sol";
import "./IERC20.sol";
import "./SafeMath.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for `sender`'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: mint to the zero address");

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: burn from the zero address");

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`.`amount` is then deducted
     * from the caller's allowance.
     *
     * See {_burn} and {_approve}.
     */
    function _burnFrom(address account, uint256 amount) internal {
        _burn(account, amount);
        _approve(account, _msgSender(), _allowances[account][_msgSender()].sub(amount, "ERC20: burn amount exceeds allowance"));
    }
}

pragma solidity ^0.5.0;

import "./Context.sol";
import "./ERC20.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public returns (bool) {
        _burn(_msgSender(), amount);
        return true;
    }

    /**
     * @dev See {ERC20-_burnFrom}.
     */
    function burnFrom(address account, uint256 amount) public returns (bool) {
        _burnFrom(account, amount);
        return true;
    }
}

pragma solidity ^0.5.0;

import "./IERC20.sol";

/**
 * @dev Optional functions from the ERC20 standard.
 */
contract ERC20Detailed is IERC20 {
    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for `name`, `symbol`, and `decimals`. All three of
     * these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol, uint8 decimals) public {
        _name = name;
        _symbol = symbol;
        _decimals = decimals;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }
}

pragma solidity ^0.5.0;

import "./ERC20.sol";
import "./ERC20Burnable.sol";
import "./ERC20VotingMintable.sol";
import "./Pausable.sol";

/**
 * @title Pausable token
 * @dev ERC20 with pausable transfers and allowances.
 *
 * Useful if you want to stop trades until the end of a crowdsale, or have
 * an emergency switch for freezing all token transfers in the event of a large
 * bug.
 */
contract ERC20Pausable is ERC20, ERC20Burnable, ERC20VotingMintable, Pausable {
    function transfer(address to, uint256 value) public whenNotPaused returns (bool) {
        return super.transfer(to, value);
    }

    function transferFrom(address from, address to, uint256 value) public whenNotPaused returns (bool) {
        return super.transferFrom(from, to, value);
    }

    function approve(address spender, uint256 value) public whenNotPaused returns (bool) {
        return super.approve(spender, value);
    }

    function increaseAllowance(address spender, uint256 addedValue) public whenNotPaused returns (bool) {
        return super.increaseAllowance(spender, addedValue);
    }

    function decreaseAllowance(address spender, uint256 subtractedValue) public whenNotPaused returns (bool) {
        return super.decreaseAllowance(spender, subtractedValue);
    }

    function burn(uint256 amount) public whenNotPaused returns (bool) {
        return super.burn(amount);
    }

    function burnFrom(address account, uint256 amount) public whenNotPaused returns (bool) {
        return super.burnFrom(account, amount);
    }

    function mintProposal(uint256 amount, uint256 duration) public whenNotPaused returns (bool) {
        return super.mintProposal(amount, duration);
    }

    
}

pragma solidity ^0.5.0;

import "./ERC20.sol";
import "./MinterRole.sol";
import "./SafeMath.sol";

contract ERC20VotingMintable is Context, ERC20, MinterRole {
    using SafeMath for uint256;
    
    event Voted(address indexed voter, uint proposalId, bool vote, uint256 amount);
    event MintProposal(uint256 indexed proposalId, address proposalAddress, uint256 amount, uint256 endTime);
    event ReleaseProposal(uint256 indexed proposalId, address proposalAddress, uint256  amount, bool isSuccess);
    event Retrieved(uint256 indexed proposalId, uint256 amount);

    struct Proposal{
        bool _isActive;
        address _proposalAddress;
        uint256 _mintAmount;
        uint256 _votingEnds;
        uint256 _agree;
        uint256 _disagree;   
    }

    struct Vote{
        bool _vote;
        uint256 _amount;
        bool _retrieved;
    }

    mapping (address => mapping(uint256 => Vote)) private _votes;

    mapping (address => uint256) private _retrieveFrom;
    
    uint256 private _proposalId = 0;
    Proposal[] private _proposalList;
    
    function mintProposal(uint256 amount, uint256 duration) public onlyMinter returns (bool) {
        
        if( _proposalList.length == 0 ){
            _proposalList.push( Proposal(false, address(0), 0, 0, 0, 0) );
        }

        require(!_proposalList[_proposalId]._isActive, "mintProposal: proposal already in progress");
        require(amount > 0, "mintProposal: amount is zero" );
        require(duration >= 1800, "mintProposal: duration is less than 30 min");

        _proposalList[_proposalId]._isActive = true;
        _proposalList[_proposalId]._proposalAddress = _msgSender();
        _proposalList[_proposalId]._mintAmount = amount;
        _proposalList[_proposalId]._votingEnds =  duration.add(block.timestamp);
        
        emit MintProposal(_proposalId, _proposalList[_proposalId]._proposalAddress, _proposalList[_proposalId]._mintAmount, _proposalList[_proposalId]._votingEnds);

        return true;
    }
    
    function voting(bool vote, uint256 amount) public returns (bool) {
        
        if (_proposalList.length == 0) { // minting Proposal array is empty
            revert("voting: proposal not active");
        } else {
            require(_proposalList[_proposalId]._isActive, "voting: proposal not active" );
        }
        
        if(_votes[_msgSender()][_proposalId]._amount == 0) { // if voter hasn't voted, or reduced vote to zero previously
            require(amount > 0, "voting: vote amount is zero" );
        }
        require(_proposalList[_proposalId]._votingEnds > block.timestamp, "voting: voting period has closed");
        require(balanceOf(_msgSender()) >= amount, "voting: vote amount cannot exceed token balance");
        
        // adjust the proposal voting balances
        if (_votes[_msgSender()][_proposalId]._vote != vote && vote == true) { // voter switched thier vote from disagree to agree
            // subtract from disagree and add to agree
            _proposalList[_proposalId]._disagree = _proposalList[_proposalId]._disagree.sub(_votes[_msgSender()][_proposalId]._amount);
            _proposalList[_proposalId]._agree = _proposalList[_proposalId]._agree.add(amount);
        } else if (_votes[_msgSender()][_proposalId]._vote != vote && vote == false){ // voter switched their vote form agree to disagree
            // subtract from agree and add to disagree
            _proposalList[_proposalId]._agree = _proposalList[_proposalId]._agree.sub(_votes[_msgSender()][_proposalId]._amount);
            _proposalList[_proposalId]._disagree = _proposalList[_proposalId]._disagree.add(amount);
        } else if ( vote == true) { // voter reinforced their agree vote
            // add to agree
            _proposalList[_proposalId]._agree = _proposalList[_proposalId]._agree.sub(_votes[_msgSender()][_proposalId]._amount).add(amount);
        } else { // voter reinforced their disagree vote
            // add to disagree
            _proposalList[_proposalId]._disagree = _proposalList[_proposalId]._disagree.sub(_votes[_msgSender()][_proposalId]._amount).add(amount);
        }
        // update 
        _votes[_msgSender()][_proposalId]._vote = vote;

        uint256 oldAmount = _votes[_msgSender()][_proposalId]._amount;

        // assign the new vote amount to this Vote
        _votes[_msgSender()][_proposalId]._amount = amount;


        if(oldAmount > amount) { // refund excess token if vote amount reduced
            _transfer(address(this), _msgSender(), oldAmount.sub(amount));    
        } else { // lock new tokens if vote amount increased
            _transfer(_msgSender(), address(this), amount.sub(oldAmount));  
        }

        emit Voted(_msgSender(), _proposalId, vote,  amount);

        return true;
    }
    
    function releaseProposal() public returns (bool) {
        if (_proposalList.length == 0) {
            revert("releaseProposal: proposal not active");
        } else {
            require(_proposalList[_proposalId]._isActive, "releaseProposal: proposal not active" );
        }
        //require(_proposalList[_proposalId]._isActive, "releaseProposal: proposal not active");
        require( _proposalList[_proposalId]._votingEnds < block.timestamp, "releaseProposal: voting period has not ended");

        _proposalList[_proposalId]._isActive = false; // deactivate proposal
        _proposalList.push(Proposal(false, address(0), 0, 0, 0, 0) );

        uint256 proposalId = _proposalId;
        
        _proposalId = _proposalId.add(1); // increase proposalId for next proposal

        bool success = _proposalList[proposalId]._agree > _proposalList[proposalId]._disagree;
        // check if anyone voted and if agree total is grater than disagree total
        if(_proposalList[proposalId]._agree > 0 && success) {
            _mint( _proposalList[proposalId]._proposalAddress, _proposalList[proposalId]._mintAmount );
        }

        emit ReleaseProposal(proposalId, _proposalList[proposalId]._proposalAddress, _proposalList[proposalId]._mintAmount, success);
        
        return true;
    }

    function retrieve(uint proposalId) public {
        require(_proposalList[proposalId]._votingEnds < block.timestamp, "retrieve: voting period has not ended");

        if (_votes[_msgSender()][proposalId]._retrieved || _votes[_msgSender()][proposalId]._amount == 0) {
            return;
        }

        _votes[_msgSender()][proposalId]._retrieved = true;

        _transfer(address(this), _msgSender(), _votes[_msgSender()][proposalId]._amount);          

       emit Retrieved(proposalId, _votes[_msgSender()][proposalId]._amount);

    }

    function retrieveAll() public {

        for (uint i = _retrieveFrom[_msgSender()]; i < currentProposalID(); i++) {
            retrieve(i);
            _retrieveFrom[_msgSender()] = i;
        }

    }

    function getVote(address voter, uint256 proposalId) public view returns( bool vote, uint256 amount, bool retrieved) {
        
        vote = _votes[voter][proposalId]._vote ;
        amount = _votes[voter][proposalId]._amount;
        retrieved = _votes[voter][proposalId]._retrieved;

        return ( vote, amount, retrieved);
    }
    
    function getProposal(uint256 proposalId) public view returns( bool isActive, string memory state, address proposalAddress, uint256 mintAmount, uint256 endTime, uint256 remainingTime, uint256 agree, uint256 disagree, bool isSuccess){
        if (_proposalList.length > 0) {
            Proposal memory proposal = _proposalList[proposalId];

            uint256 remaining;
            if (proposal._votingEnds > block.timestamp) {
                remaining = proposal._votingEnds.sub(block.timestamp);
            } else {
                remaining = 0;
            }

            string memory _state = ( proposal._isActive && proposal._votingEnds > block.timestamp ) ? "voting" : "closed";
            return ( proposal._isActive, _state , proposal._proposalAddress, proposal._mintAmount, proposal._votingEnds, remaining, proposal._agree, proposal._disagree, proposal._agree > proposal._disagree);
        } else {
            return (false, "closed", address(0), 0, 0, 0, 0, 0, false);
        }
    }
    
    function currentProposal() public view returns (bool isActive, string memory state ,address proposalAddress, uint256 mintAmount, uint256 endTime, uint256 remainingTime, uint256 agree, uint256 disagree, bool isSuccess) {
        return getProposal(currentProposalID());
    }

    function currentProposalID() public view returns (uint256 proposalId){
        return _proposalId;
    }
    
}

pragma solidity ^0.5.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP. Does not include
 * the optional functions; to access them see {ERC20Detailed}.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

  
pragma solidity ^0.5.0;

import "./Context.sol";
import "./Roles.sol";

contract MinterRole is Context {
    using Roles for Roles.Role;

    event MinterAdded(address indexed account);
    event MinterRemoved(address indexed account);

    Roles.Role private _minters;

    constructor () internal {
        _addMinter(_msgSender());
    }

    modifier onlyMinter() {
        require(isMinter(_msgSender()), "MinterRole: caller does not have the Minter role");
        _;
    }

    function isMinter(address account) public view returns (bool) {
        return _minters.has(account);
    }

    function addMinter(address account) public onlyMinter {
        _addMinter(account);
    }

    function renounceMinter() public {
        _removeMinter(_msgSender());
    }

    function _addMinter(address account) internal {
        _minters.add(account);
        emit MinterAdded(account);
    }

    function _removeMinter(address account) internal {
        _minters.remove(account);
        emit MinterRemoved(account);
    }
}

pragma solidity ^0.5.0;

import "./Context.sol";
import "./PauserRole.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
contract Pausable is Context, PauserRole {
    /**
     * @dev Emitted when the pause is triggered by a pauser (`account`).
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by a pauser (`account`).
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state. Assigns the Pauser role
     * to the deployer.
     */
    constructor () internal {
        _paused = false;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view returns (bool) {
        return _paused;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     */
    modifier whenNotPaused() {
        require(!_paused, "Pausable: paused");
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     */
    modifier whenPaused() {
        require(_paused, "Pausable: not paused");
        _;
    }

    /**
     * @dev Called by a pauser to pause, triggers stopped state.
     */
    function pause() public onlyPauser whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Called by a pauser to unpause, returns to normal state.
     */
    function unpause() public onlyPauser whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

  
pragma solidity ^0.5.0;

import "./Context.sol";
import "./Roles.sol";

contract PauserRole is Context {
    using Roles for Roles.Role;

    event PauserAdded(address indexed account);
    event PauserRemoved(address indexed account);

    Roles.Role private _pausers;

    constructor () internal {
        _addPauser(_msgSender());
    }

    modifier onlyPauser() {
        require(isPauser(_msgSender()), "PauserRole: caller does not have the Pauser role");
        _;
    }

    function isPauser(address account) public view returns (bool) {
        return _pausers.has(account);
    }

    function addPauser(address account) public onlyPauser {
        _addPauser(account);
    }

    function renouncePauser() public {
        _removePauser(_msgSender());
    }

    function _addPauser(address account) internal {
        _pausers.add(account);
        emit PauserAdded(account);
    }

    function _removePauser(address account) internal {
        _pausers.remove(account);
        emit PauserRemoved(account);
    }
}

pragma solidity ^0.5.0;

import "./Context.sol";
import "./Roles.sol";

contract RecoverRole is Context {
    using Roles for Roles.Role;

    event RecovererAdded(address indexed account);
    event RecovererRemoved(address indexed account);

    Roles.Role private _recoverers;

    constructor () internal {
        _addRecoverer(_msgSender());
    }

    modifier onlyRecoverer() {
        require(isRecoverer(_msgSender()), "RecovererRole: caller does not have the Recoverer role");
        _;
    }

    function isRecoverer(address account) public view returns (bool) {
        return _recoverers.has(account);
    }

    function addRecoverer(address account) public onlyRecoverer {
        _addRecoverer(account);
    }

    function renounceRecoverer() public {
        _removeRecoverer(_msgSender());
    }

    function _addRecoverer(address account) internal {
        _recoverers.add(account);
        emit RecovererAdded(account);
    }

    function _removeRecoverer(address account) internal {
        _recoverers.remove(account);
        emit RecovererRemoved(account);
    }
}

pragma solidity ^0.5.0;

/**
 * @title Roles
 * @dev Library for managing addresses assigned to a Role.
 */
library Roles {
    struct Role {
        mapping (address => bool) bearer;
        uint256 numberOfBearers;
    }

    /**
     * @dev Give an account access to this role.
     */
    function add(Role storage role, address account) internal {
        require(!has(role, account), "Roles: account already has role");
        role.bearer[account] = true;
        role.numberOfBearers += 1;
    }

    /**
     * @dev Remove an account's access to this role.
     */
    function remove(Role storage role, address account) internal {
        require(has(role, account), "Roles: account does not have role");
        uint256 numberOfBearers = role.numberOfBearers -= 1; // there is always at least one account added in constructor, so this cannot overflow below zero
        require(atLeastOneBearer(numberOfBearers), "Roles: there must be at least one account assigned to this role");
        
        role.bearer[account] = false;
    }

    /**
     * @dev Check if an account has this role.
     * @return bool
     */
    function has(Role storage role, address account) internal view returns (bool) {
        require(account != address(0), "Roles: account is the zero address");
        return role.bearer[account];
    }

    /**
     * @dev Check if this role has at least one account assigned to it.
     * @return bool
     */
    function atLeastOneBearer(uint256 numberOfBearers) internal pure returns (bool) {
        if (numberOfBearers > 0) {
            return true;
        } else {
            return false;
        }
    }
}

pragma solidity ^0.5.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     *
     * _Available since v2.4.0._
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

pragma solidity ^0.5.0;

import "./IERC20.sol";
import "./Context.sol";
import "./RecoverRole.sol";

contract TokenRecover is Context, RecoverRole {

    /**
     * @dev Remember that only owner can call so be careful when use on contracts generated from other contracts.
     * @param tokenAddress The token contract address
     * @param tokenAmount Number of tokens to be sent
     */
    function recoverERC20(address tokenAddress, uint256 tokenAmount) public onlyRecoverer {
        IERC20(tokenAddress).transfer(_msgSender(), tokenAmount);
    }
}

{
  "compilationTarget": {
    "ANWToken.sol": "ANWToken"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}