// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

pragma solidity 0.8.20;

import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/utils/math/Math.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "./interfaces/IDepositTokenRegistry.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./errors/DepositTokenRegistryErrors.sol";

/// @title DepositTokenRegistry
/// @notice Registry for managing deposit tokens and their associated parameters
/// @dev Handles token registration, fee management, and collateral eligibility
contract DepositTokenRegistry is
  IDepositTokenRegistry,
  AccessControl,
  ReentrancyGuard
{
  using Math for uint256;
  using Address for address;
  using EnumerableSet for EnumerableSet.AddressSet;

  address public constant NATIVE_TOKEN =
    0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
  address public wrappedNativeToken;
  uint8 public constant NATIVE_TOKEN_DECIMALS = 18;
  uint256 public constant MAX_SLIPPAGE_TOLERANCE = 3500; // 35% in basis points

  bytes32 public immutable ADMIN_ROLE = keccak256("ADMIN_ROLE");
  bytes32 public immutable PAUSER_ROLE = keccak256("PAUSER_ROLE");
  bytes32 public immutable FEE_MANAGER_ROLE = keccak256("FEE_MANAGER_ROLE");
  bytes32 public immutable ORACLE_MANAGER_ROLE =
    keccak256("ORACLE_MANAGER_ROLE");

  // Add constant for max fee
  uint256 public constant MAX_PERCENTAGE_FEE = 2500; // 25% in basis points

  string private _nativeName;
  string private _nativeSymbol;

  constructor(
    address initialAdmin_,
    address admin_,
    address pauser_,
    address feeManager_,
    address oracleManager_,
    string memory nativeName_,
    string memory nativeSymbol_
  ) {
    _grantRole(DEFAULT_ADMIN_ROLE, initialAdmin_);
    _grantRole(ADMIN_ROLE, admin_);
    _grantRole(PAUSER_ROLE, pauser_);
    _grantRole(FEE_MANAGER_ROLE, feeManager_);
    _grantRole(ORACLE_MANAGER_ROLE, oracleManager_);
    _nativeName = nativeName_;
    _nativeSymbol = nativeSymbol_;
  }

  // Mapping to store accepted tokens and their fee information
  mapping(address => TokenInfo) private tokenInfo;
  // Array to store all token addresses
  EnumerableSet.AddressSet private _tokenAddresses;
  // Array to store accepted and not paused token addresses
  EnumerableSet.AddressSet private _acceptedTokens;

  // Events
  /// @notice Emitted when a new token is added to the registry
  /// @param token Address of the token that was added
  /// @param fixedDepositFee Fixed fee amount set for deposits
  /// @param percentageDepositFee Percentage fee set for deposits (in basis points)
  /// @param priceOracle Address of the price oracle assigned to the token
  event TokenAdded(
    address indexed token,
    uint256 fixedDepositFee,
    uint256 percentageDepositFee,
    address priceOracle
  );

  /// @notice Emitted when a token is removed from the registry
  /// @param token Address of the token that was removed
  event TokenRemoved(address indexed token);

  /// @notice Emitted when a token's fee structure is updated
  /// @param token Address of the token whose fees were updated
  /// @param fixedDepositFee New fixed fee amount
  /// @param percentageDepositFee New percentage fee (in basis points)
  event TokenFeeUpdated(
    address indexed token,
    uint256 fixedDepositFee,
    uint256 percentageDepositFee
  );

  /// @notice Emitted when a token's price oracle is updated
  /// @param token Address of the token whose oracle was updated
  /// @param priceOracle Address of the new price oracle
  event TokenOracleUpdated(address indexed token, address priceOracle);

  /// @notice Emitted when deposits for a token are paused
  /// @param token Address of the token that was paused
  event TokenPaused(address indexed token);

  /// @notice Emitted when deposits for a token are unpaused
  /// @param token Address of the token that was unpaused
  event TokenUnpaused(address indexed token);

  /// @notice Emitted when a token's default slippage tolerance is updated
  /// @param token Address of the token whose slippage was updated
  /// @param defaultSlippageTolerance New slippage tolerance in basis points
  event DefaultSlippageToleranceUpdated(
    address indexed token,
    uint256 defaultSlippageTolerance
  );

  /// @notice Emitted when a token's minimum deposit requirement is updated
  /// @param token Address of the token whose minimum deposit was updated
  /// @param oldMinDeposit Previous minimum deposit amount
  /// @param newMinDeposit New minimum deposit amount
  event MinDepositUpdated(
    address indexed token,
    uint256 oldMinDeposit,
    uint256 newMinDeposit
  );

  /// @notice Emitted when a token's collateral eligibility status changes
  /// @param token Address of the token whose eligibility was updated
  /// @param oldEligibility Previous eligibility status
  /// @param newEligibility New eligibility status
  event CollateralEligibilityUpdated(
    address indexed token,
    bool oldEligibility,
    bool newEligibility
  );

  /// @notice Adds a new token to the registry
  /// @param token Address of the token to add
  /// @param fixedDepositFee_ Fixed fee amount charged for deposits
  /// @param percentageDepositFee_ Percentage fee charged for deposits (in basis points, e.g. 100 = 1%)
  /// @param priceOracle_ Address of the price oracle for this token
  /// @param eligibleAsCollateral_ Whether this token can be used as collateral
  /// @param defaultSlippageTolerance_ Default slippage tolerance in basis points (e.g. 100 = 1%)
  /// @param minDeposit_ Minimum deposit amount required
  /// @dev Only callable by accounts with ADMIN_ROLE
  /// @dev Emits TokenAdded, MinDepositUpdated, and CollateralEligibilityUpdated events
  function addToken(
    address token,
    uint256 fixedDepositFee_,
    uint256 percentageDepositFee_,
    address priceOracle_,
    bool eligibleAsCollateral_,
    uint256 defaultSlippageTolerance_,
    uint256 minDeposit_
  ) external nonReentrant onlyRole(ADMIN_ROLE) {
    if (token == address(0)) {
      revert ZeroAddressError();
    }
    if (priceOracle_ == address(0)) {
      revert ZeroAddressError();
    }
    if (tokenInfo[token].isAccepted) {
      revert TokenAlreadyAcceptedError();
    }
    if (percentageDepositFee_ > MAX_PERCENTAGE_FEE) {
      revert PercentageFeeTooHighError();
    }
    if (defaultSlippageTolerance_ > MAX_SLIPPAGE_TOLERANCE) {
      revert SlippageTooHighError();
    }
    if (minDeposit_ == 0) {
      revert MinDepositZeroError();
    }

    IERC20Metadata metadataToken = IERC20Metadata(token);
    tokenInfo[token] = TokenInfo({
      isAccepted: true,
      fixedDepositFee: fixedDepositFee_,
      percentageDepositFee: percentageDepositFee_,
      priceOracle: priceOracle_,
      paused: false,
      eligibleAsCollateral: eligibleAsCollateral_,
      decimals: metadataToken.decimals(),
      name: metadataToken.name(),
      symbol: metadataToken.symbol(),
      defaultSlippageTolerance: defaultSlippageTolerance_,
      minDeposit: minDeposit_
    });

    _tokenAddresses.add(token);
    _acceptedTokens.add(token);

    emit TokenAdded(
      token,
      fixedDepositFee_,
      percentageDepositFee_,
      priceOracle_
    );
    emit MinDepositUpdated(token, 0, minDeposit_);
    emit CollateralEligibilityUpdated(token, false, eligibleAsCollateral_);
  }

  /// @notice Removes a token from the registry
  /// @param token Address of the token to remove
  /// @dev Only callable by accounts with ADMIN_ROLE
  /// @dev Emits TokenRemoved event
  function removeToken(address token) external onlyRole(ADMIN_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }

    delete tokenInfo[token];
    _tokenAddresses.remove(token);
    _acceptedTokens.remove(token);

    emit TokenRemoved(token);
  }

  /// @notice Updates deposit fees for a specific token
  /// @param token Address of the token to update
  /// @param fixedDepositFee_ New fixed fee amount in token units
  /// @param percentageDepositFee_ New percentage fee in basis points (1 BPS = 0.01%)
  /// @dev Fee Structure:
  /// @dev 1. Fixed Fee: Flat amount charged per transaction
  /// @dev 2. Percentage Fee: Variable amount based on deposit size
  /// @dev - Maximum percentage fee is 2500 BPS (25%)
  /// @dev - Example: 300 BPS = 3%
  /// @dev Emits TokenFeeUpdated event
  function updateTokenFees(
    address token,
    uint256 fixedDepositFee_,
    uint256 percentageDepositFee_
  ) external onlyRole(FEE_MANAGER_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (percentageDepositFee_ > MAX_PERCENTAGE_FEE) {
      revert PercentageFeeTooHighError();
    }

    tokenInfo[token].fixedDepositFee = fixedDepositFee_;
    tokenInfo[token].percentageDepositFee = percentageDepositFee_;

    emit TokenFeeUpdated(token, fixedDepositFee_, percentageDepositFee_);
  }

  /// @notice Updates the price oracle for a specific token
  /// @param token Address of the token to update
  /// @param priceOracle_ New price oracle address
  /// @dev Only callable by accounts with ORACLE_MANAGER_ROLE
  /// @dev Emits TokenOracleUpdated event
  function updateTokenOracle(
    address token,
    address priceOracle_
  ) external onlyRole(ORACLE_MANAGER_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (priceOracle_ == address(0)) {
      revert ZeroAddressError();
    }

    tokenInfo[token].priceOracle = priceOracle_;

    emit TokenOracleUpdated(token, priceOracle_);
  }

  /// @notice Pauses deposits for a specific token
  /// @param token Address of the token to pause
  /// @dev Only callable by accounts with PAUSER_ROLE
  /// @dev Emits TokenPaused event
  function pauseToken(address token) external onlyRole(PAUSER_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (tokenInfo[token].paused) {
      revert TokenAlreadyPausedError();
    }

    tokenInfo[token].paused = true;
    _acceptedTokens.remove(token);

    emit TokenPaused(token);
  }

  /// @notice Unpauses deposits for a specific token
  /// @param token Address of the token to unpause
  /// @dev Only callable by accounts with PAUSER_ROLE
  /// @dev Emits TokenUnpaused event
  function unpauseToken(address token) external onlyRole(PAUSER_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (!tokenInfo[token].paused) {
      revert TokenNotPausedError();
    }

    tokenInfo[token].paused = false;
    _acceptedTokens.add(token);

    emit TokenUnpaused(token);
  }

  /// @notice Retrieves information about a specific token
  /// @param token Address of the token to query
  /// @return isAccepted Whether the token is accepted
  /// @return fixedDepositFee Fixed fee amount for deposits
  /// @return percentageDepositFee Percentage fee for deposits (in basis points)
  /// @return priceOracle Address of the price oracle contract
  /// @return paused Bool indicating whether the token is paused
  /// @return name Token name
  /// @return symbol Token symbol
  /// @return slippage Default slippage tolerance in basis points
  /// @return minDeposit Minimum deposit amount
  /// @return decimals Token decimals
  /// @return nativeToken Whether this is the native blockchain token
  function getTokenInfo(
    address token
  )
    external
    view
    returns (
      bool isAccepted,
      uint256 fixedDepositFee,
      uint256 percentageDepositFee,
      address priceOracle,
      bool paused,
      string memory name,
      string memory symbol,
      uint256 slippage,
      uint256 minDeposit,
      uint256 decimals,
      bool nativeToken
    )
  {
    TokenInfo memory info = tokenInfo[token];
    bool nativeToken_ = false;
    if (token == NATIVE_TOKEN) {
      nativeToken_ = true;
    }
    return (
      info.isAccepted,
      info.fixedDepositFee,
      info.percentageDepositFee,
      info.priceOracle,
      info.paused,
      info.name,
      info.symbol,
      info.defaultSlippageTolerance,
      info.minDeposit,
      info.decimals,
      nativeToken_
    );
  }

  /// @notice Returns only the essential token information needed for share price calculations
  /// @param token The address of the token to query
  /// @return isAccepted Whether the token is accepted
  /// @return paused Whether the token is paused
  /// @return priceOracle The address of the price oracle for this token
  /// @return decimals The number of decimals for the token
  function getTokenPriceInfo(
    address token
  )
    external
    view
    returns (bool isAccepted, bool paused, address priceOracle, uint8 decimals)
  {
    TokenInfo memory info = tokenInfo[token];

    return (info.isAccepted, info.paused, info.priceOracle, info.decimals);
  }

  /// @notice Gets a list of tokens that are accepted and not paused
  /// @return List of token addresses
  function getAcceptedTokens() external view returns (address[] memory) {
    uint256 length = _acceptedTokens.length();
    address[] memory tokens = new address[](length);

    for (uint256 i = 0; i < length; i++) {
      tokens[i] = _acceptedTokens.at(i);
    }

    return tokens;
  }

  /// @notice Checks if a token is allowed for deposits
  /// @param token Address of the token to check
  /// @return bool indicating whether the token is allowed for deposits
  function isDepositEnabled(address token) external view returns (bool) {
    TokenInfo memory info = tokenInfo[token];
    return info.isAccepted && !info.paused;
  }

  /// @notice Calculates the total fees required for minting shares
  /// @param token Address of the token being used for minting
  /// @param amount Amount of tokens being used for minting
  /// @return Total fee amount, rounded up to ensure protocol solvency
  /// @dev The percentage fee is calculated by determining how many tokens would be needed
  /// @dev to mint the desired shares after fees, then subtracting the original amount.
  /// @dev For example, if depositing 100 tokens with a 3% fee:
  /// @dev 1. Calculate post-fee amount: ceil(100 * 10000 / 9700) = 104
  /// @dev 2. Subtract original amount: 104 - 100 = 4 token fee
  function previewMintFees(
    address token,
    uint256 amount
  ) external view returns (uint256) {
    TokenInfo memory info = tokenInfo[token];

    if (!info.isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (amount == 0) {
      revert ZeroAmountError();
    }

    // Calculate percentage fee using reverse calculation to ensure exact share minting
    // Formula explanation:
    // 1. If we want X shares after fee, and fee is P%, then:
    //    X * (1 - P/100) = amount
    // 2. Solving for X:
    //    X = amount / (1 - P/100)
    // 3. In basis points (P * 100):
    //    X = amount * 10000 / (10000 - percentageFeeBPS)
    uint256 percentageFee = Math.mulDiv(
      amount,
      10000,
      10000 - info.percentageDepositFee,
      Math.Rounding.Ceil
    ) - amount;

    // Add fixed fee to percentage-based fee
    // Example: if fixed fee is 1 token and percentage fee is 3 tokens
    // totalFee = 1 + 3 = 4 tokens
    uint256 totalFee = info.fixedDepositFee + percentageFee;

    return totalFee;
  }

  /// @notice Calculates the fees required for a direct deposit
  /// @param token Address of the token being used for minting
  /// @param amount Amount of tokens being used for minting
  /// @return Total fee amount, rounded up to ensure protocol solvency
  /// @dev The percentage fee is calculated by determining how many tokens would be needed
  /// @dev to mint the desired shares after fees, then subtracting the original amount.
  /// @dev For example, if depositing 100 tokens with a 3% fee:
  /// @dev 1. Calculate post-fee amount: ceil(100 * 10000 / 9700) = 104
  /// @dev 2. Subtract original amount: 104 - 100 = 4 token fee
  function previewDepositFees(
    address token,
    uint256 amount
  ) external view returns (uint256) {
    TokenInfo memory info = tokenInfo[token];

    if (!info.isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (amount == 0) {
      revert ZeroAmountError();
    }

    // Calculate percentage fee directly
    // Example: For 100 tokens with 3% fee (300 basis points)
    // percentageFee = 100 * 300 / 10000 = 3 tokens
    uint256 percentageFee = Math.mulDiv(
      amount,
      info.percentageDepositFee,
      10000
    );

    // Add fixed fee component
    // Example: If fixed fee is 1 token:
    // totalFee = 1 + 3 = 4 tokens
    uint256 totalFee = info.fixedDepositFee + percentageFee;

    // Cap the total fee at the deposit amount to prevent taking more than 100%
    return totalFee > amount ? amount : totalFee;
  }

  function updateSlippage(
    address token,
    uint256 newSlippage
  ) external onlyRole(ADMIN_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (newSlippage > MAX_SLIPPAGE_TOLERANCE) {
      revert SlippageTooHighError();
    }

    tokenInfo[token].defaultSlippageTolerance = newSlippage;

    emit DefaultSlippageToleranceUpdated(token, newSlippage);
  }

  /// @notice Gets a list of tokens that are eligible as collateral
  /// @return An array of addresses representing the eligible collateral tokens
  function getCollateralTokens() external view returns (address[] memory) {
    uint256 length = _tokenAddresses.length();
    address[] memory collateralTokens = new address[](length);
    uint256 count = 0;

    for (uint256 i = 0; i < length; i++) {
      address token = _tokenAddresses.at(i);
      if (tokenInfo[token].eligibleAsCollateral) {
        collateralTokens[count] = token;
        count++;
      }
    }

    // Use assembly to resize array to actual number of collateral tokens
    // This is more gas efficient than creating a new array and copying values
    assembly {
      mstore(collateralTokens, count)
    }

    return collateralTokens;
  }

  /// @notice Checks if a token is eligible as collateral
  /// @param token Address of the token to check
  /// @return A boolean indicating whether the token is eligible as collateral
  function isEligibleAsCollateral(address token) external view returns (bool) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    return tokenInfo[token].eligibleAsCollateral;
  }

  /**
   * @notice Adds the native token (e.g., ETH) to the registry with specified parameters
   * @dev Only callable by accounts with ADMIN_ROLE. This function can only be called once
   *      for the native token. The native token is represented by a constant address
   *      (0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
   *
   * @param fixedDepositFee_ Fixed fee amount charged for deposits in native token units
   * @param percentageDepositFee_ Percentage fee charged for deposits (in basis points, e.g., 100 = 1%)
   * @param priceOracle_ Address of the price oracle for the native token
   * @param eligibleAsCollateral_ Whether the native token can be used as collateral
   * @param wrappedNativeToken_ Address of the wrapped version of the native token (e.g., WETH)
   * @param slippage_ Default slippage tolerance in basis points (e.g., 100 = 1%)
   * @param minDeposit_ Minimum deposit amount required in native token units
   *
   * @dev Emits TokenAdded, MinDepositUpdated, and CollateralEligibilityUpdated events
   *
   * Requirements:
   * - Native token must not already be accepted
   * - Wrapped token address must not be zero
   * - Price oracle address must not be zero
   * - Percentage fee must not exceed MAX_PERCENTAGE_FEE (25%)
   * - Slippage must not exceed MAX_SLIPPAGE_TOLERANCE (35%)
   * - Minimum deposit must be greater than 0
   */
  function addNativeToken(
    uint256 fixedDepositFee_,
    uint256 percentageDepositFee_,
    address priceOracle_,
    bool eligibleAsCollateral_,
    address wrappedNativeToken_,
    uint256 slippage_,
    uint256 minDeposit_
  ) external nonReentrant onlyRole(ADMIN_ROLE) {
    if (tokenInfo[NATIVE_TOKEN].isAccepted) {
      revert TokenAlreadyAcceptedError();
    }
    if (wrappedNativeToken_ == address(0)) {
      revert WrappedNativeZeroError();
    }
    if (priceOracle_ == address(0)) {
      revert ZeroAddressError();
    }
    if (percentageDepositFee_ > MAX_PERCENTAGE_FEE) {
      revert PercentageFeeTooHighError();
    }
    if (slippage_ > MAX_SLIPPAGE_TOLERANCE) {
      revert SlippageTooHighError();
    }
    if (minDeposit_ == 0) {
      revert MinDepositZeroError();
    }

    wrappedNativeToken = wrappedNativeToken_;

    tokenInfo[NATIVE_TOKEN] = TokenInfo({
      isAccepted: true,
      fixedDepositFee: fixedDepositFee_,
      percentageDepositFee: percentageDepositFee_,
      priceOracle: priceOracle_,
      paused: false,
      eligibleAsCollateral: eligibleAsCollateral_,
      decimals: NATIVE_TOKEN_DECIMALS,
      name: _nativeName,
      symbol: _nativeSymbol,
      defaultSlippageTolerance: slippage_,
      minDeposit: minDeposit_
    });

    // Add to token sets
    _tokenAddresses.add(NATIVE_TOKEN);
    _acceptedTokens.add(NATIVE_TOKEN);

    emit TokenAdded(
      NATIVE_TOKEN,
      fixedDepositFee_,
      percentageDepositFee_,
      priceOracle_
    );
    emit MinDepositUpdated(NATIVE_TOKEN, 0, minDeposit_);
    emit CollateralEligibilityUpdated(
      NATIVE_TOKEN,
      false,
      eligibleAsCollateral_
    );
  }

  /**
   * @notice Returns the address of the wrapped native token (e.g., WETH)
   * @dev This address is set during native token registration via addNativeToken
   * @return The address of the wrapped native token contract
   */
  function getWrappedNative() external view returns (address) {
    return address(wrappedNativeToken);
  }

  /// @notice Updates the minimum deposit requirement for a token
  /// @param token Address of the token to update
  /// @param newMinDeposit New minimum deposit amount
  /// @dev Only callable by accounts with ADMIN_ROLE
  /// @dev Emits MinDepositUpdated event
  function updateMinDeposit(
    address token,
    uint256 newMinDeposit
  ) external onlyRole(ADMIN_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }
    if (newMinDeposit == 0) {
      revert MinDepositZeroError();
    }

    uint256 oldMinDeposit = tokenInfo[token].minDeposit;
    tokenInfo[token].minDeposit = newMinDeposit;

    emit MinDepositUpdated(token, oldMinDeposit, newMinDeposit);
  }

  /// @notice Updates whether a token can be used as collateral
  /// @param token Address of the token to update
  /// @param newEligibility New collateral eligibility status
  /// @dev Only callable by accounts with ADMIN_ROLE
  /// @dev Emits CollateralEligibilityUpdated event
  function updateCollateralEligibility(
    address token,
    bool newEligibility
  ) external onlyRole(ADMIN_ROLE) {
    if (!tokenInfo[token].isAccepted) {
      revert TokenNotAcceptedError();
    }

    bool oldEligibility = tokenInfo[token].eligibleAsCollateral;
    if (oldEligibility == newEligibility) {
      revert EligibilityUnchangedError();
    }

    tokenInfo[token].eligibleAsCollateral = newEligibility;

    emit CollateralEligibilityUpdated(token, oldEligibility, newEligibility);
  }
}

