// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC1155/IERC1155Receiver.sol";
import "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./utils/Proxyable.sol";
import "./interfaces/IFishdRYFT.sol";

contract FishStaking is Ownable, ReentrancyGuard, Proxyable {
    struct User {
        uint256[] nftIds;
        uint256 rewardDebt;
        uint256 fishWeight;
        uint256 claimedRewards;
        uint256 lastStakeTime;
    }

    address public immutable fishdRYFTContract;
    address public rewardToken;
    address public treasuryAddress;

    bool public stakingEnabled; // default is false

    uint256 accTokensPerShare; // Accumulated tokens per share, times 1e12. See below.
    uint256 public blocksPerDay = 45000; // The estimated number of mined blocks per day.
    uint256 public distributionDurationDays = 30; // 30 days
    uint256 lastRewardBlock; // Last block number that tokens distribution occurs.
    uint256 public rewardPerBlock; // Tokens distributed per block. Use getTokenPerBlock() to get the updated reward.
    uint256 public stakeLockPeriod = 10 days; // 10 days
    uint256 public startBlock; // The block number when token mining starts.
    uint256 public totalFishWeight;
    uint256 public totalReward;

    mapping(address => User) public users;

    error CannotChangeStartBlock();
    error CannotWithdrawRewardToken();
    error FailedSendingETH();
    error InsufficientBalance();
    error StakeLocked();
    error StakingDisabled();
    error ZeroAddress();

    event Claim(address indexed user, uint256 indexed amount);
    event EmergencyWithdraw(address indexed user);
    event DepositRewards(
        uint256 indexed amount,
        uint256 indexed newRewardPerBlock
    );
    event ProxyStake(address user, uint256 nftId, uint256 amount);
    event Stake(address indexed user, uint256 nftId, uint256 amount);
    event Unstake(address indexed user);
    event WithdrawETH(address indexed sender, uint256 indexed balance);

    modifier nonZeroAddress(address _address) {
        if (_address == address(0)) revert ZeroAddress();
        _;
    }

    modifier updateRewardPerBlock() {
        (uint256 blockReward, bool update) = getRewardPerBlock();
        if (update) {
            rewardPerBlock = blockReward;
        }
        _;
    }

    constructor(
        address fishdRYFTContract_,
        address rewardToken_,
        address treasuryAddress_
    )
        nonZeroAddress(fishdRYFTContract_)
        nonZeroAddress(rewardToken_)
        nonZeroAddress(treasuryAddress_)
        Ownable(msg.sender)
    {
        fishdRYFTContract = fishdRYFTContract_;
        rewardToken = rewardToken_;
        treasuryAddress = treasuryAddress_;
    }

    function onERC1155Received(
        address,
        address,
        uint256,
        uint256,
        bytes memory
    ) public virtual returns (bytes4) {
        return this.onERC1155Received.selector;
    }

    function onERC1155BatchReceived(
        address,
        address,
        uint256[] memory,
        uint256[] memory,
        bytes memory
    ) public virtual returns (bytes4) {
        return this.onERC1155BatchReceived.selector;
    }

    // Update reward variables to be up-to-date when NFT deposit changes
    // For every deposit/withdraw recalculates accumulated token value
    function updateRewards() public updateRewardPerBlock {
        if (block.number <= lastRewardBlock) {
            return;
        }

        if (totalFishWeight == 0) {
            lastRewardBlock = block.number;
            return;
        }

        uint256 multiplier = block.number - (lastRewardBlock);
        uint256 tokenReward = multiplier * rewardPerBlock;

        // no minting is required, the contract should have token balance pre-allocated
        // accumulated per share is stored multiplied by 10^12 to allow small 'fractional' values
        accTokensPerShare =
            accTokensPerShare +
            ((tokenReward * 1e12) / totalFishWeight);
        lastRewardBlock = block.number;
    }

    function getRewardPerBlock() public view returns (uint256, bool) {
        if (block.number < startBlock || startBlock == 0 || totalReward == 0) {
            return (0, false);
        }

        return (rewardPerBlock, true);
    }

    function claim() external nonReentrant {
        updateRewards();
        User storage user = users[_msgSender()];
        if (user.fishWeight == 0) return;
        uint256 pending = (user.fishWeight * accTokensPerShare) /
            1e12 -
            user.rewardDebt;
        if (pending > 0) {
            user.rewardDebt += pending;
            // log contract balance of token
            IERC20(rewardToken).transfer(_msgSender(), pending);
            user.claimedRewards += pending;
        }
        emit Claim(_msgSender(), pending);
    }

    function depositRewards(uint256 amount_) external onlyProxy {
        updateRewards();
        IERC20(rewardToken).transferFrom(_msgSender(), address(this), amount_);
        totalReward += amount_;
        uint256 newRewardPerBlock = ((amount_ * 1e12) /
            (distributionDurationDays * blocksPerDay)) / 1e12;
        rewardPerBlock += newRewardPerBlock;
        emit DepositRewards(amount_, newRewardPerBlock);
    }

    // Withdraw without caring about rewards. EMERGENCY ONLY.
    function emergencyWithdraw() public {
        User storage user = users[_msgSender()];
        totalFishWeight -= user.fishWeight;
        user.fishWeight = 0;
        user.rewardDebt = 0;
        _withdrawUserNfts(user);
        emit EmergencyWithdraw(_msgSender());
    }

    function getAPY() external view returns (uint256) {
        if (totalReward == 0) return 0;
        (uint256 blockReward, ) = getRewardPerBlock();
        uint256 rewardForYear = blockReward * blocksPerDay * 365;
        return (rewardForYear * 100) / totalFishWeight;
    }

    function getWPY() external view returns (uint256) {
        if (totalReward == 0) return 0;
        (uint256 blockReward, ) = getRewardPerBlock();
        uint256 rewardForWeek = blockReward * blocksPerDay * 7;
        return (rewardForWeek * 100) / totalFishWeight;
    }

    // View function to see pending tokens on frontend.
    function pendingRewards(address user_) external view returns (uint256) {
        uint256 thisAccTokensPerShare = accTokensPerShare;
        if (block.number > lastRewardBlock && totalFishWeight != 0) {
            uint256 multiplier = block.number - (lastRewardBlock);
            (uint256 blockReward, ) = getRewardPerBlock();
            uint256 tokenReward = multiplier * blockReward;
            thisAccTokensPerShare =
                thisAccTokensPerShare +
                ((tokenReward * 1e12) / totalFishWeight);
        }
        User memory user = users[user_];
        return
            (user.fishWeight * thisAccTokensPerShare) / 1e12 - user.rewardDebt;
    }

    function proxyStake(
        address user_,
        uint256 nftId_,
        uint256 amount_
    ) external onlyProxy nonReentrant {
        _stake(user_, nftId_, amount_);
        emit ProxyStake(user_, nftId_, amount_);
    }

    function setBlocksPerDay(uint256 _blocksPerDay) external onlyOwner {
        require(
            _blocksPerDay >= 1000 && _blocksPerDay <= 40000,
            "Value is outside of range 1000-40000"
        );
        blocksPerDay = _blocksPerDay;
    }

    function setDistributionDurationDays(uint256 _days) external onlyOwner {
        require(_days >= 1 && _days <= 365, "Value is outside of range 1-365");
        distributionDurationDays = _days;
    }

    function setStakeLockDuration(uint256 _stakeLockDays) external onlyOwner {
        stakeLockPeriod = _stakeLockDays;
    }

    function setStartBlock(uint256 _startBlock) external onlyOwner {
        if (startBlock != 0) revert CannotChangeStartBlock();
        startBlock = _startBlock;
    }

    function stake(uint256 nftId_, uint256 amount_) external nonReentrant {
        _stake(_msgSender(), nftId_, amount_);
        emit Stake(_msgSender(), nftId_, amount_);
    }

    function stakeAll(uint256[] calldata nftIds_) external nonReentrant {
        for (uint256 i; i < nftIds_.length; ++i) {
            // get the amount of NFTs the user has
            uint256 bal = IERC1155(fishdRYFTContract).balanceOf(
                _msgSender(),
                nftIds_[i]
            );
            _stake(_msgSender(), nftIds_[i], bal);
        }
        emit Stake(_msgSender(), 0, nftIds_.length);
    }

    function toggleStakingEnabled() external onlyOwner {
        stakingEnabled = !stakingEnabled;
    }

    function transferTokens(
        address tokenAddr_
    ) external nonZeroAddress(tokenAddr_) onlyOwner {
        if (tokenAddr_ == rewardToken) revert CannotWithdrawRewardToken();
        IERC20(tokenAddr_).transfer(
            treasuryAddress,
            IERC20(tokenAddr_).balanceOf(address(this))
        );
    }

    // Withdraw all NFTs from Farming
    function unstake() external nonReentrant {
        User storage user = users[_msgSender()];
        if (user.fishWeight == 0) {
            return;
        }
        if (block.timestamp - user.lastStakeTime < stakeLockPeriod) {
            revert StakeLocked();
        }
        updateRewards();
        uint256 pending = (user.fishWeight * accTokensPerShare) /
            1e12 -
            user.rewardDebt;

        user.rewardDebt = 0;
        totalFishWeight -= user.fishWeight;
        user.fishWeight = 0;

        _withdrawUserNfts(user);

        if (pending > 0) {
            pending = pending > IERC20(rewardToken).balanceOf(address(this))
                ? IERC20(rewardToken).balanceOf(address(this))
                : pending;
            IERC20(rewardToken).transfer(_msgSender(), pending);
            user.claimedRewards += pending;
        }

        emit Unstake(_msgSender());
    }

    function withdrawETH() external {
        if (treasuryAddress == address(0)) revert ZeroAddress();
        uint256 bal = address(this).balance;
        (bool sent, ) = treasuryAddress.call{value: bal}("");
        if (!sent) revert FailedSendingETH();
        emit WithdrawETH(_msgSender(), bal);
    }

    function _stake(address user_, uint256 nftId_, uint256 amount_) private {
        if (!stakingEnabled) revert StakingDisabled();
        if (
            IERC1155(fishdRYFTContract).balanceOf(_msgSender(), nftId_) <
            amount_
        ) revert InsufficientBalance();
        if (fishdRYFTContract == address(0)) revert ZeroAddress();

        // Transfer NFTs first to ensure they are locked in the contract
        IERC1155(fishdRYFTContract).safeTransferFrom(
            _msgSender(),
            address(this),
            nftId_,
            amount_,
            ""
        );

        updateRewards();

        User storage user = users[user_];
        user.lastStakeTime = block.timestamp;
        uint256 pending;
        if (user.fishWeight > 0) {
            pending =
                (user.fishWeight * accTokensPerShare) /
                1e12 -
                user.rewardDebt;
        }

        // Update state after NFTs are transferred
        for (uint256 i; i < amount_; ++i) {
            user.nftIds.push(nftId_);
        }
        uint256 weight = IFishdRYFT(fishdRYFTContract).getTokenWrapAmount(
            nftId_
        ) * amount_;
        totalFishWeight += weight;
        user.fishWeight += weight;
        user.rewardDebt = (user.fishWeight * accTokensPerShare) / 1e12;

        // Transfer any pending rewards last
        if (pending > 0) {
            pending = pending > IERC20(rewardToken).balanceOf(address(this))
                ? IERC20(rewardToken).balanceOf(address(this))
                : pending;
            IERC20(rewardToken).transfer(user_, pending);
            user.claimedRewards += pending;
        }
    }

    function _withdrawUserNfts(User storage user_) private {
        if (user_.nftIds.length == 0) {
            return;
        }

        uint256[] memory values = new uint256[](user_.nftIds.length);
        for (uint256 i; i < user_.nftIds.length; ++i) {
            values[i] = 1;
        }
        IERC1155(fishdRYFTContract).safeBatchTransferFrom(
            address(this),
            _msgSender(),
            user_.nftIds,
            values,
            ""
        );
        delete user_.nftIds;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` amount of tokens of type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the value of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] calldata accounts,
        uint256[] calldata ids
    ) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers a `value` amount of tokens of type `id` from `from` to `to`.
     *
     * WARNING: This function can potentially allow a reentrancy attack when transferring tokens
     * to an untrusted contract, when invoking {onERC1155Received} on the receiver.
     * Ensure to follow the checks-effects-interactions pattern and consider employing
     * reentrancy guards when interacting with untrusted contracts.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `value` amount.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 value, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * WARNING: This function can potentially allow a reentrancy attack when transferring tokens
     * to an untrusted contract, when invoking {onERC1155BatchReceived} on the receiver.
     * Ensure to follow the checks-effects-interactions pattern and consider employing
     * reentrancy guards when interacting with untrusted contracts.
     *
     * Emits either a {TransferSingle} or a {TransferBatch} event, depending on the length of the array arguments.
     *
     * Requirements:
     *
     * - `ids` and `values` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC1155/IERC1155Receiver.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Interface that must be implemented by smart contracts in order to receive
 * ERC-1155 token transfers.
 */
interface IERC1155Receiver is IERC165 {
    /**
     * @dev Handles the receipt of a single ERC1155 token type. This function is
     * called at the end of a `safeTransferFrom` after the balance has been updated.
     *
     * NOTE: To accept the transfer, this must return
     * `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
     * (i.e. 0xf23a6e61, or its own function selector).
     *
     * @param operator The address which initiated the transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param id The ID of the token being transferred
     * @param value The amount of tokens being transferred
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
     */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    ) external returns (bytes4);

    /**
     * @dev Handles the receipt of a multiple ERC1155 token types. This function
     * is called at the end of a `safeBatchTransferFrom` after the balances have
     * been updated.
     *
     * NOTE: To accept the transfer(s), this must return
     * `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
     * (i.e. 0xbc197c81, or its own function selector).
     *
     * @param operator The address which initiated the batch transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param ids An array containing ids of each token being transferred (order and length must match values array)
     * @param values An array containing amounts of each token being transferred (order and length must match ids array)
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
     */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

interface IFishdRYFT {
    function getTokenWrapAmount(
        uint256 _fishId
    ) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

import "@openzeppelin/contracts/access/Ownable.sol";

abstract contract Proxyable is Ownable {
    mapping(address => bool) public proxyToApproved; // proxy allowance for interaction with future contract

    modifier onlyProxy() {
        require(proxyToApproved[_msgSender()], "Only proxy");
        _;
    }

    function setProxyState(
        address proxyAddress,
        bool value
    ) public virtual onlyOwner {
        proxyToApproved[proxyAddress] = value;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/FishStaking.sol": "FishStaking"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}