/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

pragma solidity ^0.7.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

pragma solidity ^0.7.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);


    /**
     * TODO: Add comment
     */
    function burn(uint256 burnQuantity) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

import "./ERC165/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
      * @dev Safely transfers `tokenId` token from `from` to `to`.
      *
      * Requirements:
      *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
      * - `tokenId` token must exist and be owned by `from`.
      * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
      * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
      *
      * Emits a {Transfer} event.
      */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;
}

import "./IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {

    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256 tokenId);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

pragma solidity ^0.7.0;

import "./IERC20.sol";

interface ISPT is IERC20 {
    
    function totalBurned() external view returns (uint256);
    function totalFromSpirits() external view returns (uint256);
    function totalFromAddons() external view returns (uint256);
    function totalAccumulatedSupply() external view returns (uint256);
    
    function accumulated(uint256 tokenIndex) external view returns (uint256);
    function totalAccumulated(uint256 tokenIndex, bool useRewardMultiplier) external view returns (uint256);
    function totalClaimed(uint256 tokenIndex) external view returns (uint256);
    
    function accumulatedNode(uint256 nodeId) external view returns (uint256);
    function totalAccumulatedNode(uint256 nodeId) external view returns (uint256);
    function lastClaimNode(uint256 nodeId) external view returns (uint256);
    function timeSinceLastClaimNode(uint256 nodeId) external view returns (uint256);
    function nodeEmissionMultiplier(uint256 nodeType) external view returns (uint256);
    function nodeEmissionRate(uint256 regTime) external view returns (uint256);
    function totalClaimedNode(uint256 nodeId) external view returns (uint256);
    function nodeEmissionEnds() external pure returns (uint256);
    function canClaimFromNode(uint256 nodeId) external view returns (bool);
    
    function totalAccumulatedDevFund() external view returns (uint256);
    function totalClaimableDevFund() external view returns (uint256);
    function totalClaimedDevFund() external view returns (uint256);
}

pragma solidity ^0.7.0;

import "./IERC721Enumerable.sol";

interface ISpirits is IERC721Enumerable {
    
    function revealStageByIndex(uint256 index) external view returns (uint256);
    function mintedTimestampByIndex(uint256 index) external view returns (uint256);
    
    function nodeInfo(uint256 nodeId) external view returns (address, string memory, uint256, uint256, uint256, bool, uint256[] memory);
    function nodeBalanceOf(address owner) external view returns (uint256);
    function ownerOfNode(uint256 nodeId) external view returns (address);
    function nodeOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);
    function totalNodes() external view returns (uint256);
    function totalActiveNodes() external view returns (uint256);
    function nodeType(uint256 nodeId) external view returns (uint256);
    function nodeSize(uint256 nodeId) external view returns (uint256);
    function nodeValid(uint256 nodeId) external view returns (bool);
    function nodeRegTime(uint256 nodeId) external view returns (uint256);
    function nodeUnregTime(uint256 nodeId) external view returns (uint256);
    function nodeName(uint256 nodeId) external view returns (string memory);
    function nodeActive(uint256 nodeId) external view returns (bool);
    function nodeTokenIds(uint256 nodeId) external view returns (uint256[] memory);
    function isNodeNameReserved(string memory nameString) external view returns (bool);
    function nodeIdFromTokenId(uint256 tokenId) external view returns (uint256);
    function nodeExists(uint256 nodeId) external view returns (bool);
    function isUserNameReserved(string memory nameString) external view returns (bool);
    function username(address owner) external view returns (string memory);
    function tokenRewardMultiplier(uint256 tokenId) external view returns (uint256, uint256);
    function testTokenRewardMultiplier(uint256 newNum, uint256 newDen) external pure returns (uint256);
}

pragma solidity ^0.7.0;

import "./Context.sol";

contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

pragma solidity ^0.7.0;

import "./ERC165/IERC165.sol";
import "./utils/SafeMath.sol";
import "./IERC20.sol";
import "./ISPT.sol";
import "./ISpirits.sol";
import "./utils/Context.sol";
import "./utils/Ownable.sol";

/**
 *
 * SPT Contract (The native token of CryptoSpirits)
 * @dev Extends standard ERC20 contract
 */