// SPDX-License-Identifier: ISC
pragma solidity 0.8.20;

/// @notice Thrown when an address parameter is zero when it should not be
error ZeroAddressError();

/// @notice Thrown when attempting to add a token that is already registered
error TokenAlreadyAcceptedError();

/// @notice Thrown when a percentage fee exceeds the maximum allowed (25%)
error PercentageFeeTooHighError();

/// @notice Thrown when slippage tolerance exceeds the maximum allowed (35%)
error SlippageTooHighError();

/// @notice Thrown when minimum deposit is set to zero
error MinDepositZeroError();

/// @notice Thrown when attempting to operate on a token that is not registered
error TokenNotAcceptedError();

/// @notice Thrown when attempting to pause an already paused token
error TokenAlreadyPausedError();

/// @notice Thrown when attempting to unpause a token that is not paused
error TokenNotPausedError();

/// @notice Thrown when amount parameter is zero when it should not be
error ZeroAmountError();

/// @notice Thrown when attempting to set wrapped native token address to zero
error WrappedNativeZeroError();

/// @notice Thrown when attempting to set collateral eligibility to its current value
error EligibilityUnchangedError();

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

//SPDX-License-Identifier: ISC
pragma solidity 0.8.20;

interface IDepositTokenRegistry {
  struct TokenInfo {
    bool isAccepted;
    uint256 fixedDepositFee;
    uint256 percentageDepositFee;
    address priceOracle;
    bool paused;
    bool eligibleAsCollateral;
    uint8 decimals;
    string name;
    string symbol;
    uint256 defaultSlippageTolerance;
    uint256 minDeposit;
  }

