// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity ^0.8.24;

import {Address} from "@openzeppelin/contracts/utils/Address.sol";
import {SafeERC20, IERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IEscrow} from "./Escrow.sol";
import {Parties, PayableParties, InsufficientBalance} from "./TypesAndConstants.sol";

/// @dev Part of `Consideration` sent to a party other than the `seller` and the platform-fee recipient.
struct Disbursement {
    address to;
    uint256 amount;
}

/**
 * @dev Fungible payment, denoted in native token. While the `buyer` of the `[Payable]Parties` is responsible for
 * payment of `total`, the `seller` will only receive the difference between `total` and the sum of `thirdParty` +
 * platform-fee amounts.
 * @dev As all fields in a <T>Swap struct are immutable (otherwise the swapper address changes), the platform fee is
 * denoted as an upper bound to allow it to be modified in favour of the `seller`.
 */
struct Consideration {
    Disbursement[] thirdParty;
    uint256 maxPlatformFee;
    uint256 total;
}

/// @dev Identical to `Consideration` except for the addition of the `currency` field.
struct ERC20Consideration {
    Disbursement[] thirdParty;
    uint256 maxPlatformFee;
    uint256 total;
    IERC20 currency;
}

/**
 * @notice Disburses `Consideration`, denominated in either native token or ERC20.
 * @dev There MUST NOT be any interactions (in the CEI sense) between calls to `_disburse()` and
 * `_postExecutionInvariantsMet() as this would open native-token swaps to griefing by breaking the invariant.
 */
