// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import { IAbridge, IAbridgeMessageHandler } from "./IAbridge.sol";

/// @title AbridgeMessageHandler
/// @notice Abstract contract for handling messages received through the Abridge bridge
abstract contract AbridgeMessageHandler is IAbridgeMessageHandler {
    /// @notice The Abridge contract for bridging messages
    IAbridge private _abridge;

    /// @dev Emitted when the Abridge contract address is updated
    /// @param oldBridge The address of the previous Abridge contract
    /// @param newBridge The address of the new Abridge contract
    event AbridgeUpdated(address indexed oldBridge, address indexed newBridge);

    /// @dev Emitted when a route is updated for a sender
    /// @param sender The address of the sender
    /// @param allowed Whether the sender is allowed to use the route
    event RouteUpdated(address indexed sender, bool allowed);

    /// @dev Error thrown when a function is not called from the Abridge contract
    error NotCalledFromAbridge();

    /// @dev Modifier to ensure the function is called only from the Abridge contract
    modifier onlyAbridge() {
        if (msg.sender != address(_abridge)) {
            revert NotCalledFromAbridge();
        }
        _;
    }

    /// @dev Constructor to initialize the AbridgeMessageHandler
    /// @param abridge_ The address of the Abridge contract
    constructor(address abridge_) {
        _abridge = IAbridge(abridge_);
    }

    /// @notice Get the current Abridge contract
    /// @return The IAbridge interface of the current Abridge contract
    function abridge() public view returns (IAbridge) {
        return _abridge;
    }

    /// @dev Internal function to update the Abridge contract
    /// @param bridge The new Abridge contract
    function _setAbridge(address bridge) internal {
        address oldBridge = address(_abridge);
        _abridge = IAbridge(bridge);
        emit AbridgeUpdated(oldBridge, address(bridge));
    }

    /// @dev Internal function to update a route for a sender
    /// @param sender The address of the sender
    /// @param allowed Whether the sender is allowed to use the route
    function _updateRoute(address sender, bool allowed) internal {
        _abridge.updateRoute(sender, allowed);
        emit RouteUpdated(sender, allowed);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { IERC20Permit } from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { IDepositPool } from "./IDepositPool.sol";
import { IVaultNav } from "../vaultNav/IVaultNav.sol";
import { MessageLib } from "../message-lib/MessageLib.sol";
import { Pausable } from "@openzeppelin/contracts/utils/Pausable.sol";
import { Ownable, Ownable2Step } from "@openzeppelin/contracts/access/Ownable2Step.sol";
import { IAbridgeMessageHandler } from "../abridge/IAbridge.sol";
import { AbridgeMessageHandler } from "../abridge/AbridgeMessageHandler.sol";

/// @title DepositPool
/// @notice DepositPool accepts tokens and sends LSD token mint messages to Gravity.
/// The withdrawer is allowed to withdraw all deposited tokens treasury address.
/// No more deposits will be accepted once the deposit capacity is met.
/// ERC-2612 permit is supported if the asset token is an ERC20 token.
/// By default, LSD tokens will be minted to the receiver on the Gravity
/// chain upon successful deposit.
/// This contract is not upgradable but owner can easily use a new contract
/// to replace this one by:
/// 1. Pausing this contract.
/// 2. Withdrawer move all deposited tokens to treasury, as usual.
/// 3. New contract can read the public state variables of this contract
///    as they are just counters.
contract DepositPool is AbridgeMessageHandler, Pausable, Ownable2Step, IDepositPool {
    using SafeERC20 for IERC20;

    /// @notice Address of LSD token
    address public immutable LSD;
    /// @notice Address of token allowed to deposit
    address public immutable ASSET_TOKEN;
    /// @notice Decimals of deposit token
    uint256 public immutable ASSET_TOKEN_DECIMALS;
    /// @notice The address of SmartSavings contract on Gravity.
    address public smartSavingsOnGravity;

    /// @notice Accumulated deposited LSD token amount
    /// These are counters for the total amount of LSD minted to the owner
    /// on the default chain: Gravity.
    mapping(address owner => uint256 totalDeposits) public totalDeposits;

    /// @notice Pending deposit amount per owner.
    /// These are counters for the LSD that should be minted to the owner,
    /// but has not been minted yet.
    /// These alternative counters can be interpreted by future contracts
    /// to mint LSD to the owner on a different chain, inlcuding directly
    /// on Ethereum mainnet. Those contracts need to make sure that the
    /// counter amount shall not be spent twice. It can be done by maintaining
    /// another counter representing the "used" amount.
    mapping(address owner => uint256 amount) public pendingDeposits;

    /// @notice Total amount of LSD Token minted on chain
    uint256 public totalLsdMinted;
    /// @notice Accumulated deposit amount
    uint256 public accDepositAmount;
    /// @notice Capacity of deposit amount
    uint256 public depositCap;
    /// @notice Address of the account who is eligible to withdraw deposited assets to treasury
    address public withdrawer;
    /// @notice Address to hold the deposited assets
    address public treasury;

    /// @notice Gas limit to execute lzReceive function on destination chain using LayerZero
    uint128 public lzReceiveGasLimit = 100_000;

    /// @notice Address of VaultNav contract which is responsible for accounting NAV
    IVaultNav public vaultNav;

    /// @dev Ensures the deposit amount is valid and within the deposit cap
    /// @param _amount The amount to be deposited
    modifier onlyValidDepositAmount(uint256 _amount) {
        if (_amount == 0) {
            revert InvalidDepositAmount();
        }
        if (accDepositAmount + _amount > depositCap) {
            revert AmountExceedsDepositCap();
        }
        _;
    }

    /// @dev Restricts function access to the designated withdrawer
    modifier onlyWithdrawer() {
        if (msg.sender != withdrawer) {
            revert InvalidWithdrawer(msg.sender);
        }
        _;
    }

    /// @dev Initializes the DepositPool contract
    /// @param _lsd The address of the LSD token
    /// @param _token The address of asset token.
    /// @param _decimals The decimals of asset token.
    /// @param _vaultNav The address of VaultNav contract.
    /// @param _owner The owner/admin of this contract.
    /// @param _treasury The address to hold the deposited assets.
    /// @param _abridge The address of the Abridge contract.
    /// @param _smartSavingsOnGravity The address of SmartSavings contract on Gravity.
    constructor(
        address _lsd,
        address _token,
        uint8 _decimals,
        address _vaultNav,
        address _owner, // solhint-disable-line no-unused-vars
        address _treasury,
        address _abridge, // solhint-disable-line no-unused-vars
        address _smartSavingsOnGravity
    ) Ownable(_owner) AbridgeMessageHandler(_abridge) {
        if (_lsd == address(0)) {
            revert InvalidLSD();
        }
        LSD = _lsd;

        ASSET_TOKEN = _token;
        ASSET_TOKEN_DECIMALS = _decimals;
        if (_decimals > 18) {
            revert InvalidVaultToken();
        }

        if (_vaultNav == address(0)) {
            revert InvalidAddress(_vaultNav);
        }
        vaultNav = IVaultNav(_vaultNav);

        if (_treasury == address(0)) {
            revert InvalidAddress(_treasury);
        }
        treasury = _treasury;
        smartSavingsOnGravity = _smartSavingsOnGravity;
    }

    /// @notice Fallback function to receive native tokens as gas fees
    receive() external payable {}

    /// @notice Deposit `_amount` of `ASSET_TOKEN` for `_to`.
    /// @param _to The address to receive shares.
    /// @param _amount Amount of `ASSET_TOKEN` to be transferred to this contract.
    /// @param _mintOnGravity If true, mint LSD on Gravity chain, otherwise add to pending deposits.
    ///  It should be below the remaining deposit capacity.
    function deposit(
        address _to,
        uint256 _amount,
        bool _mintOnGravity
    ) external payable onlyValidDepositAmount(_amount) whenNotPaused {
        _deposit(_to, _amount, _mintOnGravity);
    }

    /// @notice Deposit `_amount` of `ASSET_TOKEN` for `_to` with ERC-2612 permit support.
    /// @param _to The address to receive shares.
    /// @param _amount Amount of `ASSET_TOKEN` to be deposited. It should be below the remaining deposit capacity.
    /// @param _permit The permit input data for ERC-2612.
    /// @param _mintOnGravity If true, mint LSD on Gravity chain, otherwise add to pending deposits.
    function depositWithPermit(
        address _to,
        uint256 _amount,
        bool _mintOnGravity,
        PermitInput calldata _permit
    ) external payable onlyValidDepositAmount(_amount) whenNotPaused {
        try
            IERC20Permit(ASSET_TOKEN).permit(
                msg.sender,
                address(this),
                _permit.value,
                _permit.deadline,
                _permit.v,
                _permit.r,
                _permit.s
            )
        {} catch {} // solhint-disable-line no-empty-blocks

        _deposit(_to, _amount, _mintOnGravity);
    }

    /// @notice Withdraw the deposited tokens to treasury.
    /// @dev Emits a `Withdrawn` event.
    /// @param _amount Amount of token to withdraw.
    function withdraw(uint256 _amount) external onlyWithdrawer {
        uint256 depositedAmount = 0;
        if (ASSET_TOKEN == address(0)) {
            depositedAmount = address(this).balance;
        } else {
            depositedAmount = IERC20(ASSET_TOKEN).balanceOf(address(this));
        }

        if (_amount == 0 || _amount > depositedAmount) {
            revert InvalidWithdrawalAmount(_amount);
        }

        // transfer token
        if (ASSET_TOKEN == address(0)) {
            (bool sent, ) = treasury.call{ value: _amount }("");
            if (!sent) revert SendFailed(treasury, _amount);
        } else {
            IERC20(ASSET_TOKEN).safeTransfer(treasury, _amount);
        }

        // withdraw event
        emit Withdrawn(treasury, ASSET_TOKEN, _amount, LSD);
    }

    /// @notice Stops accepting new deposits.
    /// @dev Emits a `Paused` event.
    function pause() external onlyOwner {
        _pause();
    }
    /// @notice Resumes accepting new deposits.
    /// @dev Emits an `Unpaused` event.
    function unpause() external onlyOwner {
        _unpause();
    }

    /// @notice Withdraw unexpectedly received tokens.
    /// @param _token Address of the token to withdraw.
    /// @param _to Address to receive the withdrawn token.
    function rescueWithdraw(address _token, address _to) external onlyOwner {
        if (_token == address(0)) {
            uint256 amount = address(this).balance;
            (bool sent, ) = _to.call{ value: amount }("");
            if (!sent) {
                revert SendFailed(_to, amount);
            }
        } else {
            uint256 _amount = IERC20(_token).balanceOf(address(this));
            IERC20(_token).safeTransfer(_to, _amount);
        }
    }

    /// @notice Sets the address of SmartSavings on the Ethereum
    /// @dev Emits a `SmartSavingOnGravityUpdated` event.
    /// @param _smartSavings The address of the SmartSavings contract on the Ethereum
    function setSmartSavingsOnGravity(address _smartSavings) external onlyOwner {
        smartSavingsOnGravity = _smartSavings;
        emit SmartSavingsOnGravityUpdated(_smartSavings);
    }

    /// @notice Sets the abridge address
    /// @param _abridge The address of the Abridge contract
    function setAbridge(address _abridge) external onlyOwner {
        _setAbridge(_abridge);
    }

    /// @notice Set lzReceiveGasLimit
    /// @param _gasLimit The gas limit to execute lzReceive function on destination chain using LayerZero.
    function setLzReceiveGasLimit(uint128 _gasLimit) external onlyOwner {
        lzReceiveGasLimit = _gasLimit;
        emit NewLzReceiveGasLimit(_gasLimit);
    }

    /// @notice Set new deposit cap.
    /// @dev Emits a `NewDepositCap` event.
    /// @param _amount New deposit cap.
    function setDepositCap(uint256 _amount) external onlyOwner {
        if (_amount < accDepositAmount) revert InvalidDepositCap(_amount);
        depositCap = _amount;
        emit NewDepositCap(_amount);
    }

    /// @notice Set new withdrawer.
    /// @dev Emits a `NewWithdrawer` event.
    /// @param _withdrawer Address of new withdrawer.
    function setWithdrawer(address _withdrawer) external onlyOwner {
        withdrawer = _withdrawer;
        emit NewWithdrawer(_withdrawer);
    }

    /// @notice Set new treasury.
    /// @dev Emits a `NewTreasury` event.
    /// @param _treasury Address of new treasury.
    function setTreasury(address _treasury) external onlyOwner {
        if (_treasury == address(0)) {
            revert InvalidAddress(_treasury);
        }
        treasury = _treasury;
        emit NewTreasury(_treasury);
    }

    /// @notice Set initial amount of LSD minted.
    //   Can only be set once and must be done before any deposits are received.
    /// @dev Emits a `TotalLsdMintedInitialized` event.
    /// @param _amount Initial amount of LSD minted.
    function setInitialLsdMinted(uint256 _amount) external onlyOwner {
        if (totalLsdMinted != 0 || _amount == 0) {
            revert InvalidInitialLsdMinted(_amount);
        }
        totalLsdMinted = _amount;
        emit TotalLsdMintedInitialized(_amount);
    }

    /// @notice DepositPool is designed exclusively for sending cross-chain messages and
    ///   will always revert when receiving any.
    function handleMessage(
        address /*_from*/,
        bytes calldata /*_message*/,
        bytes32 /*_guid*/
    ) external view override onlyAbridge returns (bytes4) {
        revert NotImplemented(IAbridgeMessageHandler.handleMessage.selector);
    }

    /// @notice Get remaining deposit capacity.
    /// @return Remaining deposit capacity.
    function remainingDepositCap() external view returns (uint256) {
        return depositCap - accDepositAmount;
    }

    /// @notice Estimate deposit message bridging fee.
    /// @param _to The address to receive minted LSD.
    /// @return Amount of deposit fee.
    function depositFee(address _to) public view returns (uint256) {
        (, uint256 amount) = abridge().estimateFee(
            smartSavingsOnGravity,
            lzReceiveGasLimit,
            MessageLib.pack(
                MessageLib.Message({
                    valueType: uint8(MessageLib.TOTAL_CLAIMS_TYPE),
                    value: totalDeposits[_to],
                    owner: _to,
                    timestamp: 0,
                    delta: 0
                })
            )
        );
        return amount;
    }

    /// @notice Internal function to implement deposit logic.
    /// @dev Emits a `Deposited` event.
    /// @param _to Address to receive LSD token.
    /// @param _amount Amount of `ASSET_TOKEN` deposited.
    /// @param _mintOnGravity If true, mint LSD on Gravity chain, otherwise add to pending deposits.
    function _deposit(address _to, uint256 _amount, bool _mintOnGravity) internal {
        // receive token
        uint256 actualAmount = _amount;
        uint256 messageFee = msg.value;
        if (ASSET_TOKEN == address(0)) {
            if (msg.value < _amount) {
                revert InvalidDepositAmount();
            }
            messageFee -= _amount;
        } else {
            // be compatible with reflection tokens
            uint256 balanceBefore = IERC20(ASSET_TOKEN).balanceOf(address(this));
            IERC20(ASSET_TOKEN).safeTransferFrom(msg.sender, address(this), _amount);
            uint256 balanceAfter = IERC20(ASSET_TOKEN).balanceOf(address(this));
            actualAmount = balanceAfter - balanceBefore;
        }

        // add accumulated deposited amount
        accDepositAmount += actualAmount;

        // calc LSD amount
        uint256 lsdAmount = vaultNav.tokenE18ToLsdAtTime(
            LSD,
            actualAmount * 10 ** (18 - ASSET_TOKEN_DECIMALS),
            uint48(block.timestamp)
        );
        if (lsdAmount == 0) {
            revert DepositAmountTooSmall(actualAmount);
        }
        totalLsdMinted += lsdAmount;

        if (!_mintOnGravity) {
            // add pending deposit amount, instead of mint to gravity chain.
            pendingDeposits[_to] += lsdAmount;
            emit Deposited(msg.sender, _to, ASSET_TOKEN, actualAmount, LSD, lsdAmount, block.timestamp, 0, 0);
        } else {
            // mint LSD on gravity by sending message.
            totalDeposits[_to] += lsdAmount;

            // check message fee
            uint256 _depositFee = depositFee(_to);
            if (messageFee < _depositFee) {
                revert InsufficientFee(_depositFee, messageFee);
            }
            // bridge message to gravity to mint LSD
            (bytes32 guid, uint256 nativeFee) = _deposited(_to, messageFee);

            emit Deposited(
                msg.sender,
                _to,
                ASSET_TOKEN,
                actualAmount,
                LSD,
                lsdAmount,
                block.timestamp,
                guid,
                nativeFee
            );
        }
    }

    /// @dev Send message `totalDeposits` of `_to` to destination chain to
    ///  trigger minting LSD tokens to `_to`.
    /// @param _to Address to receive LSD token.
    /// @param _messageFee Provided native fee for sending LayerZero message.
    /// @return _guid The unique identifier for the sent LayerZero message.
    /// @return _nativeFee The actually charged native fee for sending LayerZero message.
    function _deposited(address _to, uint256 _messageFee) internal returns (bytes32 _guid, uint256 _nativeFee) {
        bytes memory message = MessageLib.pack(
            MessageLib.Message({
                valueType: uint8(MessageLib.TOTAL_DEPOSITS_TYPE),
                value: totalDeposits[_to],
                owner: _to,
                timestamp: 0,
                delta: 0
            })
        );
        uint256 balanceBeforeSend = address(this).balance;
        // Send the message through the Abridge contract
        _guid = abridge().send{ value: _messageFee }(smartSavingsOnGravity, lzReceiveGasLimit, message);
        uint256 balanceAfterSend = address(this).balance;

        _nativeFee = balanceBeforeSend - balanceAfterSend;
        // refund the unused fee
        if (_nativeFee < _messageFee) {
            uint256 refundAmount = _messageFee - _nativeFee;
            (bool sent, ) = msg.sender.call{ value: refundAmount }("");
            if (!sent) revert SendFailed(msg.sender, refundAmount);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

/// @title BridgeReceiver
/// @notice Interface for contracts that can receive messages through the bridge
interface IAbridgeMessageHandler {
    /// @notice Handles incoming messages from the bridge.
    /// @param _from The address of the sender
    /// @param _msg The message data
    /// @return response The function selector to confirm successful handling
    function handleMessage(address _from, bytes calldata _msg, bytes32 guid) external returns (bytes4 response);
}

/// @title IAbridge
/// @notice Interface for the Abridge contract
interface IAbridge {
    /// @notice Emitted when a message is sent through the bridge
    event MessageSent(address indexed sender, address indexed receiver, bytes32 guid, uint256 fee);

    /// @notice Emitted when a message is received through the bridge
    event MessageReceived(address indexed sender, address indexed receiver, bytes32 guid);

    /// @notice Emitted when an authorized sender is updated
    event AuthorizedSenderUpdated(address indexed sender, bool authorized);

    /// @notice Emitted when a route is updated
    event RouteUpdated(address indexed receiver, address indexed sender, bool allowed);

    error InsufficientFee(uint256 _sent, uint256 _required);
    error UnauthorizedSender(address _sender);
    error DisallowedRoute(address _sender, address _receiver);
    error InvalidReceiverResponse(bytes4 _response);

    /// @notice Updates the route for a specific sender
    /// @param _sender Address of the sender
    /// @param _allowed Flag to allow or disallow the route
    function updateRoute(address _sender, bool _allowed) external;

    /// @notice Sends a message through the bridge
    /// @param _receiver Address of the receiver
    /// @param _executeGasLimit Gas limit for execution
    /// @param _msg The message to be sent
    /// @return _guid The unique identifier for the sent message
    function send(
        address _receiver,
        uint128 _executeGasLimit,
        bytes memory _msg
    ) external payable returns (bytes32 _guid);

    /// @notice The endpoint ID of the destination chain
    function eid() external view returns (uint32);

    /// @notice Checks if a sender is authorized
    /// @param sender The address of the sender to check
    /// @return authorized True if the sender is authorized, false otherwise
    function authorizedSenders(address sender) external view returns (bool authorized);

    /// @notice Estimates the fee for sending a message
    /// @param _receiver Address of the receiver
    /// @param _executeGasLimit Gas limit for execution
    /// @param _msg The message to be sent
    /// @return _token The token address for the fee (address(0) for native token)
    /// @return _fee The estimated fee amount
    function estimateFee(
        address _receiver,
        uint128 _executeGasLimit,
        bytes memory _msg
    ) external view returns (address _token, uint256 _fee);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

interface IDepositPool {
    /// @notice ERC-2612 permit. Always use this contract as spender and use
    /// msg.sender as owner
    struct PermitInput {
        uint256 value;
        uint256 deadline;
        uint8 v;
        bytes32 r;
        bytes32 s;
    }

    event Deposited(
        address indexed from,
        address indexed to,
        address token,
        uint256 amount,
        address lsd,
        uint256 lsdAmount,
        uint256 timestamp,
        bytes32 guid,
        uint256 fee
    );

    event Withdrawn(address indexed _to, address _token, uint256 _amount, address _lsd);

    event NewWithdrawer(address withdrawer);
    event NewDepositCap(uint256 cap);
    event NewTreasury(address treasury);
    event NewLzReceiveGasLimit(uint128 gasLimit);
    event SmartSavingsOnGravityUpdated(address addr);
    event TotalLsdMintedInitialized(uint256 amount);

    error InvalidLSD();
    error InvalidVaultToken();
    error InvalidDepositAmount();
    error AmountExceedsDepositCap();
    error InvalidDepositCap(uint256 _cap);
    error SendFailed(address to, uint256 amount);
    error InvalidWithdrawer(address withdrawer);
    error InvalidWithdrawalAmount(uint256 amount);
    error InvalidAddress(address addr);
    error DepositAmountTooSmall(uint256 amount);
    error InsufficientFee(uint256 wanted, uint256 provided);
    error NotImplemented(bytes4 selector);
    error InvalidInitialLsdMinted(uint256 amount);

    function deposit(address _to, uint256 _amount, bool mintOnGravity) external payable;
    function depositWithPermit(
        address _to,
        uint256 _amount,
        bool mintOnGravity,
        PermitInput calldata _permit
    ) external payable;

    function setDepositCap(uint256 _amount) external;

    function setWithdrawer(address _withdrawer) external;

    function setTreasury(address _treasury) external;

    function withdraw(uint256 _amount) external;

    function remainingDepositCap() external view returns (uint256);
    function depositFee(address _to) external view returns (uint256);

    function LSD() external view returns (address); // solhint-disable-line style-guide-casing
    function ASSET_TOKEN() external view returns (address); // solhint-disable-line style-guide-casing
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

interface IVaultNav {
    event NavUpdated(address indexed lsd, uint256 nav, uint256 timestamp);
    event SetNavUpdater(address indexed lsd, address updater);

    error NavNotFound(uint48 _timestamp);
    error InvalidNavUpdater(address updater);
    error NavInvalidValue(uint256 nav);
    error TimestampTooLarge();
    error InvalidUpdatePeriod();
    error NavUpdateInvalidTimestamp();

    function appendNav(address lsd, uint256 nav, uint48 timestamp) external;
    function setNavUpdater(address lsd, address updater) external;
    function getNavByTimestamp(
        address vaultType,
        uint48 timestamp
    ) external view returns (uint256 nav, uint48 updateTime);

    function lsdToTokenE18AtTime(address _lsd, uint256 _amount, uint48 _timestamp) external view returns (uint256);
    function tokenE18ToLsdAtTime(
        address _lsd,
        uint256 _tokenAmountE18,
        uint48 _timestamp
    ) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

library MessageLib {
    /// @notice Messages are transferred between chains as 60=byte long bytes
    ///        The first 8 bits are the value type.
    ///        The next 136 bits are the value amount.
    ///        The next 160 bits are the address related to the value.
    ///        The next 48 bits are the value timestamp.
    ///        The remaining 128 bits are the value delta.
    struct Message {
        uint8 valueType;
        uint256 value;
        address owner;
        uint256 timestamp;
        uint256 delta;
    }

    uint256 internal constant _MAX_VALUE = type(uint136).max;
    uint256 internal constant _MAX_TIMESTAMP = type(uint48).max;
    uint256 internal constant _MAX_DELTA = type(uint128).max;

    uint8 public constant TOTAL_DEPOSITS_TYPE = 1;
    uint8 public constant TOTAL_POOL_UNLOCKS_TYPE = 2;
    uint8 public constant TOTAL_CLAIMS_TYPE = 3;
    uint8 public constant TOTAL_REQUESTS_TYPE = 4;
    uint8 public constant TOTAL_REDEEMEDS_TYPE = 5;

    error MessageLib_ValueOverflow();
    error MessageLib_TimestampOverflow();
    error MessageLib_DeltaOverflow();
    error MessageLib_InvalidMessageLength(uint256 length);

    ///
    /// @notice Extracts a Message from bytes.
    ///
    function unpack(bytes memory b) internal pure returns (Message memory m) {
        uint8 valueType;
        uint136 value;
        address owner;
        uint48 _timestamp;
        uint128 _delta;

        if (b.length != 60) revert MessageLib_InvalidMessageLength(b.length);

        /* solhint-disable no-inline-assembly */
        assembly {
            valueType := mload(add(b, 1))
            value := mload(add(b, 18))
            owner := mload(add(b, 38))
            _timestamp := mload(add(b, 44))
            _delta := mload(add(b, 60))
        }
        /* solhint-enable no-inline-assembly */

        return Message(valueType, value, owner, _timestamp, _delta);
    }

    ///
    /// @notice Packs a Message into bytes.
    ///
    function pack(Message memory m) internal pure returns (bytes memory) {
        if (m.value > _MAX_VALUE) revert MessageLib_ValueOverflow();
        if (m.timestamp > _MAX_TIMESTAMP) revert MessageLib_TimestampOverflow();
        if (m.delta > _MAX_DELTA) revert MessageLib_DeltaOverflow();

        return abi.encodePacked(m.valueType, uint136(m.value), m.owner, uint48(m.timestamp), uint128(m.delta));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/depositPool/DepositPool.sol": "DepositPool"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 1000
  },
  "remappings": [],
  "viaIR": true
}