  function isDepositEnabled(address token) external view returns (bool);
  function getTokenInfo(
    address token
  )
    external
    view
    returns (
      bool isAccepted,
      uint256 fixedDepositFee,
      uint256 percentageDepositFee,
      address priceOracle,
      bool paused,
      string memory name,
      string memory symbol,
      uint256 slippage,
      uint256 minDeposit,
      uint256 decimals,
      bool nativeToken
    );

  /// @notice Returns only the essential token information needed for share price calculations
  /// @param token The address of the token to query
  /// @return isAccepted Whether the token is accepted
  /// @return paused Whether the token is paused
  /// @return priceOracle The address of the price oracle for this token
  /// @return decimals The number of decimals for the token
  function getTokenPriceInfo(
    address token
  )
    external
    view
    returns (bool isAccepted, bool paused, address priceOracle, uint8 decimals);

  function getAcceptedTokens() external view returns (address[] memory);

  function previewMintFees(
    address token,
    uint256 amount
  ) external view returns (uint256);

  function previewDepositFees(
    address token,
    uint256 amount
  ) external view returns (uint256);

  function isEligibleAsCollateral(address token) external view returns (bool);

  function getCollateralTokens() external view returns (address[] memory);

  function getWrappedNative() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/DepositTokenRegistry.sol": "DepositTokenRegistry"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 100
  },
  "remappings": [],
  "viaIR": true
}