library ConsiderationLib {
    using Address for address payable;
    using SafeERC20 for IERC20;

    /**
     * ============
     *
     * Native token
     *
     * ============
     */

    /**
     * @notice Disburses funds denominated in the chain's native token.
     * @dev If the contract's balance is greater than `c.total`, the excess is sent to `parties.seller`.
     * @param parties Funds are sent from `parties.buyer` to all third-parties, the fee recipient, and `parties.seller`.
     * @param c Breakdown of fund disbursement. See `Consideration` documentation for details.
     * @param feeRecipient Recipient of `fee`.
     * @param fee Amount to send to `feeRecipient` from `parties.buyer`, in addition to all `c.thirdParty`
     * disbursements.
     */
    function _disburse(Consideration memory c, PayableParties memory parties, address payable feeRecipient, uint256 fee)
        internal
    {
        if (address(this).balance < c.total) {
            revert InsufficientBalance(address(this).balance, c.total);
        }

        // Note: we aren't concerned about griefing attacks from any recipients when fill()ing a swap because:
        // - Fee recipient is the platform-specified address
        // - Third parties are completely under the control of the parties
        // - Seller could, even more easily, stop execution by either cancel()ing or un-approving the swapper address

        feeRecipient.sendValue(fee);

        Disbursement[] memory tP = c.thirdParty;
        for (uint256 i = 0; i < tP.length; ++i) {
            payable(tP[i].to).sendValue(tP[i].amount);
        }

        // MUST remain as the last step to guarantee that _postExecutionInvariantsMet() returns true. This means that
        // the only actor capable of griefing the invariants is the seller (by returning some of these funds), which
        // would only act to harm themselves.
        parties.seller.sendValue(address(this).balance);
    }

    /**
     * @notice Sends the contract's entire balance to `parties.buyer`.
     * @dev Unlike `_disburse()` we have to protect against the buyer griefing cancellation so funds will be escrowed
     * iff the initial sending fails. Although the seller could void the swap by removing required approvals, the
     * explicit cancelling should still work as intended.
     */
    function _cancel(Consideration memory, PayableParties memory parties, IEscrow escrow) internal {
        // MUST remain as the last step for the same reason as _disburseFunds().
        uint256 bal = address(this).balance;
        if (bal > 0) {
            escrow.deposit{value: bal}(parties.buyer);
        }
    }

    /// @dev Returns whether the contract's remaining balance is zero.
    function _postExecutionInvariantsMet(Consideration memory, PayableParties memory) internal view returns (bool) {
        return address(this).balance == 0;
    }

    /**
     * =====
     *
     * ERC20
     *
     * =====
     */

    /**
     * @notice Disburses funds denominated in ERC20.
     * @param parties Funds are sent from `parties.buyer` to all third-parties, the fee recipient, and `parties.seller`.
     * @param c Breakdown of fund disbursement. See `ERC20Consideration` documentation for details.
     * @param feeRecipient Recipient of `fee`.
     * @param fee Amount to send to `feeRecipient` from `parties.buyer`, in addition to all `c.thirdParty`
     * disbursements.
     */
    function _disburse(ERC20Consideration memory c, Parties memory parties, address feeRecipient, uint256 fee)
        internal
    {
        uint256 remaining = c.total;

        c.currency.safeTransferFrom(parties.buyer, feeRecipient, fee);
        remaining -= fee;

        Disbursement[] memory tP = c.thirdParty;
        for (uint256 i = 0; i < tP.length; ++i) {
            c.currency.safeTransferFrom(parties.buyer, tP[i].to, tP[i].amount);
            remaining -= tP[i].amount;
        }

        c.currency.safeTransferFrom(parties.buyer, parties.seller, remaining);
    }

    /// @dev Noop because no explicit cancellation required for ERC20 consideration.
    function _cancel(ERC20Consideration memory, Parties memory, IEscrow) internal pure {}

    /// @dev Always returns true as there are no ERC20 invariants.
    function _postExecutionInvariantsMet(ERC20Consideration memory, Parties memory) internal pure returns (bool) {
        return true;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Create2.sol)

pragma solidity ^0.8.20;

/**
 * @dev Helper to make usage of the `CREATE2` EVM opcode easier and safer.
 * `CREATE2` can be used to compute in advance the address where a smart
 * contract will be deployed, which allows for interesting new mechanisms known
 * as 'counterfactual interactions'.
 *
 * See the https://eips.ethereum.org/EIPS/eip-1014#motivation[EIP] for more
 * information.
 */
library Create2 {
    /**
     * @dev Not enough balance for performing a CREATE2 deploy.
     */
    error Create2InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev There's no code to deploy.
     */
    error Create2EmptyBytecode();

    /**
     * @dev The deployment failed.
     */
    error Create2FailedDeployment();

    /**
     * @dev Deploys a contract using `CREATE2`. The address where the contract
     * will be deployed can be known in advance via {computeAddress}.
     *
     * The bytecode for a contract can be obtained from Solidity with
     * `type(contractName).creationCode`.
     *
     * Requirements:
     *
     * - `bytecode` must not be empty.
     * - `salt` must have not been used for `bytecode` already.
     * - the factory must have a balance of at least `amount`.
     * - if `amount` is non-zero, `bytecode` must have a `payable` constructor.
     */
    function deploy(uint256 amount, bytes32 salt, bytes memory bytecode) internal returns (address addr) {
        if (address(this).balance < amount) {
            revert Create2InsufficientBalance(address(this).balance, amount);
        }
        if (bytecode.length == 0) {
            revert Create2EmptyBytecode();
        }
        /// @solidity memory-safe-assembly
        assembly {
            addr := create2(amount, add(bytecode, 0x20), mload(bytecode), salt)
        }
        if (addr == address(0)) {
            revert Create2FailedDeployment();
        }
    }

    /**
     * @dev Returns the address where a contract will be stored if deployed via {deploy}. Any change in the
     * `bytecodeHash` or `salt` will result in a new destination address.
     */
    function computeAddress(bytes32 salt, bytes32 bytecodeHash) internal view returns (address) {
        return computeAddress(salt, bytecodeHash, address(this));
    }

    /**
     * @dev Returns the address where a contract will be stored if deployed via {deploy} from a contract located at
     * `deployer`. If `deployer` is this contract's address, returns the same value as {computeAddress}.
     */
    function computeAddress(bytes32 salt, bytes32 bytecodeHash, address deployer) internal pure returns (address addr) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40) // Get free memory pointer

            // |                   | ↓ ptr ...  ↓ ptr + 0x0B (start) ...  ↓ ptr + 0x20 ...  ↓ ptr + 0x40 ...   |
            // |-------------------|---------------------------------------------------------------------------|
            // | bytecodeHash      |                                                        CCCCCCCCCCCCC...CC |
            // | salt              |                                      BBBBBBBBBBBBB...BB                   |
            // | deployer          | 000000...0000AAAAAAAAAAAAAAAAAAA...AA                                     |
            // | 0xFF              |            FF                                                             |
            // |-------------------|---------------------------------------------------------------------------|
            // | memory            | 000000...00FFAAAAAAAAAAAAAAAAAAA...AABBBBBBBBBBBBB...BBCCCCCCCCCCCCC...CC |
            // | keccak(start, 85) |            ↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑ |

            mstore(add(ptr, 0x40), bytecodeHash)
            mstore(add(ptr, 0x20), salt)
            mstore(ptr, deployer) // Right-aligned with 12 preceding garbage bytes
            let start := add(ptr, 0x0b) // The hashed data starts at the final garbage byte which we will set to 0xff
            mstore8(start, 0xff)
            addr := keccak256(start, 85)
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {ERC20Consideration} from "../ConsiderationLib.sol";
import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {Parties} from "../TypesAndConstants.sol";

struct ERC721ForERC20Swap {
    Parties parties;
    ERC721TransferLib.ERC721Token offer;
    ERC20Consideration consideration;
    uint256 validUntilTime;
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForERC20Swap} from "./ERC721ForERC20Swap.sol";
import {ERC721ForERC20SwapperBase} from "./ERC721ForERC20SwapperBase.gen.sol";

/// @notice Executes the ERC721ForERC20Swap received in the constructor.
contract ERC721ForERC20Swapper is ERC721ForERC20SwapperBase {
    constructor(ERC721ForERC20Swap memory swap, uint256 currentChainId)
        ERC721ForERC20SwapperBase(swap, currentChainId)
    {}
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForERC20Swap} from "./ERC721ForERC20Swap.sol";

import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {IETHome, Message} from "../ET.sol";
import {ConsiderationLib} from "../ConsiderationLib.sol";
import {SwapperBase} from "../SwapperBase.sol";
import {
    Action,
    ActionMessageLib,
    UnsupportedAction,
    FILL,
    CANCEL,
    FILLED_ARTIFACT,
    CANCELLED_ARTIFACT,
    ExcessPlatformFee,
    SwapExpired,
    currentChainId
} from "../TypesAndConstants.sol";

import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";

/// @dev Base contract for a ERC721ForERC20Swapper implementation.
contract ERC721ForERC20SwapperBase is SwapperBase {
    using ActionMessageLib for Message;
    using ConsiderationLib for *;

    constructor(ERC721ForERC20Swap memory swap, uint256 currentChainId_) {
        // The ERC721ForERC20SwapperDeployer always uses its current chain ID, so this is an invariant, and hence the use of
        // assert. Inclusion of the `currentChainId_` argument is purely to couple the CREATE2 address of this contract
        // to the specific chain.
        assert(currentChainId() == currentChainId_);

        Message message = IETHome(msg.sender).etMessage();
        Action action = message.action();

        bytes3 codeToDeploy;

        if (action == FILL) {
            // Expiry of a ERC721ForERC20Swap and cancellation thereof are effectively the same thing, so we only perform this
            // check in the FILL branch.
            uint256 validUntil = swap.validUntilTime;
            if (validUntil != 0 && block.timestamp > swap.validUntilTime) {
                revert SwapExpired(swap.validUntilTime);
            }

            codeToDeploy = FILLED_ARTIFACT;

            ERC721TransferLib._transfer(swap.offer, _asNonPayableParties(swap.parties));

            (address payable feeRecipient, uint16 basisPoints) = message.feeConfig();
            uint256 fee = Math.mulDiv(swap.consideration.total, basisPoints, 10_000);
            if (fee > swap.consideration.maxPlatformFee) {
                revert ExcessPlatformFee(fee, swap.consideration.maxPlatformFee);
            }

            // MUST remain as the last step before checking post-execution invariants. See ConsiderationLib
            // documentation for rationale.
            swap.consideration._disburse(swap.parties, feeRecipient, fee);
        } else if (action == CANCEL) {
            codeToDeploy = CANCELLED_ARTIFACT;
            // MUST remain as the last step for the same reason as _disburseFunds().
            swap.consideration._cancel(swap.parties, message.escrow());
        } else {
            revert UnsupportedAction(action);
        }

        assert(swap.consideration._postExecutionInvariantsMet(swap.parties));

        assembly ("memory-safe") {
            mstore(0, codeToDeploy)
            return(0, 3)
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForERC20Swap} from "./ERC721ForERC20Swap.sol";
import {ERC721ForERC20Swapper} from "./ERC721ForERC20Swapper.gen.sol";

import {ETDeployer, ETPredictor} from "../ET.sol";
import {SwapperDeployerBase} from "../SwapperDeployerBase.sol";
import {SwapperProposerBase} from "../SwapperProposerBase.sol";
import {OnlyPartyCanCancel, ActionMessageLib, CANCEL_MSG, ISwapperEvents} from "../TypesAndConstants.sol";

/// @dev Predictor of ERC721ForERC20Swapper contract addresses.
contract ERC721ForERC20SwapperPredictor {
    function _swapper(ERC721ForERC20Swap calldata swap, bytes32 salt, address deployer, uint256 chainId)
        internal
        pure
        returns (address)
    {
        return ETPredictor.deploymentAddress(_bytecode(swap, chainId), salt, deployer);
    }

    function _bytecode(ERC721ForERC20Swap calldata swap, uint256 chainId) internal pure returns (bytes memory) {
        return abi.encodePacked(type(ERC721ForERC20Swapper).creationCode, abi.encode(swap, chainId));
    }
}

/// @dev Deployer of ERC721ForERC20Swapper contracts.
abstract contract ERC721ForERC20SwapperDeployer is
    ERC721ForERC20SwapperPredictor,
    ETDeployer,
    SwapperDeployerBase,
    ISwapperEvents
{
    /// @dev Execute the `ERC721ForERC20Swap`, transferring all assets between the parties.
    function fillERC721ForERC20(ERC721ForERC20Swap calldata swap, bytes32 salt) external payable returns (address) {
        (address payable feeRecipient, uint16 basisPoints) = _platformFeeConfig();
        address a = _deploy(
            _bytecode(swap, _currentChainId()),
            msg.value,
            salt,
            ActionMessageLib.fillWithFeeConfig(feeRecipient, basisPoints)
        );
        emit Filled(a);
        return a;
    }

    /// @dev Permanently invalidate the `ERC721ForERC20Swap`.
    function cancelERC721ForERC20(ERC721ForERC20Swap calldata swap, bytes32 salt) external returns (address) {
        if (msg.sender != swap.parties.seller && msg.sender != swap.parties.buyer) {
            revert OnlyPartyCanCancel();
        }
        address a = _deploy(_bytecode(swap, _currentChainId()), 0, salt, ActionMessageLib.cancelWithEscrow(_escrow()));
        emit Cancelled(a);
        return a;
    }

    /**
     * @notice Computes the address of the swapper contract that will be deployed to execute the `ERC721ForERC20Swap`.
     * @dev Important: see `ERC721ForERC20SwapperProposer.propose()` as an alternative.
     */
    function swapperOfERC721ForERC20(ERC721ForERC20Swap calldata swap, bytes32 salt) external view returns (address) {
        return _swapper(swap, salt, address(this), _currentChainId());
    }
}

interface IERC721ForERC20SwapperProposerEvents {
    event ERC721ForERC20Proposal(
        address indexed swapper, address indexed seller, address indexed buyer, ERC721ForERC20Swap, bytes32 salt
    );
}

abstract contract ERC721ForERC20SwapperProposer is
    ERC721ForERC20SwapperPredictor,
    IERC721ForERC20SwapperProposerEvents,
    SwapperProposerBase
{
    /**
     * @notice "Announces" a propsed swap (in the form of a `Proposal` event), using the last block's hash as the salt
     * for the predicted swapper address.
     * @dev This is an optional step and swaps will function without prior proposal, but users SHOULD use this function
     * as it provides two security benefits: (i) a trusted means by which to safely determine the address they need to
     * approve to transfer their assets; and (ii) increasing the security level of the swapper address from 80 to 160
     * bits.
     * @dev A salt known to an adversary reduces the security of the swapper address to that of collision resistance
     * (~80 bits) whereas an unknown salt relies on second pre-image resistance (full address space = 160 bits). Using
     * the last block's hash would require computing a collision in the inter-block period so is sufficient. The Bitcoin
     * hash rate at the time of writing is almost 800e18 Hz, which would require a little over 25 minutes to brute-force
     * attack 80-bit security: https://www.wolframalpha.com/input?i=%282%5E80+%2F+800e18%29+seconds.
     * @dev This function MAY be called on a different chain to the one on which the swap will occur, provided that the
     * deployer contract has the same address.
     */
    function proposeERC721ForERC20(ERC721ForERC20Swap calldata swap) external returns (bytes32, address) {
        // We use blockhash instead of difficulty to allow this to work on chains other than ETH mainnet. The
        // malleability of block hashes is too low and their rate of production too slow for an attack based on
        // discarding undesirable salts.
        bytes32 salt = blockhash(block.number - 1);
        (address deployer, uint256 chainId) = _swapperDeployer();
        address swapper_ = _swapper(swap, salt, deployer, chainId);
        emit ERC721ForERC20Proposal(swapper_, swap.parties.seller, swap.parties.buyer, swap, salt);
        return (salt, swapper_);
    }

    function _swapperDeployer(ERC721ForERC20Swap calldata) internal virtual returns (address, uint256 chainId) {
        return _swapperDeployer();
    }
}

/**
 * @dev Compile-time guarantee that the ERC721ForERC20Swapper constructor has the signature assumed by _bytecode().
 * @dev Always reverts and MUST NOT be used.
 */
function _enforceERC721ForERC20SwapperCtorSig() {
    assert(false);
    ERC721ForERC20Swap memory s;
    new ERC721ForERC20Swapper(s, uint256(0));
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {Consideration} from "../ConsiderationLib.sol";
import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {PayableParties} from "../TypesAndConstants.sol";

struct ERC721ForNativeSwap {
    PayableParties parties;
    ERC721TransferLib.ERC721Token offer;
    Consideration consideration;
    uint256 validUntilTime;
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForNativeSwap} from "./ERC721ForNativeSwap.sol";
import {ERC721ForNativeSwapperBase} from "./ERC721ForNativeSwapperBase.gen.sol";

/// @notice Executes the ERC721ForNativeSwap received in the constructor.
contract ERC721ForNativeSwapper is ERC721ForNativeSwapperBase {
    constructor(ERC721ForNativeSwap memory swap, uint256 currentChainId)
        payable
        ERC721ForNativeSwapperBase(swap, currentChainId)
    {}
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForNativeSwap} from "./ERC721ForNativeSwap.sol";

import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {IETHome, Message} from "../ET.sol";
import {ConsiderationLib} from "../ConsiderationLib.sol";
import {SwapperBase} from "../SwapperBase.sol";
import {
    Action,
    ActionMessageLib,
    UnsupportedAction,
    FILL,
    CANCEL,
    FILLED_ARTIFACT,
    CANCELLED_ARTIFACT,
    ExcessPlatformFee,
    SwapExpired,
    currentChainId
} from "../TypesAndConstants.sol";

import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";

/// @dev Base contract for a ERC721ForNativeSwapper implementation.
contract ERC721ForNativeSwapperBase is SwapperBase {
    using ActionMessageLib for Message;
    using ConsiderationLib for *;

    constructor(ERC721ForNativeSwap memory swap, uint256 currentChainId_) {
        // The ERC721ForNativeSwapperDeployer always uses its current chain ID, so this is an invariant, and hence the use of
        // assert. Inclusion of the `currentChainId_` argument is purely to couple the CREATE2 address of this contract
        // to the specific chain.
        assert(currentChainId() == currentChainId_);

        Message message = IETHome(msg.sender).etMessage();
        Action action = message.action();

        bytes3 codeToDeploy;

        if (action == FILL) {
            // Expiry of a ERC721ForNativeSwap and cancellation thereof are effectively the same thing, so we only perform this
            // check in the FILL branch.
            uint256 validUntil = swap.validUntilTime;
            if (validUntil != 0 && block.timestamp > swap.validUntilTime) {
                revert SwapExpired(swap.validUntilTime);
            }

            codeToDeploy = FILLED_ARTIFACT;

            ERC721TransferLib._transfer(swap.offer, _asNonPayableParties(swap.parties));

            (address payable feeRecipient, uint16 basisPoints) = message.feeConfig();
            uint256 fee = Math.mulDiv(swap.consideration.total, basisPoints, 10_000);
            if (fee > swap.consideration.maxPlatformFee) {
                revert ExcessPlatformFee(fee, swap.consideration.maxPlatformFee);
            }

            // MUST remain as the last step before checking post-execution invariants. See ConsiderationLib
            // documentation for rationale.
            swap.consideration._disburse(swap.parties, feeRecipient, fee);
        } else if (action == CANCEL) {
            codeToDeploy = CANCELLED_ARTIFACT;
            // MUST remain as the last step for the same reason as _disburseFunds().
            swap.consideration._cancel(swap.parties, message.escrow());
        } else {
            revert UnsupportedAction(action);
        }

        assert(swap.consideration._postExecutionInvariantsMet(swap.parties));

        assembly ("memory-safe") {
            mstore(0, codeToDeploy)
            return(0, 3)
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {ERC721ForNativeSwap} from "./ERC721ForNativeSwap.sol";
import {ERC721ForNativeSwapper} from "./ERC721ForNativeSwapper.gen.sol";

import {ETDeployer, ETPredictor} from "../ET.sol";
import {SwapperDeployerBase} from "../SwapperDeployerBase.sol";
import {SwapperProposerBase} from "../SwapperProposerBase.sol";
import {OnlyPartyCanCancel, ActionMessageLib, CANCEL_MSG, ISwapperEvents} from "../TypesAndConstants.sol";

/// @dev Predictor of ERC721ForNativeSwapper contract addresses.
contract ERC721ForNativeSwapperPredictor {
    function _swapper(ERC721ForNativeSwap calldata swap, bytes32 salt, address deployer, uint256 chainId)
        internal
        pure
        returns (address)
    {
        return ETPredictor.deploymentAddress(_bytecode(swap, chainId), salt, deployer);
    }

    function _bytecode(ERC721ForNativeSwap calldata swap, uint256 chainId) internal pure returns (bytes memory) {
        return abi.encodePacked(type(ERC721ForNativeSwapper).creationCode, abi.encode(swap, chainId));
    }
}

/// @dev Deployer of ERC721ForNativeSwapper contracts.
abstract contract ERC721ForNativeSwapperDeployer is
    ERC721ForNativeSwapperPredictor,
    ETDeployer,
    SwapperDeployerBase,
    ISwapperEvents
{
    /// @dev Execute the `ERC721ForNativeSwap`, transferring all assets between the parties.
    function fillERC721ForNative(ERC721ForNativeSwap calldata swap, bytes32 salt) external payable returns (address) {
        (address payable feeRecipient, uint16 basisPoints) = _platformFeeConfig();
        address a = _deploy(
            _bytecode(swap, _currentChainId()),
            msg.value,
            salt,
            ActionMessageLib.fillWithFeeConfig(feeRecipient, basisPoints)
        );
        emit Filled(a);
        return a;
    }

    /// @dev Permanently invalidate the `ERC721ForNativeSwap`.
    function cancelERC721ForNative(ERC721ForNativeSwap calldata swap, bytes32 salt) external returns (address) {
        if (msg.sender != swap.parties.seller && msg.sender != swap.parties.buyer) {
            revert OnlyPartyCanCancel();
        }
        address a = _deploy(_bytecode(swap, _currentChainId()), 0, salt, ActionMessageLib.cancelWithEscrow(_escrow()));
        emit Cancelled(a);
        return a;
    }

    /**
     * @notice Computes the address of the swapper contract that will be deployed to execute the `ERC721ForNativeSwap`.
     * @dev Important: see `ERC721ForNativeSwapperProposer.propose()` as an alternative.
     */
    function swapperOfERC721ForNative(ERC721ForNativeSwap calldata swap, bytes32 salt)
        external
        view
        returns (address)
    {
        return _swapper(swap, salt, address(this), _currentChainId());
    }
}

interface IERC721ForNativeSwapperProposerEvents {
    event ERC721ForNativeProposal(
        address indexed swapper, address indexed seller, address indexed buyer, ERC721ForNativeSwap, bytes32 salt
    );
}

abstract contract ERC721ForNativeSwapperProposer is
    ERC721ForNativeSwapperPredictor,
    IERC721ForNativeSwapperProposerEvents,
    SwapperProposerBase
{
    /**
     * @notice "Announces" a propsed swap (in the form of a `Proposal` event), using the last block's hash as the salt
     * for the predicted swapper address.
     * @dev This is an optional step and swaps will function without prior proposal, but users SHOULD use this function
     * as it provides two security benefits: (i) a trusted means by which to safely determine the address they need to
     * approve to transfer their assets; and (ii) increasing the security level of the swapper address from 80 to 160
     * bits.
     * @dev A salt known to an adversary reduces the security of the swapper address to that of collision resistance
     * (~80 bits) whereas an unknown salt relies on second pre-image resistance (full address space = 160 bits). Using
     * the last block's hash would require computing a collision in the inter-block period so is sufficient. The Bitcoin
     * hash rate at the time of writing is almost 800e18 Hz, which would require a little over 25 minutes to brute-force
     * attack 80-bit security: https://www.wolframalpha.com/input?i=%282%5E80+%2F+800e18%29+seconds.
     * @dev This function MAY be called on a different chain to the one on which the swap will occur, provided that the
     * deployer contract has the same address.
     */
    function proposeERC721ForNative(ERC721ForNativeSwap calldata swap) external returns (bytes32, address) {
        // We use blockhash instead of difficulty to allow this to work on chains other than ETH mainnet. The
        // malleability of block hashes is too low and their rate of production too slow for an attack based on
        // discarding undesirable salts.
        bytes32 salt = blockhash(block.number - 1);
        (address deployer, uint256 chainId) = _swapperDeployer();
        address swapper_ = _swapper(swap, salt, deployer, chainId);
        emit ERC721ForNativeProposal(swapper_, swap.parties.seller, swap.parties.buyer, swap, salt);
        return (salt, swapper_);
    }

    function _swapperDeployer(ERC721ForNativeSwap calldata) internal virtual returns (address, uint256 chainId) {
        return _swapperDeployer();
    }
}

/**
 * @dev Compile-time guarantee that the ERC721ForNativeSwapper constructor has the signature assumed by _bytecode().
 * @dev Always reverts and MUST NOT be used.
 */
function _enforceERC721ForNativeSwapperCtorSig() {
    assert(false);
    ERC721ForNativeSwap memory s;
    new ERC721ForNativeSwapper(s, uint256(0));
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity ^0.8.24;

import {IERC721} from "@openzeppelin/contracts/interfaces/IERC721.sol";
import {Parties} from "./TypesAndConstants.sol";

/**
 * @dev Transfers one or more ERC721 tokens between parties.
 * @dev Note that all `_transfer(<T>, Parties)` functions have effectively the same signature, allowing them to be
 * called without explicit knowledge of the <T> type as the constructor will select the respective function. This is
 * exploited by the `TMPL/SwapperBase.sol.tmpl` template.
 * @author Arran Schlosberg (@divergencearran / github.com/arr4n)
 */
library ERC721TransferLib {
    /// @dev Thrown if a token address doesn't contain any code.
    error NoCodeAtAddress(address);

    /// @dev Represents a single ERC721 token.
    struct ERC721Token {
        IERC721 addr;
        uint256 id;
    }

    /// @dev Transfers the token from `parties.seller` to `parties.buyer`.
    function _transfer(ERC721Token memory token, Parties memory parties) internal {
        token.addr.transferFrom(parties.seller, parties.buyer, token.id);
    }

    /// @dev Transfers the token from `parties.seller` to `parties.buyer` using `safeTransferFrom()`.
    function _safeTransfer(ERC721Token memory token, Parties memory parties, bytes memory data) internal {
        token.addr.safeTransferFrom(parties.seller, parties.buyer, token.id, data);
    }

    /// @dev Represents multiple ERC721 tokens within the same contract.
    struct MultiERC721Token {
        IERC721 addr;
        uint256[] ids; // MUST be distinct
    }

    /**
     * @dev Transfers all tokens from `parties.seller` to `parties.buyer`.
     * @param tokens Any number of ERC721 tokens from a single contract; ids MUST be distinct across the entire array.
     */
    function _transfer(MultiERC721Token memory tokens, Parties memory parties) internal {
        _transfer(tokens, _reusableTransferCallData(parties));
    }

    /**
     * @dev Transfers all tokens from `parties.seller` to `parties.buyer` using `safeTransferFrom()`.
     * @param tokens Any number of ERC721 tokens from a single contract; ids MUST be distinct across the entire array.
     */
    function _safeTransfer(MultiERC721Token memory tokens, Parties memory parties, bytes memory data) internal {
        _transfer(tokens, _reusableSafeTransferCallData(parties, data));
    }

    /**
     * @dev Transfers all tokens from `parties.seller` to `parties.buyer`.
     * @param tokens An _array_ of MultiERC721Token structs, representing any number of tokens. {addr,id} pairs MUST be
     * distinct across the entire array.
     */
    function _transfer(MultiERC721Token[] memory tokens, Parties memory parties) internal {
        bytes memory callData = _reusableTransferCallData(parties);
        for (uint256 i = 0; i < tokens.length; ++i) {
            _transfer(tokens[i], callData);
        }
    }

    /**
     * @dev Transfers all tokens from `parties.seller` to `parties.buyer` using `safeTransferFrom()`.
     * @param tokens An _array_ of MultiERC721Token structs, representing any number of tokens. {addr,id} pairs MUST be
     * distinct across the entire array.
     */
    function _safeTransfer(MultiERC721Token[] memory tokens, Parties memory parties, bytes memory data) internal {
        bytes memory callData = _reusableSafeTransferCallData(parties, data);
        for (uint256 i = 0; i < tokens.length; ++i) {
            _transfer(tokens[i], callData);
        }
    }

    /**
     * @dev Returns calldata for `ERC721.transferFrom(parties.seller, parties.buyer, 0)`, which can be reused to avoid
     * unnecessary memory expansion when transferring large numbers of tokens.
     */
    function _reusableTransferCallData(Parties memory parties) private pure returns (bytes memory) {
        return abi.encodeCall(IERC721.transferFrom, (parties.seller, parties.buyer, 0));
    }

    /**
     * @dev Returns calldata for `ERC721.safeTransferFrom(parties.seller, parties.buyer, 0, data)`. See
     * `_reusableTransferCallData()` for rationale.
     */
    function _reusableSafeTransferCallData(Parties memory parties, bytes memory data)
        private
        pure
        returns (bytes memory)
    {
        // Since `safeTransferFrom()` has an overload, we can't use `abi.encodeCall()` as it's ambiguous.
        return abi.encodeWithSignature(
            "safeTransferFrom(address,address,uint256,bytes)", parties.seller, parties.buyer, 0, data
        );
    }

    /**
     * @param token Contract and IDs of tokens to be transferred.
     * @param reusableCallData Output of `_reusableTransferCallData()` or `_reusableSafeTransferCallData()`.
     */
    function _transfer(MultiERC721Token memory token, bytes memory reusableCallData) private {
        address addr = address(token.addr);
        if (addr.code.length == 0) {
            revert NoCodeAtAddress(addr);
        }
        uint256[] memory ids = token.ids;

        assembly ("memory-safe") {
            let idSrc := add(ids, 0x20)
            let idDst := add(reusableCallData, 0x64)
            let dataPtr := add(reusableCallData, 0x20)

            for { let end := add(idSrc, mul(mload(ids), 0x20)) } lt(idSrc, end) { idSrc := add(idSrc, 0x20) } {
                mcopy(idDst, idSrc, 0x20)

                if iszero(call(gas(), addr, 0, dataPtr, reusableCallData, 0, 0)) {
                    // Even though this may extend beyond scratch space, we revert the current context immediately so
                    // it's still memory-safe.
                    returndatacopy(0, 0, returndatasize())
                    revert(0, returndatasize())
                }
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity ^0.8.24; // Requires TLOAD/TSTORE

import {Create2} from "./Create2.sol";
import {Create2 as OZCreate2} from "@openzeppelin/contracts/utils/Create2.sol";

/**
 * @dev An arbitrary word that a deploying contract can pass to a CREATE2-deployed contract that "phones home". By
 * accessing the Message in this manner, the constructor arguments can remain static so the deployment address is
 * independent of the Message.
 */
type Message is bytes32;

/**
 * @notice A CREATE2-deployed contract that can phone home to receive a Message.
 * @dev Phoning home is typically performed in a constrctor and MUST be done in the same transaction as Messages are
 * kept in transient storage.
 * @dev ET contracts SHOULD NOT be deployed directly, but instead via ETDeployer._deploy().
 * @author Arran Schlosberg (@divergencearran / github.com/arr4n)
 */
contract ET {
    function _phoneHome() internal view returns (Message) {
        return IETHome(msg.sender).etMessage();
    }
}

/**
 * @dev The interface allowing an ET contract to phone home to its deployer.
 */
interface IETHome {
    function etMessage() external view returns (Message);
}

/**
 * @dev Predictor of ET contract addresses. Little more than a wrapper around OpenZeppelin's Create2 library.
 * @author Arran Schlosberg (@divergencearran / github.com/arr4n)
 */
library ETPredictor {
    /**
     * @dev Convenience wrapper around OpenZeppelin's Create2.computeAddress() to match the argument signature of
     * `ETDeployer._deploy()`, assuming `address(this)` as the `deployer`.
     */
    function deploymentAddress(bytes memory bytecode, bytes32 salt) internal view returns (address) {
        return deploymentAddress(bytecode, salt, address(this));
    }

    /**
     * @dev Convenience wrapper around OpenZeppelin's Create2.computeAddress() to mirror the argument signature of
     * `ETDeployer._deploy()`, with the exception of an additional `deployer` address.
     */
    function deploymentAddress(bytes memory bytecode, bytes32 salt, address deployer) internal pure returns (address) {
        return OZCreate2.computeAddress(salt, keccak256(bytecode), deployer);
    }
}

/**
 * @dev Deployer of ET contracts, responsible for storing Messages and making them available to deployed contracts.
 * @author Arran Schlosberg (@divergencearran / github.com/arr4n)
 */
contract ETDeployer is IETHome {
    error PredictedAddressMismatch(address deployed, address predicted);

    /**
     * @dev Deploys an ET contract, first transiently storing the Message to make it available via etMessage().
     * @param predicted Predicted deployment address, saving gas if pre-computed off-chain.
     * @param bytecode Creation bytecode of the contract to be deployed; aka init_code or creationCode.
     * @param value Amount, in wei, to send during deployment.
     * @param salt CREATE2 salt.
     * @param message Message to be made available to the deployed contract if it calls etMessage() on this contract.
     * @return Address of the deployed contract.
     * @custom:reverts If deployment fails; propagates the return data from CREATE2, which will be empty if attempting
     * to re-deploy to the same address.
     */
    function _deploy(address predicted, bytes memory bytecode, uint256 value, bytes32 salt, Message message)
        internal
        returns (address)
    {
        assembly ("memory-safe") {
            // There is no need to explicitly clear this TSTORE (as solc recommends) because it is uniquely tied to the
            // deployed contract, which can never be reused.
            tstore(shr(96, shl(96, predicted)), message)
        }

        address deployed = Create2.deploy(bytecode, value, salt);
        if (deployed != predicted) {
            revert PredictedAddressMismatch(deployed, predicted);
        }
        return deployed;
    }

    /// @dev Identical to `_deploy(address predicted, ...)` except that the predicted address is computed.
    function _deploy(bytes memory bytecode, uint256 value, bytes32 salt, Message message) internal returns (address) {
        return _deploy(ETPredictor.deploymentAddress(bytecode, salt), bytecode, value, salt, message);
    }

    /**
     * @dev Called by the deployed ET contract to receive its message.
     * @return m The Message argument passed to _deploy().
     */
    function etMessage() external view returns (Message m) {
        assembly ("memory-safe") {
            m := tload(caller())
        }
    }
}

/**
 * @dev Equality check for two Messages, used globally as ==.
 */
function _eq(Message a, Message b) pure returns (bool) {
    return Message.unwrap(a) == Message.unwrap(b);
}

using {_eq as ==} for Message global;

/**
 * @dev Inequality check for two Messages, used globally as !=.
 */
function _neq(Message a, Message b) pure returns (bool) {
    return !_eq(a, b);
}

using {_neq as !=} for Message global;

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;

import {Address} from "@openzeppelin/contracts/utils/Address.sol";

interface IEscrowEvents {
    event Deposit(address, uint256);
    event Withdrawal(address, uint256);
}

/// @dev MUST be returned by `Escrow.isEscrow()`.
bytes32 constant ESCROW_MAGIC_NUMBER =
    keccak256("Trust me, bro, I'll protect your ETH. But not ERC20s, don't send me ERC20s!");

/// @dev Minimal interface required for depositing funds in an escrow.
interface IEscrow {
    function deposit(address payable) external payable;
}

/// @notice Permissionless escrow contract for pull payments.
contract Escrow is IEscrow, IEscrowEvents {
    /// @dev Thrown if attempting to withdraw for account with no balance.
    error ZeroBalance(address);

    /// @dev Per-account escrowed balance.
    mapping(address => uint256) public balance;

    /// @dev Deposit the sent value such that it can only be withdrawn into `account`.
    function deposit(address payable account) external payable {
        balance[account] += msg.value;
        emit Deposit(account, msg.value);
    }

    /// @dev Equivalent to `withdraw(msg.sender)`.
    function withdraw() external {
        withdraw(payable(msg.sender));
    }

    /// @dev Withdraw all funds previously deposited for `account`.
    function withdraw(address account) public {
        // CHECK
        uint256 bal = balance[account];
        if (bal == 0) {
            revert ZeroBalance(account);
        }
        // EFFECT
        balance[account] = 0;
        // INTERACTION
        Address.sendValue(payable(account), bal);

        emit Withdrawal(account, bal);
    }

    /// @dev Returns `ESCROW_MAGIC_NUMBER`.
    function isEscrow() external pure returns (bytes32) {
        return ESCROW_MAGIC_NUMBER;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC721} from "../token/ERC721/IERC721.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {ERC20Consideration} from "../ConsiderationLib.sol";
import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {Parties} from "../TypesAndConstants.sol";

struct MultiERC721ForERC20Swap {
    Parties parties;
    ERC721TransferLib.MultiERC721Token[] offer;
    ERC20Consideration consideration;
    uint256 validUntilTime;
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForERC20Swap} from "./MultiERC721ForERC20Swap.sol";
import {MultiERC721ForERC20SwapperBase} from "./MultiERC721ForERC20SwapperBase.gen.sol";

/// @notice Executes the MultiERC721ForERC20Swap received in the constructor.
contract MultiERC721ForERC20Swapper is MultiERC721ForERC20SwapperBase {
    constructor(MultiERC721ForERC20Swap memory swap, uint256 currentChainId)
        MultiERC721ForERC20SwapperBase(swap, currentChainId)
    {}
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForERC20Swap} from "./MultiERC721ForERC20Swap.sol";

import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {IETHome, Message} from "../ET.sol";
import {ConsiderationLib} from "../ConsiderationLib.sol";
import {SwapperBase} from "../SwapperBase.sol";
import {
    Action,
    ActionMessageLib,
    UnsupportedAction,
    FILL,
    CANCEL,
    FILLED_ARTIFACT,
    CANCELLED_ARTIFACT,
    ExcessPlatformFee,
    SwapExpired,
    currentChainId
} from "../TypesAndConstants.sol";

import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";

/// @dev Base contract for a MultiERC721ForERC20Swapper implementation.
contract MultiERC721ForERC20SwapperBase is SwapperBase {
    using ActionMessageLib for Message;
    using ConsiderationLib for *;

    constructor(MultiERC721ForERC20Swap memory swap, uint256 currentChainId_) {
        // The MultiERC721ForERC20SwapperDeployer always uses its current chain ID, so this is an invariant, and hence the use of
        // assert. Inclusion of the `currentChainId_` argument is purely to couple the CREATE2 address of this contract
        // to the specific chain.
        assert(currentChainId() == currentChainId_);

        Message message = IETHome(msg.sender).etMessage();
        Action action = message.action();

        bytes3 codeToDeploy;

        if (action == FILL) {
            // Expiry of a MultiERC721ForERC20Swap and cancellation thereof are effectively the same thing, so we only perform this
            // check in the FILL branch.
            uint256 validUntil = swap.validUntilTime;
            if (validUntil != 0 && block.timestamp > swap.validUntilTime) {
                revert SwapExpired(swap.validUntilTime);
            }

            codeToDeploy = FILLED_ARTIFACT;

            ERC721TransferLib._transfer(swap.offer, _asNonPayableParties(swap.parties));

            (address payable feeRecipient, uint16 basisPoints) = message.feeConfig();
            uint256 fee = Math.mulDiv(swap.consideration.total, basisPoints, 10_000);
            if (fee > swap.consideration.maxPlatformFee) {
                revert ExcessPlatformFee(fee, swap.consideration.maxPlatformFee);
            }

            // MUST remain as the last step before checking post-execution invariants. See ConsiderationLib
            // documentation for rationale.
            swap.consideration._disburse(swap.parties, feeRecipient, fee);
        } else if (action == CANCEL) {
            codeToDeploy = CANCELLED_ARTIFACT;
            // MUST remain as the last step for the same reason as _disburseFunds().
            swap.consideration._cancel(swap.parties, message.escrow());
        } else {
            revert UnsupportedAction(action);
        }

        assert(swap.consideration._postExecutionInvariantsMet(swap.parties));

        assembly ("memory-safe") {
            mstore(0, codeToDeploy)
            return(0, 3)
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForERC20Swap} from "./MultiERC721ForERC20Swap.sol";
import {MultiERC721ForERC20Swapper} from "./MultiERC721ForERC20Swapper.gen.sol";

import {ETDeployer, ETPredictor} from "../ET.sol";
import {SwapperDeployerBase} from "../SwapperDeployerBase.sol";
import {SwapperProposerBase} from "../SwapperProposerBase.sol";
import {OnlyPartyCanCancel, ActionMessageLib, CANCEL_MSG, ISwapperEvents} from "../TypesAndConstants.sol";

/// @dev Predictor of MultiERC721ForERC20Swapper contract addresses.
contract MultiERC721ForERC20SwapperPredictor {
    function _swapper(MultiERC721ForERC20Swap calldata swap, bytes32 salt, address deployer, uint256 chainId)
        internal
        pure
        returns (address)
    {
        return ETPredictor.deploymentAddress(_bytecode(swap, chainId), salt, deployer);
    }

    function _bytecode(MultiERC721ForERC20Swap calldata swap, uint256 chainId) internal pure returns (bytes memory) {
        return abi.encodePacked(type(MultiERC721ForERC20Swapper).creationCode, abi.encode(swap, chainId));
    }
}

/// @dev Deployer of MultiERC721ForERC20Swapper contracts.
abstract contract MultiERC721ForERC20SwapperDeployer is
    MultiERC721ForERC20SwapperPredictor,
    ETDeployer,
    SwapperDeployerBase,
    ISwapperEvents
{
    /// @dev Execute the `MultiERC721ForERC20Swap`, transferring all assets between the parties.
    function fillMultiERC721ForERC20(MultiERC721ForERC20Swap calldata swap, bytes32 salt)
        external
        payable
        returns (address)
    {
        (address payable feeRecipient, uint16 basisPoints) = _platformFeeConfig();
        address a = _deploy(
            _bytecode(swap, _currentChainId()),
            msg.value,
            salt,
            ActionMessageLib.fillWithFeeConfig(feeRecipient, basisPoints)
        );
        emit Filled(a);
        return a;
    }

    /// @dev Permanently invalidate the `MultiERC721ForERC20Swap`.
    function cancelMultiERC721ForERC20(MultiERC721ForERC20Swap calldata swap, bytes32 salt)
        external
        returns (address)
    {
        if (msg.sender != swap.parties.seller && msg.sender != swap.parties.buyer) {
            revert OnlyPartyCanCancel();
        }
        address a = _deploy(_bytecode(swap, _currentChainId()), 0, salt, ActionMessageLib.cancelWithEscrow(_escrow()));
        emit Cancelled(a);
        return a;
    }

    /**
     * @notice Computes the address of the swapper contract that will be deployed to execute the `MultiERC721ForERC20Swap`.
     * @dev Important: see `MultiERC721ForERC20SwapperProposer.propose()` as an alternative.
     */
    function swapperOfMultiERC721ForERC20(MultiERC721ForERC20Swap calldata swap, bytes32 salt)
        external
        view
        returns (address)
    {
        return _swapper(swap, salt, address(this), _currentChainId());
    }
}

interface IMultiERC721ForERC20SwapperProposerEvents {
    event MultiERC721ForERC20Proposal(
        address indexed swapper, address indexed seller, address indexed buyer, MultiERC721ForERC20Swap, bytes32 salt
    );
}

abstract contract MultiERC721ForERC20SwapperProposer is
    MultiERC721ForERC20SwapperPredictor,
    IMultiERC721ForERC20SwapperProposerEvents,
    SwapperProposerBase
{
    /**
     * @notice "Announces" a propsed swap (in the form of a `Proposal` event), using the last block's hash as the salt
     * for the predicted swapper address.
     * @dev This is an optional step and swaps will function without prior proposal, but users SHOULD use this function
     * as it provides two security benefits: (i) a trusted means by which to safely determine the address they need to
     * approve to transfer their assets; and (ii) increasing the security level of the swapper address from 80 to 160
     * bits.
     * @dev A salt known to an adversary reduces the security of the swapper address to that of collision resistance
     * (~80 bits) whereas an unknown salt relies on second pre-image resistance (full address space = 160 bits). Using
     * the last block's hash would require computing a collision in the inter-block period so is sufficient. The Bitcoin
     * hash rate at the time of writing is almost 800e18 Hz, which would require a little over 25 minutes to brute-force
     * attack 80-bit security: https://www.wolframalpha.com/input?i=%282%5E80+%2F+800e18%29+seconds.
     * @dev This function MAY be called on a different chain to the one on which the swap will occur, provided that the
     * deployer contract has the same address.
     */
    function proposeMultiERC721ForERC20(MultiERC721ForERC20Swap calldata swap) external returns (bytes32, address) {
        // We use blockhash instead of difficulty to allow this to work on chains other than ETH mainnet. The
        // malleability of block hashes is too low and their rate of production too slow for an attack based on
        // discarding undesirable salts.
        bytes32 salt = blockhash(block.number - 1);
        (address deployer, uint256 chainId) = _swapperDeployer();
        address swapper_ = _swapper(swap, salt, deployer, chainId);
        emit MultiERC721ForERC20Proposal(swapper_, swap.parties.seller, swap.parties.buyer, swap, salt);
        return (salt, swapper_);
    }

    function _swapperDeployer(MultiERC721ForERC20Swap calldata) internal virtual returns (address, uint256 chainId) {
        return _swapperDeployer();
    }
}

/**
 * @dev Compile-time guarantee that the MultiERC721ForERC20Swapper constructor has the signature assumed by _bytecode().
 * @dev Always reverts and MUST NOT be used.
 */
function _enforceMultiERC721ForERC20SwapperCtorSig() {
    assert(false);
    MultiERC721ForERC20Swap memory s;
    new MultiERC721ForERC20Swapper(s, uint256(0));
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {Consideration} from "../ConsiderationLib.sol";
import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {PayableParties} from "../TypesAndConstants.sol";

struct MultiERC721ForNativeSwap {
    PayableParties parties;
    ERC721TransferLib.MultiERC721Token[] offer;
    Consideration consideration;
    uint256 validUntilTime;
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForNativeSwap} from "./MultiERC721ForNativeSwap.sol";
import {MultiERC721ForNativeSwapperBase} from "./MultiERC721ForNativeSwapperBase.gen.sol";

/// @notice Executes the MultiERC721ForNativeSwap received in the constructor.
contract MultiERC721ForNativeSwapper is MultiERC721ForNativeSwapperBase {
    constructor(MultiERC721ForNativeSwap memory swap, uint256 currentChainId)
        payable
        MultiERC721ForNativeSwapperBase(swap, currentChainId)
    {}
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForNativeSwap} from "./MultiERC721ForNativeSwap.sol";

import {ERC721TransferLib} from "../ERC721TransferLib.sol";
import {IETHome, Message} from "../ET.sol";
import {ConsiderationLib} from "../ConsiderationLib.sol";
import {SwapperBase} from "../SwapperBase.sol";
import {
    Action,
    ActionMessageLib,
    UnsupportedAction,
    FILL,
    CANCEL,
    FILLED_ARTIFACT,
    CANCELLED_ARTIFACT,
    ExcessPlatformFee,
    SwapExpired,
    currentChainId
} from "../TypesAndConstants.sol";

import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";

/// @dev Base contract for a MultiERC721ForNativeSwapper implementation.
contract MultiERC721ForNativeSwapperBase is SwapperBase {
    using ActionMessageLib for Message;
    using ConsiderationLib for *;

    constructor(MultiERC721ForNativeSwap memory swap, uint256 currentChainId_) {
        // The MultiERC721ForNativeSwapperDeployer always uses its current chain ID, so this is an invariant, and hence the use of
        // assert. Inclusion of the `currentChainId_` argument is purely to couple the CREATE2 address of this contract
        // to the specific chain.
        assert(currentChainId() == currentChainId_);

        Message message = IETHome(msg.sender).etMessage();
        Action action = message.action();

        bytes3 codeToDeploy;

        if (action == FILL) {
            // Expiry of a MultiERC721ForNativeSwap and cancellation thereof are effectively the same thing, so we only perform this
            // check in the FILL branch.
            uint256 validUntil = swap.validUntilTime;
            if (validUntil != 0 && block.timestamp > swap.validUntilTime) {
                revert SwapExpired(swap.validUntilTime);
            }

            codeToDeploy = FILLED_ARTIFACT;

            ERC721TransferLib._transfer(swap.offer, _asNonPayableParties(swap.parties));

            (address payable feeRecipient, uint16 basisPoints) = message.feeConfig();
            uint256 fee = Math.mulDiv(swap.consideration.total, basisPoints, 10_000);
            if (fee > swap.consideration.maxPlatformFee) {
                revert ExcessPlatformFee(fee, swap.consideration.maxPlatformFee);
            }

            // MUST remain as the last step before checking post-execution invariants. See ConsiderationLib
            // documentation for rationale.
            swap.consideration._disburse(swap.parties, feeRecipient, fee);
        } else if (action == CANCEL) {
            codeToDeploy = CANCELLED_ARTIFACT;
            // MUST remain as the last step for the same reason as _disburseFunds().
            swap.consideration._cancel(swap.parties, message.escrow());
        } else {
            revert UnsupportedAction(action);
        }

        assert(swap.consideration._postExecutionInvariantsMet(swap.parties));

        assembly ("memory-safe") {
            mstore(0, codeToDeploy)
            return(0, 3)
        }
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity 0.8.25;
/**
 * GENERATED CODE - DO NOT EDIT
 */

import {MultiERC721ForNativeSwap} from "./MultiERC721ForNativeSwap.sol";
import {MultiERC721ForNativeSwapper} from "./MultiERC721ForNativeSwapper.gen.sol";

import {ETDeployer, ETPredictor} from "../ET.sol";
import {SwapperDeployerBase} from "../SwapperDeployerBase.sol";
import {SwapperProposerBase} from "../SwapperProposerBase.sol";
import {OnlyPartyCanCancel, ActionMessageLib, CANCEL_MSG, ISwapperEvents} from "../TypesAndConstants.sol";

/// @dev Predictor of MultiERC721ForNativeSwapper contract addresses.
contract MultiERC721ForNativeSwapperPredictor {
    function _swapper(MultiERC721ForNativeSwap calldata swap, bytes32 salt, address deployer, uint256 chainId)
        internal
        pure
        returns (address)
    {
        return ETPredictor.deploymentAddress(_bytecode(swap, chainId), salt, deployer);
    }

    function _bytecode(MultiERC721ForNativeSwap calldata swap, uint256 chainId) internal pure returns (bytes memory) {
        return abi.encodePacked(type(MultiERC721ForNativeSwapper).creationCode, abi.encode(swap, chainId));
    }
}

/// @dev Deployer of MultiERC721ForNativeSwapper contracts.
abstract contract MultiERC721ForNativeSwapperDeployer is
    MultiERC721ForNativeSwapperPredictor,
    ETDeployer,
    SwapperDeployerBase,
    ISwapperEvents
{
    /// @dev Execute the `MultiERC721ForNativeSwap`, transferring all assets between the parties.
    function fillMultiERC721ForNative(MultiERC721ForNativeSwap calldata swap, bytes32 salt)
        external
        payable
        returns (address)
    {
        (address payable feeRecipient, uint16 basisPoints) = _platformFeeConfig();
        address a = _deploy(
            _bytecode(swap, _currentChainId()),
            msg.value,
            salt,
            ActionMessageLib.fillWithFeeConfig(feeRecipient, basisPoints)
        );
        emit Filled(a);
        return a;
    }

    /// @dev Permanently invalidate the `MultiERC721ForNativeSwap`.
    function cancelMultiERC721ForNative(MultiERC721ForNativeSwap calldata swap, bytes32 salt)
        external
        returns (address)
    {
        if (msg.sender != swap.parties.seller && msg.sender != swap.parties.buyer) {
            revert OnlyPartyCanCancel();
        }
        address a = _deploy(_bytecode(swap, _currentChainId()), 0, salt, ActionMessageLib.cancelWithEscrow(_escrow()));
        emit Cancelled(a);
        return a;
    }

    /**
     * @notice Computes the address of the swapper contract that will be deployed to execute the `MultiERC721ForNativeSwap`.
     * @dev Important: see `MultiERC721ForNativeSwapperProposer.propose()` as an alternative.
     */
    function swapperOfMultiERC721ForNative(MultiERC721ForNativeSwap calldata swap, bytes32 salt)
        external
        view
        returns (address)
    {
        return _swapper(swap, salt, address(this), _currentChainId());
    }
}

interface IMultiERC721ForNativeSwapperProposerEvents {
    event MultiERC721ForNativeProposal(
        address indexed swapper, address indexed seller, address indexed buyer, MultiERC721ForNativeSwap, bytes32 salt
    );
}

abstract contract MultiERC721ForNativeSwapperProposer is
    MultiERC721ForNativeSwapperPredictor,
    IMultiERC721ForNativeSwapperProposerEvents,
    SwapperProposerBase
{
    /**
     * @notice "Announces" a propsed swap (in the form of a `Proposal` event), using the last block's hash as the salt
     * for the predicted swapper address.
     * @dev This is an optional step and swaps will function without prior proposal, but users SHOULD use this function
     * as it provides two security benefits: (i) a trusted means by which to safely determine the address they need to
     * approve to transfer their assets; and (ii) increasing the security level of the swapper address from 80 to 160
     * bits.
     * @dev A salt known to an adversary reduces the security of the swapper address to that of collision resistance
     * (~80 bits) whereas an unknown salt relies on second pre-image resistance (full address space = 160 bits). Using
     * the last block's hash would require computing a collision in the inter-block period so is sufficient. The Bitcoin
     * hash rate at the time of writing is almost 800e18 Hz, which would require a little over 25 minutes to brute-force
     * attack 80-bit security: https://www.wolframalpha.com/input?i=%282%5E80+%2F+800e18%29+seconds.
     * @dev This function MAY be called on a different chain to the one on which the swap will occur, provided that the
     * deployer contract has the same address.
     */
    function proposeMultiERC721ForNative(MultiERC721ForNativeSwap calldata swap) external returns (bytes32, address) {
        // We use blockhash instead of difficulty to allow this to work on chains other than ETH mainnet. The
        // malleability of block hashes is too low and their rate of production too slow for an attack based on
        // discarding undesirable salts.
        bytes32 salt = blockhash(block.number - 1);
        (address deployer, uint256 chainId) = _swapperDeployer();
        address swapper_ = _swapper(swap, salt, deployer, chainId);
        emit MultiERC721ForNativeProposal(swapper_, swap.parties.seller, swap.parties.buyer, swap, salt);
        return (salt, swapper_);
    }

    function _swapperDeployer(MultiERC721ForNativeSwap calldata) internal virtual returns (address, uint256 chainId) {
        return _swapperDeployer();
    }
}

/**
 * @dev Compile-time guarantee that the MultiERC721ForNativeSwapper constructor has the signature assumed by _bytecode().
 * @dev Always reverts and MUST NOT be used.
 */
function _enforceMultiERC721ForNativeSwapperCtorSig() {
    assert(false);
    MultiERC721ForNativeSwap memory s;
    new MultiERC721ForNativeSwapper(s, uint256(0));
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {
    ERC721ForNativeSwapperDeployer,
    ERC721ForNativeSwapperProposer
} from "./ERC721ForNative/ERC721ForNativeSwapperDeployer.gen.sol";
import {
    ERC721ForERC20SwapperDeployer,
    ERC721ForERC20SwapperProposer
} from "./ERC721ForERC20/ERC721ForERC20SwapperDeployer.gen.sol";
import {
    MultiERC721ForNativeSwapperDeployer,
    MultiERC721ForNativeSwapperProposer
} from "./MultiERC721ForNative/MultiERC721ForNativeSwapperDeployer.gen.sol";
import {
    MultiERC721ForERC20SwapperDeployer,
    MultiERC721ForERC20SwapperProposer
} from "./MultiERC721ForERC20/MultiERC721ForERC20SwapperDeployer.gen.sol";

import {Escrow, IEscrow, ESCROW_MAGIC_NUMBER} from "./Escrow.sol";
import {SwapperDeployerBase} from "./SwapperDeployerBase.sol";

import {Ownable, Ownable2Step} from "@openzeppelin/contracts/access/Ownable2Step.sol";

/// @author Arran Schlosberg (@divergencearran / github.com/arr4n)
contract SWAP2Deployer is
    Ownable2Step,
    ERC721ForNativeSwapperDeployer,
    ERC721ForERC20SwapperDeployer,
    MultiERC721ForNativeSwapperDeployer,
    MultiERC721ForERC20SwapperDeployer
{
    /// @dev Thrown if constructor `Escrow` argument is invalid; either address(0) or fails the magic-number test.
    error InvalidEscrowContract(address);

    /// @notice Escrow contract used in case of failed push payments.
    Escrow public immutable escrow;

    /**
     * @param initialOwner Initial owner of the contract. SHOULD be a multisig as this address can modify platform-fee
     * configuration.
     */
    constructor(address initialOwner, Escrow escrow_, address payable feeRecipient, uint16 feeBasisPoints)
        Ownable(initialOwner)
    {
        address escrowA = address(escrow_);
        if (escrowA == address(0) || escrowA.code.length == 0 || escrow_.isEscrow() != ESCROW_MAGIC_NUMBER) {
            revert InvalidEscrowContract(escrowA);
        }
        escrow = escrow_;

        _setPlatformFee(feeRecipient, feeBasisPoints);
    }

    /// @dev Packs platform-fee configuration into a single word.
    struct PlatformFeeConfig {
        address payable recipient;
        uint16 basisPoints;
    }

    /// @notice Platform-fee configuration.
    PlatformFeeConfig public feeConfig;

    /**
     * @notice Sets the platform fee and recipient.
     * @dev Evert <T>Swap struct includes a maximum fee, above which the swap will revert, making it impossible for this
     * function to front-run a swap unless it's in favour of the parties. In the event of a fee increase, the UI SHOULD
     * warn users and begin computing swapper addresses at the higher maximum fee.
     * @param recipient Address to which platform fees are sent.
     * @param basisPoints One-hundredths of a percentage point of swap consideration to charge as a platform fee.
     */
    function setPlatformFee(address payable recipient, uint16 basisPoints) external onlyOwner {
        _setPlatformFee(recipient, basisPoints);
    }

    function _setPlatformFee(address payable recipient, uint16 basisPoints) private {
        feeConfig = PlatformFeeConfig({recipient: recipient, basisPoints: basisPoints});
        emit PlatformFeeChanged(recipient, basisPoints);
    }

    /**
     * @dev Implements virtual function required by all <T>Deployers.
     * @return Most recent values passed to `setPlatformFee()`.
     */
    function _platformFeeConfig() internal view override returns (address payable, uint16) {
        PlatformFeeConfig memory config = feeConfig;
        return (config.recipient, config.basisPoints);
    }

    /// @inheritdoc SwapperDeployerBase
    function _escrow() internal view override returns (IEscrow) {
        return escrow;
    }
}

abstract contract SWAP2ProposerBase is
    ERC721ForNativeSwapperProposer,
    ERC721ForERC20SwapperProposer,
    MultiERC721ForNativeSwapperProposer,
    MultiERC721ForERC20SwapperProposer
{}

/// @notice A standalone SWAP2 proposer for an immutable deployer address and chain ID.
/// @author Arran Schlosberg (@divergencearran / github.com/arr4n)
contract SWAP2Proposer is SWAP2ProposerBase {
    /// @notice The SWAP2Deployer for which this contract proposes swaps.
    address public immutable deployer;

    /// @notice The chain on which proposed swaps will be executed.
    uint256 public immutable chainId;

    /**
     * @param deployer_ Address of the SWAP2Deployer for which this contract proposes swaps.
     * @param chainId_ Chain on which proposed swaps will be executed.
     */
    constructor(address deployer_, uint256 chainId_) {
        deployer = deployer_;
        chainId = chainId_;
    }

    /// @dev The immutable `deployer` is the swapper deployer for all types.
    function _swapperDeployer() internal view override returns (address, uint256) {
        return (deployer, chainId);
    }
}

/// @notice A combined SWAP2{Deployer,Proposer}.
/// @author Arran Schlosberg (@divergencearran / github.com/arr4n)
contract SWAP2 is SWAP2Deployer, SWAP2ProposerBase {
    constructor(address initialOwner, Escrow escrow_, address payable feeRecipient, uint16 feeBasisPoints)
        SWAP2Deployer(initialOwner, escrow_, feeRecipient, feeBasisPoints)
    {}

    /// @dev The current contract is the swapper deployer for all types.
    function _swapperDeployer() internal view override returns (address, uint256) {
        return (address(this), _currentChainId());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {Parties, PayableParties} from "./TypesAndConstants.sol";

/**
 * @dev Base contract for all <T>Swapper implementations. As implementations are created by simple text substitution
 * from templates, they require function overloading based on <T>Swap struct fields; this contract enables such
 * behaviour, greatly simplifying code generation.
 * @author Arran Schlosberg (@divergencearran / github.com/arr4n)
 */
contract SwapperBase {
    /// @dev Converts a `PayableParties` struct into a `Parties`, using the same backing memory.
    function _asNonPayableParties(PayableParties memory pay) internal pure returns (Parties memory nonPay) {
        assembly ("memory-safe") {
            nonPay := pay
        }
    }

    /// @dev Echoes its argument unchanged.
    function _asNonPayableParties(Parties memory p) internal pure returns (Parties memory) {
        return p;
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

import {IEscrow} from "./Escrow.sol";
import {currentChainId} from "./TypesAndConstants.sol";

interface ISwapperDeployerEvents {
    /// @dev SHOULD be emitted when the values to be returned by `_platformFeeConfig()` change.
    event PlatformFeeChanged(address indexed recipient, uint16 basisPoints);
}

/// @dev Abstract base contract for all <T>SwapperDeployer implementations.
abstract contract SwapperDeployerBase is ISwapperDeployerEvents {
    /**
     * @return recipient Address to which platform fees MUST be sent by swapper contracts.
     * @return basisPoints One-hundredths of a percentage point of swap consideration that MUST be sent to `recipient`.
     */
    function _platformFeeConfig() internal view virtual returns (address payable recipient, uint16 basisPoints);

    /**
     * @return Address of an IEscrow contract, for possible use when native-token `cancel()` fails to reimburse the
     * buyer.
     */
    function _escrow() internal view virtual returns (IEscrow);

    /// @return The current chain ID.
    function _currentChainId() internal view returns (uint256) {
        return currentChainId();
    }
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Lomita Digital, Inc.
pragma solidity 0.8.25;

/// @dev Abstract base contract for all <T>SwapperProposer implementations.
abstract contract SwapperProposerBase {
    /// @dev Returns the address and chain ID of the factory contract that deploys swappers, regardless of swap type.
    function _swapperDeployer() internal view virtual returns (address, uint256 chainId);
}

// SPDX-License-Identifier: MIT
// Copyright 2024 Divergence Tech Ltd.
pragma solidity ^0.8.24;

import {IEscrow} from "./Escrow.sol";
import {Message} from "./ET.sol";

/**
 * ===================
 *
 * <T>Swap field types
 *
 * Also see ConsiderationLib.sol and ERC721TransferLib.sol.
 *
 * ===================
 */

/// @dev Parties involved in a swap. The `buyer` pays `Consideration` that the `seller` (partly) receives.
struct Parties {
    address seller;
    address buyer;
}

/// @dev Substitute for `Parties` when `Consideration` is denoted in the chain's native token.
struct PayableParties {
    address payable seller;
    address payable buyer;
}

/**
 * ======
 *
 * Events
 *
 * ======
 */

/// @dev Events emitted by <T>SwapperDeployer contracts.
interface ISwapperEvents {
    event Filled(address swapper);
    event Cancelled(address swapper);
}

/**
 * =======
 *
 * Actions
 *
 * =======
 */

/**
 * @dev Denotes an action that a swapper contract must perform.
 * @dev Swapper contracts "phone home" to their deployer, receiving a single-word `Message`. An `Action` is analogous
 * to a function selector in said `Message`, with the remaining bytes being analogous to call data.
 */
type Action is bytes4;

/// @dev Indicates that the user requested that the swap be performed.
Action constant FILL = Action.wrap(bytes4(keccak256("FILL")));

/// @dev Indicates that the user requested that the swap be cancelled.
Action constant CANCEL = Action.wrap(bytes4(keccak256("CANCEL")));

/// @dev A precomputed `Message` with the cancellation `Action` as it has no arguments.
Message constant CANCEL_MSG = Message.wrap(bytes32(Action.unwrap(CANCEL)));

/// @dev Converts between `Action` and `Message` types.
library ActionMessageLib {
    /// @dev Appends the `FILL` action with platform-fee configuration. See `SwapperDeployerBase` re params.
    function fillWithFeeConfig(address feeRecipient, uint16 basisPoints) internal pure returns (Message) {
        return Message.wrap(bytes32(abi.encodePacked(FILL, feeRecipient, basisPoints)));
    }

    /// @dev Appends the `CANCEL` action with the address of an `IEscrow` contract.
    function cancelWithEscrow(IEscrow escrow_) internal pure returns (Message) {
        return Message.wrap(bytes32(abi.encodePacked(CANCEL, escrow_)));
    }

    /// @dev Extracts the `Action` from the `Message`, assuming that it is the prefix.
    function action(Message m) internal pure returns (Action) {
        return Action.wrap(bytes4(Message.unwrap(m)));
    }

    /// @dev Inverse of `fillWithFeeConfig()`.
    function feeConfig(Message m) internal pure returns (address payable feeRecipient, uint16 basisPoints) {
        assert(action(m) == FILL);
        uint256 u = uint256(Message.unwrap(m));
        feeRecipient = payable(address(bytes20(bytes28(uint224(u)))));
        basisPoints = uint16(bytes2(bytes8(uint64(u))));
    }

    /// @dev Inverse of `cancelWithEscrow()`.
    function escrow(Message m) internal pure returns (IEscrow) {
        assert(action(m) == CANCEL);
        return IEscrow(address(bytes20(bytes28(uint224(uint256(Message.unwrap(m)))))));
    }
}

/**
 * @dev Equality check for two Actions, used globally as ==.
 */
function _eq(Action a, Action b) pure returns (bool) {
    return Action.unwrap(a) == Action.unwrap(b);
}

using {_eq as ==} for Action global;

/**
 * ===========================
 *
 * Deployed contract artifacts
 *
 * To minimise gas, swapper contracts deploy minimal footprints of only 3 bytes (600 gas). Although single-byte
 * artifacts are possible, cleanly reverting contracts are desirable (see below). As such, all artifacts are equivalent
 * to `revert(0,0)` but differ in their approach so their codehashes can be used as a record of the `Action` taken.
 *
 * One use case of native-token consideration is to allow for prepayment of consideration into the predicted swapper
 * address. Reverting contracts avoid accidental locking of funds should there be (a) a race condition between buyer
 * prepayment and seller cancellation; or (b) buyer's accidentally reusing a swapper address from a previous trade.
 *
 * ===========================
 */

/// @dev Contract code to deploy when the fill() function is called; simply `revert(0,0)`.
bytes3 constant FILLED_ARTIFACT = 0x5f5ffd; // PUSH0 PUSH0 REVERT

/// @dev Codehash of a swapper artifact denoting that the swap was filled.
bytes32 constant FILLED_CODEHASH = keccak256(abi.encodePacked(uint24(FILLED_ARTIFACT)));

/// @dev Contract code to deploy when the cancel() function is called; functionally equivalent to `FILLED_ARTIFACT`.
bytes3 constant CANCELLED_ARTIFACT = 0x585ffd; // PC(0) PUSH0 REVERT

/// @dev Codehash of a swapper artifact denoting that the swap was cancelled.
bytes32 constant CANCELLED_CODEHASH = keccak256(abi.encodePacked(uint24(CANCELLED_ARTIFACT)));

/// @dev Codehash denoting that a (presumed) swapper is yet to be deployed.
bytes32 constant PENDING_CODEHASH = keccak256("");

/// @dev Status of a swapper contract, determined from an account's codehash.
enum SwapStatus {
    Pending,
    Filled,
    Cancelled,
    Invalid
}

/**
 * @dev Determines the `SwapStatus` of a swapper.
 * @param swapper Predicted or existing address of a swapper contract. MUST be a valid swapper address otherwise the
 * returned value is invalid.
 */
function swapStatus(address swapper) view returns (SwapStatus) {
    bytes32 h = swapper.codehash;
    // EIP-1052 differentiates between non-existent and existent-but-codeless accounts. Any prepayment of ETH to the
    // swapper will move it from former to latter and change the value returned by EXTCODEHASH.
    if (h == 0 || h == PENDING_CODEHASH) {
        return SwapStatus.Pending;
    }
    if (h == FILLED_CODEHASH) {
        return SwapStatus.Filled;
    }
    if (h == CANCELLED_CODEHASH) {
        return SwapStatus.Cancelled;
    }
    return SwapStatus.Invalid;
}

// The current chain ID is effectively a constant so it belongs in this file.

/// @return id The current chain ID.
function currentChainId() view returns (uint256 id) {
    assembly ("memory-safe") {
        id := chainid()
    }
}

/**
 * ======
 *
 * Errors
 *
 * ======
 */

/// @dev Thrown if an address other than the selling or buying party attempts to cancel a swap.
error OnlyPartyCanCancel();

/// @dev Thrown if phoning home returns an unsupported action. NOTE: if this happens there is a bug.
error UnsupportedAction(Action);

/// @dev Thrown by native-token swappers if the contract balance is less than `Consideration.total`.
error InsufficientBalance(uint256 actual, uint256 expected);

/// @dev Thrown if the platform fee is greater than the threshold in the swap struct.
error ExcessPlatformFee(uint256 fee, uint256 max);

/// @dev Thrown if the Swap's `validUntilTime` field is non-zero and before the current `block.timestamp`.
error SwapExpired(uint256 validUntilTime);

{
  "compilationTarget": {
    "src/SWAP2.sol": "SWAP2"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/"
  ],
  "viaIR": true
}