// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity ^0.8.19;

import {SafeERC20, IERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IPod, IRouter, IWeth} from "src/interfaces/IHam.sol";

contract HamZap is Ownable {
    using SafeERC20 for IERC20;

    /* ========== STATE VARIABLES ========== */

    IPod public constant pHAM =
        IPod(0x2C8D2FC58B80aCb3b307C165af8F3eE296e6A271);

    IRouter public constant bmxRouter =
        IRouter(0x3003a6A708679B415E03B25bbaEca19F8345D235);

    IWeth public constant weth =
        IWeth(0x4200000000000000000000000000000000000006);

    // address tokenIn => address tokenOut => IRouter.Routes[] swapRoute
    mapping(address => mapping(address => IRouter.Routes[])) public zapRoutes;

    address[6] public tokens;

    /* ========== EVENTS ========== */

    event ZapIn(
        address indexed user,
        address indexed zapToken,
        uint256 zapTokenAmount,
        uint256 pHamAmount
    );
    event ZapOut(
        address indexed user,
        address indexed zapToken,
        uint256 amount
    );
    event Recovered(address token, uint256 amount);

    /* ========== CONSTRUCTOR ========== */

    constructor() {
        tokens[0] = 0x548f93779fBC992010C07467cBaf329DD5F059B7; // BMX
        tokens[1] = 0x0d97F261b1e88845184f678e2d1e7a98D9FD38dE; // TYBG
        tokens[2] = 0x4ed4E862860beD51a9570b96d89aF5E1B0Efefed; // DEGEN
        tokens[3] = 0xecaF81Eb42cd30014EB44130b89Bcd6d4Ad98B92; // CHAD
        tokens[4] = 0x5B5dee44552546ECEA05EDeA01DCD7Be7aa6144A; // TN100X
        tokens[5] = 0x6921B130D297cc43754afba22e5EAc0FBf8Db75b; // DOGINME

        // approve our tokens on pHAM and our router
        for (uint256 i; i < 6; ++i) {
            IERC20(tokens[i]).safeApprove(address(pHAM), type(uint256).max);
            IERC20(tokens[i]).safeApprove(
                address(bmxRouter),
                type(uint256).max
            );
        }
    }

    /* ========== VIEW FUNCTIONS ========== */

    /**
     * @notice Estimate how much pHAM we get from zapping in a given token.
     * @param _zapToken Token to zap in.
     * @param _zapTokenAmount Amount of tokens to zap in.
     * @param _slippage Extra slippage to account for, in bps.
     * @return pHamOut Estimated amount of pHAM tokens minted.
     */
    function estimateZapIn(
        address _zapToken,
        uint256 _zapTokenAmount,
        uint256 _slippage
    ) external view returns (uint256 pHamOut) {
        address[6] memory _tokens = tokens;
        require(zapRoutes[_zapToken][tokens[0]].length > 0, "no route set");
        require(_slippage < 10_000, "bps");

        uint256[6] memory percentages = getCurrentPercentages(
            _tokens,
            _zapToken,
            _zapTokenAmount / 6 // assume 1/6 to each token as our starting point
        );
        uint256[] memory amountsOut;
        uint256[6] memory tokenAmounts;

        for (uint256 i; i < 6; ++i) {
            amountsOut = bmxRouter.getAmountsOut(
                (percentages[i] * 1e6 * _zapTokenAmount) / 1e24,
                zapRoutes[_zapToken][_tokens[i]]
            );
            tokenAmounts[i] = amountsOut[amountsOut.length - 1];
        }

        // check how much BMX we should use based on all our other amounts
        pHamOut = _getAmountForBond(_tokens, tokenAmounts);

        // shave off a few bps to avoid rounding issues
        pHamOut = (pHamOut * (10_000 - _slippage)) / 10_000;

        // check our min bond out
        pHamOut = _getBondMinOut(pHamOut);
    }

    /**
     * @notice Estimate how much zapToken we get zapping out from pHAM.
     * @param _phamAmount Amount of pHAM to zap out.
     * @param _zapToken Token to zap out to.
     * @return zapTokenOut Estimated amount of zapToken received.
     */
    function estimateZapOut(
        uint256 _phamAmount,
        address _zapToken
    ) external view returns (uint256 zapTokenOut) {
        address[6] memory _tokens = tokens;
        require(zapRoutes[_tokens[0]][_zapToken].length > 0, "no route set");
        uint256 amountOut;
        uint256[] memory amountsOut;

        for (uint256 i; i < 6; ++i) {
            // immutable 0.8% bond/debond fee on pHAM, add another 0.01% to avoid rounding errors
            amountOut =
                (991_900 *
                    _phamAmount *
                    IERC20(_tokens[i]).balanceOf(address(pHAM))) /
                pHAM.totalSupply() /
                1e6;
            amountsOut = bmxRouter.getAmountsOut(
                amountOut,
                zapRoutes[_tokens[i]][_zapToken]
            );
            zapTokenOut += amountsOut[amountsOut.length - 1];
        }
    }

    /// @notice Pull the six token addresses that make up pHAM.
    function getTokens() public view returns (address[6] memory tokenList) {
        tokenList = tokens;
    }

    /**
     * @notice Calculates how much _zapToken to use to buy each of our 6 underlying tokens when zapping in.
     * @param _tokens Our array of tokens to use, passed in as a memory arg to save gas.
     * @param _zapToken Token to zap in with.
     * @param _zapAmount Token amount to zap in.
     * @return currentPercentages The percentage (base 1e18) of _zapToken to swap for each of our 6 pHAM tokens.
     */
    function getCurrentPercentages(
        address[6] memory _tokens,
        address _zapToken,
        uint256 _zapAmount
    ) public view returns (uint256[6] memory currentPercentages) {
        // use these for our first for loop
        uint256 runningTotal;
        uint256[6] memory amounts;

        // use these for our second for loop
        uint256 newPercentage;
        uint256 relativeTotal;

        // store our tokens array in memory to save gas
        uint256[6] memory basePercentages = _getBasePercentages(_tokens);

        for (uint256 i; i < 6; ++i) {
            uint256[] memory amountsOut = bmxRouter.getAmountsOut(
                _zapAmount,
                zapRoutes[_zapToken][_tokens[i]]
            );
            // reassign our now-used currentPercentage to amountOut from our swap
            amounts[i] = amountsOut[amountsOut.length - 1];
            runningTotal += amounts[i];
        }

        for (uint256 i; i < 6; ++i) {
            newPercentage = (amounts[i] * 1e24) / runningTotal / 1e6;
            amounts[i] = (basePercentages[i] * 1e24) / newPercentage / 1e6;
            relativeTotal += amounts[i];
        }

        for (uint256 i; i < 6; ++i) {
            currentPercentages[i] = (amounts[i] * 1e24) / relativeTotal / 1e6;
        }
    }

    function _getBondMinOut(
        uint256 _bmxDepositAmount
    ) internal view returns (uint256 minAmountOut) {
        // immutable 0.8% bond/debond fee on pHAM, add another 0.01% to avoid rounding errors
        minAmountOut =
            (991_900 * _bmxDepositAmount * pHAM.totalSupply()) /
            IERC20(tokens[0]).balanceOf(address(pHAM)) /
            1e6;
    }

    function _getBasePercentages(
        address[6] memory _tokens
    ) internal view returns (uint256[6] memory basePercentages) {
        // for each asset, calculate relative share of total
        uint256[6] memory currentAmounts;
        uint256 runningBaseTotal;

        for (uint256 i; i < 6; ++i) {
            currentAmounts[i] = IERC20(_tokens[i]).balanceOf(address(pHAM));
            runningBaseTotal += currentAmounts[i];
        }

        // calculate our base percentage
        for (uint256 i; i < 6; ++i) {
            basePercentages[i] =
                (currentAmounts[i] * 1e24) /
                runningBaseTotal /
                1e6;
        }
    }

    function _getAmountForBond(
        address[6] memory _tokens,
        uint256[6] memory _tokensIn
    ) internal view returns (uint256 bmxAmount) {
        uint256 fraction;
        uint256 bmxPhamBalance = IERC20(_tokens[0]).balanceOf(address(pHAM));
        for (uint256 i = 1; i < 6; ++i) {
            // we calculate how much BMX we need, based on our amount of token i
            // if that's less than we have, use the smaller amount
            fraction =
                (_tokensIn[i] * 1e24) /
                IERC20(_tokens[i]).balanceOf(address(pHAM)) /
                1e6;
            bmxAmount = (fraction * 1e6 * bmxPhamBalance) / 1e24;
            bmxAmount = min(bmxAmount, _tokensIn[0]);
        }
    }

    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /* ========== MUTATIVE FUNCTIONS ========== */

    /**
     * @notice Zap in an asset for pHAM.
     * @param _zapToken Token to zap in.
     * @param _zapTokenAmount Amount of tokens to zap in.
     * @param _slippage Extra slippage to account for, in bps.
     * @param _minAmountOut Minimum amount of pHAM we require for zap to succeed.
     * @param _remainderAsZapToken Bool to swap leftover underlying tokens back to the zapToken.
     * @return amount Amount of pHAM tokens minted.
     */
    function zapIn(
        address _zapToken,
        uint256 _zapTokenAmount,
        uint256 _slippage,
        uint256 _minAmountOut,
        bool _remainderAsZapToken
    ) external returns (uint256 amount) {
        // store locally to save gas
        address[6] memory _tokens = tokens;
        require(_slippage < 10_000, "bps");
        require(zapRoutes[_zapToken][tokens[0]].length > 0, "no route set");

        // calculate how much of our input amount should be swapped for each token
        uint256[6] memory amounts = getCurrentPercentages(
            _tokens,
            _zapToken,
            _zapTokenAmount / 6 // assume 1/6 to each token as our starting point
        );

        IERC20(_zapToken).safeTransferFrom(
            msg.sender,
            address(this),
            _zapTokenAmount
        );

        // swap for different amount of assets based on our currentPercentages
        // leave an extra 0.1 bps of space for rounding error
        for (uint256 i; i < 6; ++i) {
            uint256[] memory amountsOut = bmxRouter.swapExactTokensForTokens(
                (amounts[i] * 1e5 * _zapTokenAmount * 99999) / 1e28,
                0,
                zapRoutes[_zapToken][_tokens[i]],
                address(this),
                type(uint256).max
            );
            // reassign our now-used currentPercentage to amountOut from our swap
            amounts[i] = amountsOut[amountsOut.length - 1];
        }

        // now we need to bond!
        // first, check how much bmx we should bond so we don't revert
        uint256 toDeposit = _getAmountForBond(_tokens, amounts);

        // shave off a few bps to avoid rounding issues
        toDeposit = (toDeposit * (10_000 - _slippage)) / 10_000;

        // then, bond, using our min out param as well
        pHAM.bond(_tokens[0], toDeposit, _minAmountOut);

        // send back our extra zapToken to user
        amount = IERC20(_zapToken).balanceOf(address(this));
        IERC20(_zapToken).safeTransfer(msg.sender, amount);

        if (_remainderAsZapToken) {
            // swap back all of our tokens to zap token, send to user
            for (uint256 i; i < 6; ++i) {
                bmxRouter.swapExactTokensForTokens(
                    IERC20(_tokens[i]).balanceOf(address(this)),
                    0,
                    zapRoutes[_tokens[i]][_zapToken],
                    msg.sender,
                    type(uint256).max
                );
            }
        } else {
            // send back any extra other tokens as well
            for (uint256 i; i < 6; ++i) {
                amount = IERC20(_tokens[i]).balanceOf(address(this));
                IERC20(_tokens[i]).safeTransfer(msg.sender, amount);
            }
        }

        // send pHAM to user
        amount = pHAM.balanceOf(address(this));
        pHAM.transfer(msg.sender, amount);

        emit ZapIn(msg.sender, _zapToken, _zapTokenAmount, amount);
    }

    /**
     * @notice Zap in ether for pHAM.
     * @param _zapTokenAmount Amount of ether to zap in.
     * @param _slippage Extra slippage to account for, in bps.
     * @param _minAmountOut Minimum amount of pHAM we require for zap to succeed.
     * @param _remainderAsZapToken Bool to swap leftover underlying tokens back to WETH.
     * @return amount Amount of pHAM tokens minted.
     */
    function zapInEther(
        uint256 _zapTokenAmount,
        uint256 _slippage,
        uint256 _minAmountOut,
        bool _remainderAsZapToken
    ) external payable returns (uint256 amount) {
        // store locally to save gas
        address[6] memory _tokens = tokens;
        require(_slippage < 10_000, "bps");

        // deposit our ETH to WETH
        address _weth = address(weth);
        weth.deposit{value: msg.value}();
        require(
            _zapTokenAmount == weth.balanceOf(address(this)),
            "not enough weth"
        );

        require(zapRoutes[_weth][tokens[0]].length > 0, "no route set");

        // calculate how much of our input amount should be swapped for each token
        uint256[6] memory amounts = getCurrentPercentages(
            _tokens,
            _weth,
            _zapTokenAmount / 6 // assume 1/6 to each token as our starting point
        );

        // swap for different amount of assets based on our currentPercentages
        // leave an extra 0.1 bps of space for rounding error
        for (uint256 i; i < 6; ++i) {
            uint256[] memory amountsOut = bmxRouter.swapExactTokensForTokens(
                (amounts[i] * 1e5 * _zapTokenAmount * 99999) / 1e28,
                0,
                zapRoutes[_weth][_tokens[i]],
                address(this),
                type(uint256).max
            );
            // reassign our now-used currentPercentage to amountOut from our swap
            amounts[i] = amountsOut[amountsOut.length - 1];
        }

        // now we need to bond!
        // first, check how much bmx we should bond so we don't revert
        uint256 toDeposit = _getAmountForBond(_tokens, amounts);

        // shave off a few bps to avoid rounding issues
        toDeposit = (toDeposit * (10_000 - _slippage)) / 10_000;

        // then, bond, using our min out param as well
        pHAM.bond(_tokens[0], toDeposit, _minAmountOut);

        // send back our extra zapToken to user
        amount = IERC20(_weth).balanceOf(address(this));
        IERC20(_weth).safeTransfer(msg.sender, amount);

        if (_remainderAsZapToken) {
            // swap back all of our tokens to zap token, send to user
            for (uint256 i; i < 6; ++i) {
                bmxRouter.swapExactTokensForTokens(
                    IERC20(_tokens[i]).balanceOf(address(this)),
                    0,
                    zapRoutes[_tokens[i]][_weth],
                    msg.sender,
                    type(uint256).max
                );
            }
        } else {
            // send back any extra other tokens as well
            for (uint256 i; i < 6; ++i) {
                amount = IERC20(_tokens[i]).balanceOf(address(this));
                IERC20(_tokens[i]).safeTransfer(msg.sender, amount);
            }
        }

        // send pHAM to user
        amount = pHAM.balanceOf(address(this));
        pHAM.transfer(msg.sender, amount);

        emit ZapIn(msg.sender, _weth, _zapTokenAmount, amount);
    }

    /**
     * @notice Convert pHAM to a chosen zap token.
     * @param _amount Amount of pHAM tokens to zap out.
     * @param _tokenOut Token to swap pHAM for.
     * @param _minAmountOut Minimum amount of tokenOut to accept for a successful transaction.
     * @return amountOut Amount of tokenOut sent back to user.
     */
    function zapOut(
        uint256 _amount,
        address _tokenOut,
        uint256 _minAmountOut
    ) external returns (uint256 amountOut) {
        // store locally to save gas
        address[6] memory _tokens = tokens;
        // don't allow a zap if we haven't set up the route
        require(zapRoutes[_tokens[0]][_tokenOut].length > 0, "no route set");
        // transfer in the pHAM to the zap
        pHAM.transferFrom(msg.sender, address(this), _amount);

        // debond our pHAM to the underlying assets
        uint8[] memory emptyUint;
        address[] memory emptyAddress;
        pHAM.debond(_amount, emptyAddress, emptyUint);

        // swap back all of our tokens to tokenOut
        for (uint256 i; i < 6; ++i) {
            bmxRouter.swapExactTokensForTokens(
                IERC20(_tokens[i]).balanceOf(address(this)),
                0,
                zapRoutes[_tokens[i]][_tokenOut],
                address(this),
                type(uint256).max
            );
        }

        // send back our tokenOut to user; do this step to validate minAmountOut
        amountOut = IERC20(_tokenOut).balanceOf(address(this));
        require(amountOut >= _minAmountOut, "below minAmountOut");
        IERC20(_tokenOut).safeTransfer(msg.sender, amountOut);

        emit ZapOut(msg.sender, _tokenOut, amountOut);
    }

    /**
     * @notice Convert pHAM to ether.
     * @param _amount Amount of pHAM tokens to zap out.
     * @param _minAmountOut Minimum amount of ether to accept for a successful transaction.
     * @return amountOut Amount of ether sent back to user.
     */
    function zapOutEther(
        uint256 _amount,
        uint256 _minAmountOut
    ) external returns (uint256 amountOut) {
        // store locally to save gas
        address[6] memory _tokens = tokens;
        address _tokenOut = address(weth);
        require(zapRoutes[_tokens[0]][_tokenOut].length > 0, "no route set");

        // transfer in the pHAM to the zap
        pHAM.transferFrom(msg.sender, address(this), _amount);

        // debond our pHAM to the underlying assets
        uint8[] memory emptyUint;
        address[] memory emptyAddress;
        pHAM.debond(_amount, emptyAddress, emptyUint);

        // swap back all of our tokens to token out
        for (uint256 i; i < 6; ++i) {
            bmxRouter.swapExactTokensForTokens(
                IERC20(_tokens[i]).balanceOf(address(this)),
                0,
                zapRoutes[_tokens[i]][_tokenOut],
                address(this),
                type(uint256).max
            );
        }

        // send back our ether to user
        amountOut = IERC20(_tokenOut).balanceOf(address(this));
        weth.withdraw(amountOut);
        amountOut = address(this).balance;
        require(amountOut >= _minAmountOut, "below minAmountOut");
        address payable to = payable(msg.sender);
        to.transfer(amountOut);

        emit ZapOut(msg.sender, _tokenOut, amountOut);
    }

    // use this function so we don't have to do specific approvals for any token we may want to zap in
    function _checkAllowance(address _contract, address _token) internal {
        if (IERC20(_token).allowance(address(this), _contract) == 0) {
            IERC20(_token).safeApprove(_contract, type(uint256).max);
        }
    }

    /// @notice Use this in case someone accidentally sends tokens here.
    function recoverERC20(
        address tokenAddress,
        uint256 tokenAmount
    ) external onlyOwner {
        IERC20(tokenAddress).safeTransfer(owner(), tokenAmount);
        emit Recovered(tokenAddress, tokenAmount);
    }

    receive() external payable {}

    /* ========== SETTERS ========== */
    /**
     * @notice Here we can add swap routes for various tokens.
     * @dev Must be called by owner.
     * @param _tokenIn Token to zap in.
     * @param _tokenOut Token to receive.
     * @param _newSwapRoute Swap route for _tokenIn -> _tokenOut, using Routes structs.
     */
    function setSwapRoutes(
        address _tokenIn,
        address _tokenOut,
        IRouter.Routes[] memory _newSwapRoute
    ) external onlyOwner {
        delete zapRoutes[_tokenIn][_tokenOut];

        // check approval of zapToken on our router
        _checkAllowance(address(bmxRouter), _tokenIn);

        for (uint256 i; i < _newSwapRoute.length; ++i) {
            zapRoutes[_tokenIn][_tokenOut].push(_newSwapRoute[i]);
        }

        if (
            _tokenOut !=
            zapRoutes[_tokenIn][_tokenOut][_newSwapRoute.length - 1].to
        ) {
            revert("tokenOut route error");
        }

        if (_tokenIn != zapRoutes[_tokenIn][_tokenOut][0].from) {
            revert("tokenIn route error");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: GNU AGPLv3
pragma solidity ^0.8.19;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IPod is IERC20 {
    function bond(
        address token,
        uint256 amount,
        uint256 amountMintMin
    ) external;

    function debond(
        uint256 amount,
        address[] memory token,
        uint8[] memory percentage
    ) external;
}

interface IRouter {
    struct Routes {
        address from;
        address to;
        bool stable;
    }

    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        Routes[] memory routes,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function getAmountOut(
        uint256 amountIn,
        address tokenIn,
        address tokenOut,
        bool stable
    ) external view returns (uint256 amount);

    function getAmountsOut(
        uint256 _amountIn,
        Routes[] memory _routes
    ) external view returns (uint256[] memory amounts);

    function getMintAmountWrappedBLT(
        address tokenIn,
        uint256 amountIn
    ) external view returns (uint256);

    function getRedeemAmountWrappedBLT(
        address _tokenOut,
        uint256 _amount,
        bool _roundUp
    ) external view returns (uint256);
}

interface IWeth is IERC20 {
    function deposit() external payable;

    function withdraw(uint256 wad) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

{
  "compilationTarget": {
    "src/HamZap.sol": "HamZap"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":@tokenized-strategy/=lib/tokenized-strategy-periphery/lib/tokenized-strategy/src/",
    ":@yearn-vaults/=lib/tokenized-strategy-periphery/lib/yearn-vaults-v3/contracts/",
    ":ds-test/=lib/tokenized-strategy-periphery/lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/tokenized-strategy/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":openzeppelin/=lib/openzeppelin-contracts/contracts/",
    ":tokenized-strategy-periphery/=lib/tokenized-strategy-periphery/",
    ":tokenized-strategy/=lib/tokenized-strategy/",
    ":yearn-vaults-v3/=lib/tokenized-strategy-periphery/lib/yearn-vaults-v3/"
  ]
}