contract SPT is Context, Ownable, ISPT {
    using SafeMath for uint256;

    // Constants
    uint256 public constant SECONDS_IN_A_DAY = 86400;
    uint256 public constant SECONDS_IN_2_WEEKS = SECONDS_IN_A_DAY * 14;
    uint256 public constant SECONDS_IN_A_YEAR = SECONDS_IN_A_DAY * 365;
    
    uint256 public constant INITIAL_ALLOTMENT = 100 * (10 ** 18);

    // Public variables
    uint256 public constant EMISSION_START = 1625245200; // Friday, July 2, 2021 6:00:00 PM BST
    uint256 public constant EMISSION_END = EMISSION_START + (SECONDS_IN_A_YEAR * 3); // 3 years
    uint256 public constant EMISSION_END_NODE = EMISSION_START + (SECONDS_IN_A_YEAR * 6); // 6 years
    
    // emission rate decreases with a reduction of 50% per year
    uint256 public constant EMISSION_PER_DAY_YEAR_0 = 1.00 * (10 ** 18);
    uint256 public constant EMISSION_PER_DAY_YEAR_1 = 0.50 * (10 ** 18);
    uint256 public constant EMISSION_PER_DAY_YEAR_2 = 0.25 * (10 ** 18);
    
    uint256[3] public EMISSION_PER_DAY_YEARS = [EMISSION_PER_DAY_YEAR_0, 
                                                EMISSION_PER_DAY_YEAR_1, 
                                                EMISSION_PER_DAY_YEAR_2];

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;
    
    mapping(uint256 => uint256) private _lastClaim;
    mapping(uint256 => uint256) private _claimedAmount;
    
    mapping(uint256 => uint256) private _lastClaimNode;
    mapping(uint256 => uint256) private _claimedAmountNode;
    
    // node multipliers
    uint256 public nodeEmissionMultiplierType1 = 1;
    uint256 public nodeEmissionMultiplierType2 = 5;
    uint256 public nodeEmissionMultiplierType3 = 3;
    uint256 public nodeEmissionMultiplierType4 = 12;

    uint256 private _totalSupply;
    uint256 private _totalBurned;
    
    uint256 private _totalFromSpirits = 0;
    uint256 private _totalFromAddons = 0;
    
    uint256 private _claimedAmountDevFund = 0;
    
    string private _name;
    string private _symbol;
    uint8 private _decimals;
    address private _spiritsAddress;
    address private _addonsAddress;

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    constructor () {
        _name = "SpiritToken";
        _symbol = "SPT";
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view override returns (uint256) {
        return _balances[account];
    }
    
    /**
     *  total number of tokens sent to the burn address
     */
    function totalBurned() public view override returns (uint256) {
        return _totalBurned;
    }
    
    /**
     *  total number of tokens sent to the SPT address via the Spirits contract (name change utility etc)
     */
    function totalFromSpirits() public view override returns (uint256) {
        return _totalFromSpirits;
    }
    
    /**
     *  total number of tokens sent to the SPT address via the Addons contract (extra utility etc)
     */
    function totalFromAddons() public view override returns (uint256) {
        return _totalFromAddons;
    }
    
    /**
     * @dev When accumulated SPTs have last been claimed for a CryptoSpirits index
     */
    function lastClaim(uint256 tokenIndex) public view returns (uint256) {
        require(ISpirits(_spiritsAddress).ownerOf(tokenIndex) != address(0), "Owner cannot be 0 address");
        require(tokenIndex < ISpirits(_spiritsAddress).totalSupply(), "NFT at index has not been minted yet");

        uint256 lastClaimed = uint256(_lastClaim[tokenIndex]) != 0 ? uint256(_lastClaim[tokenIndex]) : EMISSION_START;
        return lastClaimed;
    }
    
    /**
     * @dev Total accumulated SPT tokens for all existing CryptoSpirits NFTs - ignores reward multipliers
     */
    function totalAccumulatedSupply() public view override returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");
        require(ISpirits(_spiritsAddress).ownerOf(0) != address(0), "Owner of NFT #0 cannot be 0 address");
        uint256 nftSupply = ISpirits(_spiritsAddress).totalSupply();
        require(nftSupply > 0, "No NFTs have been minted yet");
        return nftSupply.mul(totalAccumulated(0, false));
    }
    
    /**
     * @dev Accumulated SPT tokens for a CryptoSpirits token index.
     */
    function accumulated(uint256 tokenIndex) public view override returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");
        require(ISpirits(_spiritsAddress).ownerOf(tokenIndex) != address(0), "Owner cannot be 0 address");
        require(tokenIndex < ISpirits(_spiritsAddress).totalSupply(), "NFT at index has not been minted yet");

        uint256 lastClaimed = lastClaim(tokenIndex);

        // sanity check if last claim was on or after emission end
        if (lastClaimed >= EMISSION_END) return 0;

        uint256 accumulatedQty = totalAccumulated(tokenIndex, true).sub(totalClaimed(tokenIndex));
        return accumulatedQty;
    }
    
    /**
     * @dev Lifetime Accumulated SPT tokens for a CryptoSpirits token index.
     */
    function totalAccumulated(uint256 tokenIndex, bool useRewardMultiplier) public view override returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");
        require(ISpirits(_spiritsAddress).ownerOf(tokenIndex) != address(0), "Owner cannot be 0 address");
        require(tokenIndex < ISpirits(_spiritsAddress).totalSupply(), "NFT at index has not been minted yet");
        
        uint256 nowTime = block.timestamp < EMISSION_END ? block.timestamp : EMISSION_END;
        uint256 elapsedTime = nowTime.sub(EMISSION_START);
        uint256 yearsElapsed = elapsedTime.div(SECONDS_IN_A_YEAR);
        uint256 totalAmountAccumulated = 0;
        uint256 timeAccountedFor = 0;
        
        // amount accumulated in each year
        for(uint year = 0; year < yearsElapsed; year++) {
            uint256 emissionPerDayForYear = EMISSION_PER_DAY_YEARS[year];
            uint256 yearAccumulated = emissionPerDayForYear.mul(365);
            totalAmountAccumulated = totalAmountAccumulated.add(yearAccumulated);
            timeAccountedFor = timeAccountedFor.add(SECONDS_IN_A_YEAR);
        }
        // amount accumulated since last full year
        if(elapsedTime > timeAccountedFor && yearsElapsed < 3) {
            uint256 remainingTime = elapsedTime.sub(timeAccountedFor);
            uint256 currentEmissionRate = EMISSION_PER_DAY_YEARS[yearsElapsed];
            uint256 remainingAccumulated = remainingTime.mul(currentEmissionRate).div(SECONDS_IN_A_DAY);
            totalAmountAccumulated = totalAmountAccumulated.add(remainingAccumulated);
        }
        if(useRewardMultiplier) {
            // reward multiplier
            uint256 rewardNum;
            uint256 rewardDen;
            (rewardNum, rewardDen) = ISpirits(_spiritsAddress).tokenRewardMultiplier(tokenIndex);
            totalAmountAccumulated = (totalAmountAccumulated.mul(rewardNum)).div(rewardDen);
        }
        // add initial allotment
        totalAmountAccumulated = totalAmountAccumulated.add(INITIAL_ALLOTMENT);
        
        return totalAmountAccumulated;
    }
    
    /**
     * @dev Lifetime SPT tokens claimed from a token index CryptoSpirits NFT
     */
    function totalClaimed(uint256 tokenIndex) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).ownerOf(tokenIndex) != address(0), "Owner cannot be 0 address");
        require(tokenIndex < ISpirits(_spiritsAddress).totalSupply(), "NFT at index has not been minted yet");
        
        uint256 claimed = uint256(_claimedAmount[tokenIndex]) >= 0 ? uint256(_claimedAmount[tokenIndex]) : 0;
        return claimed;
    }

    /**
     * @dev Set right after deployment and verified
     */
    function setSpiritsAddress(address spiritsAddress) onlyOwner public {
        require(_spiritsAddress == address(0), "Already set");
        _spiritsAddress = spiritsAddress;
    }
    
    /**
     * @dev To be set at a later date when the platform is developed
     */
    function setAddonsAddress(address addonsAddress) onlyOwner public {
        _addonsAddress = addonsAddress;
    }
    
    /**
     * @dev Claim mints SPTs and supports multiple CryptoSpirits token indices at once.
     */
    function claim(uint256[] memory tokenIndices) public returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");

        uint256 totalClaimQty = 0;
        for (uint i = 0; i < tokenIndices.length; i++) {
            // Sanity check for non-minted index
            require(tokenIndices[i] < ISpirits(_spiritsAddress).totalSupply(), "NFT at index has not been minted yet");
            // Duplicate token index check
            for (uint j = i + 1; j < tokenIndices.length; j++) {
                require(tokenIndices[i] != tokenIndices[j], "Duplicate token index");
            }

            uint tokenIndex = tokenIndices[i];
            require(ISpirits(_spiritsAddress).ownerOf(tokenIndex) == msg.sender, "Sender is not the owner");

            uint256 claimQty = accumulated(tokenIndex);
            if (claimQty != 0) {
                _lastClaim[tokenIndex] = block.timestamp;
                uint256 alreadyClaimed = _claimedAmount[tokenIndex];
                _claimedAmount[tokenIndex] = alreadyClaimed.add(claimQty);
                totalClaimQty = totalClaimQty.add(claimQty);
            }
        }

        require(totalClaimQty != 0, "No accumulated SPT");
        _mint(msg.sender, totalClaimQty); 
        return totalClaimQty;
    }
    
    /* Dev Fund */
    /* Claim mints SPTs allocated to the dev fund (5% of the amount generated by all minted Spirits) (callable by Owner only */
    function claimDev() onlyOwner public returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");

        uint256 claimQty = totalClaimableDevFund();
        require(claimQty != 0, "No accumulated SPT");
        _claimedAmountDevFund = _claimedAmountDevFund.add(claimQty);
        _mint(msg.sender, claimQty); 
        return claimQty;
    }
    function totalAccumulatedDevFund() public view override returns (uint256) {
        // dev fund is 5% of the total accumulated by the minted Spirits
        return totalAccumulatedSupply().div(20);
    }
    
    function totalClaimableDevFund() public view override returns (uint256) {
        return totalAccumulatedDevFund().sub(totalClaimedDevFund());
    }
    
    function totalClaimedDevFund() public view override returns (uint256) {
        return _claimedAmountDevFund;
    }
    
    /* Nodes */
    
    /**
     * @dev canClaimFromNode - the owner can make a claim from this node
     */
    function canClaimFromNode(uint256 nodeId) public view override returns (bool) {
        if(ISpirits(_spiritsAddress).nodeActive(nodeId) && ISpirits(_spiritsAddress).nodeValid(nodeId) && timeSinceLastClaimNode(nodeId) >= SECONDS_IN_2_WEEKS) {
            return true;
        }
        return false;
    }
    
    /**
     * @dev claimNode mints SPTs earned from nodes
     */
    function claimNode(uint256 nodeId) public returns (uint256) {
        require(block.timestamp > EMISSION_START, "Emission has not started yet");
        require(ISpirits(_spiritsAddress).nodeActive(nodeId), "Node does not exist or has been unregistered");
        require(ISpirits(_spiritsAddress).nodeValid(nodeId), "Node is not valid (pending approval by admin)");
        require(ISpirits(_spiritsAddress).ownerOfNode(nodeId) == msg.sender, "Sender is not the node owner");
        
        require(timeSinceLastClaimNode(nodeId) >= SECONDS_IN_2_WEEKS, "Must wait 14 days between claims");

        uint256 claimQty = accumulatedNode(nodeId);

        require(claimQty != 0, "No accumulated SPT");
        _lastClaimNode[nodeId] = block.timestamp;
        uint256 alreadyClaimed = _claimedAmountNode[nodeId];
        _claimedAmountNode[nodeId] = alreadyClaimed.add(claimQty);
        _mint(msg.sender, claimQty); 
        return claimQty;
    }
    
    /**
     * @dev Accumulated SPT tokens for a Spirit node.
     */
    function accumulatedNode(uint256 nodeId) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).nodeExists(nodeId), "Node with specified id does not exist");
        uint256 regTime = ISpirits(_spiritsAddress).nodeRegTime(nodeId);
        require(regTime > 0 && block.timestamp > regTime, "Emission has not started yet");

        uint256 lastClaimed = lastClaimNode(nodeId);

        // sanity check if last claim was on or after emission end
        if (lastClaimed >= EMISSION_END_NODE) return 0;

        uint256 accumulatedQty = totalAccumulatedNode(nodeId).sub(totalClaimedNode(nodeId));
        return accumulatedQty;
    }
    
    /**
     * @dev lifetime Accumulated SPT tokens for a node.
     */
    function totalAccumulatedNode(uint256 nodeId) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).nodeExists(nodeId), "Node with specified id does not exist");
        uint256 regTime = ISpirits(_spiritsAddress).nodeRegTime(nodeId);
        uint256 unregTime = ISpirits(_spiritsAddress).nodeUnregTime(nodeId);
        uint256 nodeType = ISpirits(_spiritsAddress).nodeType(nodeId);
        require(regTime > 0 && block.timestamp > regTime, "Emission has not started yet");
        
        // node is still registered then current time, else unreg time
        uint256 nowTime = block.timestamp;
        if(unregTime > 0) {
            nowTime = unregTime;
        }
        // cap at node emission end time
        if(nowTime > EMISSION_END_NODE) {
            nowTime = EMISSION_END_NODE;
        }
        
        // node registered after node emission end
        if(nowTime <= regTime) {
            return 0;
        }
        
        // time active
        uint256 elapsedTime = nowTime.sub(regTime);
        
        // emission rate for node
        uint256 emissionRatePerDay = nodeEmissionRate(regTime).mul(nodeEmissionMultiplier(nodeType));
        
        uint256 totalAmountAccumulated = elapsedTime.mul(emissionRatePerDay).div(SECONDS_IN_A_DAY);
        return totalAmountAccumulated;
    }
    
    /**
     * @dev When accumulated SPTs have last been claimed for a node
     */
    function lastClaimNode(uint256 nodeId) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).nodeExists(nodeId), "Node with specified id does not exist");
        uint256 regTime = ISpirits(_spiritsAddress).nodeRegTime(nodeId);
        uint256 lastClaimed = uint256(_lastClaimNode[nodeId]) != 0 ? uint256(_lastClaimNode[nodeId]) : regTime;
        return lastClaimed;
    }
    
    function timeSinceLastClaimNode(uint256 nodeId) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).nodeExists(nodeId), "Node with specified id does not exist");
        return block.timestamp - lastClaimNode(nodeId);
    }
    
    function nodeEmissionEnds() public pure override returns (uint256) {
        return EMISSION_END_NODE;
    }
    
    function nodeEmissionMultiplier(uint256 nodeType) public view override returns (uint256) {
        require(nodeType >= 1 && nodeType <= 4, "Invalid node type");
        if(nodeType == 1) {
            return nodeEmissionMultiplierType1;
        }
        if(nodeType == 2) {
            return nodeEmissionMultiplierType2;
        }
        if(nodeType == 3) {
            return nodeEmissionMultiplierType3;
        }
        if(nodeType == 4) {
            return nodeEmissionMultiplierType4;
        }
        return nodeEmissionMultiplierType1;
    }
    
    /* changes the emission rewards for a given node type */
    function changeNodeEmissionMultiplier(uint256 nodeType, uint256 newMultiplier) onlyOwner public {
        require(nodeType >= 1 && nodeType <= 4, "Invalid node type");
        if(nodeType == 1) {
            nodeEmissionMultiplierType1 = newMultiplier;
        }
        if(nodeType == 2) {
            nodeEmissionMultiplierType2 = newMultiplier;
        }
        if(nodeType == 3) {
            nodeEmissionMultiplierType3 = newMultiplier;
        }
        if(nodeType == 4) {
            nodeEmissionMultiplierType4 = newMultiplier;
        }
    }
    
    // gets the SPT emission rate for a node - nodes are locked into the emission rate that was active at the time of registration 
    function nodeEmissionRate(uint256 regTime) public view override returns (uint256) {
        uint256 band1 = EMISSION_START + (SECONDS_IN_A_YEAR * 1);
        if(regTime <= band1) {
            return EMISSION_PER_DAY_YEARS[0];
        }
        uint256 band2 = EMISSION_START + (SECONDS_IN_A_YEAR * 2);
        if(regTime <= band2) {
            return EMISSION_PER_DAY_YEARS[1];
        }
        return EMISSION_PER_DAY_YEARS[2];
    }
    
    /**
     * @dev lifetime SPT tokens claimed from a node
     */
    function totalClaimedNode(uint256 nodeId) public view override returns (uint256) {
        require(ISpirits(_spiritsAddress).nodeExists(nodeId), "Node with specified id does not exist");
        uint256 claimed = uint256(_claimedAmountNode[nodeId]) >= 0 ? uint256(_claimedAmountNode[nodeId]) : 0;
        return claimed;
    }
    

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * Requirements:
     *
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);
        // Approval check is skipped if the caller of transferFrom is the CryptoSpirits or CryptoSpirits Addons contract. For better UX.
        if (msg.sender == _spiritsAddress) {
            // caller of transferFrom is the CryptoSpirits contract
            _totalFromSpirits = _totalFromSpirits.add(amount);
        }
        else if(_addonsAddress != address(0) && msg.sender == _addonsAddress) {
            // addons contract address is set and caller is from the CryptoSpirits Addons contract
            _totalFromAddons = _totalFromAddons.add(amount);
        }
        else {
            _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        }
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    // ++
    /**
     * @dev Burns a quantity of tokens held by the caller.
     *
     * Emits an {Transfer} event to 0 address
     *
     */
    function burn(uint256 burnQuantity) public virtual override returns (bool) {
        _burn(msg.sender, burnQuantity);
        return true;
    }
    // ++

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        _totalBurned = _totalBurned.add(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }
}

pragma solidity ^0.7.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

{
  "compilationTarget": {
    "contracts/SPT.sol": "SPT"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}