// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: Unlicensed

pragma solidity 0.8.2;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

interface ITGC {
   function lockedAmount(address account) external view returns (uint256);
   function lockToken(uint256 amount, address user) external;
   function unlockToken(uint256 amount, address user) external;
   function unlockSend(uint256 amount, address user) external;
}

contract TGCStaking {
    using SafeERC20 for IERC20;
	
	address public immutable TGC;
	
	struct UserInfo {
	  uint256 amount; 
	  uint256 rewardDebt;
	  uint256 startTime;
	  uint256 claimed;
	  uint256 lockClaimed;
	  uint256 locked;
	  uint256 pendingToClaimed;
    }
	
	struct UserInfoLock {
	  uint256 amount; 
	  uint256 startTime;
	  uint256 endTime;
	  uint256 rewardDebt;
    }
	
	struct HighestAstaStaker {
       uint256 deposited;
       address addr;
    }
	
	uint256 public totalStaked;
	uint256 public totalLocked;
	uint256 public totalStaker;
	uint256 public accTokenPerShare;
	uint256 public accTokenPerShareLock;
	uint256 public accTokenPerShareLastTxn;
	uint256 public harvestFee;
	uint256 public lockFee;
	uint256 public precisionFactor;
	
	uint256 public immutable minStakingToken;
	uint256 public immutable topStakerNumber;
	
	mapping(address => UserInfo) public mapUserInfo;
	mapping(address => mapping(uint256 => UserInfoLock)) public mapUserInfoLock;
    mapping(uint256 => HighestAstaStaker[]) public highestStakerInPool;
	mapping(address => uint256) public lockCount;
	
    event MigrateTokens(address tokenRecovered, address receiver, uint256 amount);
    event Deposit(address user, uint256 amount);
    event Withdraw(address user, uint256 amount);
	event NewUnlockFeeUpdated(uint256 newFee);
	event PoolUpdated(uint256 amount);	
	event Lock(uint256 amount, uint256 period);	
	
    constructor () {
	   harvestFee = 100;
	   lockFee = 3000;
	   topStakerNumber = 100;
	   minStakingToken = 1 * 10**18;
	   precisionFactor = 10**18;
	   TGC = address(0x5c7AD3EB8264eF91dD4d756Ef9759F7aa86744e7);
    }
	
	function deposit(uint256 amount) external {
		require(IERC20(TGC).balanceOf(msg.sender) - ITGC(TGC).lockedAmount(msg.sender) >= amount, "balance not available for staking");
		require(amount >= minStakingToken, "amount is less than minimum staking amount");
		
		if(mapUserInfo[msg.sender].amount > 0) 
		{
            uint256 pending = pendingReward(msg.sender);
            if(pending > 0) 
			{
			   mapUserInfo[msg.sender].pendingToClaimed += pending;
            }
        }
		
		if(mapUserInfo[msg.sender].amount == 0) {
		   totalStaker++;
		}
		
		mapUserInfo[msg.sender].amount += amount;
		mapUserInfo[msg.sender].startTime = block.timestamp;
		mapUserInfo[msg.sender].rewardDebt = (mapUserInfo[msg.sender].amount * accTokenPerShare) / (precisionFactor);
		
		totalStaked += amount;
		ITGC(TGC).lockToken(amount, msg.sender);
		addHighestStakedUser(mapUserInfo[msg.sender].amount, msg.sender);
        emit Deposit(msg.sender, amount);
    }
	
	function lock(uint256 amount, uint256 period) external {
		require(mapUserInfo[msg.sender].amount - mapUserInfo[msg.sender].locked >= amount, "amount is greater than available");
		require(period >= 90 days, "min 90 day locking is required");
		require(period <= 3650 days, "max locking period is 10 years");
		
		lockCount[msg.sender] += 1;
		mapUserInfo[msg.sender].locked += amount;
		totalLocked += amount;
		
		mapUserInfoLock[msg.sender][lockCount[msg.sender]].amount = amount;
		mapUserInfoLock[msg.sender][lockCount[msg.sender]].startTime = block.timestamp;
		mapUserInfoLock[msg.sender][lockCount[msg.sender]].endTime = block.timestamp + period;
		mapUserInfoLock[msg.sender][lockCount[msg.sender]].rewardDebt = (amount * accTokenPerShareLock) / (precisionFactor);
		
        emit Lock(amount, period);
    }
	
	function unlock(uint256[] calldata lockID) external {
		for(uint i=0; i < lockID.length; i++)
		{
		   if(mapUserInfoLock[msg.sender][lockID[i]].amount > 0)
		   {
		       uint256 pending = pendingRewardLock(msg.sender, lockID[i]);
			   if(pending > 0)
			   {
				   uint256 burnAmount;
				   uint256 period = mapUserInfoLock[msg.sender][lockID[i]].endTime - mapUserInfoLock[msg.sender][lockID[i]].startTime;
				   
				   if(period >= 9 * 365 days)
				   {
				       burnAmount = 0;
				   }
				   else if(period >= 8 * 365 days)
				   {
				       burnAmount = pending * 5 / 100;
				   }
				   else if(period >= 7 * 365 days)
				   {
				       burnAmount = pending * 10 / 100;
				   }
				   else if(period >= 6 * 365 days)
				   {
				       burnAmount = pending * 15 / 100;
				   }
				   else if(period >= 5 * 365 days)
				   {
				       burnAmount = pending * 20 / 100;
				   }
				   else if(period >= 4 * 365 days)
				   {
				       burnAmount = pending * 25 / 100;
				   }
				   else if(period >= 3 * 365 days)
				   {
				       burnAmount = pending * 30 / 100;
				   }
				   else if(period >= 2 * 365 days)
				   {
				       burnAmount = pending * 35 / 100;
				   }
				   else if(period >= 365 days)
				   {
				       burnAmount = pending * 40 / 100;
				   }
				   else
				   {
				       burnAmount = pending * 45 / 100;
				   }
				   
				   if(burnAmount > 0)
				   {
				       mapUserInfo[msg.sender].lockClaimed += pending - burnAmount;
				       IERC20(TGC).safeTransfer(address(0x000000000000000000000000000000000000dEaD), burnAmount);
				       IERC20(TGC).safeTransfer(address(msg.sender), pending - burnAmount);
				   }
				   else
				   {
				       mapUserInfo[msg.sender].lockClaimed += pending;
				       IERC20(TGC).safeTransfer(address(msg.sender), pending);
				   }
			   }
			   
			   totalLocked -= mapUserInfoLock[msg.sender][lockID[i]].amount;
			   mapUserInfo[msg.sender].locked -= mapUserInfoLock[msg.sender][lockID[i]].amount;
			   
			   if(mapUserInfoLock[msg.sender][lockID[i]].endTime > block.timestamp) 
			   {
				  uint256 fee = mapUserInfoLock[msg.sender][lockID[i]].amount * lockFee / 10000;
				  ITGC(TGC).unlockSend(fee, msg.sender);
				  _updatePoolLock(fee);
				  
				  uint256 pendingR = pendingReward(msg.sender);
				  if(pendingR > 0)  
				  {
					  mapUserInfo[msg.sender].pendingToClaimed += pendingR;
				  }
				  
				  totalStaked -= fee;
				  mapUserInfo[msg.sender].startTime = block.timestamp;
				  mapUserInfo[msg.sender].amount -= fee;
				  mapUserInfo[msg.sender].rewardDebt = (mapUserInfo[msg.sender].amount * accTokenPerShare) / (precisionFactor);
			   }
			   
			   mapUserInfoLock[msg.sender][lockID[i]].amount = 0;
			   mapUserInfoLock[msg.sender][lockID[i]].startTime = 0;
			   mapUserInfoLock[msg.sender][lockID[i]].endTime = 0;
			   mapUserInfoLock[msg.sender][lockID[i]].rewardDebt = 0;
		   }
		}
    }
	
	function withdrawReward() external {
		if(mapUserInfo[msg.sender].amount > 0) 
		{
            uint256 pending = pendingReward(msg.sender);
			        pending += mapUserInfo[msg.sender].pendingToClaimed; 
			if (pending > 0) 
			{
                IERC20(TGC).safeTransfer(address(msg.sender), pending);
				
			    mapUserInfo[msg.sender].rewardDebt = (mapUserInfo[msg.sender].amount * accTokenPerShare) / (precisionFactor);
				mapUserInfo[msg.sender].claimed += pending;
				mapUserInfo[msg.sender].pendingToClaimed = 0;
			    emit Withdraw(msg.sender, pending);
            }
        } 
    }
	
	function withdrawRewardLock(uint256[] calldata lockID) external {
		for(uint i=0; i < lockID.length; i++)
		{
		   if(mapUserInfoLock[msg.sender][lockID[i]].amount > 0)
		   {
		       uint256 pending = pendingRewardLock(msg.sender, lockID[i]);
			   if(pending > 0)
			   {
			       mapUserInfoLock[msg.sender][lockID[i]].rewardDebt += pending;
				   uint256 period = mapUserInfoLock[msg.sender][lockID[i]].endTime - mapUserInfoLock[msg.sender][lockID[i]].startTime;
				   uint256 burnAmount;
				   
				   if(period >= 9 * 365 days)
				   {
				       burnAmount = 0;
				   }
				   else if(period >= 8 * 365 days)
				   {
				       burnAmount = pending * 5 / 100;
				   }
				   else if(period >= 7 * 365 days)
				   {
				       burnAmount = pending * 10 / 100;
				   }
				   else if(period >= 6 * 365 days)
				   {
				       burnAmount = pending * 15 / 100;
				   }
				   else if(period >= 5 * 365 days)
				   {
				       burnAmount = pending * 20 / 100;
				   }
				   else if(period >= 4 * 365 days)
				   {
				       burnAmount = pending * 25 / 100;
				   }
				   else if(period >= 3 * 365 days)
				   {
				       burnAmount = pending * 30 / 100;
				   }
				   else if(period >= 2 * 365 days)
				   {
				       burnAmount = pending * 35 / 100;
				   }
				   else if(period >= 365 days)
				   {
				       burnAmount = pending * 40 / 100;
				   }
				   else
				   {
				       burnAmount = pending * 45 / 100;
				   }
				   
				   if(burnAmount > 0)
				   {
				       mapUserInfo[msg.sender].lockClaimed += pending - burnAmount;
				       IERC20(TGC).safeTransfer(address(0x000000000000000000000000000000000000dEaD), burnAmount);
				       IERC20(TGC).safeTransfer(address(msg.sender), pending - burnAmount);
				   }
				   else
				   {
				       mapUserInfo[msg.sender].lockClaimed += pending;
				       IERC20(TGC).safeTransfer(address(msg.sender), pending);
				   }
				   emit Withdraw(msg.sender, pending);
			   }
            }
		}	
    }
	
	function withdraw(uint256 amount) external {
	    require(mapUserInfo[msg.sender].amount - mapUserInfo[msg.sender].locked >= amount, "amount is greater than available");
		
		if(mapUserInfo[msg.sender].amount > amount)
		{
			uint256 pending = pendingReward(msg.sender);
					pending += mapUserInfo[msg.sender].pendingToClaimed; 
			if(pending > 0)
			{
			   IERC20(TGC).safeTransfer(address(msg.sender), pending);
			}
			totalStaked -= amount;
			
			removeHighestStakedUser(msg.sender);
		
			mapUserInfo[msg.sender].startTime = block.timestamp;
			mapUserInfo[msg.sender].amount -= amount;
			mapUserInfo[msg.sender].rewardDebt = (mapUserInfo[msg.sender].amount * accTokenPerShare) / (precisionFactor);
			mapUserInfo[msg.sender].claimed += pending;
			mapUserInfo[msg.sender].pendingToClaimed = 0;
			
			uint256 fee = amount * harvestFee / 10000;
		    ITGC(TGC).unlockSend(fee, msg.sender);
			ITGC(TGC).unlockToken(amount - fee, msg.sender);
			_updatePool(fee);
			
			addHighestStakedUser(mapUserInfo[msg.sender].amount, msg.sender);
			emit Withdraw(msg.sender, pending + amount);
		}
		else
		{
			uint256 pending = pendingReward(msg.sender);
					pending += mapUserInfo[msg.sender].pendingToClaimed; 
			if(pending > 0)
			{
			   IERC20(TGC).safeTransfer(address(msg.sender), pending);
			}
			totalStaked -= amount;
			
			uint256 fee = amount * harvestFee / 10000;
		    ITGC(TGC).unlockSend(fee, msg.sender);
			ITGC(TGC).unlockToken(amount - fee, msg.sender);
			_updatePool(fee);
			totalStaker--;
			
			removeHighestStakedUser(msg.sender);
			
			mapUserInfo[msg.sender].startTime = 0;
			mapUserInfo[msg.sender].amount = 0;
			mapUserInfo[msg.sender].rewardDebt = 0;
			mapUserInfo[msg.sender].claimed += pending;
			mapUserInfo[msg.sender].pendingToClaimed = 0;
			emit Withdraw(msg.sender, pending + amount);
		}
         
    }
	
	function _updatePoolLock(uint256 amount) internal {
	    if(totalLocked > 0) 
		{
		    accTokenPerShareLock = accTokenPerShareLock + (amount * precisionFactor) / totalLocked;
		}
		emit PoolUpdated(amount);
    }
	
	function _updatePool(uint256 amount) internal {
		if(totalStaked > 0) 
		{
			accTokenPerShare = accTokenPerShare + (amount * precisionFactor) / totalStaked;
			accTokenPerShareLastTxn = amount;
		}
		emit PoolUpdated(amount);
    }
	
	function updatePool(uint256 amount) external {
	   require(msg.sender == address(TGC), "sender not allowed");
	   _updatePool(amount);
    }
	
	function pendingReward(address user) public view returns (uint256) {
		if(mapUserInfo[user].amount > 0) 
		{
            uint256 pending = (mapUserInfo[user].amount * accTokenPerShare) / (precisionFactor) - mapUserInfo[user].rewardDebt;
			return pending;
        } 
		else 
		{
		   return 0;
		}
    }
	
	function pendingRewardLock(address user, uint256 id) public view returns (uint256) {
		if(mapUserInfoLock[user][id].amount > 0)
		{
		    uint256 pending = (mapUserInfoLock[user][id].amount * accTokenPerShareLock) / (precisionFactor) - mapUserInfoLock[user][id].rewardDebt;
			return pending;
		}
		else
		{
		   return 0;
		}
    }
	
	function quickSort(uint256 pid, uint256 left, uint256 right) internal {
        HighestAstaStaker[] storage arr = highestStakerInPool[pid];
        if (left >= right) return;
        uint256 divtwo = 2;
        uint256 p = arr[(left + right) / divtwo].deposited;
        uint256 i = left;
        uint256 j = right;
        while (i < j) 
		{
			while (arr[i].deposited < p) ++i;
			while (arr[j].deposited > p) --j;
			if (arr[i].deposited > arr[j].deposited) {
				(arr[i].deposited, arr[j].deposited) = (
				   arr[j].deposited,
				   arr[i].deposited
				);
			   (arr[i].addr, arr[j].addr) = (arr[j].addr, arr[i].addr);
			} else ++i;
        }
        if (j > left) quickSort(pid, left, j - 1);
        quickSort(pid, j + 1, right);
    }
	
	function addHighestStakedUser(uint256 amount, address user) private {
        uint256 i;
        HighestAstaStaker[] storage highestStaker = highestStakerInPool[0];
        for (i = 0; i < highestStaker.length; i++) {
			if (highestStaker[i].addr == user) {
			    highestStaker[i].deposited = amount;
			    quickSort(0, 0, highestStaker.length - 1);
				return;
			}
        }
		
        if(highestStaker.length < topStakerNumber)
		{
            highestStaker.push(HighestAstaStaker(amount, user));
            quickSort(0, 0, highestStaker.length - 1);
        } 
		else 
		{
            if (highestStaker[0].deposited < amount) 
			{
                highestStaker[0].deposited = amount;
                highestStaker[0].addr = user;
                quickSort(0, 0, highestStaker.length - 1);
            }
        }
    }
	
	function removeHighestStakedUser(address user) private {
        HighestAstaStaker[] storage highestStaker = highestStakerInPool[0];
        for (uint256 i = 0; i < highestStaker.length; i++) {
            if (highestStaker[i].addr == user) {
                delete highestStaker[i];
                return;
            }
        }
    }
	
	function checkHighestStaker(address user) external view returns (bool){
        HighestAstaStaker[] storage highestStaker = highestStakerInPool[0];
        uint256 i = 0;
        for (i; i < highestStaker.length; i++) {
            if (highestStaker[i].addr == user) {
                return true;
            }
        }
		return false;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "compilationTarget": {
    "contracts/TGCStaking.sol": "TGCStaking"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}