// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;


/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/interfaces/draft-IERC6093.sol


// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;





/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// File: @openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;



/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/utils/Address.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// File: @openzeppelin/contracts/security/ReentrancyGuard.sol


// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// File: contracts/interfaces/IBotRegistry.sol


pragma solidity ^0.8.0;

interface IBotRegistry {
    function botRegistry(address addr) external view returns (bool);
    function updateBotRegistry(address addr, bool status) external;
    function bulkUpdateBotRegistry(address[] memory accounts, bool status) external;
}
// File: contracts/tokens/Friendo.sol


pragma solidity ^0.8.20;







// Set token name
contract Friendo is ERC20, ERC20Burnable, Ownable, ReentrancyGuard {
    using Address for address payable;

    // Events
    event TradingEnabled(uint256 blockNumber);
    event PresaleActive(bool active, uint256 blockNumber);
    event TokenPurchase(address indexed buyer, uint256 ethAmount, uint256 tokenAmount);
    event RouterUpdated(address newRouterAddress);
    event WalletUpdated(string walletType, address newWalletAddress);
    event SniperProtectionUpdated(bool status);
    event FrontrunProtectionUpdated(bool status);
    event MinTxBlocksUpdated(uint256 blocks);
    event MaxWalletBalanceUpdated(uint256 balance);
    event BotRegistryUpdated(address indexed newAddress);
    event ProtectionExemptionsUpdated(address indexed addr, bool status);

    // Interfaces
    IBotRegistry public botRegistry; // External blacklist for anti-bot shenanigans

    // System Operation
    bool private publicTradingEnabled; // Allows accounts to purchase token without being flagged as a sniper
    bool private frontrunProtection; // Auto blacklists frontrunning bots
    bool private sniperProtection; // Auto blacklists snipers
    bool public presaleActive; // Does the contract accept ETH as part of a presale round?
    bool private inPresaleTx = false; // Disables trade protections for presale transactions

    // Modifiers
    // check if presale is active
    modifier onlyPresaleActive() {
        require(presaleActive, "Presale is not active");
        _;
    }

    // Struct for team wallets
    struct TeamWallets {
        address marketing;
        address dev;
        address liquidity;
        address burn;
    }

    TeamWallets public teamWallets;

    // Operation whitelist
    mapping(address => bool) public protectionExemption; // Allows specific team wallets to bypass limits such as max wallet size
    mapping(address => uint256) public purchaseRegistry; // Tracks accounts receiving tokens for frontrun protection
    uint256 public minTxBlocks; // Minimum blocks between purchase/sell transactions
    uint256 public maxWalletBalance;

    // Presale tracking
    mapping(address => uint256) public tokensPurchased;

    struct PresaleAllocations {
        uint256 purchaser;
        uint256 marketing;
        uint256 dev;
        uint256 liquidity;
        uint256 burn;
    }

    PresaleAllocations public presaleAllocations;

    uint256 public constant presaleTokenPrice = 10**6; // 0.000001 ETH/token
    uint256 public immutable maxPresaleTokenBuy;
    uint256 public immutable minPresaleTokenBuy;
    uint256 public immutable maxTokenSupply;

    // Define token settings
    constructor(
        address _marketingWallet,
        address _devWallet,
        address _liquidityWallet,
        address _burnWallet
    ) Ownable(msg.sender) ERC20("Friendo", "FRIENDO") {
        maxTokenSupply = 50000000 * 10 ** decimals();
        // Initial max wallet size
        maxWalletBalance = 1500000 * 10 ** decimals();
        // Presale min/max buys
        maxPresaleTokenBuy = 750000 * 10 ** decimals();
        minPresaleTokenBuy = 5000 * 10 ** decimals();

        // Bot/malicious user mitigation
        sniperProtection = true;
        frontrunProtection = true;
        minTxBlocks = 4; // Blocks between transfer/sell

        // Set Team Wallets
        teamWallets.marketing = _marketingWallet;
        teamWallets.dev = _devWallet;
        teamWallets.liquidity = _liquidityWallet;
        teamWallets.burn = _burnWallet;

        // Protection Exemptions
        protectionExemption[address(this)] = true;
        protectionExemption[msg.sender] = true;
        protectionExemption[teamWallets.marketing] = true;
        protectionExemption[teamWallets.dev] = true;
        protectionExemption[teamWallets.liquidity] = true;
        protectionExemption[teamWallets.burn] = true;

        // Initialize presale allocations
        presaleAllocations = PresaleAllocations({
            purchaser: 30,
            marketing: 10,
            dev: 5,
            liquidity: 35,
            burn: 20
        });

        // Mint tokens to contract and deployer for presale/initial liquidity
        uint256 totalSupply = maxTokenSupply;
        uint256 purchaserTokens = (totalSupply * presaleAllocations.purchaser) / 100;
        uint256 marketingTokens = (totalSupply * presaleAllocations.marketing) / 100;
        uint256 devTokens = (totalSupply * presaleAllocations.dev) / 100;
        uint256 liquidityTokens = (totalSupply * presaleAllocations.liquidity) / 100;
        uint256 burnTokens = (totalSupply * presaleAllocations.burn) / 100;

        _mint(address(this), purchaserTokens);
        _mint(teamWallets.marketing, marketingTokens);
        _mint(teamWallets.dev, devTokens);
        _mint(teamWallets.liquidity, liquidityTokens);
        _mint(teamWallets.burn, burnTokens);

    }

    // USER FUNCTIONS
    function _update(
        address sender,
        address recipient,
        uint256 amount
    ) internal override {
        require(amount > 0, "You attempt to throw 0 tokens but wrench your shoulder from the effort.");
        require(!isRegistered(sender) && !isRegistered(tx.origin), "Your account is not permitted to transfer tokens. If you wish to appeal, contact the team on Telegram.");
        require(protectionExemption[recipient] || presaleActive || publicTradingEnabled, "Trading is not enabled for the public. Please try again later.");
        
        // Prevent the burn wallet from transferring tokens to any address other than the zero address
        if (sender == teamWallets.burn) {
            require(recipient == address(0), "Burn wallet can only burn tokens");
        }

        // Max wallet balance logic
        if (!protectionExemption[recipient] && maxWalletBalance > 0) {
            uint256 newBalance = balanceOf(recipient) + amount;
            require(newBalance <= maxWalletBalance, "Amount exceeds max wallet balance");
        }
        
        if (!inPresaleTx) { // Bypass all protections when inside a presale transaction
            // Catch snipers. Note: This will catch *any* non-exempted buys until trading is enabled. Beware collateral damage
            // Used for stealth launches and to auto blacklist bots that try to snipe before a token is live
            if (sniperProtection && !publicTradingEnabled) {
                require(tokensPurchased[recipient] == 0, "Please wait until the presale is completed before or transferring tokens.");
                require(tokensPurchased[sender] == 0, "Please wait until the presale is completed before transferring tokens.");
                if (!protectionExemption[recipient]) { // Not exempted
                    _registerBot(recipient); // Blacklists account receiving tokens (commonly a MEV treasury contract)
                    _registerBot(tx.origin); // Blacklists operator (common with MEV bots)
                }
            }

            // Logic to detect or blacklist frontrunning bots
            if ( frontrunProtection ) {
                // If an account receives and sends tokens in a short window we assume they are a bot and add them to the bot registry 
                // Note: If the bot requires a minAmountOut (uniswap) or equivalent the tx will revert and won't be saved.
                // Adds token recipient/holder to purchase registry if not authorized

                if (!protectionExemption[recipient]) // 1. If the recipient is not exempted
                    purchaseRegistry[recipient] = block.number;
                
                if (!protectionExemption[sender]) { // 2. Sender not exempted
                    // If this sender has received tokens within the minTxBlocks period and is attempting to transfer
                    if (block.number - purchaseRegistry[sender] < minTxBlocks) {
                        _registerBot(sender); // Blacklists account sending tokens (commonly a MEV treasury contract)
                        _registerBot(tx.origin); // Blacklists operator (common with MEV bots)
                        return; // Attempted frontrun sells fail to transfer tokens
                    }
                }
            }
        }
        // Transfer the tokens. No taxes, no funny logic.
        super._update(sender, recipient, amount);
    }

    // END USER FUNCTIONS

    // INTERNAL FUNCTIONS
    function isRegistered(address addr) internal view returns (bool) {
        if (address(botRegistry) != address(0)) { // We have defined the address
            return botRegistry.botRegistry(addr);
        } else
            return false; // If we haven't defined it, nobody is a bot!
    }

    // Adds a bot to the registry. Accounts can be removed directly from the registry if needed
    function _registerBot(address addr) internal {
        if (address(botRegistry) != address(0)) { // We have defined the address
            // This contract must be a manager on the registry otherwise this will fail
            botRegistry.updateBotRegistry(addr, true);
        }
    }

    // END INTERNAL FUNCTIONS

    // ADMIN TOOLS
    // Enable trading. Cannot be used to disable trading
    function enableTrading() external onlyOwner {
        require(!publicTradingEnabled, "Trading is already enabled");
        publicTradingEnabled = true;
        sniperProtection = false;
        emit TradingEnabled(block.number);
    }
    // Enable presale.
    function startPresale() external onlyOwner {
        require(!presaleActive, "Presale is already active");
        presaleActive = true;
        emit PresaleActive(true, block.number);
    }
    function endPresale() external onlyOwner onlyPresaleActive() { // WARNING: This will burn all tokens held by the contract!
        presaleActive = false;
        emit PresaleActive(false, block.number);
        // Burn remaining tokens after presale concludes
        uint256 tokenBalance = balanceOf(address(this));
        _burn(address(this), tokenBalance);
    }

    // Enable/disable sniper protection
    function updateSniperProtection(bool status) external onlyOwner {
        require(sniperProtection != status, "Protection already set");
        sniperProtection = status;
        emit SniperProtectionUpdated(status);
    }
    // Enable/disable frontrun protection
    function updateFrontrunProtection(bool status) external onlyOwner {
        require(frontrunProtection != status, "Protection already set");
        frontrunProtection = status;
        emit FrontrunProtectionUpdated(status);
    }
    // Update minimum blocks between purchase/sell transactions
    function updateMinTxBlocks(uint256 blocks) external onlyOwner {
        require(blocks < 75, "Longer periods aren't really frontunning, are they?");
        minTxBlocks = blocks;
        emit MinTxBlocksUpdated(blocks);
    }
    // Define the bot registry
    function setBotRegistry(address addr) external onlyOwner {
        botRegistry = IBotRegistry(addr); // Can be changed to other a different registry later
        emit BotRegistryUpdated(addr);
    }
    // Set max wallet balance. Set 0 to disable.
    function setMaxWalletBalance(uint256 balance) external onlyOwner {
        maxWalletBalance = balance;
        emit MaxWalletBalanceUpdated(balance);
    }
    // Set protection exemptions
    function setProtectionExemption(address addr, bool status) external onlyOwner {
        protectionExemption[addr] = status;
        emit ProtectionExemptionsUpdated(addr, status);
    }

    // Note: Burn wallet is defined at deployment and cannot be changed
    function updateTeamWallet(string memory walletType, address newWallet) external onlyOwner {
        if (keccak256(abi.encodePacked(walletType)) == keccak256(abi.encodePacked("marketing"))) {
            protectionExemption[teamWallets.marketing] = false;
            teamWallets.marketing = newWallet;
            protectionExemption[newWallet] = true;
        } else if (keccak256(abi.encodePacked(walletType)) == keccak256(abi.encodePacked("dev"))) {
            protectionExemption[teamWallets.dev] = false;
            teamWallets.dev = newWallet;
            protectionExemption[newWallet] = true;
        } else if (keccak256(abi.encodePacked(walletType)) == keccak256(abi.encodePacked("liquidity"))) {
            protectionExemption[teamWallets.liquidity] = false;
            teamWallets.liquidity = newWallet;
            protectionExemption[newWallet] = true;
        } else {
            revert("Invalid wallet type");
        }
        emit WalletUpdated(walletType, newWallet);
    }

    /** Emergency withdraw for ETH left in contract **/
    function rescueNative(uint256 amount) external onlyOwner nonReentrant {
        require(!presaleActive, "Sorry, unable to rug presale participants, politely get lost.");
        payable(owner()).transfer(amount);
    }

    // END ADMIN TOOLS

    // Handle funds deposited into the contract during/after the presale
    receive() external payable onlyPresaleActive() nonReentrant {
        uint256 ethAmount = msg.value;
        uint256 tokenAmount = ethAmount * presaleTokenPrice;

        require(tokenAmount >= minPresaleTokenBuy, "Purchase amount is below the minimum purchase amount");

        // Calculate the maximum token amount the buyer can purchase
        uint256 maxTokensPurchasable = maxPresaleTokenBuy - tokensPurchased[msg.sender];

        // Ensure the purchase does not exceed the max presale buy limit for the user
        require(maxTokensPurchasable > 0, "Purchase exceeds maximum presale amount");

        // If tokenAmount exceeds max buy limit, adjust and send change back
        if (tokenAmount > maxTokensPurchasable) {
            // Calculate the excess token amount and convert it back to ETH
            uint256 excessEthAmount = (tokenAmount - maxTokensPurchasable) / presaleTokenPrice;

            // Adjust the tokenAmount to the max buy limit
            tokenAmount = maxTokensPurchasable;

            // Send the excess ETH back to the buyer
            (bool success, ) = msg.sender.call{value: excessEthAmount}("");
            require(success, "User transfer failed");

            // Adjust the ethAmount to the actual amount used for the purchase
            ethAmount -= excessEthAmount;
        }

        // Ensure the contract has enough tokens to distribute
        require(balanceOf(address(this)) >= tokenAmount, "Not enough tokens in contract");

        // Emit event
        emit TokenPurchase(msg.sender, ethAmount, tokenAmount);

        inPresaleTx = true;

        // Transfer the full token amount to the purchaser
        super._transfer(address(this), msg.sender, tokenAmount);
        tokensPurchased[msg.sender] += tokenAmount;

        inPresaleTx = false;

        // Transfer 10% of the ETH balance to the marketing wallet
        uint256 marketingEthAmount = ethAmount / 10;
        (bool successMarketing, ) = teamWallets.marketing.call{value: marketingEthAmount}("");
        require(successMarketing, "Transfer to marketing wallet failed");

        // Transfer the rest to the liquidity wallet
        uint256 remainingEthAmount = ethAmount - marketingEthAmount;
        (bool successLiquidity, ) = teamWallets.liquidity.call{value: remainingEthAmount}("");
        require(successLiquidity, "Transfer to liquidity wallet failed");
    }
}

{
  "compilationTarget": {
    "Friendo.sol": "Friendo"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}