// File: @openzeppelin/contracts/utils/Address.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// File: @openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;




/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// File: LAKE_Vesting_Private.sol


pragma solidity = 0.8.21;


interface Token {
    function balanceOf(address) external view returns(uint);
}

/* 
LOCKING WITH REWARDS CONTRACT
    - Allows to deposit [DEPOSIT_TOKEN_ADDRESS]
    - Allows to claim and withdraw [TOKEN_ADDRESS]
    - Each user goes through 3 phases:
        - Everything locked 
        - Claiming Mode: Divided in [TOTAL_WITHDRAWS] periods
        - Unlocking Mode: Divided in [TOTAL_WITHDRAWS] periods
    - Each phase has a duration of [FULL_LOCKUP_PERIOD]
    - Claiming is only available once per period during the Claiming Mode, and has a max amount to be claimed equal to [MAX_MONTHLY_REWARDS]
    - Unlocking is only available once per period during the Unlocking Mode, and will also claim the claimable rewards (up to [MAX_MONTHLY_REWARDS])
    - The last unlock will unlock and claim all the non-unlocked and non-claimed tokens without limit
    - To claim for the first time, user has to wait for [FULL_LOCKUP_PERIOD] + [TIME_1_MONTH_ADJUSTED]
    - To unlock for the first time, user has to wait for [FULL_LOCKUP_PERIOD] * 2 + [TIME_1_MONTH_ADJUSTED]
    - The total claimed amount must be 100% of the deposited amount. Meaning the total amount received at the end by an user must be 200% of the deposited amount 
    - Naming of rewards:
        - Claimable rewards: Amount of rewards that can be redeemed
        - Pending rewards: Amount of generated rewards less the already claimed rewards
        - Generated rewards: Amount of generated rewards since tokens were deposited by the user
    - Times considerations for phases & periods:
        - 1 month = 30 days
        - 1 year = 12 months of 30 days
*/

