// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "./Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        } else if (error == RecoverError.InvalidSignatureV) {
            revert("ECDSA: invalid signature 'v' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        // Check the signature length
        // - case 65: r,s,v signature (standard)
        // - case 64: r,vs signature (cf https://eips.ethereum.org/EIPS/eip-2098) _Available since v4.1._
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else if (signature.length == 64) {
            bytes32 r;
            bytes32 vs;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            assembly {
                r := mload(add(signature, 0x20))
                vs := mload(add(signature, 0x40))
            }
            return tryRecover(hash, r, vs);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }
        if (v != 27 && v != 28) {
            return (address(0), RecoverError.InvalidSignatureV);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", hash));
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x01", domainSeparator, structHash));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: UNLICENSED

// ███████╗███╗   ██╗███████╗ █████╗ ██╗  ██╗██╗   ██╗     ██████╗  ██████╗ ██████╗ ██╗     ██╗███╗   ██╗███████╗
// ██╔════╝████╗  ██║██╔════╝██╔══██╗██║ ██╔╝╚██╗ ██╔╝    ██╔════╝ ██╔═══██╗██╔══██╗██║     ██║████╗  ██║██╔════╝
// ███████╗██╔██╗ ██║█████╗  ███████║█████╔╝  ╚████╔╝     ██║  ███╗██║   ██║██████╔╝██║     ██║██╔██╗ ██║███████╗
// ╚════██║██║╚██╗██║██╔══╝  ██╔══██║██╔═██╗   ╚██╔╝      ██║   ██║██║   ██║██╔══██╗██║     ██║██║╚██╗██║╚════██║
// ███████║██║ ╚████║███████╗██║  ██║██║  ██╗   ██║       ╚██████╔╝╚██████╔╝██████╔╝███████╗██║██║ ╚████║███████║
// ╚══════╝╚═╝  ╚═══╝╚══════╝╚═╝  ╚═╝╚═╝  ╚═╝   ╚═╝        ╚═════╝  ╚═════╝ ╚═════╝ ╚══════╝╚═╝╚═╝  ╚═══╝╚══════╝

pragma solidity 0.8.13;

// Imports
import "./Ownable.sol";
import "./IERC721.sol";
import "./IERC20.sol";
import "./ECDSA.sol";
import "./ReentrancyGuard.sol";

/**
 * @title The staking smart contract.
 */
contract NFTStaking is Ownable, ReentrancyGuard {
  /// @notice The staker details.
  struct Staker {
    uint256 claimedRewards;
    uint256 lastCheckpoint;
    uint256[] stakedToken1;
    uint256[] stakedToken2;
    uint256[] stakedBoosters;
  }
  // @notice The available contract types.
  enum ContractTypes {
    Token1,
    Token2,
    Booster
  }
  /// @notice The number of seconds in a day.
  uint256 public constant SECONDS_IN_DAY = 24 * 60 * 60;
  /// @notice The flag that indicates if staking is launched.
  bool public stakingLaunched;
  /// @notice The flag that indicates if deposit is paused.
  bool public depositPaused;
  /// @notice The addresses of the token contracts.
  address[3] public tokenAddresses;
  /// @notice The flag indicates if the categories have been seeded.
  bool[3] public tokenTypeSeeded;
  /// @notice The index of the first NFT smart contract.
  uint256 private constant TOKEN1 = 0;
  /// @notice The index of the second NFT smart contract.
  uint256 private constant TOKEN2 = 1;
  /// @notice The index of the booster NFT smart contract.
  uint256 private constant BOOSTER = 2;
  /// @notice The number of types of tokens available.
  uint256 constant private NUMBER_OF_TOKEN_TYPES = 3;
  /// @notice The max number of token categories.
  uint256 constant private MAX_NUMBER_OF_CATEGORIES_PER_TOKEN_TYPE = 5;
  /// @notice The numbers of categories of each token type.
  uint256[NUMBER_OF_TOKEN_TYPES] public numberOfCategoryPerType = [5, 5, 3];
  /// @notice The yields for categories per token types.
  uint256[MAX_NUMBER_OF_CATEGORIES_PER_TOKEN_TYPE][NUMBER_OF_TOKEN_TYPES] public yieldsPerCategoryPerTokenType;
  /// @notice The categories of the first NFT smart contract tokens.
  bytes private _token1Categories;
  /// @notice The categories of the second NFT smart contract tokens.
  bytes private _token2Categories;
  /// @notice The categories of the booster NFT smart contract tokens.
  bytes private _boosterCategories;
  /// @notice The mapping of stakers.
  mapping(address => Staker) public stakers;
  /// @notice The mapping of token owners.
  mapping(uint256 => mapping(uint256 => address)) private _ownerOfToken;
  /// @notice The stake event.
  event Deposit(address indexed staker, address nftContract, uint256 tokensAmount);
  /// @notice The unstake event.
  event Withdraw(address indexed staker, address nftContract, uint256 tokensAmount);
  /// @notice The event fires during emergency funds withdrawal process.
  event WithdrawStuckERC721(address indexed receiver, address indexed tokenAddress, uint256 indexed tokenId);

  /**
   * @notice The smart contract constructor that initializes the contract.
   * @param _token1 The address of the first NFT smart contract.
   */
  constructor(
  // declare a base NFT contract for staking
    address _token1
  ) {
    // Set the variables.
    tokenAddresses[TOKEN1] = _token1;
    yieldsPerCategoryPerTokenType[0][0] = 100 ether;
    yieldsPerCategoryPerTokenType[0][1] = 120 ether;
    yieldsPerCategoryPerTokenType[0][2] = 140 ether;
    yieldsPerCategoryPerTokenType[0][3] = 150 ether;
    yieldsPerCategoryPerTokenType[0][4] = 200 ether;
  }

  /*
   * @notice Sets the addresses of the NFT collections.
   * @param token1 The address of the first collection.
   * @param token2 The address of the second collection.
   * @param booster The address of the booster collection.
   */
  function setTokenAddresses(address token1, address token2, address booster) external onlyOwner {
    tokenAddresses[TOKEN1] = token1;
    tokenAddresses[TOKEN2] = token2;
    tokenAddresses[BOOSTER] = booster;
  }

  /*
   * @notice Sets the categories of a specific collection.
   * @param contractType The type of the collection.
   * @param categoryInBytes The categories as an array of bytes.
   */
  function setCategoriesBatch(ContractTypes contractType, bytes calldata categoryInBytes) external onlyOwner {
    tokenTypeSeeded[uint(contractType)] = true;
    if (contractType == ContractTypes.Token1) {
      _token1Categories = categoryInBytes;
    } else if (contractType == ContractTypes.Token2) {
      _token2Categories = categoryInBytes;
    } else if (contractType == ContractTypes.Booster) {
      _boosterCategories = categoryInBytes;
    }
  }

  /*
   * @notice Sets the yields of a specific collection category.
   * @param contractType The type of the collection.
   * @param category The category.
   * @param yield The yield value.
   */
  function setCategoryYield(
    ContractTypes contractType,
    uint8 category,
    uint256 yield
  ) external onlyOwner {
    require(category <= numberOfCategoryPerType[uint(contractType)], "Invalid category number");
    yieldsPerCategoryPerTokenType[uint(contractType)][category] = yield;
  }

  /*
   * @notice Sets the yields of collection categories.
   * @param contractType The type of the collection.
   * @param category The category.
   * @param yields The yield values.
   */
  function setCategoryYieldsBatch(ContractTypes contractType, uint256[] memory yields) external onlyOwner {
    require(yields.length == numberOfCategoryPerType[uint(contractType)], "Length not match");
    for (uint256 i; i < yields.length; i++) {
      yieldsPerCategoryPerTokenType[uint(contractType)][i] = yields[i];
    }
  }
  
  /*
   * @notice Returns the categories of the tokens.
   * @param contractType The type of the collection.
   * @param tokenIds The IDs of the tokens to get categories of.
   * @return The categories of the provided tokens.
   */
  function getCategoriesOfTokens(ContractTypes contractType, uint256[] memory tokenIds) external view returns (uint8[] memory) {
    uint8[] memory categories = new uint8[](tokenIds.length);
    for (uint256 i; i < tokenIds.length; i++) {
      categories[i] = getCategoryOfToken(contractType, tokenIds[i]);
    }
    return categories;
  }

  /*
   * @notice Stakes the NFTs.
   * @param contractType The type of the collection.
   * @param tokenIds The IDs of the tokens to stake.
   */
  function deposit(ContractTypes contractType, uint256[] memory tokenIds) external nonReentrant {
    require(uint(contractType) < tokenAddresses.length, "Not a valid contract");
    require(!depositPaused, "Deposit paused");
    require(stakingLaunched, "Staking is disabled");
    require(tokenIds.length > 0, "No token Ids specified");
    address tokenAddress = tokenAddresses[uint(contractType)];

    _claimRewards(_msgSender());

    Staker storage user = stakers[_msgSender()];

    if (contractType == ContractTypes.Booster) {
      // If a user tries to stake a Booster but does not have any Collection1 NFTs staked, the stake is prohibited
      require(user.stakedBoosters.length + tokenIds.length <= user.stakedToken1.length * 2, "Maximum num of boosters reached");
    }

    for (uint256 i; i < tokenIds.length; i++) {
      require(IERC721(tokenAddress).ownerOf(tokenIds[i]) == _msgSender(), "Not the owner");
      IERC721(tokenAddress).safeTransferFrom(_msgSender(), address(this), tokenIds[i]);
      _ownerOfToken[uint(contractType)][tokenIds[i]] = _msgSender();

      if (contractType == ContractTypes.Token1) {
        user.stakedToken1.push(tokenIds[i]);
      } else if (contractType == ContractTypes.Token2) {
        user.stakedToken2.push(tokenIds[i]);
      } else if (contractType == ContractTypes.Booster) {
        user.stakedBoosters.push(tokenIds[i]);
      }
    }
    emit Deposit(_msgSender(), tokenAddress, tokenIds.length);
  }

  /*
   * @notice Unstakes the NFTs.
   * @param contractType The type of the collection.
   * @param tokenIds The IDs of the tokens to unstake.
   */
  function withdraw(ContractTypes contractType, uint256[] memory tokenIds) external nonReentrant {
    require(uint(contractType) < tokenAddresses.length, "Not a valid contract");
    require(tokenIds.length > 0, "No token Ids specified");
    address tokenAddress = tokenAddresses[uint(contractType)];

    _claimRewards(_msgSender());

    Staker storage user = stakers[_msgSender()];

    for (uint256 i; i < tokenIds.length; i++) {
      uint256 tokenId = tokenIds[i];
      require(IERC721(tokenAddress).ownerOf(tokenId) == address(this), "Invalid tokenIds provided");
      require(_ownerOfToken[uint(contractType)][tokenId] == _msgSender(), "Not token owner");
      _ownerOfToken[uint(contractType)][tokenId] = address(0);

      if (contractType == ContractTypes.Token1) {
        user.stakedToken1 = _moveTokenToLast(user.stakedToken1, tokenId);
        user.stakedToken1.pop();
      } else if (contractType == ContractTypes.Token2) {
        user.stakedToken2 = _moveTokenToLast(user.stakedToken2, tokenId);
        user.stakedToken2.pop();
      } else if (contractType == ContractTypes.Booster) {
        user.stakedBoosters = _moveTokenToLast(user.stakedBoosters, tokenId);
        user.stakedBoosters.pop();
      }

      IERC721(tokenAddress).safeTransferFrom(address(this), _msgSender(), tokenId);
    }

    emit Withdraw(_msgSender(), tokenAddress, tokenIds.length);
  }

  /*
   * @notice Calculates the total reward of a staker.
   * @param staker The address of the staker.
   * @return The total reward of the staker.
   */
  function getTotalRewards(address staker) external view returns (uint256) {
    return stakers[staker].claimedRewards + getUnclaimedRewards(staker);
  }

  /*
   * @notice Gets yields of tokens of a specific collection.
   * @param contractType The type of the collection.
   * @param tokenIds The IDs of the tokens to get the yields of.
   * @return The yields of the tokens provided.
   */
  function getYieldsForTokens(ContractTypes contractType, uint256[] memory tokenIds) external view returns (uint256[] memory) {
    uint256[] memory yields = new uint256[](tokenIds.length);
    for (uint256 i; i < tokenIds.length; i++) {
      yields[i] = getTokenYield(contractType, tokenIds[i]);
    }
    return yields;
  }

  /*
   * @notice Gets called whenever an IERC721 tokenId token is transferred to this contract via IERC721.safeTransferFrom.
   */
  function onERC721Received(
    address,
    address,
    uint256,
    bytes calldata
  ) external pure returns (bytes4) {
    return bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"));
  }

  /**
   * @notice Pauses the deposit process.
   * @param _pause The deposit state value.
   */
  function pauseDeposit(bool _pause) public onlyOwner {
    depositPaused = _pause;
  }

  /**
   * @notice Launches staking.
   */
  function launchStaking() public onlyOwner {
    require(!stakingLaunched, "Staking was enabled");
    stakingLaunched = true;
  }

  /**
   * @notice Allows the owner to withdraw ERC721 in case of an emergency.
   * @param contractType The type of the collection.
   * @param tokenIds The IDs of the tokens to withdraw.
   */
  function emergencyWithdraw(ContractTypes contractType, uint256[] memory tokenIds) public onlyOwner {
    require(tokenIds.length <= 50, "50 is max per tx");
    require(uint(contractType) < tokenAddresses.length, "Not a valid contract");
    address tokenAddress = tokenAddresses[uint(contractType)];
    pauseDeposit(true);
    for (uint256 i; i < tokenIds.length; i++) {
      address receiver = _ownerOfToken[uint(contractType)][tokenIds[i]];
      if (receiver != address(0) && IERC721(tokenAddress).ownerOf(tokenIds[i]) == address(this)) {
        IERC721(tokenAddress).transferFrom(address(this), receiver, tokenIds[i]);
        emit WithdrawStuckERC721(receiver, tokenAddress, tokenIds[i]);
      }
    }
  }

  /*
   * @notice Gets a category of a token of a specific collection.
   * @param contractType The type of the collection.
   * @param tokenId The ID of the token to get the category of.
   * @return The category of the token provided.
   */
  function getCategoryOfToken(ContractTypes contractType, uint256 tokenId) public view returns (uint8) {
    if (tokenTypeSeeded[uint(contractType)] == false) {
      return 0;
    }
    if (contractType == ContractTypes.Token1) {
      return uint8(_token1Categories[tokenId]);
    } else if (contractType == ContractTypes.Token2) {
      return uint8(_token2Categories[tokenId]);
    } else if (contractType == ContractTypes.Booster) {
      return uint8(_boosterCategories[tokenId]);
    }
    return 0;
  }

  /*
   * @notice Gets a yield of a token of a specific collection.
   * @param contractType The type of the collection.
   * @param tokenId The ID of the token to get the yield of.
   * @return The yield of the token provided.
   */
  function getTokenYield(ContractTypes contractType, uint256 tokenId) public view returns (uint256) {
    uint8 category = getCategoryOfToken(contractType, tokenId);
    return yieldsPerCategoryPerTokenType[uint(contractType)][category];
  }

  /*
   * @notice Calculates the yields produced by staked boosters.
   * @param userAddress The address of a user to calculate the booster yield for.
   * @return The booster yield produced for the users.
   */
  function calculateBoostersYield(address userAddress) public view returns (uint256) {
    uint256 numberToken1Staked = stakers[userAddress].stakedToken1.length;
    uint256[] memory boosters = stakers[userAddress].stakedBoosters;

    // Maximum of 2 boosters can be applied to each token
    uint256 maximumApplicableBoosters = numberToken1Staked * 2;
    uint256 applicableBoosters = boosters.length < maximumApplicableBoosters ? boosters.length : maximumApplicableBoosters;

    uint256 totalBoosterYield;
    for (uint256 i; i < applicableBoosters; i++) {
      uint256 tokenId = boosters[i];
      totalBoosterYield += getTokenYield(ContractTypes.Booster, tokenId);
    }

    return totalBoosterYield;
  }

  /*
   * @notice Calculates the yields produced by staked boosters.
   * @param userAddress The address of a user to calculate the booster yield for.
   * @return The booster yield produced for the users.
   */
  function getCurrentYield(address userAddress) public view returns (uint256) {
    uint256 numberToken1Staked = stakers[userAddress].stakedToken1.length;
    uint256 numberToken2Staked = stakers[userAddress].stakedToken2.length;
    uint currentYield = 0;
    for (uint256 i; i < numberToken1Staked; i++) {
      currentYield += getTokenYield(ContractTypes.Token1, stakers[userAddress].stakedToken1[i]);
    }
    for (uint256 i; i < numberToken2Staked; i++) {
      currentYield += getTokenYield(ContractTypes.Token2, stakers[userAddress].stakedToken2[i]);
    }
    currentYield += calculateBoostersYield(userAddress);
    return currentYield;
  }

  /*
   * @notice Calculates unclaimed reward of a staker.
   * @param staker The address of the staker.
   * @return The unclaimed reward of the staker.
   */
  function getUnclaimedRewards(address staker) public view returns (uint256) {
    if (stakers[staker].lastCheckpoint == 0) {
      return 0;
    }
    return ((block.timestamp - stakers[staker].lastCheckpoint) * getCurrentYield(staker)) / SECONDS_IN_DAY;
  }

  /*
   * @notice Gets tokens of a staker.
   * @param contractType The type of the collection.
   * @param staker The address of the staker.
   * @return The tokens of the staker.
   */
  function getStakerTokens(ContractTypes contractType, address staker) public view returns (uint256[] memory) {
    uint256[] memory tokens;
    if (contractType == ContractTypes.Token1) {
      tokens = stakers[staker].stakedToken1;
    } else if (contractType == ContractTypes.Token2) {
      tokens = stakers[staker].stakedToken2;
    } else if (contractType == ContractTypes.Booster) {
      tokens = stakers[staker].stakedBoosters;
    }
    return tokens;
  }

  /**
   * @notice Returns the address of a token owner.
   * @param contractType The type of the collection.
   * @param tokenId The token ID to get the owner of.
   * @return The owner address.
   */
  function ownerOf(ContractTypes contractType, uint256 tokenId) public view returns (address) {
    return _ownerOfToken[uint(contractType)][tokenId];
  }

  /*
   * @notice Moves a token to the last position in an array.
   * @param list The array of token IDs.
   * @param tokenId The ID of the token to move.
   * @return The updated array.
   */
  function _moveTokenToLast(uint256[] memory list, uint256 tokenId) internal pure returns (uint256[] memory) {
    uint256 tokenIndex = 0;
    uint256 lastTokenIndex = list.length - 1;
    uint256 length = list.length;

    for (uint256 i = 0; i < length; i++) {
      if (list[i] == tokenId) {
        tokenIndex = i + 1;
        break;
      }
    }
    require(tokenIndex != 0, "msg.sender is not the owner");

    tokenIndex -= 1;

    if (tokenIndex != lastTokenIndex) {
      list[tokenIndex] = list[lastTokenIndex];
      list[lastTokenIndex] = tokenId;
    }

    return list;
  }

  /*
   * @notice Transfers the reward to a staker.
   * @param staker The address of the staker.
   */
  function _claimRewards(address staker) internal {
    stakers[staker].claimedRewards += getUnclaimedRewards(staker);
    stakers[staker].lastCheckpoint = block.timestamp;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

{
  "compilationTarget": {
    "NFTStaking.sol": "NFTStaking"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}