// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

interface ITheChainCollection {
	struct HashData {
		bytes32 previousHash;
		address creator;
		uint96 tokenId;
		string uri;
	}

	function mint(
		uint256 tokenId,
		address creator,
		address transferTo,
		bytes32 currentHash,
		bytes32 previousHash,
		string calldata uri
	) external;
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

interface ITheChainSales {
	event NewOrder(uint256 orderId, address creator, uint256 tokenId, uint256 price, uint256 startsAt);

	event OrderClosed(uint256 orderId, address operator, bool canceled);

	struct Order {
		address creator;
		uint96 price;
		uint128 tokenId;
		uint128 startsAt;
	}

	function getOrders(uint256[] calldata orderIds) external view returns (Order[] memory);

	function fulfillOrder(uint256 orderId) external payable;

	function createOrder(address creator, uint96 price, uint128 tokenId, uint128 startsAt) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {WithOperators} from "./WithOperators.sol";

/// @title OwnableOperators
/// @author dev by @dievardump
/// @notice This contract adds ownable & operators management
abstract contract OwnableOperators is Ownable, WithOperators {
	modifier onlyOperator() virtual override {
		if (msg.sender != owner()) {
			if (!operators[msg.sender]) {
				revert NotAuthorized();
			}
		}
		_;
	}

	/// @notice Allows to add operators to this contract
	/// @param operatorsList the new operators to add
	/// @param isOperator if the operators should be added or removed
	function setOperators(address[] memory operatorsList, bool isOperator) public onlyOwner {
		_setOperators(operatorsList, isOperator);
	}
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import {IERC721} from "@openzeppelin/contracts/interfaces/IERC721.sol";

import {OwnableOperators} from "./utils/OwnableOperators.sol";

import {ITheChainCollection} from "./interfaces/ITheChainCollection.sol";
import {ITheChainSales} from "./interfaces/ITheChainSales.sol";

contract TheChainSales is ITheChainSales, OwnableOperators {
	error InvalidOrder();
	error TooEarly();
	error InvalidPayment();
	error FailedPayment();

	error TokenNotEscrowed();
	error UnknownOrder();
	error OrderExpired();

	struct ShareHolder {
		address account;
		uint96 share;
	}

	address public immutable THE_CHAIN;

	mapping(uint256 => Order) public orders;

	ShareHolder public theChainShare;

	uint256 private _lastOrderId;

	uint256 public startsAt;

	constructor(address theChain, ShareHolder memory initShare) {
		THE_CHAIN = theChain;
		theChainShare = initShare;
	}

	function getOrders(uint256[] calldata orderIds) external view override returns (Order[] memory) {
		uint256 length = orderIds.length;
		Order[] memory results = new Order[](length);
		for (uint i; i < length; i++) {
			results[i] = orders[orderIds[i]];
		}

		return results;
	}

	// =============================================================
	//                       	   Interactions
	// =============================================================

	function fulfillOrder(uint256 orderId) external payable override {
		Order memory order = _requireOrderExists(orderId);

		if (order.startsAt > block.timestamp || startsAt > block.timestamp) {
			revert TooEarly();
		}

		if (msg.value != order.price) {
			revert InvalidPayment();
		}

		// we delete the order
		delete orders[orderId];

		// we close it
		emit OrderClosed(orderId, msg.sender, false);

		ShareHolder memory theChainShare_ = theChainShare;

		// the chain
		uint256 share = (msg.value * theChainShare_.share) / 10000;
		if (share > 0) {
			_transferValue(theChainShare_.account, share);
		}

		// creator
		_transferValue(order.creator, msg.value - share);

		// transfer
		IERC721(THE_CHAIN).transferFrom(address(this), msg.sender, order.tokenId);
	}

	function createOrder(address creator, uint96 price, uint128 tokenId, uint128 saleStartsAt) external onlyOperator {
		_requireEscrowed(tokenId);

		uint256 orderId = ++_lastOrderId;

		orders[orderId] = Order(creator, price, tokenId, saleStartsAt);

		emit NewOrder(orderId, creator, tokenId, price, saleStartsAt);
	}

	// =============================================================
	//                    	Creators & Owner
	// =============================================================

	function cancelOrder(uint256 orderId, address recipient) external {
		// only the contract owner or the creator can cancel an order
		if (msg.sender != owner()) {
			if (msg.sender != orders[orderId].creator) {
				revert NotAuthorized();
			}
		}

		_cancelOrder(orderId, recipient);
	}

	function cancelOrders(uint256[] memory orderIds, address recipient) external onlyOwner {
		uint256 length = orderIds.length;
		for (uint256 i; i < length; i++) {
			_cancelOrder(orderIds[i], recipient);
		}
	}

	// =============================================================
	//                       	 Owner
	// =============================================================

	function editTheChainShares(ShareHolder calldata newShares) external onlyOwner {
		theChainShare = newShares;
	}

	/// @notice Allows owner to update when the sales starts
	/// @param newStartsAt the new timestamp (in seconds)
	function setStartsAt(uint256 newStartsAt) external onlyOwner {
		startsAt = newStartsAt;
	}

	// =============================================================
	//                       	 Internals
	// =============================================================

	function _transferValue(address payee, uint256 value) internal {
		(bool success, ) = payee.call{value: value, gas: 30_000}("");
		if (!success) {
			revert FailedPayment();
		}
	}

	function _requireOrderExists(uint256 orderId) internal view returns (Order memory) {
		Order memory order = orders[orderId];

		if (order.creator == address(0)) {
			if (orderId <= _lastOrderId) {
				revert OrderExpired();
			} else {
				revert UnknownOrder();
			}
		}

		_requireEscrowed(order.tokenId);

		return order;
	}

	function _requireEscrowed(uint256 tokenId) internal view {
		if (IERC721(THE_CHAIN).ownerOf(tokenId) != address(this)) {
			revert TokenNotEscrowed();
		}
	}

	function _cancelOrder(uint256 orderId, address recipient) internal {
		Order memory order = _requireOrderExists(orderId);

		// we delete the order
		delete orders[orderId];

		// we close it
		emit OrderClosed(orderId, msg.sender, true);

		// transfer to recipient
		IERC721(THE_CHAIN).transferFrom(address(this), recipient, order.tokenId);
	}
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

/// @title WithOperators
/// @author dev by @dievardump
/// @notice This contract adds operators management
abstract contract WithOperators {
	error NotAuthorized();

	/// @notice the address of the minter module
	mapping(address => bool) public operators;

	modifier onlyOperator() virtual {
		if (!operators[msg.sender]) {
			revert NotAuthorized();
		}
		_;
	}

	/// @notice Allows to add operators to this contract
	/// @param operatorsList the new operators to add
	/// @param isOperator if the operators should be added or removed
	function _setOperators(address[] memory operatorsList, bool isOperator) internal virtual {
		uint256 length = operatorsList.length;
		for (uint256 i; i < length; i++) {
			operators[operatorsList[i]] = isOperator;
		}
	}
}

{
  "compilationTarget": {
    "src/TheChainSales.sol": "TheChainSales"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 2000
  },
  "remappings": []
}