contract LakeVestingPrivate {
    address public immutable TOKEN_ADDRESS;  // ERC20 withdraw token contract address
    address public immutable DEPOSIT_TOKEN_ADDRESS;  // ERC20 deposit token contract address
    address public constant BURN_ADDRESS =
        0x000000000000000000000000000000000000dEaD;  // Burn address

    uint256 public constant FULL_LOCKUP_PERIOD = 360 days;     // Time for each phase = 360 days
    uint256 public constant TIME_1_MONTH_ADJUSTED = 30 days;   // Time for each period = 30 days
    uint256 public constant TOTAL_WITHDRAWS = 12;              // Num periods = Max number of withdraws/claims = 12
    uint8 public constant TOKEN_RATIO = 2;                     // Amount of tokens to be claimed + withdrawn has to be 2 times the amount deposited
    uint256 public totalDeposited;                             // Total amount deposited
    uint256 public totalPendingToGet;                          // Total amount deposited * 2 - Total amount withdrawn or claimed (Total amount pending to be gotten by users from the contract)
    

    uint256 public constant REWARD_RATE = 6666; // 66.66% APY
    uint256 public constant REWARD_INTERVAL = 365 days;

    uint256 public constant MAX_MONTHLY_REWARDS = 1e5 ether;

    mapping(address => uint64) public lockingTime;      // Depositing time by an address
    mapping(address => uint256) public depositedAmount; // Total deposited ERC-20 tokens by an address
    mapping(address => uint256) public remainingAmount; // Remaining locked ERC-20 tokens by an address [deposited - withdrawn]
    mapping(address => uint256) public withdrawnAmount; // Total unlocked ERC-20 tokens by an address
    mapping(address => uint256) public claimedAmount;   // Total claimed ERC-20 tokens (as rewards) by an address [ MAX(claimedAmount) = depositedAmount ]

    // bool[23] --> last month not needed
    mapping(address => bool[TOTAL_WITHDRAWS * 2 - 1]) private monthlyClaim; // Indicate if the user already claimed during the current period

    event Locked(address indexed, uint256 indexed amount);
    event Unlocked(address indexed, uint256 indexed amount);
    event Claimed(address indexed, uint256 indexed amount);

    constructor(address _lockToken, address _unlockToken) {
        require(_lockToken != address(0) && _unlockToken != address(0), "Null address");
        DEPOSIT_TOKEN_ADDRESS = _lockToken;
        TOKEN_ADDRESS = _unlockToken;
    }
    /*
    Allows to deposit tokens [DEPOSIT_TOKEN_ADDRESS]
    @param amount: Amount to deposit.
    */
    function lock(uint256 amount) external {
        require(depositedAmount[msg.sender] == 0, "Already locked tokens");
        require(amount > 0, "Cannot deposit 0 tokens");
        /* Check the contract holds enough tokens to withdraw by doing a externall call "balanceOf()", 
        which is a view function from a trusted contract (LAK3 token contract), avoiding "checks-effects-interactions" pattern violation risks */
        require(Token(TOKEN_ADDRESS).balanceOf(address(this)) >= (TOKEN_RATIO * amount) + totalPendingToGet , "Contract does not hold enough tokens");

        depositedAmount[msg.sender] = amount;
        remainingAmount[msg.sender] = amount;
        lockingTime[msg.sender] = uint64(block.timestamp);
        totalDeposited += amount;
        totalPendingToGet += TOKEN_RATIO * amount;

        SafeERC20.safeTransferFrom(IERC20(DEPOSIT_TOKEN_ADDRESS), msg.sender, BURN_ADDRESS, amount);

        emit Locked(msg.sender, amount);
    }

    /*
    Allows to withdraw all unlockable tokens [TOKEN_ADDRESS], as well as claim all claimable rewards [TOKEN_ADDRESS]
    */
    function unLock() external {
        uint256 _amount = getUnlockableAmount(msg.sender);
        require(_amount > 0, "Nothing to unlock");

        uint256 _rewards = getClaimableRewards(msg.sender);
        

        if (
            block.timestamp - lockingTime[msg.sender] < FULL_LOCKUP_PERIOD * 3
        ) {
            uint256 currentPeriodIndex = (block.timestamp -
                lockingTime[msg.sender] -
                FULL_LOCKUP_PERIOD) / TIME_1_MONTH_ADJUSTED;
            monthlyClaim[msg.sender][currentPeriodIndex - 1] = true;
        }

        /* underflow/overflow cannot happen:
            - Max of _rewards = Max of _amount = remainingAmount
            - Max of withdrawnAmount = Max of claimedAmount = depositedAmount
            - Max of (_amount + _rewards) = totalPendingToGet
        */
        unchecked { 
            claimedAmount[msg.sender] += _rewards;
            remainingAmount[msg.sender] -= _amount;
            withdrawnAmount[msg.sender] += _amount;
            totalPendingToGet -= (_amount + _rewards);
        }
        _amount += _rewards;
        
        SafeERC20.safeTransfer(IERC20(TOKEN_ADDRESS), msg.sender, _amount);

        emit Unlocked(msg.sender, _amount);
    }

    /*
    Allows to claim all claimable rewards [TOKEN_ADDRESS]
    */
    function claim() external {
        require(isInClaimingMode(msg.sender), "Not claiming period");

        uint256 _toSend = getClaimableRewards(msg.sender);

        require(_toSend > 0, "Nothing to claim");

        uint256 currentPeriodIndex = (block.timestamp -
            lockingTime[msg.sender] -
            FULL_LOCKUP_PERIOD) / TIME_1_MONTH_ADJUSTED;
            
        monthlyClaim[msg.sender][currentPeriodIndex - 1] = true;

        /* underflow/overflow cannot happen:
            - Max of _toSend = deposited
            - Max of _toSend = totalPendingToGet
        */
        unchecked {
            claimedAmount[msg.sender] += _toSend;
            totalPendingToGet -= _toSend;
        }
        
        SafeERC20.safeTransfer(IERC20(TOKEN_ADDRESS), msg.sender, _toSend);

        emit Claimed(msg.sender, _toSend);
    }

    /*
    Get the amount of claimable rewards [TOKEN_ADDRESS]
    @param _wallet: Address to check
    */
    function getClaimableRewards(address _wallet)
        public
        view
        returns (uint256)
    {
        if (
            block.timestamp - lockingTime[_wallet] <
            FULL_LOCKUP_PERIOD + TIME_1_MONTH_ADJUSTED
        ) return 0;

        uint256 claimableAmount = getPendingRewards(_wallet);

        // Check the monthly limit
        if (block.timestamp - lockingTime[_wallet] < FULL_LOCKUP_PERIOD * 3) {
            uint256 currentPeriodIndex = (block.timestamp -
                lockingTime[_wallet] -
                FULL_LOCKUP_PERIOD) / TIME_1_MONTH_ADJUSTED;
            if (monthlyClaim[_wallet][currentPeriodIndex - 1]) return 0;
            if (claimableAmount > MAX_MONTHLY_REWARDS)
                claimableAmount = MAX_MONTHLY_REWARDS;
        }
        return claimableAmount;
    }

    /*
    Get the amount of pending rewards [TOKEN_ADDRESS]
    @param _wallet: Address to check
    */
    function getPendingRewards(address _wallet) public view returns (uint256) {
        if (remainingAmount[_wallet] == 0) return 0;

        uint256 pendingRewards = getGeneratedRewards(_wallet);
        
        /* underflow/overflow cannot happen:
            - pendingRewards is always >= claimedAmount
        */
        unchecked {
            pendingRewards -= claimedAmount[_wallet];
        }
        

        return pendingRewards;
    }

    /*
    Get the amount of generated rewards [TOKEN_ADDRESS]
    @param _wallet: Address to check
    */
    function getGeneratedRewards(address _wallet)
        public
        view
        returns (uint256)
    {
        if (remainingAmount[_wallet] == 0) return 0;
        uint256 generatedRewards;

        if (
            // >= 18 months (540 days) --> all the rewards are generated (100% of the deposited amount)
            block.timestamp - lockingTime[_wallet] >=
            FULL_LOCKUP_PERIOD + (FULL_LOCKUP_PERIOD / 2)
        ) {
            generatedRewards = depositedAmount[_wallet];
        } else {
            // < 18 months --> Needs calculation (66.66% APY)
            uint256 timeDiff = block.timestamp - lockingTime[_wallet];

            generatedRewards =
                (((depositedAmount[_wallet] * REWARD_RATE) / 1e4) * timeDiff) /
                REWARD_INTERVAL;
        }

        return generatedRewards;
    }

    /*
    Get the amount of unlockable tokens [TOKEN_ADDRESS]
    @param _wallet: Address to check
    */
    function getUnlockableAmount(address _wallet)
        public
        view
        returns (uint256)
    {
        if (remainingAmount[_wallet] == 0) return 0;
        if (!isInUnlockingMode(_wallet)) return 0;
        uint256 numWithdraws = getNumUnlockPeriods(_wallet);
        uint256 _toSend = (numWithdraws * depositedAmount[_wallet]) /
            TOTAL_WITHDRAWS -
            withdrawnAmount[_wallet];

        if (
            _toSend > remainingAmount[_wallet] ||
            remainingAmount[_wallet] - _toSend < numWithdraws // decimals check (for the last withdraw) - 0,000000000000000012
        ) {
            _toSend = remainingAmount[_wallet];
        }

        return _toSend;
    }

    /*
    Get the number of unlockable periods (30 days)
    @param _wallet: Address to check
    */
    function getNumUnlockPeriods(address _wallet)
        internal
        view
        returns (uint256)
    {
        return
            (block.timestamp -
                lockingTime[_wallet] -
                (FULL_LOCKUP_PERIOD * 2)) / TIME_1_MONTH_ADJUSTED;
    }

    /*
    Get if is in the claiming phase or not
    @param _wallet: Address to check
    */
    function isInClaimingMode(address _wallet) public view returns (bool) {
        if (remainingAmount[_wallet] == 0) return false;
        return
            (block.timestamp - lockingTime[_wallet] >=
                FULL_LOCKUP_PERIOD + TIME_1_MONTH_ADJUSTED) &&
            (block.timestamp - lockingTime[_wallet] <
                FULL_LOCKUP_PERIOD * 2 + TIME_1_MONTH_ADJUSTED);
    }

    /*
    Get if is in the unlocking phase or not
    @param _wallet: Address to check
    */
    function isInUnlockingMode(address _wallet) public view returns (bool) {
        if (remainingAmount[_wallet] == 0) return false;
        return (block.timestamp - lockingTime[_wallet] >=
            FULL_LOCKUP_PERIOD * 2 + TIME_1_MONTH_ADJUSTED);
    }

    /*
    Get the time (in seconds) till the next unlock
    @param _wallet: Address to check
    returns 0 if remaining tokens is 0
    returns 0 if unlockable amount is greater than 0
    */
    function getTimeUntilNextUnlock(address _wallet)
        public
        view
        returns (uint256)
    {   
        uint _res = 0;
        if (
            remainingAmount[_wallet] == 0 ||
            getUnlockableAmount(_wallet) > 0 
        ){
            // must return 0
        } else if (!isInUnlockingMode(_wallet)){
            _res = lockingTime[_wallet] +
                   FULL_LOCKUP_PERIOD *
                   2 +
                   TIME_1_MONTH_ADJUSTED -
                   block.timestamp;
        } else {
            uint256 numPeriods = getNumUnlockPeriods(_wallet);
            _res = lockingTime[_wallet] +
                   (FULL_LOCKUP_PERIOD * 2) +
                   (numPeriods + 1) *
                   TIME_1_MONTH_ADJUSTED -
                   block.timestamp;
        } 
        return _res;
        
    }

    /*
    Get the time (in seconds) till the next claim
    @param _wallet: Address to check
    returns 0 if remaining tokens is 0
    returns 0 if claimable amount is greater than 0
    returns 0 if unlocking phase is completed
    */
    function getTimeUntilNextClaim(address _wallet)
        external
        view
        returns (uint256)

    {
        uint256 _res = 0;
        if (
            remainingAmount[_wallet] == 0 || 
            block.timestamp - lockingTime[_wallet] >= FULL_LOCKUP_PERIOD * 3 ||
            getClaimableRewards(_wallet) > 0
        ){
            // must return 0
        } else if (isInUnlockingMode(_wallet)) {
            _res = getTimeUntilNextUnlock(_wallet);
        } else if (isInClaimingMode(_wallet)) {
            uint256 numPeriods = (block.timestamp -
                lockingTime[_wallet] -
                FULL_LOCKUP_PERIOD) / TIME_1_MONTH_ADJUSTED;
            _res =
                lockingTime[_wallet] +
                FULL_LOCKUP_PERIOD +
                (numPeriods + 1) *
                TIME_1_MONTH_ADJUSTED -
                block.timestamp;
        } else {
            _res =
                lockingTime[_wallet] +
                FULL_LOCKUP_PERIOD +
                TIME_1_MONTH_ADJUSTED -
                block.timestamp;
        }

        return _res;
    }
}

{
  "compilationTarget": {
    "LakeVestingPrivate.sol": "LakeVestingPrivate"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}